netapi32.dll NetUserAdd Problem

  • Hallo,

    mein Skript stürzt ständig ab wenn ich mein Funktion zun erstellen eines Users über die netapi32.dll durchlaufen lasse.


    [autoit][/autoit][autoit][/autoit][autoit]

    Global Const $tagUSER_INFO_1 = "wstr Name; wstr Password; dword PasswordAge; dword Priv; wstr HomeDir; wstr Comment; dword Flags; wstr ScriptPath"
    Const $ADS_UF_DONT_EXPIRE_PASSWD = 0X10000

    [/autoit][autoit][/autoit][autoit]

    Func _NetUserAdd($strComputer, $strUser, $strPWD)
    ;Local $tBufPtr = DllStructCreate("ptr")
    Local $ptrParm_err = DllStructCreate("ptr")
    Local $tBufPtr = DllStructCreate($tagUSER_INFO_1)
    DllStructSetData($tBufPtr, "Name", $strUser)
    DllStructSetData($tBufPtr, "Password", $strPWD)
    DllStructSetData($tBufPtr, "PasswordAge", -1)
    DllStructSetData($tBufPtr, "Priv", 1)
    DllStructSetData($tBufPtr, "HomeDir", "")
    DllStructSetData($tBufPtr, "Comment", "Administrativer Acount von " & $strUser)
    DllStructSetData($tBufPtr, "Flags", $ADS_UF_DONT_EXPIRE_PASSWD)
    DllStructSetData($tBufPtr, "ScriptPath", "")

    [/autoit][autoit][/autoit][autoit]

    DllCall("netapi32.dll", "int", "NetUserAdd", "ptr", $strComputer, "dword", 1, "ptr", DllStructGetPtr($tBufPtr), "ptr", $ptrParm_err)

    EndFunc

    [/autoit]
  • Es sollte so etwa in die Richtung gehen:

    Spoiler anzeigen
    [autoit]

    Global Const $tagUSER_INFO_1 = " ptr usri1_name; ptr usri1_password; DWORD usri1_password_age; DWORD usri1_priv; ptr usri1_home_dir; ptr usri1_comment; DWORD usri1_flags; ptr usri1_script_path;"

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $UF_SCRIPT = 0x000001
    Global Const $UF_ACCOUNTDISABLE = 0x000002
    Global Const $UF_HOMEDIR_REQUIRED = 0x000008
    Global Const $UF_LOCKOUT = 0x000010
    Global Const $UF_PASSWD_NOTREQD = 0x000020
    Global Const $UF_PASSWD_CANT_CHANGE = 0x000040
    Global Const $UF_ENCRYPTED_TEXT_PASSWORD_ALLOWED = 0x000080
    Global Const $UF_TEMP_DUPLICATE_ACCOUNT = 0x000100
    Global Const $UF_NORMAL_ACCOUNT = 0x000200
    Global Const $UF_INTERDOMAIN_TRUST_ACCOUNT = 0x000800
    Global Const $UF_WORKSTATION_TRUST_ACCOUNT = 0x001000
    Global Const $UF_SERVER_TRUST_ACCOUNT = 0x002000
    Global Const $UF_DONT_EXPIRE_PASSWD = 0x010000
    Global Const $UF_MNS_LOGON_ACCOUNT = 0x020000
    Global Const $UF_SMARTCARD_REQUIRED = 0x040000
    Global Const $UF_TRUSTED_FOR_DELEGATION = 0x080000
    Global Const $UF_NOT_DELEGATED = 0x100000
    Global Const $UF_USE_DES_KEY_ONLY = 0x200000
    Global Const $UF_DONT_REQUIRE_PREAUTH = 0x400000
    Global Const $UF_PASSWORD_EXPIRED = 0x800000
    Global Const $UF_MACHINE_ACCOUNT_MASK = BitOr($UF_INTERDOMAIN_TRUST_ACCOUNT, $UF_WORKSTATION_TRUST_ACCOUNT, $UF_SERVER_TRUST_ACCOUNT)
    Global Const $UF_ACCOUNT_TYPE_MASK = BitOr($UF_TEMP_DUPLICATE_ACCOUNT, $UF_NORMAL_ACCOUNT, $UF_INTERDOMAIN_TRUST_ACCOUNT, $UF_WORKSTATION_TRUST_ACCOUNT, $UF_SERVER_TRUST_ACCOUNT)
    Global Const $UF_SETTABLE_BITS = BitOr($UF_SCRIPT, $UF_ACCOUNTDISABLE, $UF_LOCKOUT, $UF_HOMEDIR_REQUIRED, $UF_PASSWD_NOTREQD, $UF_PASSWD_CANT_CHANGE, $UF_ACCOUNT_TYPE_MASK, $UF_DONT_EXPIRE_PASSWD)

    [/autoit] [autoit][/autoit] [autoit]

    Global Enum $USER_PRIV_GUEST = 0, $USER_PRIV_USER = 1, $USER_PRIV_POWERUSER = 2, $USER_PRIV_ADMIN = 3

    [/autoit] [autoit][/autoit] [autoit]

    Func _Net_User_Add($sServername, $iLevel, $tInfo)
    ; Author: ProgAndy
    Local $sTypeServer = "ptr", $pInfo
    If IsString($sServername) And $sServername <> "" Then $sTypeServer = "wstr"
    If IsDllStruct($tInfo) Then
    $pInfo = DllStructGetPtr($tInfo)
    Else
    $pInfo = $tInfo
    EndIf
    Local $aRes = DllCall("netapi32.dll", "int", "NetUserAdd", $sTypeServer, $sServername, "dword", $iLevel, "ptr", $pInfo, "dword*", 0)
    If @error Then Return SetError(1, 0, False)
    Return SetError($aRes[0], $aRes[4], $aRes[0] = 0)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Net_WStr_Create($sText)
    ; Author: ProgAndy
    Local $tString = DllStructCreate("wchar[" & (StringLen($sText)+1) & "]")
    DllStructSetData($tString, 1, $sText)
    Return $tString
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    ;------ EXAMPLE -----

    [/autoit] [autoit][/autoit] [autoit]

    $tUSER_INFO_1 = DllStructCreate($tagUSER_INFO_1)

    [/autoit] [autoit][/autoit] [autoit]

    $tName = _Net_WStr_Create("Name")
    DllStructSetData($tUSER_INFO_1, "usri1_name", DllStructGetPtr($tName))

    [/autoit] [autoit][/autoit] [autoit]

    $tPassword = _Net_WStr_Create("Password")
    DllStructSetData($tUSER_INFO_1, "usri1_password", DllStructGetPtr($tPassword))

    [/autoit] [autoit][/autoit] [autoit]

    DllStructSetData($tUSER_INFO_1, "usri1_priv", $USER_PRIV_USER)

    [/autoit] [autoit][/autoit] [autoit]

    DllStructSetData($tUSER_INFO_1, "usri1_flags", BitOR($UF_SCRIPT, $UF_DONT_EXPIRE_PASSWD))

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    _Net_User_Add("", 1, $tUSER_INFO_1)

    [/autoit] [autoit][/autoit] [autoit][/autoit]
  • Danke, wie nicht anders zu erwarten war hat es funktioniert. Was ich aber nicht ganz verstehe ist, dass in der MSDN was von LPWSTR steht und der mit Wchar zusammengebaut wird. Wo komme ich an diese Info, dass ich sowas mit Wchar aufbauen muss, ich will ja nicht jedesmal hier nachfragen wollen und habe noch zwei Funktionen vor mir (NetLocalGroupAddMembers und NetLocalGroupDelMembers).

  • LPWSTR ist ein Pointer zu einem nullterminierten UTF-16-String. Da AutoIt diesen Typ nicht eingebaut hat, muss man das selbst machen.
    Ein String ist eine Folge von Zeichen und wegen UTF-16 eben UTF-16-Zeichen.