Befehle nur ausführen wenn die Farbe stimmt

fachinformadiga

Hi

ich wollt fragen ob es was gibt wie z.b. winwait pixel 200,300 = rot then quit oder dann weiter starten

if 300,200 rot then ...

sowas?

hab nix gefunden

danke

Dr.Galvany

Code

PixelSearch ( left, top, right, bottom, color [, shade-variation] [, step]] )

Eddy_Erpel

Hallo,
wenn Du es nur von einem einzigen Punkt wissen willst:

Code

while 1
     if PixelGetColor(x,y)="13947080" then ExitLoop     ;Pixelfarbe in Dezimal
Wend

eddy_erpel

fachinformadiga

ich dachte so

:1
if pixelcolor(300,200)="blau" <-- ps. gibtsn tool um die farbe auszulesen?
then
mouse click 100,200

else
mouseclick 100,290
sleep1000
endif
goto :1

**GtaSpider**

Hallo

:] ich glaube du hast noch autoit v2, oder? GoTo wurde aber der 3. abgeschafft Die Beta und die Version 3.1.1 kannst du dir hier runterladen:
http://www.autoitscript.com/autoit3/downloads.php
Ich würde dir empfehlen die Beta mit runterzuladen, da die betas doch recht stabil sind!

Also ja das gibt es! Entweder du baust es mit der Beta selber mit der Function _ChooseColor oder du holst dir ScitTe
Im anhang ist mal eine exe die Ich mit Der Beta gebaut habe mit der du das raussuchen kannst
Der Code ist

Spoiler anzeigen

Code

;Erklärung zu _ChooseColor:
;===============================================================================
;
; Description:            _ChooseColor
; Parameter(s):        $i_ReturnType - Optional: determines return type
;                            $i_colorref - Optional: default selected Color
;                            $i_refType - Optional: Type of $i_colorref passed in
; Requirement:            None
; Return Value(s):    Returns COLORREF rgbcolor if $i_refType = 0 (default)
;                            Returns Hex RGB value if $i_refType = 1
;                            Returns Hex BGR Color if $i_refType = 2
;                            if error occurs, @error is set
; User CallTip:        _ChooseColor([$i_ReturnType = 0[, $i_colorref = 0[, $i_refType=0]]]) Creates a Color dialog box that enables the user to select a color. (required: <Misc.au3>)
; Author(s):            Gary Frost (custompcs at charter dot net)
; Note(s):                $i_ReturnType = 0 then COLORREF rgbcolor is returned (default)
;                            $i_ReturnType = 1 then Hex BGR Color is returned
;                            $i_ReturnType = 2 Hex RGB Color is returned
;
;                            $i_colorref = 0 (default)
;
;                            $i_refType = 0 then $i_colorref is COLORREF rgbcolor value (default)
;                            $i_refType = 1 then $i_colorref is BGR hex value
;                            $i_refType = 2 then $i_colorref is RGB hex value
;
;===============================================================================
; Color Dialog constants
Global Const $CC_ANYCOLOR = 0x100
Global Const $CC_FULLOPEN = 0x2
Global Const $CC_RGBINIT = 0x1


$color = _ChooseColor (0,13947080); 0 = Dezimal, 1 = RGB Farbe, 2 = BGR
If @error Then
	MsgBox(16,"","Error in _ChooseColor, Sie haben abgebrochen, oder es ist ein unerwarteter Fehler aufgetreten!")
Else
	$colorrgb = Hex($color,6)
	$colorbgr = "0x"&$colorrgb
	$colorrgb = '0x' & StringMid($colorrgb, 5, 2) & StringMid($colorrgb, 3, 2) & StringMid($colorrgb, 1, 2)
	GUICreate("",400,400,100,200)
	GUICtrlCreateEdit("",0,0)
	GUICtrlSetData(-1,"Dezimal: "&$color&@CRLF&"RGB: "&$colorrgb&@CRLF&"BGR: "&$colorbgr)
	GUISetBkColor($colorrgb)

	GUISetState()
	Do
		$msg = GUIGetMsg()
	Until $msg = -3 ;ExitGui
EndIf






Func _ChooseColor($i_ReturnType = 0, $i_colorref = 0, $i_refType = 0)
	Local $custcolors = "int[16]"
	Local $struct = "dword;int;int;int;ptr;dword;int;ptr;ptr"
	Local $p = DllStructCreate($struct)
	If @error Then
		SetError(-1)
		Return -1
	EndIf
	Local $cc = DllStructCreate($custcolors)
	If @error Then
		SetError(-2)
		Return -1
	EndIf
	If ($i_refType == 1) Then
		$i_colorref = Int($i_colorref)
	ElseIf ($i_refType == 2) Then
		$i_colorref = Hex(String($i_colorref), 6)
		$i_colorref = '0x' & StringMid($i_colorref, 5, 2) & StringMid($i_colorref, 3, 2) & StringMid($i_colorref, 1, 2)
	EndIf
	DllStructSetData($p, 1, DllStructGetSize($p))
	DllStructSetData($p, 2, 0)
	DllStructSetData($p, 4, $i_colorref)
	DllStructSetData($p, 5, DllStructGetPtr($cc))
	DllStructSetData($p, 6, BitOR($CC_ANYCOLOR, $CC_FULLOPEN, $CC_RGBINIT))
	Local $ret = DllCall("comdlg32.dll", "long", "ChooseColor", "ptr", DllStructGetPtr($p))
	If ($ret[0] == 0) Then
		SetError(-3)
		Return -1
	EndIf
	Local $color_picked = DllStructGetData($p, 4)
	If ($i_ReturnType == 1) Then
		; return Hex BGR Color
		Return '0x' & Hex(String($color_picked), 6)
	ElseIf ($i_ReturnType == 2) Then
		; return Hex RGB Color
		$color_picked = Hex(String($color_picked), 6)
		Return '0x' & StringMid($color_picked, 5, 2) & StringMid($color_picked, 3, 2) & StringMid($color_picked, 1, 2)
	ElseIf ($i_ReturnType == 0) Then
		Return $color_picked
	Else
		SetError(-4)
		Return -1
	EndIf
EndFunc   ;==>_ChooseColor

Alles anzeigen

Mfg Spider

Dr.Galvany

wie schon von mein vorredner gesagt, gibt es das goto von der 2er bzw von dos hier nicht mehr.

ich habe mal genau das was du willst umgesetzt in einen aktuellen script auf AutoIt3 basis.

du weisst aber schon, das das eine entlosschleife ist was du hier dargestellt hast?
wenn du nach gefundenen pixel und ausgeführten click weiter machen willst bzw. das script sich schliessen soll musst du entweder das "ExitLoop" oder das "Exit" aktivieren in dem du das --> ; <-- davor entfernst.

Code

opt("MouseCoordMode", 0)
opt("PixelCoordMode", 0)


While 1
	If PixelGetColor( 300 , 200 ) = 0x0000FF Then
		MouseClick("left", 100,200)
		;ExitLoop
		;Exit
	Else
		MouseClick("left", 100,290)
	EndIf
	Sleep(50)
WEnd

Alles anzeigen