Dateigröße wird nicht erkannt/aktualisiert

Schweizergeizer

Hallo erstmal,
ich weiß nicht, ob hier das richtige Forum für mein Problem ist, aber ich hoffe, dass mir jemand helfen kann:
ich habe mit Autoit ein Programm geschrieben, dass Dateien verschlüsselt und abspeichert.
Der Fortschritt-Balken bei der Verschlüsselung entspricht dem Verhältnis von der verschlüsselten Datei zu der Datei, die verschlüsselt werden soll,
da ich keine Ahnung hatte, wie ich den Fortschritt-Balken sonst realisieren soll;
die Dateigrößen von verschlüsselter und nicht verschlüsselter Datei sind nahezu identisch, daher schien mir diese Möglichkeit akkurat genug,
falls jemand eine elegantere Möglichkeit weiß, bin ich offen für Vorschläge
Nun aber zu meinem eigentlichen Problem:
Die Dateigröße der von meinem Script erstellten Datei wird nicht automatisch aktualisiert, erst wenn ich das entsprechende Verzeichnis aufrufe und "aktualisieren" wähle, erkennt Autoit die Dateigröße.
Upgedatet wird sie auch nur, wenn ich manuell ständig aktualisiere.
Der Windows Explorer aktualisiert die Dateigröße auch nicht automatisch.

Die Verschlüsselung erfolgt mit Methoden der Crypt.au3 und dem AES 256
Die Abfrage der Dateigrröße erfolgt durch die Methode FileGetSize(..)

Wie bekomme ich Autoit dazu die Dateigröße richtig zu erkennen oder den Explorer dazu sie automatisch zu aktualisieren?
So ist mein Fortschrittbalken doch total doof

Verzweifelte Grüße
Schweizergeizer

**AspirinJunkie**

Weißt du was ein Minimalbeispiel ist?
Das ist ein Skript welches so klein wie möglich ist und von allem unnötigen befreit wurde aber das angesprochene Verhalten reproduziert.
Es sollte ohne weitere nötige Anpassungen direkt bei jedem lauffähig sein.

Das hat den Riesenvorteil, dass dir schneller und besser geholfen werden kann und oftmals du beim Erstellen eines solchen Beispiels selbst auf die Lösung stößt.
Wenn du ein solches Beispiel hierzu postest wirst du sicherlich schnell Hinweise bekommen.

Schweizergeizer

hier ein kleines Beispielprogramm:

AutoIt

#include <Crypt.au3>


HotKeySet("{ESC}","_Ende")


AdlibRegister("_Ausgabe",1000)


_Crypt_EncryptFile("C:\test.txt","C:\test.crypt","test",26128)


Func _Ende()
	Exit
EndFunc


Func _Ausgabe()
	ConsoleWrite("Die Datei ist "&FileGetSize("C:\test.crypt")&" Bytes groß."&@CRLF)
EndFunc

Alles anzeigen

Zur Verdeutlichung habe ich eine 4gb große Textdatei genommen,
diese ist komprimiert im Anhang zu finden.
test.rar

Ich erhalte trotz stetig wachsender Dateigröße in der Konsole nach der ersten Zeile mit 0 Bytes immer die gleiche Ausgabe, wie im Screenshot im Anhang sichtbar.

Die angezeigte Dateigröße ändert sich erst, wenn ich den Pfad zur Datei aufrufe und mit dem Explorer aktualisiere.

Ich habe keine Ahnung was ich tun soll und bin über jede Antwort dankbar

LG
Schweizergeizer

**AspirinJunkie**

FileWrite schreibt nicht direkt auf die Festplatte, sondern in einen Puffer.
Dieser wird erst dann in einen Rutsch auf die Platte geschrieben wenn das Dateihandle geschlossen wird oder der Puffer voll ist.
Filegetsize lügt also gar nicht wenn es sagt die Datei ist 0 Bytes groß, denn zu diesem Zeitpunkt befinden sich die Daten noch im Puffer.

Zur Lösung: Eine Möglichkeit ist es nach jedem Schreibvorgang ein FileFlush() zu setzen. Das erzwingt das Leeren des Puffers auf die Festplatte.
Das ist aber nicht wirklich effektiv.
Stattdessen ist es sinnvoller die Größe der bereits verarbeiteten Daten zu merken und dann auf diese zuzugreifen:

Spoiler anzeigen

AutoIt

#include <Crypt.au3>


Global $iOutFileSize = 0 ; Globale Variable welche _Crypt_EncryptFile2 beschreibt und _Ausgabe liest




HotKeySet("{ESC}","_Ende")


AdlibRegister("_Ausgabe",1000)


_Crypt_EncryptFile2("C:\test.txt","C:\test.crypt","test",26128)


Func _Ende()
	Exit
EndFunc


Func _Ausgabe()
	ConsoleWrite("Die Datei ist "&$iOutFileSize&" Bytes groß."&@CRLF)
EndFunc








Func _Crypt_EncryptFile2($sSourceFile, $sDestinationFile, $vCryptKey, $iALG_ID)
	Local $bTempData = 0, _
			$hInFile = 0, $hOutFile = 0, _
			$iError = 0, $iExtended = 0, $iFileSize = FileGetSize($sSourceFile), $iRead = 0, _
			$bReturn = True


	_Crypt_Startup()


	Do
		If $iALG_ID <> $CALG_USERKEY Then
			$vCryptKey = _Crypt_DeriveKey($vCryptKey, $iALG_ID)
			If @error Then
				$iError = @error
				$iExtended = @extended
				$bReturn = False
				ExitLoop
			EndIf
		EndIf


		$hInFile = FileOpen($sSourceFile, $FO_BINARY)
		If @error Then
			$iError = 2
			$bReturn = False
			ExitLoop
		EndIf
		$hOutFile = FileOpen($sDestinationFile, $FO_OVERWRITE + $FO_CREATEPATH + $FO_BINARY)
		If @error Then
			$iError = 3
			$bReturn = False
			ExitLoop
		EndIf


		Do
			$bTempData = FileRead($hInFile, 1024 * 1024)
			$iRead += BinaryLen($bTempData)
			$iOutFileSize = $iRead
			If $iRead = $iFileSize Then
				$bTempData = _Crypt_EncryptData($bTempData, $vCryptKey, $CALG_USERKEY, True)
				If @error Then
					$iError = @error + 400
					$iExtended = @extended
					$bReturn = False
				EndIf
				FileWrite($hOutFile, $bTempData)
				ExitLoop 2
			Else
				$bTempData = _Crypt_EncryptData($bTempData, $vCryptKey, $CALG_USERKEY, False)
				If @error Then
					$iError = @error + 500
					$iExtended = @extended
					$bReturn = False
					ExitLoop 2
				EndIf
				FileWrite($hOutFile, $bTempData)
			EndIf
;~ 			FileFlush($hOutFile)
		Until False
	Until True


	If $iALG_ID <> $CALG_USERKEY Then _Crypt_DestroyKey($vCryptKey)
	_Crypt_Shutdown()
	If $hInFile <> -1 Then FileClose($hInFile)
	If $hOutFile <> -1 Then FileClose($hOutFile)


	Return SetError($iError, $iExtended, $bReturn)
EndFunc   ;==>_Crypt_EncryptFile

Alles anzeigen