Probleme bzgl Gui resize und Listview

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <Constants.au3>
#include <GuiListView.au3>


$hGUI = GUICreate("My GUI", 540, 500,-1,-1,BitOR($WS_SIZEBOX,$WS_SYSMENU))
$loglistview = GUICtrlCreateListView("Info1|Info2|Info3|Info4|Info5", 10, 10, 520, 200, $LVS_SHOWSELALWAYS)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKRIGHT + $GUI_DOCKTOP)
_GUICtrlListView_SetColumnWidth($loglistview, 0, 70)
_GUICtrlListView_SetColumnWidth($loglistview, 1, 70)
_GUICtrlListView_SetColumnWidth($loglistview, 2, 70)
_GUICtrlListView_SetColumnWidth($loglistview, 3, 70)
_GUICtrlListView_SetColumnWidth($loglistview, 4, 300)


GUICtrlCreateListViewItem("Some1|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some2|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some3|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some4|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some5|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some6|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some7|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some8|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some9|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some10|info|will|be|added", $loglistview)
GUICtrlCreateListViewItem("Some11|info|will|be|added", $loglistview)




$logedit = GUICtrlCreateEdit("", 10, 255, 520, 210, $WS_VSCROLL + $WS_HSCROLL + $ES_READONLY)
GUICtrlSetBkColor($logedit, "0xffffff")


$dellog = GUICtrlCreateButton("&Delete", 20, 220, 160)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKHCENTER)
$emaillog = GUICtrlCreateButton("&Mail", 190, 220, 160)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKHCENTER)
$printlog = GUICtrlCreateButton("&Print", 360, 220, 160)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKHCENTER)


GUISetState()
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")


_GUICtrlListView_ClickItem($loglistview, 0)


; Run the GUI until the dialog is closed
While 1
	$msg = GUIGetMsg()
	Switch $msg
		Case $GUI_EVENT_CLOSE
			ExitLoop
		Case $dellog
			processlogs("delete")
		Case $printlog
			processlogs("print")
		Case $emaillog
			processlogs("mail")
	EndSwitch
WEnd
GUIDelete()
Exit


Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
	#forceref $hWnd, $iMsg, $iwParam
	Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
	$hWndListView = $loglistview
	If Not IsHWnd($loglistview) Then $hWndListView = GUICtrlGetHandle($loglistview)


	$tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
	$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
	$iCode = DllStructGetData($tNMHDR, "Code")
	Switch $hWndFrom
		Case $hWndListView
			Switch $iCode
				Case $NM_CLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
					$item = _GUICtrlListView_GetItemTextArray($loglistview, -1)
					GUICtrlSetData($logedit, $item[1])
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY




Func processlogs($action)
	MsgBox(0,"To be done",$action)
EndFunc   ;==>processlogs

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <Constants.au3>
#include <GuiListView.au3>


; Create the GUI
$hGUI = GUICreate("My GUI", 540, 500, -1, -1, BitOR($WS_SIZEBOX, $WS_SYSMENU))


; Create the ListView
$hLV = GUICtrlCreateListView("", 10, 10, 520, 190)
GUICtrlSetBkColor(-1, 0xFFCCCC)
; Allow this to resize automatically
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKTOP)


; Create buttons
$hButton_1 = GUICtrlCreateButton("Test 1", 10, 210, 160, 30)
$hButton_2 = GUICtrlCreateButton("Test 2", 190, 210, 160, 30)
$hButton_3 = GUICtrlCreateButton("Test 3", 370, 210, 160, 30)


; Create Edit
$hEdit = GUICtrlCreateEdit("", 10, 250, 520, 210)
GUICtrlSetBkColor(-1, 0xCCFFCC)


GUISetState()


; Register the SIZE and MINMAX messages
GUIRegisterMsg($WM_SIZE, "_WM_SIZE")
GUIRegisterMsg($WM_GETMINMAXINFO, "_WM_GETMINMAXINFO")


While 1


	Switch GUIGetMsg()
    	Case $GUI_EVENT_CLOSE
        	Exit
	EndSwitch
WEnd


Func _WM_SIZE($hWnd, $iMsg, $wParam, $lParam)


	; If it is our GUI
	If $hWnd = $hGUI Then
    	; Get the new size of the GUI
    	$iGUIWidth = BitAND($lParam, 0xFFFF)
    	$iGUIHeight = BitShift($lParam, 16)
    	; Find position of ListView
    	$aLVPos = ControlGetPos($hGUI, "", $hLV)
    	; Set width of buttons
    	$iButton_Width = 160
    	; Work out positions for the buttons and edit
    	$iY_Button = $aLVPos[1] + $aLVPos[3] + 10
    	$iY_Edit = $iY_Button + 40
    	$iButtonX_1 = 10
    	$iButtonX_2 = ($iGUIWidth - $iButton_Width) / 2
    	$iButtonX_3 = $iGUIWidth - $iButton_Width - 10
    	; Determine Height of Edit
    	$iEdit_Ht = $iGUIHeight - $iY_Edit - 10
    	; Move buttons and Edit
    	GUICtrlSetPos($hButton_1, $iButtonX_1, $iY_Button)
    	GUICtrlSetPos($hButton_2, $iButtonX_2, $iY_Button)
    	GUICtrlSetPos($hButton_3, $iButtonX_3, $iY_Button)
    	GUICtrlSetPos($hEdit, 10, $iY_Edit, $iGUIWidth - 20, $iEdit_Ht)
	EndIf


EndFunc


Func _WM_GETMINMAXINFO($hwnd, $Msg, $wParam, $lParam)
	If $hWnd = $hGUI Then
    	$tagMaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    	DllStructSetData($tagMaxinfo, 7,  540) ; min X
    	DllStructSetData($tagMaxinfo, 8,  230) ; min Y
    	DllStructSetData($tagMaxinfo, 9,  800) ; max X
    	DllStructSetData($tagMaxinfo, 10, 600) ; max Y
    	Return 0
	EndIf
EndFunc   ;==>WM_GETMINMAXINFO