letzter Lauf einer Batch über Datum prüfen

firewalldevil

Hallo,

ich möchte den Lauf einer Batch über das Datum prüfen.

Ich starte heute das erste mal die Batch, also Tag merken, wenn der PC zb in 5 Tagen wieder gestartet wird soll nichts passieren, aber wenn z.b 7 vergangen sind nach dem letzten Lauf der Batch, dann soll die Batch aufgerufen werden.
Beim ersten Aufrufen soll abgefragt werden in viel Tagen die Prüfung laufen soll.

Das script soll ein Backup anstoßen, wenn das über ein Task läuft kann ich nicht sicherstellen, das min alle 7 Tage gesichert wird.

Gruß

**Raupi**

Also die Beschreibung deines Scriptes haben wir. Was ist(sind) nun deine Frage(n)? Willst du nur eien Denkanstoß? Hast du schon angefangen? Wenn ja wo ist der Code?
Oder möchtest du das man es für dich schreibt?

Fragen über Fragen.

firewalldevil

ähhm... sorry...

Denkanstoß wäre gut.. aber ein Vorschlag eines Script wäre super, ich weiß nicht wie man das Datum als feste Variable schreib, da der Computer evtl ausgeschaltet wird und nach dem Einschalten ja wieder pürfen muss wieviel Tage sind vergangen nach dem letzten Start, größer 7 Tage dann starte Batch...

Gummibaer

firewalldevil

Zeige mal was du hast denkanstoß habe ich schon gegeben.

[autoit]

$iDateCalc = _DateDiff( 'D',$timecheck,_NowCalc())
if $iDateCalc > 7 Then
$timecheck = _NowCalc()
run ... batch oder was auch immer
endif

[/autoit]

$timecheck <-- beinhaltet dann immer die letzte zeit
solltest du in einer ini oder so speichern und beim start auch einlesen
und vor dem run dann auch wieder speichern

schau mal in die Hilfe
IniRead
und IniWirte

[autoit]

IniWrite ( "filename", "section", "key", "value" )
IniRead ( "filename", "section", "key", "default" )

[/autoit]

**BugFix**

Hier mal ein Lösungsvorschlag:

Spoiler anzeigen

[autoit]

#Include <Date.au3>
Local $INI = @ScriptDir & '\backupRun.ini', $intervall
Local $Batch = 'Pfad der Batch'
If Not FileExists($INI) Then
Do
$intervall = InputBox('Backup-Intervall', 'Bitte Sicherungsintervall angeben (Tage)', 7)
Until $intervall <> ''
IniWrite($INI, 'backup', 'intervall', $intervall)
IniWrite($INI, 'backup', 'last', '2000/01/01')
EndIf
$intervall = IniRead($INI, 'backup', 'intervall', 7)

[/autoit] [autoit][/autoit] [autoit]

If _DateDiff('D', IniRead($INI, 'backup', 'last', '2000/01/01'), _NowCalcDate()) < $intervall Then
Exit MsgBox(0, 'Abbruch', 'Neue Sicherung noch nicht erforderlich.')
EndIf

[/autoit] [autoit][/autoit] [autoit]

If MsgBox(262180,"Start Batch","Soll die Batchdatei jetzt gestartet werden?") = 7 Then
Exit MsgBox(0, 'Abbruch', 'Verarbeitung abgebrochen!')
EndIf

[/autoit] [autoit][/autoit] [autoit]

IniWrite($INI, 'backup', 'last', _NowCalcDate())
ShellExecuteWait($Batch) ; <== evtl. WorkingDir mit angeben
MsgBox(0, 'Fertig', 'Batchverarbeitung abgeschlossen.')

[/autoit]

firewalldevil

tja jetzt läßt der Frosch die Locken....

theorie und praxis.....

ich kann es nicht als script schreiben....

also erster run setze datum, zweiter run prüfe datum wenn da, dann nicht ernuet setzen, wenn datum älter 7 tage dann run batch...

aber ich weiß nicht wie ich es ins script bekomme...

Gummibaer

Mein vorschlag Trayicon noch ausblenden und das prog läuft im hintergrund
und alle 7 tage wird ein backup ausgeführt ( bzw deine bat )

Spoiler anzeigen

[autoit]

#include <Date.au3>
Global $timecheck = IniRead ( "settings.ini", "Lastupdate", "Date" ,"")
Global $Intervall = 7 ; tages intervall
while 1
$iDateCalc = _DateDiff( 'D',$timecheck,_NowCalc())
if $iDateCalc > $Intervall or $timecheck = "" Then
$timecheck = _NowCalc()
IniWrite ( "settings.ini", "Lastupdate", "Date", $timecheck )
run("ftpbackup.exe") ; anpassen auf dein prog alternative ShellExecuteWait("deine.bat")
endif
Sleep(10000) ; 10 sekunden schlafen
WEnd

[/autoit]

**BugFix**

Zitat von firewalldevil

aber ich weiß nicht wie ich es ins script bekomme...

Hast du dir mal mein Bsp. angeschaut? Das tut genau dieses.

**Raupi**

@firewalldevil:Ähm, hast du dir mal das Script von BugFix angesehen? Ich find es passend und ausbaufähig. Ich denke, jetzt ist mal ein wenig Initiative von dir gefragt.
Wenn nicht, solltest du es eher in die Jobbörse posten.

firewalldevil

hat sich wohl überschnitten, lese grade das Posting... werde es testen

melde micht sonst

Danke

firewalldevil

BugFix ...

PERFEKT, danke

Der erste Lauf ist super, den zweiten werden ich so einstellen das nur gepürft wird und keine Meldung, diese wird nur angezeigt, wenn es notwendig ist.

SUPER, vielen Dank @all