Hallo ich habe hier ein kleines Script geschrieben um mit dem o2 Handyfinder meine Handy´s zu Orten.
Die Funktion ermittelt mit dem o2 Tool die Koordinaten und öffnet diese mit Googlemaps, da die Funktionen hier einfach wesentlich besser sind als bei o2.
Details zur o2 Handyortung findet ihr hier.
Das ganze dauert, sofern der Dienst bei o2 freigeschaltet ist, und die Login-Daten stimmen in etwa 45 Sekunden.
Was ich noch nicht eingebaut habe ist irgend eine Art Fehlerbehandlung oder dergl.
#include <IE.au3>
#include <String.au3>
#include <Date.au3>
MsgBox(0,"Link zu Google Maps",_o2_Handyortung("017123456789","passwort",1))
[/autoit][autoit][/autoit][autoit];===============================================================================
;
; Function Name: _o2_Handyortung()
; Description: Ortet ein o2-Handy mit Hilfe der Handyfinder-Webseite von o2. Sofern dieser Dienst freigeschaltet ist
; siehe -> http://www.o2online.de/nw/meino2/self…andyfinder.html
; Parameter(s): $Handynummer - Handynummer die geortet werden soll
; $Passwort - Passwort für den o2 Online-Login
; $googlemaps - 1 (default) öffnet ein IE-Fenster mit den ermittelten Koorinaten bei Google-Maps
; - 0 öffnet kein Fenster
; Requirement(s): #include <IE.au3>,<String.au3>,<Date.au3>
; Return Value(s): On Success - Link zu Google-Maps mit Koordinaten
; On Failure - leerer String
; Author(s): Tobias Bartsch - 13.04.2010
;
;===============================================================================
;
Func _o2_Handyortung($Handynummer,$Passwort,$googlemaps = 1)
$ret_val = ""
$Gefunden = False
$oIE = _IECreate("https://login.o2online.de/loginRegistration/loginAction.do?_flowId=logout",0,0) ; generel vorher ausloggen
_IENavigate($oIE,"http://www.o2online.de/nw/meino2/selfcare-public/handyfinder/handyfinder.html") ; bei o2 Einloggen
$o_login = _IEGetObjById($oIE, "id_7027232")
$o_password = _IEGetObjById ($oIE, "id_7027234")
$oForm = _IEFormGetObjByName ($oIE, "contentLogin")
_IEFormElementSetValue ($o_login, $Handynummer)
_IEFormElementSetValue ($o_password, $Passwort)
_IEFormSubmit ($oForm)
_IENavigate($oIE,"http://handy-finder.o2online.de/app01/handyfinder") ; zum Handyfinder navigieren
$oForm = _IEFormGetObjByName ($oIE, "data01")
_IEFormElementCheckboxSelect($oForm,"true","bgb_accepted",1)
_IEFormSubmit ($oForm)
;~ * Handy wird nun geortet
For $count = 1 To 24
;~ * Alle 5 Sekunden prüfen, ob Handy nun lokalisiert wurde
_IELoadWait($oIE)
$text = _IEBodyReadText($oIE)
If StringInStr($text,"Ihr Handy wurde lokalisiert",0,1) Then
$Gefunden = True
ExitLoop
EndIf
Sleep(5000)
Next
If Not $Gefunden Then
;~ * Fall Handy nach 2 Minuten noch nicht geortet wurde, auf den Weiter-Button klicken, um fortzufahren
$oForm = _IEFormGetObjByName ($oIE, "data01")
_IEFormSubmit($oForm)
_IELoadWait($oIE)
$text = _IEBodyReadText($oIE)
If StringInStr($text,"Ihr Handy wurde lokalisiert",0,1) Then
$Gefunden = True
EndIf
EndIf
If $Gefunden Then
;~ * Handy wurde gefunden, nun Koordinaten ermitteln und Koordinaten bei Google-Maps anzeigen
_IELoadWait($oIE)
$url = _IEPropertyGet($oIE, "locationurl")
$X = _StringBetween($url,"result&SX=","&SY",-1)
$Y = _StringBetween($url,"&SY=","&RAD",-1)
$ret_val = "http://maps.google.com/?q=" & $Y[0] & "," & $x[0] & "(" & $Handynummer & " - " & _DateTimeFormat( _NowCalc(),0) & ")"
If $googlemaps Then
_IECreate($ret_val,0,1)
EndIf
EndIf
_IEQuit($oIE) ; Unsichtbares IE-Fenster schließen
Return $ret_val
EndFunc
