Hey
hab mal nochmal ein Problem und zwar hab ich ein Fenster mit 5 Inputs hintereinander, pro Input ist ein zeichen erlaubt,ich hätte es gerne so das wenn das Zeichen eingegeben ist ,man nicht selber auf das nächste Input drücken muss sondern das das Skript das von alleine macht!
Wäre klasse wenn jemand einen Befehl hat oder sogar ein Beispielskript macht
Hatte ich mal ein Bsp. für gemacht, kannst es ja dann anpassen (zum nächsten Feld mit ENTER):
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <Array.au3>
Opt("GUIOnEventMode", 1)
OnAutoItExitRegister('OnAutoItExit')
Global $hStub_KeyProc = DllCallbackRegister("_KeyProc", "long", "int;wparam;lparam")
Global $hmod = _WinAPI_GetModuleHandle(0)
Global $hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hStub_KeyProc), $hmod)
Global $active = False, $gui, $ID_lastFocus = 0
Enum $i1, $i2, $c1, $i3, $c2, $i4, $n ; <== hier die Reihenfolge, wie der Fokus 'wandern' soll ($n ist Zähler für Anz. Ctrl)
Global $a[$n]
$gui = GUICreate('')
GUISetOnEvent(-3, '_ende')
$a[$i1] = GUICtrlCreateInput('', 10,10,40)
$a[$i2] = GUICtrlCreateInput('', 60,10,40)
$a[$c1] = GUICtrlCreateCombo('', 110,10,40)
$a[$i3] = GUICtrlCreateInput('', 160,10,40)
$a[$c2] = GUICtrlCreateCombo('', 210,10,40)
$a[$i4] = GUICtrlCreateInput('', 260,10,40)
GUISetState()
While 1
If BitAND(WinGetState($gui), 
Then
$active = True
Else
$active = False
EndIf
Sleep(100)
WEnd
Func _ende()
Exit
EndFunc
;===========================================================
; callback function
;===========================================================
Func _KeyProc($nCode, $wParam, $lParam)
Local $tKEYHOOKS, $vkCode, $ID, $index
$tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
If $nCode < 0 Or Not $active Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
$vkCode = DllStructGetData($tKEYHOOKS, "vkCode")
If $wParam = $WM_KEYDOWN And $vkCode = 13 Then ; ENTER gedrückt
$ID = _WinAPI_GetDlgCtrlID(ControlGetHandle($gui, '', ControlGetFocus($gui)))
; Für ComboBoxen kann NICHT der Fokus abgefragt werden, da dieser auf dem Input-Ctrl der ComboBox liegt.
; Hier muß in der Instanz-Reihenfolge mit dem Wert des letzten Ctrl verglichen werden.
; Die Reihenfolge der Erstellung in der GUI ist egal, da der Fokus über die enumerierte Reihenfolge der Ctrl-Variablen
; weitergesetzt wird.
; Falls eine ComboBox als letztes Ctrl in der Folge erscheint, muß dies in der Abfragelogik berücksichtigt werden.
If _WinAPI_GetClassName($ID) <> 'Edit' Then
; Variante 1: über Class+Instance
$ID = _WinAPI_GetDlgCtrlID(ControlGetHandle($gui, "", "[CLASS:ComboBox; INSTANCE:1]"))
If $ID_lastFocus > $ID Then $ID = _WinAPI_GetDlgCtrlID(ControlGetHandle($gui, "", "[CLASS:ComboBox; INSTANCE:2]"))
; Variante 2: über Enumerations-Reihenfolge der ComboCtrls
;~ $ID = $a[$c1]
;~ If $ID_lastFocus > $ID Then $ID = $a[$c2]
EndIf
$index = _ArraySearch($a, $ID)
If @error Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
If $index < UBound($a)-1 Then
GUICtrlSetState($a[$index +1], $GUI_FOCUS)
$ID_lastFocus = $a[$index +1]
Else
GUICtrlSetState($a[0], $GUI_FOCUS)
$ID_lastFocus = $a[0]
EndIf
EndIf
Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc
Func OnAutoItExit()
_WinAPI_UnhookWindowsHookEx($hHook)
DllCallbackFree($hStub_KeyProc)
EndFunc
Edit: Hier die Variante "direkt weiter":
#include <EditConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
Global $gui
Enum $i1, $i2, $i3, $i4, $n ; <== hier die Reihenfolge, wie der Fokus 'wandern' soll ($n ist Zähler für Anz. Ctrl)
Global $a[$n]
$gui = GUICreate('')
GUISetOnEvent(-3, '_ende')
$a[$i1] = GUICtrlCreateInput('', 10,10,40)
$a[$i2] = GUICtrlCreateInput('', 60,10,40)
$a[$i3] = GUICtrlCreateInput('', 160,10,40)
$a[$i4] = GUICtrlCreateInput('', 260,10,40)
GUISetState()
ControlFocus($gui, '', $a[$i1])
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
While True
Sleep(50)
WEnd
Func _ende()
Exit
EndFunc
Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
Local $hWndFrom, $iIDFrom, $iCode, $hWndEdit, $sRead
$hWndFrom = $ilParam
$iIDFrom = BitAND($iwParam, 0xFFFF) ; Low Word
$iCode = BitShift($iwParam, 16) ; Hi Word
For $i = 0 To UBound($a) -2
Switch $hWndFrom
Case GUICtrlGetHandle($a[$i])
If $iCode = $EN_CHANGE Then
ControlFocus($gui, '', $a[$i+1])
ExitLoop
EndIf
EndSwitch
Next
Return 0
EndFunc ;==>WM_COMMAND
Okay die Variante "direkt weiter " ist einfacher aber die mit ENTER ging au nich schlecht
