_GUICtrlListView_FormattingCell() "funktioniert nicht"

1. offizieller Beitrag

    Hallo,

    ich möchte in einem ListView einem Element per Rechtsklick die Hintergrundfarbe ändern.

    Spoiler anzeigen
    [autoit]

    Func _RightClickOnListView($hWnd, $Msg, $wParam, $lParam) ;Rechtsklick auf ein ListViewItem
    Local $tNMHDR, $event, $hwndFrom, $code, $ItemText = "" , $hItem, $hSubItem
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hwndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    Switch $hwndFrom
    Case $aHWnd[0], $aHWnd[1]
    $event = DllStructGetData($tNMHDR, "Code")
    If $event = $NM_RCLICK Then
    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
    $hItem = DllStructGetData($tInfo, "Index")
    $hSubItem = DllStructGetData($tInfo, "SubItem")
    $ItemText = _GUICtrlListView_GetItemText($hWndFrom, $hItem, $hSubItem)
    If $ItemText <> "" Then
    MsgBox(0,"",$ItemText)
    _GUICtrlListView_FormattingCell($hWndFrom, $hItem, $hSubItem , 0x00FF00) ;, -1, -1, -1, -1)
    EndIf
    EndIf
    EndSwitch
    EndFunc ;==>_RightClickOnListView

    [/autoit]

    Die ListView werden durch GUICtrlCreateListView() erzeugt. Es ist egal, ob ich die Elemente per
    _GUICtrlListView_AddOrIns_Item() oder _GUICtrlListView_AddItem() erzeuge. Ich habe beides probiert.

    Der Rechtsklick funktioniert korrekt, da ich die MsgBox jedes mal (mit entsprechedem Inhalt) angezeigt bekomme. Jedoch wird die Farbe des Elemts nicht geändert. Wo kann mein Fehler liegen?
    Das Forum habe ich schon abgesucht und auch ähnliche Fragestellungen gefunden. Jedoch konnte ich in keinem Beitrag den entscheidenden Hinweis finden, so dass es bei mir funktioniert. :(

    Gruß
    (VX-)Rexx

    Einmal editiert, zuletzt von (VX-)Rexx (8. Dezember 2009 um 14:01)

    • Offizieller Beitrag

    Schau dir das mal an: ListView - SubItem einzeln färben/formatieren, Finale Version!

    • Offizieller Beitrag

    Puuh, du hast da ganz schön was durcheinander gemixt. ;)
    In mei ner Listview-Format UDF ist das ganze WM_Message-Gedöns in ein Include ausgelagert.
    Wenn du damit arbeitest, gehst du ähnlich vor, wie bei GDI+
    - Startup
    - Einträge erstellen
    - Einträge formatieren
    - am Skriptende Shutdown

    Raupi hat den entsprechenden Link geposted. Das dortige Bsp. kannst du für deinen Bedarf anpassen.

    Hallo BugFix, hallo Raupi,

    den angegebenen Link kenne ich - bin ich doch erst über diesen auf die (einzige?) Möglichkeit gestossen, wie ich ein ListView-Element farbig markieren kann. Also erst einmal Danke für dein Arbeit BugFix.
    In allen Beispielen kann ich aber nur sehen, dass ein Änderung eines Elements immer über einen Button erfolgt. Ich brauche aber die Änderung auf einen Mausklick - und da der Klick der rechten Maustaste bei mir für nichts anderes belegt ist, nehme ich halt diesen.

    So habe ich jetzt den Hinweis umgesetzt und im Beispiel
    Example_LV_Format.au3
    meinen Wunsch-Code eingebaut. Das Ergebnis ist aber immer noch genau so wie in meinem Ursprungs-Beitrag.

    Spoiler anzeigen
    [autoit]

    #include <GuiListView.au3>
    #include <WindowsConstants.au3>
    #include 'LV_Format_include.au3'

    [/autoit] [autoit][/autoit] [autoit]

    Local $col = ''
    For $i = 1 To 6
    $col &= $i & '|'
    Next

    [/autoit] [autoit][/autoit] [autoit]

    $GUI = GUICreate('')
    $lv = GUICtrlCreateListView(StringTrimRight($col,1), 10, 10, 300, 150)
    $hLV = GUICtrlGetHandle($lv)
    For $i = 0 To 5
    _GUICtrlListView_SetColumnWidth($hLV, $i, 49)
    Next
    $col = StringTrimRight($col, 2)
    $lv2 = GUICtrlCreateListView(StringTrimRight($col,1), 10, 180, 300, 150)
    $hLV2 = GUICtrlGetHandle($lv2)
    For $i = 0 To 4
    _GUICtrlListView_SetColumnWidth($hLV2, $i, 59)
    Next

    [/autoit] [autoit][/autoit] [autoit]

    ; initialize Global vars
    ; for more than one Listview commit Listview handle as array
    Local $aHWnd[2] = [$hLV,$hLV2]
    _GUICtrlListView_Formatting_Startup($GUI, $aHWnd)
    ;~ _GUICtrlListView_Formatting_Startup($GUI, $hLV)

    [/autoit] [autoit][/autoit] [autoit]

    ; add new Items
    _GUICtrlListView_AddOrIns_Item($hLV, 'Test0|Test1|Test2|Test3|Test4|Test5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Blub0|Blub1|Blub2|Blub3|Blub4|Blub5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Club0|Club1|Club2|Club3|Club4|Club5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Blab0|Blab1|Blab2|Blab3|Blab4|Blab5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Bumm0|Bumm1|Bumm2|Bumm3|Bumm4|Bumm5')
    ; set format
    _GUICtrlListView_FormattingCell($hLV, 0, 2, 0xff0000, -1, -1, 600, 'Times New Roman')
    _GUICtrlListView_FormattingCell($hLV, 1, 4, 0xffff00, -1, -1, 600, 'Comic Sans MS')
    _GUICtrlListView_FormattingCell($hLV, 1, 3, 0xff0000, -1, -1, 600, 'Times New Roman')

    [/autoit] [autoit][/autoit] [autoit]

    ; add new Items
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Test0|Test1|Test2|Test3|Test4')
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Blub0|Blub1|Blub2|Blub3|Blub4')
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Club0|Club1|Club2|Club3|Club4')
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Blab0|Blab1|Blab2|Blab3|Blab4')
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Bumm0|Bumm1|Bumm2|Bumm3|Bumm4')
    ; set format
    _GUICtrlListView_FormattingCell($hLV2, 0, 2, 0xff0000, -1, -1, 600, 'Times New Roman')
    _GUICtrlListView_FormattingCell($hLV2, 1, 4, 0xffff00, -1, -1, 600, 'Comic Sans MS')
    _GUICtrlListView_FormattingCell($hLV2, 1, 3, 0xff0000, -1, -1, 600, 'Times New Roman')

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState(@SW_SHOW, $GUI)

    [/autoit] [autoit][/autoit] [autoit]

    ;################################################################################################
    GUIRegisterMsg($WM_NOTIFY, "_RightClickOnListView")
    ;################################################################################################

    [/autoit] [autoit][/autoit] [autoit]

    Sleep(1000)
    _GUICtrlListView_FormattingCell($hLV, 1, 4) ; set format to default for Item at index 1, column-index 4
    _GUICtrlListView_DefaultsSet(0x00FFFF, 0xFFFFFF, 14, 400, 'Courier') ; change default settings
    Sleep(1000)
    _GUICtrlListView_FormattedDeleteItem($hLV, 1) ; delete Item at index 1
    Sleep(1000)
    _GUICtrlListView_FormattedDeleteAllItems($hLV)
    Sleep(1000)
    _GUICtrlListView_BeginUpdate($hLV)
    _GUICtrlListView_AddOrIns_Item($hLV, 'Test0|Test1|Test2|Test3|Test4|Test5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Blub0|Blub1|Blub2|Blub3|Blub4|Blub5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Club0|Club1|Club2|Club3|Club4|Club5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Blab0|Blab1|Blab2|Blab3|Blab4|Blab5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Bumm0|Bumm1|Bumm2|Bumm3|Bumm4|Bumm5')
    _GUICtrlListView_EndUpdate($hLV)
    _GUICtrlListView_FormattingCell($hLV, 0, 1, 0xff0000, 0x000000, -1, 600, 'Times New Roman')
    _GUICtrlListView_FormattingCell($hLV, 1, 2, 0xffff00, 0x000000, -1, 600, 'Comic Sans MS')
    _GUICtrlListView_FormattingCell($hLV, 2, 3, 0xff0000, 0x000000, -1, 600, 'Times New Roman')
    Sleep(1000)
    _GUICtrlListView_DefaultsSet() ; change default settings to standard

    [/autoit] [autoit][/autoit] [autoit]

    WinSetTitle($GUI, '', 'Now click column header to sort')

    [/autoit] [autoit][/autoit] [autoit]

    Do
    Until GUIGetMsg() = -3
    ; clear ressources
    _GUICtrlListView_Formatting_Shutdown()

    [/autoit] [autoit][/autoit] [autoit]

    ;################################################################################################
    Func _RightClickOnListView($hWnd, $Msg, $wParam, $lParam) ;Rechtsklick auf ein ListViewItem
    Local $tNMHDR, $event, $hwndFrom, $code, $ItemText = "" , $hItem, $hSubItem
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hwndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    Switch $hwndFrom
    Case $aHWnd[0], $aHWnd[1]
    $event = DllStructGetData($tNMHDR, "Code")
    If $event = $NM_RCLICK Then
    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
    $hItem = DllStructGetData($tInfo, "Index")
    $hSubItem = DllStructGetData($tInfo, "SubItem")
    $ItemText = _GUICtrlListView_GetItemText($hWndFrom, $hItem, $hSubItem)
    If $ItemText <> "" Then
    MsgBox(0,"",$ItemText)
    _GUICtrlListView_FormattingCell($hWndFrom, $hItem, $hSubItem , 0x00FF00) ;, -1, -1, -1, -1)
    EndIf
    EndIf
    EndSwitch
    EndFunc ;==>_RightClickOnListView
    ;################################################################################################

    [/autoit]

    Liegt das Problem in GUIRegisterMs()? Also alles, was in der jeweiligen Funktion ( _RightClickOnListView() ) ausgeführt wird, kann nicht auf Funktionen zugreifen, die in einer anderen Funktion ( per GUIRegisterMs() ) definiert sind?

    Gruß
    (VX-)Rexx

    • Offizieller Beitrag
    Zitat von (VX-)Rexx

    Liegt das Problem in GUIRegisterMs()?


    Genau da liegt der Hund begraben. Diese Message wird ja bereits mit _GUICtrlListView_Formatting_Startup() innerhalb des Include verwendet. Wenn du also andere Aktionen in Auswertung von WM_NOTIFY nutzen möchtest, mußt du dies innerhalb des Includes einbauen. Eine andere Möglichkeit das zu Lösen ist in Planung, aber vorläufig noch nicht verfügbar.

    • Offizieller Beitrag

    Ich hab dir mal eine Lösung gebastelt.

    Ersetze als erstes in der "LV_Format_include.au3" die Funktion WM_NOTIFY_LV_FORMAT mit der folgenden Version (Änderungen habe ich kenntlich gemacht):

    Spoiler anzeigen
    [autoit]

    Func WM_NOTIFY_LV_FORMAT($hWnd, $Msg, $wParam, $lParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    For $i = 0 To UBound($aHWnd) -1
    If $hWndFrom = $aHWnd[$i] Then
    Switch $iCode
    Case $LVN_COLUMNCLICK
    Local $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
    __GUICtrlListView_SimpleSort($hWndFrom, $B_DESCENDING, DllStructGetData($tInfo, "SubItem"))
    Case $NM_CUSTOMDRAW
    If Not _GUICtrlListView_GetViewDetails($hWndFrom) Then Return $GUI_RUNDEFMSG
    Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
    Local $iDrawStage, $iItem, $iSubitem, $hDC, $tRect
    $iDrawStage = DllStructGetData($tCustDraw, 'dwDrawStage')
    Switch $iDrawStage
    Case $CDDS_ITEMPREPAINT
    Return $CDRF_NOTIFYSUBITEMDRAW
    Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM)
    $iItem = DllStructGetData($tCustDraw, 'dwItemSpec')
    $iSubitem = DllStructGetData($tCustDraw, 'iSubItem')
    Local $index = __getMarked($hWndFrom, $iItem, $iSubitem)
    If $index = -1 Then
    __DrawDefault($hDC, $tCustDraw)
    Else
    __DrawItemCol($hDC, $tCustDraw, $hWndFrom, $index, $iSubitem)
    EndIf
    Return $CDRF_NEWFONT
    EndSwitch

    [/autoit] [autoit][/autoit] [autoit]

    ; ######## zusätzliche Ereignisse verwalten
    Case $NM_RCLICK
    Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
    Local $aInfo[9] = [True,$hWndFrom, DllStructGetData($tInfo, "Index"), DllStructGetData($tInfo, "SubItem")]
    If $aInfo[2] < 0 Then
    $aInfo[0] = False
    Return $GUI_RUNDEFMSG
    EndIf
    Local $isFormatted = __getMarked($hWndFrom, $aInfo[2], $aInfo[3]) ; bereits formatiert ?
    If $isFormatted = -1 Then
    For $i = 4 To 8
    $aInfo[$i] = -1
    Next
    Else ; bereits gesetzte Formatierung auslesen
    $aInfo[4] = $aIParam[$aInfo[2]][$aInfo[3]+1][0]
    $aInfo[5] = $aIParam[$aInfo[2]][$aInfo[3]+1][1]
    $aInfo[6] = $aIParam[$aInfo[2]][$aInfo[3]+1][2]
    $aInfo[7] = $aIParam[$aInfo[2]][$aInfo[3]+1][3]
    $aInfo[8] = $aIParam[$aInfo[2]][$aInfo[3]+1][4]
    EndIf
    ; $aItemIndex als Globale Variable im Hauptskript deklarieren
    If Not IsDeclared('aItemIndex') Then Global $aItemIndex ; falls nicht deklariert
    $aItemIndex = $aInfo
    ; weitere Verarbeitung erfolgt im Hauptskript
    ; ######## Ende zusätzliche Ereignisse

    [/autoit] [autoit][/autoit] [autoit]

    EndSwitch
    EndIf
    Next
    Return $GUI_RUNDEFMSG
    EndFunc ;==>WM_NOTIFY_LV_FORMAT

    [/autoit]


    Und hier nun das Bsp.-Skript. Per Rechtsklick wird eine Einstell-GUI mit Einstellparametern geöffnet. Wenn die angeklickte Zelle bereits formatiert ist, werden diese Werte in der Einstell-GUI angezeigt.
    Beim Schliessen der Einstell-GUI wird die Formatierung ausgeführt.
    Wichtig:
    Innerhalb der WM_NOTIFY nur die erforderlichen Werte ermitteln und dann schnellstmöglich diese Funktion verlassen. Deshalb hier auch Übergabe der Werte in ein Array, welches per AdlibEnable abgefragt wird.

    Spoiler anzeigen
    [autoit]


    #include <GuiListView.au3>
    #include <EditConstants.au3>
    #include <LV_Format_include.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Local $col = ''
    For $i = 1 To 6
    $col &= $i & '|'
    Next

    [/autoit] [autoit][/autoit] [autoit]

    $GUI = GUICreate('')
    $lv = GUICtrlCreateListView(StringTrimRight($col,1), 10, 10, 300, 150)
    $hLV = GUICtrlGetHandle($lv)
    For $i = 0 To 5
    _GUICtrlListView_SetColumnWidth($hLV, $i, 49)
    Next
    $col = StringTrimRight($col, 2)
    $lv2 = GUICtrlCreateListView(StringTrimRight($col,1), 10, 180, 300, 150)
    $hLV2 = GUICtrlGetHandle($lv2)
    For $i = 0 To 4
    _GUICtrlListView_SetColumnWidth($hLV2, $i, 59)
    Next

    [/autoit] [autoit][/autoit] [autoit]

    ; initialize Global vars
    ; for more than one Listview commit Listview handle as array
    Local $aHWnd[2] = [$hLV,$hLV2]
    _GUICtrlListView_Formatting_Startup($GUI, $aHWnd)

    [/autoit] [autoit][/autoit] [autoit]

    ; add new Items
    _GUICtrlListView_AddOrIns_Item($hLV, 'Test0|Test1|Test2|Test3|Test4|Test5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Blub0|Blub1|Blub2|Blub3|Blub4|Blub5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Club0|Club1|Club2|Club3|Club4|Club5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Blab0|Blab1|Blab2|Blab3|Blab4|Blab5')
    _GUICtrlListView_AddOrIns_Item($hLV, 'Bumm0|Bumm1|Bumm2|Bumm3|Bumm4|Bumm5')
    ; set format
    _GUICtrlListView_FormattingCell($hLV, 0, 2, 0xff0000, -1, -1, 600, 'Times New Roman')
    _GUICtrlListView_FormattingCell($hLV, 1, 4, 0xffff00, -1, -1, 600, 'Comic Sans MS')
    _GUICtrlListView_FormattingCell($hLV, 1, 3, 0xff0000, -1, -1, 600, 'Times New Roman')

    [/autoit] [autoit][/autoit] [autoit]

    ; add new Items
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Test0|Test1|Test2|Test3|Test4')
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Blub0|Blub1|Blub2|Blub3|Blub4')
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Club0|Club1|Club2|Club3|Club4')
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Blab0|Blab1|Blab2|Blab3|Blab4')
    _GUICtrlListView_AddOrIns_Item($hLV2, 'Bumm0|Bumm1|Bumm2|Bumm3|Bumm4')
    ; set format
    _GUICtrlListView_FormattingCell($hLV2, 0, 2, 0xff0000, -1, -1, 600, 'Times New Roman')
    _GUICtrlListView_FormattingCell($hLV2, 1, 4, 0xffff00, -1, -1, 600, 'Comic Sans MS')
    _GUICtrlListView_FormattingCell($hLV2, 1, 3, 0xff0000, -1, -1, 600, 'Times New Roman')

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState(@SW_SHOW, $GUI)

    [/autoit] [autoit][/autoit] [autoit]

    Global $aItemIndex ; wird als Array in WM_NOTIFY befüllt bei Rechtsklick

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateLabel('Mit Rechtsklick auf ein einzelnes Element' & @LF & 'wird Formatierungs-GUI geladen', 10, 350, 300, 40)
    $GUI_Format = GUICreate('Formatierung setzen', 200, 180)
    GUICtrlCreateLabel(' Control | Index Zeile | Spalte', 10, 10, 180, 17)
    $ctrl = GUICtrlCreateInput('', 10, 30, 85, 20, $ES_READONLY)
    $zeile = GUICtrlCreateInput('', 100, 30, 30, 20, BitOR($ES_READONLY,$ES_RIGHT))
    $spalte = GUICtrlCreateInput('', 135, 30, 30, 20, BitOR($ES_READONLY,$ES_RIGHT))
    GUICtrlCreateLabel(' BkColor | TextColor | Size', 10, 70, 180, 17)
    $inBkCol = GUICtrlCreateInput('-1', 10, 90, 55, 20, $ES_RIGHT)
    $inTxtCol = GUICtrlCreateInput('-1', 75, 90, 55, 20, $ES_RIGHT)
    $inSize = GUICtrlCreateInput('-1', 140, 90, 50, 20, $ES_RIGHT)
    GUICtrlCreateLabel(' Weight | Font', 10, 130, 150, 17)
    $inWeight = GUICtrlCreateInput('-1', 10, 150, 50, 20, $ES_RIGHT)
    $inFont = GUICtrlCreateInput('-1', 75, 150, 115, 20, $ES_RIGHT)

    [/autoit] [autoit][/autoit] [autoit]

    AdlibEnable('_isRightClick')

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $msg = GUIGetMsg(1)
    Switch $msg[1]
    Case $GUI
    If $msg[0] = -3 Then ExitLoop
    Case $GUI_Format
    If $msg[0] = -3 Then
    GUISetState(@SW_HIDE, $GUI_Format)
    _setFormat()
    EndIf
    EndSwitch
    WEnd
    ; clear ressources
    _GUICtrlListView_Formatting_Shutdown()

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func _isRightClick()
    If Not IsArray($aItemIndex) Then Return
    If Not $aItemIndex[0] Then Return
    $aItemIndex[0] = False ; wurde geklickt, Status zurück auf nicht geklickt
    GUICtrlSetData($ctrl, $aItemIndex[1])
    GUICtrlSetData($zeile, $aItemIndex[2])
    GUICtrlSetData($spalte, $aItemIndex[3])
    Local $bk = $aItemIndex[4]
    If $bk = -1 Then
    GUICtrlSetData($inBkCol, $bk)
    Else
    GUICtrlSetData($inBkCol, '0x' & Hex($bk,6))
    EndIf
    Local $tx = $aItemIndex[5]
    If $tx = -1 Then
    GUICtrlSetData($inTxtCol, $tx)
    Else
    GUICtrlSetData($inTxtCol, '0x' & Hex($tx,6))
    EndIf
    GUICtrlSetData($inSize, $aItemIndex[6])
    GUICtrlSetData($inWeight, $aItemIndex[7])
    GUICtrlSetData($inFont, $aItemIndex[8])
    GUISetState(@SW_SHOW, $GUI_Format)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _setFormat()
    Local $bk = GUICtrlRead($inBkCol)
    Local $tx = GUICtrlRead($inTxtCol)
    Local $sz = GUICtrlRead($inSize)
    Local $wt = GUICtrlRead($inWeight)
    Local $ft = GUICtrlRead($inFont)
    If $bk = '' Or $tx = '' Or $sz = '' Or $wt = '' Or $ft = '' Then Return
    _GUICtrlListView_FormattingCell($aItemIndex[1], $aItemIndex[2], $aItemIndex[3], $bk, $tx, $sz, $wt, $ft)
    EndFunc

    [/autoit]

    Danke BugFix.

    Gruß
    (VX-)Rexx

    PS. Wie kann ich den Faden jetzt schließen?

    Einmal editiert, zuletzt von (VX-)Rexx (8. Dezember 2009 um 11:06)

    • Offizieller Beitrag
    Zitat

    PS. Wie kann ich den Faden jetzt schließen?

    Meinst du damit, wie du den Thread auf gelöst setzen kannst? Wenn ja einfach deinen 1. Post editieren und auf gelöst setzen.

    Raupi
    Wie doch die Foren verschieden sein können. Die meisten Foren, die ich kenne, erlauben nur eine gewisse Zeit nach Erstellung des Beitrages diesen anschließend noch editieren zu können.

    Gruß
    (VX-)Rexx