Hallo,
ich habe hier ein .ini file das in etwa so aussieht:
[001]
Abteilung = "Abt.1"
Name = "MA.1"
Gruppe = 1
[002]
Abteilung = "Abt.1"
Name = "MA.2"
Gruppe = 1
[003]
Abteilung = "Abt.1"
Name = "MA.3"
Gruppe = 1
Jetzt suche ich nach einer Funktion die mir alle "Namen" aus der .ini Datei, aus allen Sektionen, ... in einer Combobox ausgibt.
Um zu verdeutlichen was ich meine, hier ein Foto:
http://gyazo.com/43567afd7c16794716c455499945c70e
Danke
Hallo,
das geht mit IniReadSectionNames und IniRead!
#include <GUIConstants.au3>
#include <GuiComboBox.au3>
#include <Array.au3>
$inifile = @ScriptDir & "\00031.ini"
$bExit = False
Opt("GUIOnEventMode", 1)
GUICreate("",400,500)
$hCombo = GUICtrlCreateCombo("", 16, 16)
GUISetOnEvent($GUI_EVENT_CLOSE, "ByeBye")
GuiSetState()
$aSections = IniReadSectionNames($inifile)
For $i = 1 To $aSections[0]
$szName = IniRead($inifile, $aSections[$i], "name", "")
if ($szName <> "") Then _GUICtrlComboBox_InsertString($hCombo, $szName)
Next
_GUICtrlComboBox_SetCurSel($hCombo, 0)
While 1
if $bExit Then ExitLoop
Sleep(100)
WEnd
Func ByeBye()
$bExit = True
EndFuncMoin!
Hier mal ne "Quick and Dirty" Variante ohne ini-Befehle, dafür mit RegEx:
#include "Array.au3"
;~ $sBeispiel = FileRead("pfadZurIni\Ini.ini")
$sBeispiel = '[001]' & @CRLF & _
'Abteilung = "Abt.1"' & @CRLF & _
'Name = "MA.1"' & @CRLF & _
'Gruppe = 1' & @CRLF & _
'[002]' & @CRLF & _
'Abteilung = "Abt.1"' & @CRLF & _
'Name = "MA.2"' & @CRLF & _
'Gruppe = 1' & @CRLF & _
'[003]' & @CRLF & _
'Abteilung = "Abt.1"' & @CRLF & _
'Name = "MA.3"' & @CRLF & _
'Gruppe = 1'
$aNamen = StringRegExp($sBeispiel, '(?i)Name.*=.*"(.+)"', 3)
$sNamen = _ArrayToString($aNamen)
GUICreate("Alle Namen")
$idCombo = GUICtrlCreateCombo("", 100, 100)
$sFirstSel = ""
If IsArray($aNamen) Then $sFirstSel = $aNamen[0] ; nur um zu verhindern, dass das Programm abstürzt, wenn nichts gefunden wurde
GUICtrlSetData($idCombo, $sNamen, $sFirstSel)
GUISetState()
Do
Until GUIGetMsg() = -3Hallo,
vielen Dank für eure Hilfe, es funktioniert jetzt.
Wo kann man jetzt das Thema als "gelöst" markieren?