Ich habe ein Knick in der Birne, daher muss sich der Mauszeiger nach rechts bewegen, wenn ich die Maus nach links bewege, bis jetzt habe ich das immer technisch gelöst, in dem ich in der Maus die Kontakte der Lichtschranken vertauscht habe.
Neure Mäuse haben aber leider oft Multilayerplatinen und dann geht das nicht.
Ist möglich mit Autoit die Achsen zu vertauschen, dies würde ich dann las Sciprt im Hintergrund laufen lassen.
Das ist kein Scherz
Gilt das nur für rechts-links oder auch hoch-runter?
für beide Richtung, der Knick ist beidseits
Hier der Code:
#NoTrayIcon
HotKeySet("^!i","_InvertOnOff")
Global $MouseStart = MouseGetPos()
Global $MousePos
Global Const $InvertX = True ; X-Achse tauschen (rechts-links)
Global Const $InvertY = True ; Y-Achse tauschen (hoch-runter)
Global $InvertOn = False
While 1
If $InvertOn Then
$MousePos = MouseGetPos()
$Dx = $MousePos[0] - $MouseStart[0]
$Dy = $MousePos[1] - $MouseStart[1]
; Mousepositionen am Rand korrigieren
If $Dx > 1500 Then $Dx = -1
If $Dy > 1500 Then $Dy = -1
If $Dx < -1500 Then $Dx = 1
If $Dy < -1500 Then $Dy = 1
If $InvertX Then
$MouseStart[0] = $MousePos[0] - 2 * $Dx
Else
$MouseStart[0] = $MousePos[0]
EndIf
If $InvertY Then
$MouseStart[1] = $MousePos[1] - 2 * $Dy
Else
$MouseStart[1] = $MousePos[1]
EndIf
MouseMove($MouseStart[0], $MouseStart[1],0)
EndIf
Sleep(2) ; Prozessor entlasten
Wend
Func _InvertOnOff()
If $InvertOn Then
$InvertOn = False
Else
$InvertOn = True
$MouseStart = MouseGetPos()
EndIf
EndFunc@edit1: Jetzt kann man mit Strg+Alt+I ein- und ausschalten
Big THX, funzt, ist aber zu träge leider
Wurde gerne den linK von @th.merger ausprobieren, erhalte eine vbp Datei, wie muss man die ausfuhren?
Dafür benötigst du VisualBasic!
Ich habe mal die DLL-Aufrufe mit ins Script eingebaut, probier mal ob es jetzt besser geht:
#NoTrayIcon
HotKeySet("^!i","_InvertOnOff")
HotKeySet("^!x","_InvertXOnOff")
HotKeySet("^!y","_InvertYOnOff")
Global $MouseStart = _GetCursorPos()
Global $MousePos
Global $InvertX = True ; X-Achse tauschen (rechts-links)
Global $InvertY = True ; Y-Achse tauschen (hoch-runter)
Global $InvertOn = False
While 1
If $InvertOn Then
$MousePos = _GetCursorPos()
$Dx = $MousePos[0] - $MouseStart[0]
$Dy = $MousePos[1] - $MouseStart[1]
; Mousepositionen am Rand korrigieren
If $Dx > 1500 Then $Dx = -1
If $Dy > 1500 Then $Dy = -1
If $Dx < -1500 Then $Dx = 1
If $Dy < -1500 Then $Dy = 1
If $InvertX Then
$MouseStart[0] = $MousePos[0] - 2 * $Dx
Else
$MouseStart[0] = $MousePos[0]
EndIf
If $InvertY Then
$MouseStart[1] = $MousePos[1] - 2 * $Dy
Else
$MouseStart[1] = $MousePos[1]
EndIf
_SetCursorPos($MouseStart[0], $MouseStart[1])
EndIf
Sleep(2) ; Prozessor entlasten
Wend
Func _InvertOnOff()
If $InvertOn Then
$InvertOn = False
Else
$InvertOn = True
$MouseStart = _GetCursorPos()
EndIf
EndFunc
Func _GetCursorPos()
Local $Pt = DllStructCreate("uint;uint")
Local $RetVal[2]
DllCall("user32.dll", "long", "GetCursorPos", "ptr", DllStructGetPtr($Pt))
$RetVal[0] = DllStructGetData($Pt,1)
$RetVal[1] = DllStructGetData($Pt,2)
Return $RetVal
EndFunc
Func _SetCursorPos($PosX, $PosY)
DllCall("user32.dll", "long", "SetCursorPos", "long", $PosX, "long", $PosY)
EndFunc
Func _InvertXOnOff()
if $InvertX Then
$InvertX = False
Else
$InvertX = True
EndIf
EndFunc
Func _InvertYOnOff()
if $InvertY Then
$InvertY = False
Else
$InvertY = True
EndIf
EndFuncZum aktivieren Strg+Alt+I drücken
Man ihr gibt nie auf, klasse, super Forum, ich kucke jeden Tag hier vorbei, kann man immer wieder tolle Scripte absahnen
hackt zwar noch ein bissel, aber wesentlich besser, damit kann ich leben, BiG THXXXXXXXXXXXXXXXXXXXXXXXXXXXXxxxxx :stolz_bin: 
:party4: :party4:
HI,
aber jetzt mal ganz im Ernst, willst du damit deine Freundin reinlegen, oder brauchst du das wirklich für dich? :irre: (keine Beledigung!)
So long,
Mega
ne, ich brauche das wirklich für mich, seit ich ein PC habe kamm ich mit einer normalen Maus nie richtig klar, dann habe ich angefangen sie umzupolen.
bin gelernter Elektriker und Hobbyelektroniker