AVI Index in Shell32.dll

Func _SHFileOperation($wFunc, $sFrom, $sTo = "", $wFlags = 0x0, $hWnd = 0, $sTitle = "")
; http://msdn.microsoft.com/en-us/library/…28VS.85%29.aspx
; Die Struktur SHFILEOPTSTRUCT (vgl. Link in Vorzeile) wird erstellt.
Local $tSHFILEOPSTRUCT = DllStructCreate("HWND hWnd;UINT wFunc;Ptr pFrom;Ptr pTo;WORD fFlags;BOOL fAborted;Ptr;Ptr pTitle")
; Wir holen uns das aktuell eingestellte Listentrennzeichen (Standard: |), dieses Zeichen wird als Trennzeichen zwischen
; mehreren Namen in $sFrom bzw. $sTo erwartet.
Local $Sep = Opt("GUIDataSeparatorChar")
; Locale Variablen werden auf Grundstellung gesetzt
Local $iFrom = 0, $iTo = 0, $pTo = 0, $pTitle = 0
; Evtl. am Ende von $sFrom stehende Trennzeichen werden entfernt.
While StringRight($sFrom, 1) = $Sep
StringTrimRight($sFrom, 1)
WEnd
; Evtl. am Ende von $sTo stehende Trennzeichen werden entfernt.
While StringRight($sTo, 1) = $Sep
StringTrimRight($sTo, 1)
WEnd
; An das Ende von $sFrom werden zwei Trennzeichen angehängt, dann werden alle in $sFrom enthaltenen Trennzeichen
; durch binäre Nullen ersetzt, weil die Funktion SHFileOperation einzelne binäre Nullen als Trenner zwischen
; mehreren Namen und zumindest zwei aufeinanderfolgende binäre Nullen als Merkmal für das Ende der Namen erwartet.
$sFrom = StringReplace($sFrom & $Sep & $Sep, $Sep, Chr(0))
; Die Anzahl der ersetzten Trennzeichen wird in $iFrom abgelegt
$iFrom = @extended
; Für die Übergabe der Werte aus $sFrom wird eine UNICODE-String-Struktur in der Länge von $sFrom angelegt.
; Die Anweisung StringLen() zählt netterweise die binären Nullen mit.
Local $tFrom = DllStructCreate("WChar[" & StringLen($sFrom) & "]")
; Die UNICODE-String-Struktur wird mit dem Inhalt von $sFrom gefüllt und dabei ggf. automatisch konvertiert.
DllStructSetData($tFrom, 1, $sFrom)
; Ein Pointer auf die (Zeiger auf die Adresse der) UNICODE-String-Struktur wird in $pFrom abgelegt.
Local $pFrom = DllStructGetPtr($tFrom)
; Wenn $sTo nicht leer ist, wiederholen wir die Konvertierungsschritte von $sFrom für $sTo
If $sTo Then
$sTo = StringReplace($sTo & $Sep & $Sep, $Sep, Chr(0))
$iTo = @extended
Local $tTo = DllStructCreate("WChar[" & StringLen($sTo) & "]")
DllStructSetData($tTo, 1, $sTo)
$pTo = DllStructGetPtr($tTo)
EndIf
; Wenn in $sFrom und in $sTo mehr als zwei Trennzeichen ersetzt wurden und die Anzahl der Ersetzungen gleich ist,
; ist davon auszugehen, dass beide Parameter mehrere Dateinamen enthalten, der Parameter $wFlags wird deshalb mit
; dem Flag $FOF_MULTIDESTFILES verodert (d.h. das Flag wird hinzugefügt, wenn es nicht schon gesetzt ist).
If $iFrom > 2 And $iTo > 2 And $iFrom = $iTo Then
$wFlags = BitOR($wFlags, $FOF_MULTIDESTFILES)
EndIf
; Wenn der Parameter $sTitle nicht leer ist, wird er in eine UNICODE-String-Struktur übertragen (s.o.)
If $sTitle Then
; Struktur erstellen
Local $tTitle = DllStructCreate("WChar[" & StringLen($sTitle) + 1 & "]")
; Daten übertragen
DllStructSetData($tTitle, 1, $sTitle)
; Zeiger holen
$pTitle = DllStructGetPtr($tTitle)
EndIf
; Jetzt kann die oben angelegte Struktur SHFILEOPSTRUCT endlich gefüllt werden ...
DllStructSetData($tSHFILEOPSTRUCT, "hWnd", $hWnd) ; hwnd <- Parameter
DllStructSetData($tSHFILEOPSTRUCT, "wFunc", $wFunc) ; wFunc <- Parameter
DllStructSetData($tSHFILEOPSTRUCT, "pFrom", $pFrom) ; pFrom <- Zeiger auf UNICODE-String-Struktur $tFrom
DllStructSetData($tSHFILEOPSTRUCT, "pTo", $pTo) ; pTo <- Zeiger auf UNICODE-String-Struktur $tTo
DllStructSetData($tSHFILEOPSTRUCT, "fFlags", $wFlags) ; fFlags <- Parameter
DllStructSetData($tSHFILEOPSTRUCT, "fAborted", 0) ; fAnyOperationsAborted <- NULL als Grundstellung
DllStructSetData($tSHFILEOPSTRUCT, 7, 0) ; hNameMappings - wird nicht unterstützt
DllStructSetData($tSHFILEOPSTRUCT, "pTitle", $pTitle) ; lpszProgressTitle <- Zeiger auf UNICODE-String-Struktur $tTitle
; ... und nun kann die Funktion SHFileOperation() per DllCall() aufgerufen werden.
Local $aResult = DllCall("Shell32.dll", "INT", "SHFileOperationW", "Ptr", DllStructGetPtr($tSHFILEOPSTRUCT))
; Fehlerbehandlung
If @error <> 0 Then Return SetError(1, @error, False)
If $aResult[0] <> 0 Then Return SetError(2, $aResult[0], False)
; Falls das Feld "fAborted" der Struktur SHFILEOPSTRUCT einen Wert ungleich Null enthält, wurde die Aktion vom
; Anwender abgebrochen, @extended wird dann auf 1 gesetzt.
If DllStructGetData($tSHFILEOPSTRUCT, "fAborted") Then Return SetExtended(1, True)
; Alles sollte wunschgemäß gelaufen sein.
Return True
EndFunc ;==>_SHFileOperation