listview frage

  • Hallo Leute

    Also ich habe eine listview(2Spalten 4 Zeilen) erstellt und wollte fragen wie ich es schaffen kann bei eibenm klick auf einen Button die angeklickte zeile auszulesen und in ner msgbox augeben zu lassen(nur als Beispiel)

  • hm sorry aber ich kann da nich wirklich finden was ich suche
    meine frage war ja nich ob ein objekt angeklickt wurde sondern wie der eintrag der ersten spalte der markierten Zeile heißt wenn ich einen button klicke

    • Offizieller Beitrag

    Wenn du dein Problem richtig beschreiben würdest, dann wüßte man auch was du brauchst.

    Zitat

    Also ich habe eine listview(2Spalten 4 Zeilen) erstellt und wollte fragen wie ich es schaffen kann bei eibenm klick auf einen Button die angeklickte zeile auszulesen und in ner msgbox augeben zu lassen(nur als Beispiel)


    Da steht nix von der 1. Spalte

    Das Beispiel aus dem 1. Link macht doch genau was du willst.

    Spoiler anzeigen
    [autoit]

    #include<GUIConstantsEx.au3>
    #include<WindowsConstants.au3>
    #include <GUIListView.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $gui = GUICreate('test')
    $hListView = GUICtrlCreateListView('Spalte1|Spalte2', 10, 10, 300, 200)
    _GUICtrlListView_SetColumnWidth($hListView, 0, 146)
    _GUICtrlListView_SetColumnWidth($hListView, 1, $LVSCW_AUTOSIZE_USEHEADER)
    For $i = 1 To 10
    GUICtrlCreateListViewItem('Zeile ' & $i & ' Spalte 1|Zeile ' & $i & ' Spalte 2', $hListView)
    Next
    GUISetState()
    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
    Do
    $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    [/autoit] [autoit][/autoit] [autoit]

    Func _LeftDblClick($Info)
    MsgBox(0, 'Text in Spalte', _GUICtrlListView_GetItemText($Info[1], $Info[3], $Info[4]) )
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    [/autoit] [autoit][/autoit] [autoit]

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
    Case $hWndListView
    Switch $iCode
    Case $NM_CLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
    Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
    Local $aInfo[12] = [$hWndFrom, _
    $iIDFrom, _
    $iCode, _
    DllStructGetData($tInfo, "Index"), _
    DllStructGetData($tInfo, "SubItem"), _
    DllStructGetData($tInfo, "NewState"), _
    DllStructGetData($tInfo, "OldState"), _
    DllStructGetData($tInfo, "Changed"), _
    DllStructGetData($tInfo, "ActionX"), _
    DllStructGetData($tInfo, "ActionY"), _
    DllStructGetData($tInfo, "lParam"), _
    DllStructGetData($tInfo, "KeyFlags")]
    _LeftDblClick($aInfo)
    Case $NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
    Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
    Local $aInfo[12] = [$hWndFrom, _
    $iIDFrom, _
    $iCode, _
    DllStructGetData($tInfo, "Index"), _
    DllStructGetData($tInfo, "SubItem"), _
    DllStructGetData($tInfo, "NewState"), _
    DllStructGetData($tInfo, "OldState"), _
    DllStructGetData($tInfo, "Changed"), _
    DllStructGetData($tInfo, "ActionX"), _
    DllStructGetData($tInfo, "ActionY"), _
    DllStructGetData($tInfo, "lParam"), _
    DllStructGetData($tInfo, "KeyFlags")]
    _LeftDblClick($aInfo)
    EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
    EndFunc ;==>WM_NOTIFY

    [/autoit]


    Edit hab noch die Verarbeitung von einem Click hinzugefügt und auf das Wesentliche gekürzt.

  • nicht ein klick auf ein listviewitem ein klick auf einen BUTTON
    ich will nur die markierte zeile auslesen

    edit: Much sry hab das erste glatt übersehen also _GUICtrlListView_GetItemText
    Danke nochma und sry wegen dem post

  • Guten Morgen,

    Dazu wirst du auch noch _GUICtrlListView_GetSelectedIndices brauchen um den Selektierten Eintrag zu bekommen.


    nicht unbedingt, ListViews sind gar nicht so "stumm":

    Spoiler anzeigen
    [autoit]

    #include <GuiConstantsEx.au3>
    Opt("GUIOnEventMode", 1)
    $hGUI = GUICreate("ListView")
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    $idLV = GUICtrlCreateListView("Eins|Zwei", 0, 0, 400, 350)
    For $I = 1 To 4
    GUICtrlCreateListViewItem($I & "|" & $I + 1, $idLV)
    GUICtrlSetOnEvent(-1, "_Item_Clicked")
    Next
    $idBtn = GUICtrlCreateButton("Anzeigen", 0, 370, 400, 30)
    GUICtrlSetOnEvent(-1, "_Btn_Clicked")
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    While True
    Sleep(1000)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    Exit
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Item_Clicked()
    MsgBox(0, "Item_Clicked", GUICtrlRead(@GUI_CtrlId))
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Btn_Clicked()
    MsgBox(0, "Btn_Clicked", GUICtrlRead(GUICtrlRead($idLV)))
    EndFunc

    [/autoit]
    • Offizieller Beitrag

    Hast du auch wieder Recht, ich benutz halt meistens die UDF Funktionen. :D
    Edit: Wenn man nur die 1. Spalte braucht muß mal trotzdem weiter bearbeiten mit StringSplit. ;)
    [OT]
    Ich versteh sowieso nicht warum GUICtrlRead bei einem 2 Spalten Listview sowas zurückliefert 1|2|, vollkommen sinnlos der letzte Seperator.
    [/OT]

  • [OT]
    Ich versteh sowieso nicht warum GUICtrlRead bei einem 2 Spalten Listview sowas zurückliefert 1|2|, vollkommen sinnlos der letzte Seperator.
    [/OT]


    Das weiß ich auch nicht, ich könnte mir aber vorstellen, dass die Listviews nach der letzten belegten Spalte automatisch eine leere als Füllspalte anlegen.