input erneut auslesen, stop (button) während des ganzen scripts, reset funktion?

  • hi,

    ich hab seit einiger zeit autoit, was aber nicht heißt das ich besonders bewandert mit dem umgang darin bin. zurzeit spiele ich mehr damit, als es effektiv zu nutzen, wahrscheinlich weil mir die grundlagen fehlen. ich lese aber viel.

    gestern und heute habe ich einige zeit an folgendem kleinem script verbracht, dazu habe ich 2 probleme die ich einfach nicht gelöst bekomme. deshalb habe ich mich hier angemldet und hoffe ihr könnt mir helfen.

    zum ersten würd ich gerne während des ganzen scripts meinen $stop button nutzen können, das geht irgendwie nicht? und außerdem wenn man das script startet wird einem die eingegebene zahl ja über die msgbox wiedergegeben, gibt man etwas anderes als 50 ein und geht nicht in die while schleife, und man drückt erneut auf den start button, wird immer angezeigt das man 0 eingegeben hat??

    1. wiso kann ich es nicht während dem laufen über den stop button stoppen?
    2. wiso ließt er ab dem 2ten start den input nicht richtig aus und gibt immer 0 zurück?
    und außerdem 3. weiß jemand ob es möglich ist das script zu "resetten", also wenn es läuft ? also so das es neu startet, als hätte man es gerade neu gestartet?

    bin für jede hilfe dankbar.

    Spoiler anzeigen
    [autoit]

    #include <ButtonConstants.au3>
    #include <EditConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    HotKeySet("{F2}", "start")

    [/autoit] [autoit][/autoit] [autoit]

    #Region ### START Koda GUI section ### Form=
    $Form1 = GUICreate("Form1", 100, 50, 192, 124)
    $var1 = GUICtrlCreateInput("50", 0, 0, 50, 21)
    $start = GUICtrlCreateButton("Start",55, 0, 40, 21)
    $stop = GUICtrlCreateButton("Stop",55, 25, 40, 21)
    GUISetState(@SW_SHOW)
    #EndRegion ### END Koda GUI section ###

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit
    Case $start
    $var1 = GUICtrlRead($var1)
    start()
    Case $stop
    Exit
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func start()
    MsgBox(4096, "Zahl ist", $var1)
    If $var1 = 50 Then
    While 1
    sleep(3000)
    MsgBox(4096, "Zahl ist", $var1)
    WEnd
    EndIf
    EndFunc

    [/autoit]

    Einmal editiert, zuletzt von anja (14. Januar 2011 um 22:26)

    • Offizieller Beitrag

    1. der Stop Button kann nicht reagieren, weil er nicht mehr abgefragt wird. Während die Func start läuft, wird die 1.While Wend Schleife nicht mehr ausgeführt.
    2. Beim auslesen des Inputs mittels

    [autoit]

    $var1 = GUICtrlRead($var1)

    [/autoit]


    weist du der Variable $Var1 den Inhalt des Controls zu, d.H. beim erneuten ausführen wird nicht das Control ausgelesen, sondern wird
    versucht die Variable auszulesen. GUICtrlRead kennt kein Control mit dieser Controlid, also ist das Ergebnis = False oder 0.
    Der Quellcode

    [autoit]

    If $var1 = 50 Then
    While 1
    sleep(3000)
    MsgBox(4096, "Zahl ist", $var1)
    WEnd
    EndIf

    [/autoit]


    wird niemals ausgeführt weil die Rückgabe von GUICtrlRead ein String ist und keine Zahl.
    Zum Glück wird sie nicht ausgeführt, weil die While Wend Schleife nie wieder verlassen wird.
    Die Abbruchbedingung der Schleife wird niemals erreicht.


    Edit: Da ich gerade nix besseres zu tun habe hier ein Beispiel:

    Spoiler anzeigen
    [autoit]

    #include <EditConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    Global $var1 ; Variable muß deklariert sein, weil sie Global (also auch in der Funktion) benutzt wird
    Global $bstop = False
    HotKeySet("{F2}", "start")
    HotKeySet("{F3}", "stop"); Funktionsabbruch mittels F3
    #region ### START Koda GUI section ### Form=
    $Form1 = GUICreate("Form1", 100, 50, 192, 124)
    $varInput = GUICtrlCreateInput("50", 0, 0, 50, 21, $ES_NUMBER); Da deine Eingabe eine Zahl sein soll ist es Sinnvoll die Eingabe auch darauf zu begrenzen !!!
    $start = GUICtrlCreateButton("Start", 55, 0, 40, 21)
    $stop = GUICtrlCreateButton("Stop", 55, 25, 40, 21)
    GUISetState(@SW_SHOW)
    #endregion ### END Koda GUI section ###

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit
    Case $start
    $var1 = GUICtrlRead($varInput);$Var1 ist ein String weil GUICtrlRead einen String zurückliefert die RückgabeVariable ($var1) muß eine andere sein als die Variable, welche die ControlID enthällt
    $bstop = False; $bStop auf False setzen damit die While Schleife in der Func Start laufen kann
    start()
    Case $stop
    Exit
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func Stop()
    $bstop = True; Variable $bstop auf True setzen, damit die Schleife in Func start abgebrochen werden kann
    EndFunc ;==>Stop

    [/autoit] [autoit][/autoit] [autoit]

    Func start()
    If IsString($var1) Then MsgBox(4096, "Achtung ", "Variable ist ein String ", 1); Hier wird zur Veranschaulichung mal geprüft ob die Rückgabe von GUICtrlRead ein String ist !
    If IsNumber($var1) Then MsgBox(4096, "Achtung ", "Variable ist eine Zahl", 1); Hier wird zur Veranschaulichung mal geprüft ob die Rückgabe von GUICtrlRead eine Zahl ist !
    Local $iVar = Number($var1) ; $iVar ist eine Nummer gebildet aus dem String
    Local $iCount = 0
    If $iVar = 50 Then
    While Not $bstop; Schleife wird ausgeführt solange $bStop nicht Trueist
    Local $nMsg = GUIGetMsg()
    If $nMsg = $stop Then $bstop = True ; Stop wurde gedrückt, Abbruchbedingung setzen $bStop = True
    If $nMsg = $GUI_EVENT_CLOSE Then Exit ; Gui wurde geschlossen Exit
    Sleep(50)
    ToolTip("ZÄHLER Läuft " & $iCount)
    $iCount += 1
    WEnd
    ToolTip("")
    EndIf
    EndFunc ;==>start

    [/autoit]
  • danke! :)

    bin gerade erst nach hause gekommen, werds mir gleich mal genau angucken, aber nach dem ersten start glaub ich das es mir weiterhilft!

    wie ist das denn mit dem dim? wo ist der unterschied zu global?