Moin, moin
ich habe ein Problem mit dem Auslesen von mehrere "ipconfig" Dateien.
Die Dateien liegen local auf nem Server und ich müsste die darin enthaltenen Werte wie "DNS-Suffix" oder "IP" und "MAC" Adresse auslesen.
Ich scheitere aber daran dass in manchen Dateien die Werte mehrmals auftreten. Dies ist ja bei Rechner mit mehreren Netzwerkkarten der Fall.
Meine Frage ist nun wie bekomme ich die Werte einzeln herausgelesen und zB in eine neue Text Datei geschrieben.
Hallo und herzlich :willkommen: Teckert!
Das Geht mit StdoutRead/StderrRead und dem Run paramteter 6 bei Standart I/O Flag! Ausserdem brauchst du die Beta!ich habe dir hier mal ein beispiel gemcaht:
FileWrite("test.txt",_GetIpConfig())
Func _GetIpConfig()
;By Max(gtaspider)
$run = Run(@ComSpec & ' /c ipconfig', '', @SW_HIDE,6)
Sleep(3000);ist wichtig weil er ja immer etwas zeit brauch
$stdoutread = StdoutRead($run)
If Not @error = -1 Then $outread=$stdoutread
$stderrRead = StderrRead($run)
If Not @error = -1 Then $outread = $stderrRead
Return StringTrimLeft($outread,1)
EndFuncMfg Spider
Auch von mir ein herzliches :willkommen:,
GtaSpider , wenn ich ihn richtig verstanden habe hat der die Daten bereits in Dateien abgelegt!
@Teckert, hast du den schon mal was auf das man aufbauen kann?
Danke für das herzliche Willkommen und auf die schnelle Antwort.
GtaSpider , die Dateien existieren schon sie liegen zentral auf nem Server ich möchte jetzt einfach ne Excel Liste erstellen in der die einzelnen Werte sich befinden.
Ich wollte das jetzt so machen das ich mit nem Script die Sachen aus den einzelnen Dateien auslese in eine einzelne Datei schreibe und sie dann in Excel importiere.
Ich habe schon auf dem Englischen Forum geschaut aber da ist wenig was für diesen Fall zutrifft.
sorry, ich hab mich wohl unverständlich ausgedrückt
; Description: : Gets all the IP related information about your computer
; Parameter(s): : -
; Return Value(s): : An array containing the folowing:
; $ret[0][0] = Host Name of Computer
; $ret[1 to *][0] = Type Of Adapter
; $ret[1 to *][1] = Name Of Adapter
; $ret[1 to *][2] = Adapter Description
; $ret[1 to *][3] = Physical Address of Adapter
; $ret[1 to *][4] = IP Address of Adapter
; $ret[1 to *][5] = Subnet Mask of IP Address of Adapter
; $ret[1 to *][6] = Default Gateway of Adapter
; $ret[1 to *][7] = Array of DNS servers this adapter uses
; Author(s): : nfwu
; Note(s): : Only works on a Windows machine
;
;===============================================================================
;Func _GetIPConfigData()
$search = FileFindFirstFile("*.txt")
; Suche erfolgreich?
If $search = -1 Then
MsgBox(0, "Error", "Keine Datei gefunden")
Exit
EndIf
$file = FileOpen("test.txt", 1)
; Hat das Öffnen geklappt
If $file = -1 Then
MsgBox(0, "Error", "Fehler beim öffnen.")
Exit
EndIf
While 1
$datei = FileFindNextFile($search)
If @error Then ExitLoop
$data = StringSplit($datei, @CRLF)
Local Const $adapter_no = 8
Local $retval[1][$adapter_no]
Local $curr_adapter = 0
Local $tmp
For $i = 1 to $data[0]
If __GPA_EL($data[$i], " Hostname. . . . . . . . . . . . . : ") Then
$retval[0][0] = __GPA_GL($data[$i], " Hostname. . . . . . . . . . . . . : ")
ElseIf StringInStr($data[$i],"adapter") Then
$tmp = StringSplit($data[$i],"adapter",1)
$curr_adapter += 1
ReDim $retval[$curr_adapter+1][$adapter_no]
$retval[$curr_adapter][0] = $tmp[0]
$retval[$curr_adapter][1] = $tmp[1]
ElseIf __GPA_EL($data[$i], " Beschreibung. . . . . . . . . . . : ") Then
$retval[$curr_adapter][2] = __GPA_GL($data[$i], " Beschreibung. . . . . . . . . . . : ")
ElseIf __GPA_EL($data[$i], " Physikalische Adresse . . . . . . : ") Then
$retval[$curr_adapter][3] = __GPA_GL($data[$i], " Physikalische Adresse . . . . . . : ")
ElseIf __GPA_EL($data[$i], " IP-Adresse. . . . . . . . . . . . : ") Then
$retval[$curr_adapter][4] = __GPA_GL($data[$i], " IP-Adresse. . . . . . . . . . . . : ")
ElseIf __GPA_EL($data[$i], " Subnetzmaske. . . . . . . . . . . : ") Then
$retval[$curr_adapter][5] = __GPA_GL($data[$i], " Subnetzmaske. . . . . . . . . . . : ")
ElseIf __GPA_EL($data[$i], " Standardgateway . . . . . . . . . : ") Then
$retval[$curr_adapter][6] = __GPA_GL($data[$i], " Standardgateway . . . . . . . . . : ")
ElseIf __GPA_EL($data[$i], " DNS-Server. . . . . . . . . . . . : ") Then
__GPA_StackPush($retval[$curr_adapter][7], __GPA_GL($data[$i], " DNS-Server. . . . . . . . . . . . : "))
ElseIf __GPA_EL($data[$i], " ") Then
__GPA_StackPush($retval[$curr_adapter][7], __GPA_GL($data[$i], " "))
EndIf
Next
;EndFunc
WEnd
Func __GPA_EL($data,$eqstr)
Return StringLeft( $data, StringLen($eqstr)) == $eqstr
EndFunc
Func __GPA_GL($data,$eqstr)
Return StringRight($data, Stringlen($data)-Stringlen($eqstr) )
EndFunc
Func __GPA_StackPush(ByRef $avArray, $sValue)
IF IsArray( $avArray ) Then
ReDim $avArray[Ubound($avArray)+1]
Else
Dim $avArray[1]
EndIf
$avArray[UBound($avArray)] = $sValue
SetError(0)
Return 1
EndFunc
FileClose($search)
FileClose($file)Das ist das was ich habe, er such nach den Ausdrücken in den *.txt Dateien und schreibt sie in ein Array nur bekomme ich die Sachen im Array nicht ausgegeben.
Hab mir das Script beim obrigen Author einfach abgeändert aber hab wohl was vergessen.
Edit bernd670 : Spoiler eingebaut 
Ich versuch dir mal eine Lösung zu schreiben, wie soll den das Ergebnis in der Datei aussehen, alle Werte durch ";" getreinnt dann kannst du sie in Excel importieren !?
Die IPConfig-Dateien liegen die alle in einem Verzeichnis und welche Dateiendung haben die?
Die Werte sollten jeweils durch ein ";" getrennt werden.
Zum Beispiel "192.168.0.1;10.10.1.1;10.10.1.12".
Die Dateien liegen alle in einem Verzeichnis, und es sind alles .txt Dateien.
so in der art hab ich mir das vorgestellt.
teckert;teckert.home.de;255.255.255.0;192.168.1.12;192.168.1.1;192.168.1.21;00:11:2F:01:02:9F;
nächste config;
und die nächste;also als csv-Datei (jede Zeile eine Ipconfig)
Jepp! Genau so.
Hier mal der Code für einen 1. Test:
Dim $sHostname
Dim $sPriDNSSuffix
Dim $sKnotentyp
Dim $sIPRouting
Dim $sWINSProxyAktiv
Dim $sVerbDNSSuffix
Dim $sBeschreibung
Dim $sMACAdresse
Dim $sDHCPAktiv
Dim $sIPAdresse
Dim $sSubnetzmaske
Dim $sGateway
Dim $sDNSServer
Dim $sHeadLine = "Hostname;" & _
"Primäres DNS-Suffix;" & _
"Knotentyp;" & _
"IP-Routing aktiviert;" & _
"WINS-Proxy aktiviert;" & _
"Verbindungsspezifisches DNS-Suffix;" & _
"Beschreibung;" & _
"Physikalische Adresse;" & _
"DHCP aktiviert;" & _
"IP-Adresse;" & _
"Subnetzmaske;" & _
"Standardgateway;" & _
"DNS-Server"
$sFSF = FileSelectFolder("Wählen Sie das Verzeichnis mit den IPConfig-Dateien!", "::{20D04FE0-3AEA-1069-A2D8-08002B30309D}")
If $sFSF <> "" And @error = 0 Then
$hFF = FileFindFirstFile($sFSF & "\*.txt")
if @error = 0 Then
$hDestFile = FileOpen($sFSF & "\" & @YEAR & @MON & @MDAY & "_" & @HOUR & @MIN & ".csv", 2)
; Kopfzeile schreiben
FileWriteLine($hDestFile,$sHeadLine)
While 1
$sFileName = FileFindNextFile($hFF)
if @error <> 0 Then ExitLoop
$sHostname = ""
$sPriDNSSuffix = ""
$sKnotentyp = ""
$sIPRouting = ""
$sWINSProxyAktiv = ""
$sVerbDNSSuffix = ""
$sBeschreibung = ""
$sMACAdresse = ""
$sDHCPAktiv = ""
$sIPAdresse = ""
$sSubnetzmaske = ""
$sGateway = ""
$sDNSServer = ""
$hSourceFile = FileOpen($sFSF & "\" & $sFileName, 0)
If $hSourceFile <> -1 Then
$iAdapters = 0
While 1
$sLine = FileReadLine($hSourceFile)
If @error <> 0 Then ExitLoop
If StringInStr($sLine, "Hostname. .") Then $sHostname = _GetLineValue($sLine)
If StringInStr($sLine, "Primäres DNS-Suffix") Then $sPriDNSSuffix = _GetLineValue($sLine)
If StringInStr($sLine, "Knotentyp") Then $sKnotentyp = _GetLineValue($sLine)
If StringInStr($sLine, "IP-Routing aktiviert") Then $sIPRouting = _GetLineValue($sLine)
If StringInStr($sLine, "WINS-Proxy aktiviert") Then $sWINSProxyAktiv = _GetLineValue($sLine)
If StringInStr($sLine, "Verbindungsspezifisches DNS-Suffix") Then
If $iAdapters > 0 Then _WriteValues($hDestFile)
$sVerbDNSSuffix = _GetLineValue($sLine)
$iAdapters = $iAdapters + 1
EndIf
If StringInStr($sLine, "Beschreibung") Then $sBeschreibung = _GetLineValue($sLine)
If StringInStr($sLine, "Physikalische Adresse") Then $sMACAdresse = _GetLineValue($sLine)
If StringInStr($sLine, "DHCP aktiviert") Then $sDHCPAktiv = _GetLineValue($sLine)
If StringInStr($sLine, "IP-Adresse") Then $sIPAdresse = _GetLineValue($sLine)
If StringInStr($sLine, "Subnetzmaske") Then $sSubnetzmaske = _GetLineValue($sLine)
If StringInStr($sLine, "Standardgateway") Then $sGateway = _GetLineValue($sLine)
If StringInStr($sLine, "DNS-Server") Then $sDNSServer = _GetLineValue($sLine)
Wend
_WriteValues($hDestFile)
FileClose($hSourceFile)
Else
MsgBox(16,"Fehler!", "Datei " & $sFileName & " kann nicht geöffnet werden!")
ExitLoop
EndIf
Wend
FileClose($hDestFile)
Else
MsgBox(16,"Datei nicht gefunden","Es sind keine IPConfig-Datein vorhanden!")
Endif
EndIf
Func _GetLineValue($sString)
$Pos = StringInStr($sString,":",0,-1) + 2
Return StringMid($sString,$Pos)
EndFunc
Func _WriteValues($hFile)
FileWriteLine($hFile, $sHostname & ";" & _
$sPriDNSSuffix & ";" & _
$sKnotentyp & ";" & _
$sIPRouting & ";" & _
$sWINSProxyAktiv & ";" & _
$sVerbDNSSuffix & ";" & _
$sBeschreibung & ";" & _
$sMACAdresse & ";" & _
$sDHCPAktiv & ";" & _
$sIPAdresse & ";" & _
$sSubnetzmaske & ";" & _
$sGateway & ";" & _
$sDNSServer _
)
EndFuncDie CSV-Datei wird in gleiche Verzeichnis geschrieben wie IPConfig-Dateien,
zur Zeit wird nur 1 DNS-Server eingetragen!
Die erste Zeile in der CSV-Datei enthält die Spaltenüberschriften!
bernd670 , Das ist ja der Hammer! 
Genau so sollte die Tabelle aussehen.
Ich werde das am Montag noch mal in der Arbeit ausprobieren und dann wird es wohl noch mehr lob regnen. 
Das einzige was mir jetzt so auf die Schnelle aufgefallen war das er einzelne leere Zeilen stehen hat in der Excel Tabelle aber das liegt warscheinlich an der einzelnen ipconfig.
Echt super das Teil.
Doch ich hab heute leider keine Zeit mehr und da ich einsameer Modem User bin wirt es auch so langsam heute ziemlich teuer. 
Aber ich melde mich Montag noch mal ob alles klappt.
Dank dir bernd670
Hallo!
Ich habe das Script noch etwas überarbeitet, jetzt werden alle DNS-Server ausgelesen und, durch Komma getrennt, angehängt! Zur Zeit habe ich leider kene IPConfg-Dateien in denen ein WINS- oder DHCP-Server eingetragen ist!
@13.08.2006 16:15: So jetzt sollten alle Werte die IPCONFIG ausgibt, ausgelesen werden!
@13.08.2006 18:30: Alle Adapter die IPCONFIG kennt eingearbeitet
@14.08.2006 13:45: Fehler aufgrund der Umlaute behoben
Dim $sHostname
Dim $sPriDNSSuffix
Dim $sKnotentyp
Dim $sIPRouting
Dim $sWINSProxyAktiv
Dim $sDNSSuffixSuchliste
Dim $sVerbDNSSuffix
Dim $sBeschreibung
Dim $sMACAdresse
Dim $sDHCPAktiv
Dim $sAutokonfAktiv
Dim $sIPAdresse
Dim $sSubnetzmaske
Dim $sGateway
Dim $sDNSServer
Dim $sPriWINS
Dim $sSekWINS
Dim $sLeaseErhalten
Dim $sLeaseLaeuftAb
Dim $sHeadLine = "Hostname;" & _
"Primäres DNS-Suffix;" & _
"Knotentyp;" & _
"IP-Routing aktiviert;" & _
"WINS-Proxy aktiviert;" & _
"DNS-Suffixsuchliste;" & _
"Verbindungsspezifisches DNS-Suffix;" & _
"Beschreibung;" & _
"Physikalische Adresse;" & _
"DHCP aktiviert;" & _
"Autokonfiguration aktiviert;" & _
"IP-Adresse;" & _
"Subnetzmaske;" & _
"Standardgateway;" & _
"DNS-Server;" & _
"Primärer WINS-Server;" & _
"Sekundärer WINS-Server;" & _
"Lease erhalten;" & _
"Lease läuft ab"
$sFSF = FileSelectFolder("Wählen Sie das Verzeichnis mit den IPConfig-Dateien!", "::{20D04FE0-3AEA-1069-A2D8-08002B30309D}")
If $sFSF <> "" And @error = 0 Then
$hFF = FileFindFirstFile($sFSF & "\*.txt")
if @error = 0 Then
$hDestFile = FileOpen($sFSF & "\" & @YEAR & @MON & @MDAY & "_" & @HOUR & @MIN & ".csv", 2)
; Kopfzeile schreiben
FileWriteLine($hDestFile,$sHeadLine)
While 1
$sFileName = FileFindNextFile($hFF)
if @error <> 0 Then ExitLoop
; Werte zurücksetzen
$sHostname = ""
$sPriDNSSuffix = ""
$sKnotentyp = ""
$sIPRouting = ""
$sWINSProxyAktiv = ""
$sDNSSuffixSuchliste = ""
$sVerbDNSSuffix = ""
$sBeschreibung = ""
$sMACAdresse = ""
$sDHCPAktiv = ""
$sAutokonfAktiv = ""
$sIPAdresse = ""
$sSubnetzmaske = ""
$sGateway = ""
$sDNSServer = ""
$sPriWINS = ""
$sSekWINS = ""
$sLeaseErhalten = ""
$sLeaseLaeuftAb = ""
$hSourceFile = FileOpen($sFSF & "\" & $sFileName, 0)
If $hSourceFile <> -1 Then
$iAdapters = 1
While 1
$sLine = FileReadLine($hSourceFile)
If @error <> 0 Then ExitLoop
;~ ConsoleWrite($sLine & @CRLF)
Select
Case StringInStr($sLine, "Hostname")
$sHostname = _GetLineValue($sLine)
$sLastValue = "Hostname"
Case StringInStr($sLine, "Prim") And StringInStr($sLine, "res DNS-Suffix")
$sPriDNSSuffix = _GetLineValue($sLine)
$sLastValue = "Primäres DNS-Suffix"
Case StringInStr($sLine, "Knotentyp")
$sKnotentyp = _GetLineValue($sLine)
$sLastValue = "Knotentyp"
Case StringInStr($sLine, "IP-Routing aktiviert")
$sIPRouting = _GetLineValue($sLine)
$sLastValue = "IP-Routing aktiviert"
Case StringInStr($sLine, "WINS-Proxy aktiviert")
$sWINSProxyAktiv = _GetLineValue($sLine)
$sLastValue = "WINS-Proxy aktiviert"
Case StringInStr($sLine, "DNS-Suffixsuchliste")
$sDNSSuffixSuchliste = _GetLineValue($sLine)
$sLastValue = "DNS-Suffixsuchliste"
Case StringInStr($sLine, "Verbindungsspezifisches DNS-Suffix")
$sVerbDNSSuffix = _GetLineValue($sLine)
$sLastValue = "Verbindungsspezifisches DNS-Suffix"
Case StringInStr($sLine, "Beschreibung")
$sBeschreibung = _GetLineValue($sLine)
$sLastValue = "Beschreibung"
Case StringInStr($sLine, "Physikalische Adresse")
$sMACAdresse = _GetLineValue($sLine)
$sLastValue = "Physikalische Adresse"
Case StringInStr($sLine, "DHCP aktiviert") Or _ ; WinXP
StringInStr($sLine, "DHCP-aktiviert") ; W2K (thx @Teckert)
$sDHCPAktiv = _GetLineValue($sLine)
$sLastValue = "DHCP aktiviert"
Case StringInStr($sLine, "Autokonfiguration aktiviert")
$sAutokonfAktiv = _GetLineValue($sLine)
$sLastValue = "Autokonfiguration aktiviert"
Case StringInStr($sLine, "IP-Adresse")
$sIPAdresse = _GetLineValue($sLine)
$sLastValue = "IP-Adresse"
Case StringInStr($sLine, "Subnetzmaske")
$sSubnetzmaske = _GetLineValue($sLine)
$sLastValue = "Subnetzmaske"
Case StringInStr($sLine, "Standardgateway")
$sGateway = _GetLineValue($sLine)
$sLastValue = "Standardgateway"
Case StringInStr($sLine, "DNS-Server")
$sDNSServer = _GetLineValue($sLine)
$sLastValue = "DNS-Server"
Case StringInStr($sLine, "Prim") And StringInStr($sLine, "rer WINS-Server")
$sPriWINS = _GetLineValue($sLine)
$sLastValue = "Primärer WINS-Server"
Case StringInStr($sLine, "Sekund") And StringInStr($sLine, "rer WINS-Server")
$sSekWINS = _GetLineValue($sLine)
$sLastValue = "Sekundärer WINS-Server"
Case StringInStr($sLine, "Lease erhalten")
$sLeaseErhalten = _GetLineValue($sLine)
$sLastValue = "Lease erhalten"
Case StringInStr($sLine, "Lease l") And StringInStr($sLine, "uft ab")
$sLeaseLaeuftAb = _GetLineValue($sLine)
$sLastValue = "Lease läuft ab"
;Adapterwechsel
Case StringInStr($sLine, "Unbekannter Adapter") = 1 Or _
StringInStr($sLine, "Anderer Adapter") = 1 Or _
StringInStr($sLine, "Ethernetadapter") = 1 Or _
StringInStr($sLine, "Token Ring-Adapter") = 1 Or _
StringInStr($sLine, "FDDI-Adapter") = 1 Or _
StringInStr($sLine, "Loopbackadapter") = 1 Or _
StringInStr($sLine, "PPP-Adapter") = 1 Or _
StringInStr($sLine, "SLIP-Adapter") = 1 Or _
StringInStr($sLine, "Tunneladapter") = 1
If $iAdapters > 1 Then
_WriteValues($hDestFile)
$sVerbDNSSuffix = ""
$sBeschreibung = ""
$sMACAdresse = ""
$sDHCPAktiv = ""
$sAutokonfAktiv = ""
$sIPAdresse = ""
$sSubnetzmaske = ""
$sGateway = ""
$sDNSServer = ""
$sPriWINS = ""
$sSekWINS = ""
$sLeaseErhalten = ""
$sLeaseLaeuftAb = ""
EndIf
$iAdapters += 1
; Wenn Zeile mit Leerzeichen beginnt handelt es sich um weitere DNS-Server od.
; einen weiteren Eintrag in der DNS-Suffixsuchliste
Case StringInStr($sLine, " ")
Switch $sLastValue
Case "DNS-Server"
$sDNSServer &= "," & _GetLineValue($sLine)
Case "DNS-Suffixsuchliste"
$sDNSSuffixSuchliste &= "," & _GetLineValue($sLine)
Case Else
;;;;;;
EndSwitch
Case Else
;;;;;;
EndSelect
Wend
_WriteValues($hDestFile)
FileClose($hSourceFile)
Else
MsgBox(16,"Fehler!", "Datei " & $sFileName & " kann nicht geöffnet werden!")
ExitLoop
EndIf
Wend
FileClose($hDestFile)
Else
MsgBox(16,"Datei nicht gefunden","Es sind keine IPConfig-Datein vorhanden!")
Endif
EndIf
MsgBox(64,"Fertig!", "Done!",10)
Func _GetLineValue($sString)
$Pos = StringInStr($sString,": ",0,-1)
;~ ConsoleWrite($Pos & " " & $sString & @CRLF)
If $Pos = 0 Then
$Pos = 1
Else
$Pos += 2
EndIf
Return StringStripWS(StringMid($sString,$Pos),3)
EndFunc
Func _WriteValues($hFile)
FileWriteLine($hFile, $sHostname & ";" & _
$sPriDNSSuffix & ";" & _
$sKnotentyp & ";" & _
$sIPRouting & ";" & _
$sWINSProxyAktiv & ";" & _
$sDNSSuffixSuchliste & ";" & _
$sVerbDNSSuffix & ";" & _
$sBeschreibung & ";" & _
StringReplace($sMACAdresse,"-",":") & ";" & _
$sDHCPAktiv & ";" & _
$sAutokonfAktiv & ";" & _
$sIPAdresse & ";" & _
$sSubnetzmaske & ";" & _
$sGateway & ";" & _
$sDNSServer & ";" & _
$sPriWINS & ";" & _
$sSekWINS & ";" & _
$sLeaseErhalten & ";" & _
$sLeaseLaeuftAb _
)
EndFuncDas mit den Leerzeilen konnte ich bei mir nicht nachvollziehen, vllt. kannst du mir ja mal die CSV-Datei und ein paar IPConfig-Dateien zur Verfügung stellen!
Moin
ich hab mal ein wenig mit dem Script gebastelt und ein Problem entfernt wenn mehrere Adapter
installiert waren die nicht angeschlossen waren. Weil die Variablen nicht nach dem Schreiben
zurückgesetzt wurden gab es teilweise falsche Zuweisungen der MAC bzw IP-Adressen.
Zusätzlich gibt es noch ne Zweite Datei in der die Anzahl der Netzwerkkarten festgehalten wird. War am Anfang nur für Testzwecke gadacht, hab ich aber dann drin gelassen.
Dim $sHostname
Dim $sVerbDNSSuffix
Dim $sBeschreibung
Dim $sMACAdresse
Dim $sDHCPAktiv
Dim $sIPAdresse
Dim $sSubnetzmaske
Dim $sGateway
Dim $sDNSServer
Dim $sStatus
Dim $sHeadLine = "Hostname;" & _
"Status;" & _
"DNS-Suffix;" & _
"Beschreibung;" & _
"Physikalische Adresse;" & _
"DHCP aktiviert;" & _
"IP-Adresse;" & _
"Subnetzmaske;" & _
"Standardgateway;" & _
"DNS-Server"
Dim $sZahlHeadLine = "Hostname;" & _
"Karten Anzahl;"
$sFSF = FileSelectFolder("Wählen Sie das Verzeichnis mit den IPConfig-Dateien!", "::{20D04FE0-3AEA-1069-A2D8-08002B30309D}")
If $sFSF <> "" And @error = 0 Then
$hFF = FileFindFirstFile($sFSF & "\*.txt")
if @error = 0 Then
$hDestFile = FileOpen($sFSF & "\" & "IPCFG_" & @YEAR & @MON & @MDAY & "_" & @HOUR & @MIN & ".csv", 2)
$hZahlFile = FileOpen($sFSF & "\" & "Anzahl_" & @YEAR & @MON & @MDAY & "_" & @HOUR & @MIN & ".csv", 2)
; Kopfzeile schreiben
FileWriteLine($hDestFile,$sHeadLine)
FileWriteLine($hZahlFile,$sZahlHeadLine)
While 1
$sFileName = FileFindNextFile($hFF)
if @error <> 0 Then ExitLoop
$sHostname = ""
$sVerbDNSSuffix = ""
$sBeschreibung = ""
$sMACAdresse = ""
$sDHCPAktiv = ""
$sIPAdresse = ""
$sSubnetzmaske = ""
$sGateway = ""
$sDNSServer = ""
$sStatus = "aktiviert"
$hSourceFile = FileOpen($sFSF & "\" & $sFileName, 0)
If $hSourceFile <> -1 Then
$iAdapters = 0
$iAnzahlAdapters = 0
While 1
$sLine = FileReadLine($hSourceFile)
If @error <> 0 Then ExitLoop
If StringInStr($sLine, "Hostname. .") Then $sHostname = _GetLineValue($sLine)
If StringInStr($sLine, 'Ethernetadapter "') Then
$iAnzahlAdapters = $iAnzahlAdapters + 1
If $iAdapters > 0 Then _WriteValues($hDestFile)
$sVerbDNSSuffix = _GetLineValue($sLine)
$iAdapters = $iAdapters + 1
EndIf
If StringInStr($sLine, "Medienstatus") Then $sStatus = _GetLineValue($sline)
If StringInStr($sLine, "Verbindungsspezifisches DNS-Suffix") Then $sVerbDNSSuffix = _GetLineValue($sline)
If StringInStr($sLine, "Beschreibung") Then $sBeschreibung = _GetLineValue($sLine)
If StringInStr($sLine, "Physikalische Adresse") Then $sMACAdresse = _GetLineValue($sLine)
If StringInStr($sLine, "DHCP-aktiviert") Then $sDHCPAktiv = _GetLineValue($sLine)
If StringInStr($sLine, "IP-Adresse") Then $sIPAdresse = _GetLineValue($sLine)
If StringInStr($sLine, "Subnetzmaske") Then $sSubnetzmaske = _GetLineValue($sLine)
If StringInStr($sLine, "Standardgateway") Then $sGateway = _GetLineValue($sLine)
If StringInStr($sLine, "DNS-Server") Then $sDNSServer = _GetLineValue($sLine)
Wend
_WriteValues($hDestFile)
If $iAnzahlAdapters > 1 Then _Anzahl($hZahlFile)
FileClose($hSourceFile)
Else
MsgBox(16,"Fehler!", "Datei " & $sFileName & " kann nicht geöffnet werden!")
ExitLoop
EndIf
Wend
FileClose($hDestFile)
FileClose($hZahlFile)
Else
MsgBox(16,"Datei nicht gefunden","Es sind keine IPConfig-Datein vorhanden!")
Endif
EndIf
Func _GetLineValue($sString)
$Pos = StringInStr($sString,":",0,-1) + 2
Return StringMid($sString,$Pos)
EndFunc
Func _WriteValues($hFile)
FileWriteLine($hFile, $sHostname & ";" & _
$sStatus & ";" & _
$sVerbDNSSuffix & ";" & _
$sBeschreibung & ";" & _
$sMACAdresse & ";" & _
$sDHCPAktiv & ";" & _
$sIPAdresse & ";" & _
$sSubnetzmaske & ";" & _
$sGateway & ";" & _
$sDNSServer _
)
$sVerbDNSSuffix = ""
$sBeschreibung = ""
$sMACAdresse = ""
$sDHCPAktiv = ""
$sIPAdresse = ""
$sSubnetzmaske = ""
$sGateway = ""
$sDNSServer = ""
$sStatus = "aktiviert"
EndFunc
Func _Anzahl($hFile2)
FileWriteLine($hFile2, $sHostname & ";" & _
$iAnzahlAdapters _
)
EndFuncbernd670 , du hast es bestimmt unter Windows XP getestet?!
Denn es gibt winzig kleine Unterschiede im Aufbau der IPCONFIG unter "Win XP" und "Win2k".
Es ist nur ein "-" beim DHCP Server und die Zeile mit den Ethernetadaptern unterscheidet sich in einem Gänsefüßchen.
Danke noch mal Bernd für das Grundscript jetzt muss ich nicht jede Woche nachschauen welche Configs neu hizukommen sondern nur das Script laufen lassen. 
Das neue Script von dir werd ich auch noch mal Testen. Aber das das Script die DHCP Server einträgt funktioniert.
Hmm, hat jemand ne Ahnung warum er den Code oben teilweise falsch eingerückt zeigt.
EDIT:
So ich hab mir dein neues Script mal abgeschaut aber irgedwas scheint mit den Leases nicht zu stimmen. Er zählt etwas was aber nicht stimmt?
Ist aber auch nicht schlimm. Denn ich hab ja oben schon mal alles rausgeschmissen was ich nicht brauche. Ich wollte mir nur anzeigen lassen ob der DHCP aktiviert ist damit ich ihn dann wieder deaktiviere. So das die Leases nicht erforderlich sind.
Gut ist das die MAC-Adresse jetzt mit ":" getrennt wird die normalen Bindestriche hätte man sonst noch ändern müssen.
Sorry das ich vorher nicht genau gesagt habe was ich alles an Werten brauchte und welche nicht.
Edit bernd670 : Spoiler eingebaut
Hallo!
Freut mich wenn es dir geholfen hat! :musik2:
[EDIT]
Ich werde es morgen noch mal überarbeiten dann habe ich auch alle benötigten Daten, und ein anderes System (W2K)
[/EDIT]
Das mit den Einrückungen liegt an den unterschiedlichen Tabeinstellungen zwischen deinem Texteditor und hier im Forum! Wenn du z.B. eine Tablulatorweite von 2 eingstellt hast und hier eine von 4 eingestellt ist, wird der Text hier doppelt so weit eingerückt! Viele Editoren haben eine Funktion die Tabulatoren in Leerzeichen umwandelt, wenn das einschalten wird der Text immer richtig dargestellt!
Ich zeig dir mal was ich meine wenn ein paar Adapter nicht angeschlossen sind.
Eine ".csv" ist mit deinem gemacht das andere mit meinem. Du siehst die falsche Zuordnung der IP-Adressen und das nicht alle Adapter aufgelistet werden. Aber mit dem Zurücksetzen war das dann Geschichte.