Membersearch

  • Hallo,

    würde gerne den Membersearch: https://autoit.de/index.php?form=MembersSearch
    in die GUI "einfügen".

    Der GUI ist folgendermassen aufgebaut:

    Spoiler anzeigen
    [autoit]

    #include <ButtonConstants.au3>
    #include <EditConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <StaticConstants.au3>
    #include <WindowsConstants.au3>
    #Region ### START Koda GUI section ### Form=
    $Form1 = GUICreate("Form1", 316, 143, 192, 124)
    $name = GUICtrlCreateLabel("Benutzername:", 8, 8, 93, 20)
    GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
    $registrierung = GUICtrlCreateLabel("Registrierungsdatum:", 8, 32, 131, 20)
    GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
    $beitraege = GUICtrlCreateLabel("Beiträge:", 8, 56, 58, 20)
    GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
    $Label1 = GUICtrlCreateLabel("Forumname", 176, 8, 76, 20)
    GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
    $Label2 = GUICtrlCreateLabel("regdatum", 176, 32, 61, 20)
    GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
    $Label3 = GUICtrlCreateLabel("anzahl_beitraege", 176, 56, 108, 20)
    GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
    $Input1 = GUICtrlCreateInput("Input1", 8, 88, 129, 21)
    $Button1 = GUICtrlCreateButton("Mitglied suchen", 168, 88, 89, 25)
    GUISetState(@SW_SHOW)
    #EndRegion ### END Koda GUI section ###

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit

    [/autoit] [autoit][/autoit] [autoit]

    EndSwitch
    WEnd

    [/autoit]

    Im Input den Namen des jeweiligen User, und auf Buttondrück sollen die Informationen wiedergegeben werden.

    Wie mache ich das denn?

    Einmal editiert, zuletzt von Jikilie (23. April 2011 um 15:36)

  • Erfolgreich eine GUI mit Koda hast du ja schonmal zusammengeklickt...
    Wenn du es wirklich selbst machen willst dann ist als 1. erstmal zu klären ob die Betreiber überhaupt zulassen möchten das mit andren Tools als einem Browser auf die Inhalte ihrer Seite zugegriffen wird.
    Ansonsten ist die Abfolge folgendermaßen:

    • Membersuchseite mit Usernamen als Post-Daten aufrufen (entweder per IE.au3, FF.au3, winhttp-Objekt oder Winhttp.au3)
    • Erhaltenen Quelltext mit Stringfunktionen so auswerten das die gewünschten Informationen rausgefiltert werden.
    • Die gefilterten Informationen in das GUI eintragen.

    Da mit langweilig war und ich ohnehin mal probieren wollte wie man direkt auf Http-Ebene Informationen beziehen kann hab ich sowas mal gebastelt (es werden nur die ersten 30 Mitglieder ausgegeben):

    AutoIt-Membersuche
    [autoit]

    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <Array.au3>
    #Include <GuiListView.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIOnEventMode", 1)
    Global $oUserLinks = ObjCreate('Scripting.Dictionary')

    [/autoit] [autoit][/autoit] [autoit]

    #region GUI
    Global $hGUI = GUICreate("AutoIt-Membersuche", 316, 443)

    [/autoit] [autoit][/autoit] [autoit]

    Global $idList = GUICtrlCreateListView("Benutzername|Registrierdatum|Beiträge", 8, 32, 300, 396)
    Global $idUserInput = GUICtrlCreateInput("", 8, 8, 216, 21)
    Global $idSuchButton = GUICtrlCreateButton("Suche", 228, 6, 80, 25, $WS_GROUP)

    [/autoit] [autoit][/autoit] [autoit]

    GUISetOnEvent($GUI_EVENT_CLOSE, "_raus")
    GUICtrlSetOnEvent($idSuchButton, "StartSuche")

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState(@SW_SHOW)

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    Sleep(100)
    WEnd
    #endregion

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func StartSuche()
    _GUICtrlListView_DeleteAllItems($idList)
    $oUserLinks.RemoveAll()
    Local $sURL, $idListItem
    Local $sMemberSource = _ConvertEntities(EasyPost("http://autoit.de/index.php?form=MembersSearch", "staticParameters[username]=" & GUICtrlRead($idUserInput) ))
    Local $aRegExp = StringRegExp($sMemberSource, '(?s)<tr class="container-.+?<td class="columnUsername">[^\r\n]+?<a href="([^"]+?)"[^\r\n]+?>(\w+?)</a.+?<td class="columnRegistrationDate">([^<]+?)<.+?<td class="columnPosts">[^\r\n]+?>([^<]+?)</a.+?</tr>', 4)
    For $i In $aRegExp
    $idListItem = GUICtrlCreateListViewItem($i[2] & "|" & $i[3] & "|" & $i[4], $idList)
    GUICtrlSetOnEvent(-1, "ListViewClicked")
    If Not $oUserLinks.Exists($idListItem) Then $oUserLinks.Add($idListItem, "http://www.autoit.de/" & $i[1])
    Next
    GUICtrlSetData($idUserInput, "")
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _raus()
    Exit
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func ListViewClicked()
    ShellExecute($oUserLinks(@GUI_CtrlId))
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func EasyPost($sAddr, $sPost)
    ; by Sprenger120 (http://www.autoit.de)
    Local Static $oWinHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    $oWinHTTP.Open("POST", $sAddr, False)
    $oWinHTTP.SetRequestHeader("User-Agent", "Mozilla/5.0 (Windows; U; Windows NT 6.1; en-US; rv:1.9.0.10) Gecko/2009042316 Firefox/3.0.10 (.NET CLR 4.0.20506)")
    $oWinHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
    $oWinHTTP.Send($sPost)
    Return $oWinHTTP.ResponseText
    EndFunc ;==>EasyPost

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ====================================================================================================
    ; Description ...: _ConvertEntities
    ; Parameters ....: $sURL - IN - The Text to convert
    ; Return values .: Success - Converted string
    ; Author ........: Stephen Podhajecki {gehossafats at netmdc. com}
    ; Remarks .......: Replaces HTML escape sequences with character representation
    ; Based on information found here: http://www.theukwebdesigncompany.com/artic...-characters.php
    ; nbsp is changed to 32 instead of 160
    ; Related .......:
    ; ====================================================================================================
    Func _ConvertEntities($sURL)
    Local $sTemp = $sUrl
    Local $aEntities[95][2]=[["&quot;",34],["&amp;",38],["&lt;",60],["&gt;",62],["&nbsp;",32] _
    ,["&iexcl;",161],["&cent;",162],["&pound;",163],["&curren;",164],["&yen;",165],["&brvbar;",166] _
    ,["&sect;",167],["&uml;",168],["&copy;",169],["&ordf;",170],["&not;",172],["&shy;",173] _
    ,["&reg;",174],["&macr;",175],["&deg;",176],["&plusmn;",177],["&sup2;",178],["&sup3;",179] _
    ,["&acute;",180],["&micro;",181],["&para;",182],["&middot;",183],["&cedil;",184],["&sup1;",185] _
    ,["&ordm;",186],["&raquo;",187],["&frac14;",188],["&frac12;",189],["&frac34;",190],["&iquest;",191] _
    ,["&Agrave;",192],["&Aacute;",193],["&Atilde;",195],["&Auml;",196],["&Aring;",197],["&AElig;",198] _
    ,["&Ccedil;",199],["&Egrave;",200],["&Eacute;",201],["&Ecirc;",202],["&Igrave;",204],["&Iacute;",205] _
    ,["&Icirc;",206],["&Iuml;",207],["&ETH;",208],["&Ntilde;",209],["&Ograve;",210],["&Oacute;",211] _
    ,["&Ocirc;",212],["&Otilde;",213],["&Ouml;",214],["&times;",215],["&Oslash;",216],["&Ugrave;",217] _
    ,["&Uacute;",218],["&Ucirc;",219],["&Uuml;",220],["&Yacute;",221],["&THORN;",222],["&szlig;",223] _
    ,["&agrave;",224],["&aacute;",225],["&acirc;",226],["&atilde;",227],["&auml;",228],["&aring;",229] _
    ,["&aelig;",230],["&ccedil;",231],["&egrave;",232],["&eacute;",233],["&ecirc;",234],["&euml;",235] _
    ,["&igrave;",236],["&iacute;",237],["&icirc;",238],["&iuml;",239],["&eth;",240],["&ntilde;",241] _
    ,["&ograve;",242],["&oacute;",243],["&ocirc;",244],["&otilde;",245],["&ouml;",246],["&divide;",247] _
    ,["&oslash;",248],["&ugrave;",249],["&uacute;",250],["&ucirc;",251],["&uuml;",252],["&thorn;",254]]
    For $x = 0 to Ubound($aEntities)-1
    $sTemp = StringReplace($sTemp,$aEntities[$x][0],Chr($aEntities[$x][1]),0,2)
    Next
    For $x = 32 to 255
    $sTemp = StringReplace($sTemp,"&#"&$x&";",chr($x))
    Next
    Return $sTemp
    EndFunc

    [/autoit]


    @Admins & Mods: Bitte natürlich sofort löschen falls ein solches Tool für AutoIt.de nicht geduldet wird.

    Einmal editiert, zuletzt von AspirinJunkie (14. April 2011 um 18:29)