Icons in Toolbar nur 16x16?

  • Hi,

    kann es sein, dass die Funktion _GUIImageList_AddIcon nur 16x16 große Icons aus DLLs holen kann?
    Ich habe aus Windows-Standard-DLLs Icons benutzt, die bestimmt dort in 32x32 vorliegen.
    Die Werte _GUIImageList_Create(32, 32, ... vergrößern nur die 16x16 Icon, was die Icons pixelig macht.
    Gibt's einen Work-Around?

    [autoit]

    #include <GUIConstantsEx.au3>
    #include <GuiToolbar.au3>
    #include <WindowsConstants.au3>
    #Include <GuiImageList.au3>

    [/autoit][autoit][/autoit][autoit]

    Example()

    [/autoit][autoit][/autoit][autoit]

    Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    [/autoit][autoit][/autoit][autoit]

    ; Create GUI
    $hGUI = GUICreate("Toolbar", 700, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI, BitOR($BTNS_AUTOSIZE, $BTNS_BUTTON, $BTNS_SHOWTEXT, $TBSTYLE_FLAT, $TBSTYLE_LIST))
    ;$aSize = _GUICtrlToolbar_GetMaxSize($hToolbar)
    GUISetState(@SW_SHOW)

    [/autoit][autoit][/autoit][autoit]

    _GUICtrlToolbar_AddString($hToolbar,"New Project")
    _GUICtrlToolbar_AddString($hToolbar,"Open Project")
    _GUICtrlToolbar_AddString($hToolbar,"Save As")
    _GUICtrlToolbar_AddString($hToolbar,"Properties")
    _GUICtrlToolbar_AddString($hToolbar,"Help / About")

    [/autoit][autoit][/autoit][autoit]

    $hToolBarImageListNorm = _GUIImageList_Create(32, 32, 5, 3)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\ieframe.dll", 79)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 146)
    _GUICtrlToolbar_SetImageList($hToolbar, $hToolBarImageListNorm)

    [/autoit][autoit][/autoit][autoit]

    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, 0, 0, $BTNS_CHECK)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, 1, 1)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, 2, 2)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, 3, 3)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, 4, 4)

    [/autoit][autoit][/autoit][autoit]

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc

    [/autoit]
    • Offizieller Beitrag

    Du verwendest bei _GUIImageList_AddIcon den 4. Parameter nicht, somit wird das kleine Icon in die ImageList eingefügt.
    Der 4. Parameter ist standardmäßig mit false vorbelegt.

    Zitat von Hilfe zu _GUIImageList_AddIcon 4. Parameter

    $fLarge [optional] Extract Large Icon

    [autoit]

    #include <GUIConstantsEx.au3>
    #include <GuiToolbar.au3>
    #include <WindowsConstants.au3>
    #Include <GuiImageList.au3>
    Example()
    Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
    ; Create GUI
    $hGUI = GUICreate("Toolbar", 700, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI, BitOR($BTNS_AUTOSIZE, $BTNS_BUTTON, $BTNS_SHOWTEXT, $TBSTYLE_FLAT, $TBSTYLE_LIST))
    ;$aSize = _GUICtrlToolbar_GetMaxSize($hToolbar)
    GUISetState(@SW_SHOW)
    _GUICtrlToolbar_AddString($hToolbar,"New Project")
    _GUICtrlToolbar_AddString($hToolbar,"Open Project")
    _GUICtrlToolbar_AddString($hToolbar,"Save As")
    _GUICtrlToolbar_AddString($hToolbar,"Properties")
    _GUICtrlToolbar_AddString($hToolbar,"Help / About")
    $hToolBarImageListNorm = _GUIImageList_Create(32, 32, 5, 3)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 110,true)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 131,true)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\ieframe.dll", 79,true)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 168,true)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 137,true)
    _GUIImageList_AddIcon($hToolBarImageListNorm, @SystemDir & "\shell32.dll", 146,true)
    _GUICtrlToolbar_SetImageList($hToolbar, $hToolBarImageListNorm)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, 0, 0, $BTNS_CHECK)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, 1, 1)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, 2, 2)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, 3, 3)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, 4, 4)
    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc

    [/autoit]

    Einmal editiert, zuletzt von Raupi (23. Oktober 2014 um 18:06)

  • Vielen Dank, Raupi!

    Mann, was habe ich gesucht...
    Tomaten auf den Augen, denn _GUIImageList_AddIcon hatte ich mir in der Hilfe auch angeschaut.
    Jedenfalls funzt es jetzt, wie ich es möchte.