Desktop reservieren bei zwei Monitoren

4ern

Hallo zusammen, mit folgendem Code kann ich bestimmten Platz auf meinem Desktop für meine GUI Taskleiste reservieren. Jedoch wird hier immer vom Hauptmonitor ausgegangen. Hat evtl. jemand eine Idee, wie ich diesen Code auf mein zweiten Monitor anwenden kann?

Spoiler anzeigen

AutoIt

Const $SPI_SETWORKAREA = 47
Const $SPIF_SENDCHANGE


$tRECT = DllStructCreate('int;int;int;int')
DllStructSetData($tRECT, 1, 0) ; left
DllStructSetData($tRECT, 2, 40) ; top
DllStructSetData($tRECT, 3, @DesktopWidth) ; right
DllStructSetData($tRECT, 4, @DesktopHeight -  40) ; buttom
_WinAPI_SystemParametersInfo($SPI_SETWORKAREA, 0, DllStructGetPtr($tRECT), $SPIF_SENDCHANGE)

**bernd670**

Hallo,

evtl. mal so probieren.

AutoIt

#include <ScreenCapture.au3>
#include <WindowsConstants.au3>


Const $SPI_SETWORKAREA = 47
Const $SPIF_SENDCHANGE = 2


$aVS = _GetVirtualScreenSize() ; [0] = breite, [1] = höhe


$tRECT = DllStructCreate('int;int;int;int')
DllStructSetData($tRECT, 1, 0) ; left
DllStructSetData($tRECT, 2, 40) ; top
DllStructSetData($tRECT, 3, $aVS[0]) ; right
DllStructSetData($tRECT, 4, @DesktopHeight -  40) ; buttom
_WinAPI_SystemParametersInfo($SPI_SETWORKAREA, 0, DllStructGetPtr($tRECT), $SPIF_SENDCHANGE)




Func _GetVirtualScreenSize()
	Local $aVSS[2] = [0, 0]


	$aVSS[0] = _WinAPI_GetSystemMetrics($SM_CXVIRTUALSCREEN)
	$aVSS[1] = _WinAPI_GetSystemMetrics($SM_CYVIRTUALSCREEN)


	If ($aVSS[0] = 0) Or ($aVSS[1] = 0) Then
		$aVSS[0] = 0
		$aVSS[1] = 0
	EndIf


	Return SetError(($aVSS[0] Or $aVSS[1]),0, $aVSS)
EndFunc

Alles anzeigen

Wenn das nicht geht, muss man wahrscheinlich mit der Funktion GetMonitorInfo erstmal den Bereich des 2. Montiors auslesen und dann setzten.

4ern

hm das haut nicht ganze hin, denn wenn ich das ganze z.B auf den rechten Bildschirm anwende, ist der Linke komplett blockiert

Yaerox

Zitat von 4ern

Hallo zusammen, mit folgendem Code kann ich bestimmten Platz auf meinem Desktop für meine GUI Taskleiste reservieren.

Kannst du mir davon vll. mal n Screen zukommen lassen, sofern du fertig bist. Würde mir mal gern anschauen, wie du das nutzt. Es scheint ja keine Standard-Taskbar zu sein, oder? Klingt interessant...

4ern

Zitat von YaeroxXO

Kannst du mir davon vll. mal n Screen zukommen lassen, sofern du fertig bist. Würde mir mal gern anschauen, wie du das nutzt. Es scheint ja keine Standard-Taskbar zu sein, oder? Klingt interessant...

Tatsächlich gibt es noch nicht viel zusehen, wie du auf den Bildern siehst, reserviert sich das Script oben den Platz, sodass Icons & Maximierte Fenster sich nun an diese Größe halten.

Yaerox

Okay

Danke.

4ern

OK kurzes Update meinerseits,

laut MSDN muss ich bei multiblen Monitoren die Funktion "GetMonitorInfo" aufrufen, zum Glück gibt es hier bereits was von AutoIt _WinAPI_GetMonitorInfo($hMonitor).

So nun habe ich keine Ahnung wie ich anhand dieser Informationen eine Struct erstelle, sodass ich die Workarea vom zweiten Bildschirm anspreche.

4ern

Ok nun hab ich es raus.

@bernd670 du hattest von Anfang an recht, leider habe ich das nicht von Anfang an verstanden.

Mir hat im Struct immer die Zuweisung der Monitore gefehlt, jedoch ist dies garnicht notwendig, denn Windows macht das ganz von alleine. Anhand der X,Y Kordinaten ermittelt Windows, welche Workarea gemeint ist und wendet dort die SPI_SetWorkarea an.

So sieht dann der Code aus

AutoIt

#include <WinAPIGdi.au3>
#include <WinAPISys.au3>


Const $SPI_SETWORKAREA = 47
Const $SPIF_SENDCHANGE = 2


;Workarea ermitteln.
$pRECT = DllStructCreate('long X;long Y')
DllStructSetData($pRECT, "X" , @Desktopwidth+1) ; // -1 = Monitor 1 || +1 = Monitor 2
DllStructSetData($pRECT, "Y" , @DesktopHeight)
$aData = _WinAPI_GetMonitorInfo(_WinAPI_MonitorFromPoint($pRECT))


;Desktop Reservieren
$tRECT = DllStructCreate('int;int;int;int')
DllStructSetData($tRECT, 1, DllStructGetData($aData[1], 1)) ; left
DllStructSetData($tRECT, 2, DllStructGetData($aData[1], 2)+40) ; top
DllStructSetData($tRECT, 3, DllStructGetData($aData[1], 3)) ; right
DllStructSetData($tRECT, 4, DllStructGetData($aData[1], 4)) ; buttom
_WinAPI_SystemParametersInfo($SPI_SETWORKAREA, 1, DllStructGetPtr($tRECT), $SPIF_SENDCHANGE)

Alles anzeigen