GuiListView zeigt ScrollBar erst nach reinklicken und scrollen an

AutoTim

Hallo,

ich habe in meinem Code irgendwo einen kleine Fehler.
Das Script soll eine Art "Filmbibliothek werden". Dazu sollte man das ListView nach unten scrollen können.
Leider sehe ich keinen vertikalen Scrollbalken. Dazu muss ich erst in eines meiner Zeilen des Listview reinklicken und dann mit den Pfeiltasten navigieren. Dann wird der Scrollbalken auf der rechten Seite eingeblendet.
Das muss doch auch gleich nach Start der GUI möglich sein ?

Grüße Tim

Script:

AutoIt

#cs ----------------------------------------------------------------------------


 AutoIt Version: 3.3.8.1
 Author:         Tim E.


 Script Function:
	BloodMoon


#ce ----------------------------------------------------------------------------


; Script Start - Add your code below here


#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include "list_stuktur.au3"
#include <Array.au3>


Global $hImage, $idListview	;Wird für Listview gebraucht
Global $ini = "config.ini"	;Name der Ini Datei
Global $pfad	;Pfad zum Bibliotheks Ordner


GUICreate("ListView Set Image List", 800, 620)
$idListview = GUICtrlCreateListView("", 2, 2, 796, 300)
GUISetState(@SW_SHOW)


	Ini_einlesen() ;Pfad aus Ini Lesen
	Global $array_dateien = _ordner_rekursiv($pfad, 1,True,False,"bmp|mkv|avi|mp4")	;Alle Dateien auflisten lassen
	_ArrayDisplay($array_dateien)	;Zeig es
	ListView_erzeugen()




while 1
	if GUIGetMsg() = $GUI_EVENT_CLOSE then exit




WEnd




Func Ini_einlesen()
	If FileExists($ini) Then
	;Nothing
	Else
		IniWrite($ini,"Filmbibliothek","Pfad","C:\Filmbibliothek")	;Ini erstellen
	EndIf


	$Pfad = IniRead($ini,"Filmbibliothek","Pfad","")	;Ini Lesen
	If $pfad == "" then MsgBox(16,"Fehler!","Ein fehler beim Lesen der config.ini ist aufgetreten.")	;Fehler ausgeben wenn kein Pfad angegeben
	If FileExists($pfad) == 0 then MsgBox(16,"Fehler!","Bitte Pfadangeben in config.ini anpassen.")	;Fehler ausgeben wenn Pfad nicht existiert


EndFunc


Func ListView_erzeugen() ;==>Listview erzeugen
    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Cover", 105)
    _GUICtrlListView_AddColumn($idListview, "Titel", 350)
    _GUICtrlListView_AddColumn($idListview, "Details", 270)




    ; Load images
    $hImage = _GUIImageList_Create()
	_GUIImageList_SetIconSize($hImage, 100, 150)




	Global $anzahl_zeile = 0
	For $anzahl_array = 1 to UBound($array_dateien)-1 step 1
		;Msgbox(0,"",$array_dateien[$anzahl_array][1])




		If FileExists($array_dateien[$anzahl_array][0]&"#cover.bmp") AND ($array_dateien[$anzahl_array][0] <> $array_dateien[$anzahl_array + 1][0]) Then	;Überprüfen ob ein Cover vorhanden ist und ein Film dazu vorhanden
			$filmvorhanden = 0	;Kein Film vorhanden
			;MsgBox(0,"Es existiert kein Film","")
		Else
			$filmvorhanden = 1	;Film vorhanden
		EndIf


		If FileExists($array_dateien[$anzahl_array][0]&"#cover.bmp") then ;Überprüfen ob in dem Ordner ein Cover vorhanden ist
			_GUIImageList_AddBitmap($hImage, $array_dateien[$anzahl_array][0]&"#cover.bmp") ;Bild hinzufügen
			IF $filmvorhanden == 1 then $anzahl_array = $anzahl_array + 1 ;Nur wenn Film vorhanden zähle Bild eingefügt zähle eine Zeile weiter zum Film
		Else
			_GUIImageList_AddBitmap($hImage, "cover_fehlt.bmp") ;Wenn nicht, das fehlen des Covers als Bild wählen
		EndIf


		If $filmvorhanden = 0 Then	;Kein Film vorhanden
			_GUICtrlListView_AddItem($idListview, "", $anzahl_zeile)	;Leerer Text für "Cover"


			_GUICtrlListView_AddSubItem($idListview,$anzahl_zeile,"Kein Film vorhanden !",1,1)	;Film Titel
		Else	;Film vorhanden
			_GUICtrlListView_AddItem($idListview, "", $anzahl_zeile)	;Leerer Text für "Cover"
			$filmtitel = StringSplit($array_dateien[$anzahl_array][1],".",2) ;Filmtitel von Dateityp abtrennen
			$typ = $filmtitel[1]
			_GUICtrlListView_AddSubItem($idListview,$anzahl_zeile,$filmtitel[0],1,1)	;Film Titel


			$dateigrose = Round(FileGetsize($array_dateien[$anzahl_array][0]&$array_dateien[$anzahl_array][1])/1048576,2)
			_GUICtrlListView_AddSubItem($idListview,$anzahl_zeile,"Dateityp: "&$typ&@CRLF&"Dateigröße: "&$dateigrose&"MB",2,1)	;Film Titel
		endif


		$anzahl_zeile = $anzahl_zeile + 1	;Am Ende die geschriebene Zeile um eins erhöhen
	Next




	;Weist die Bilderliste dem Listview zu
    Local $hPrevImageList = _GUICtrlListView_SetImageList($idListview, $hImage, 1)




EndFunc   ;==>Listview erzeugen

Alles anzeigen

**BugFix**

Du mußt das Listview erzeugen bevor du die GUI auf SHOW setzt. Andere Variante wäre, nach dem Erstellen des LV ein Neuzeichnen zu erzwingen (_WinAPI_RedrawWindow).
Dein GUICtrlCreateListView("", 2, 2, 796, 300) ist beim besten Willen noch kein LV, das entsteht erst duch das Hinzufügen der Spalten (warum erstellst du diese nicht sofort?).

AutoTim

Danke BugFix!
Ich füge die Spalten mit _GUICtrlListView_AddColumn hinzu, weil ich deren Breite dann gleich mit angeben kann.
Versucht habe ich nun mit _WinAPI_RedrawWindow das Fenster neu zu zeichen, was ebenfalls nicht funktioniert wie das GUISetState(@SW_SHOW) nach dem Listview_erzeugen() auszuführen.

Hier der letzte Versuch:

AutoIt

#cs ----------------------------------------------------------------------------


	AutoIt Version: 3.3.8.1
	Author:         Tim E.


	Script Function:
	BloodMoon


#ce ----------------------------------------------------------------------------


; Script Start - Add your code below here


#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include "list_stuktur.au3"
#include <Array.au3>
#include <WinAPI.au3>


Global $hImage, $idListview ;Wird für Listview gebraucht
Global $ini = "config.ini" ;Name der Ini Datei
Global $pfad ;Pfad zum Bibliotheks Ordner
Global $arrayscollandfilepath[1000] ;Wird zum starten des Filmes benötigt


$bloodmoon = GUICreate("ListView Set Image List", 800, 620)
$idListview = GUICtrlCreateListView("", 2, 2, 796, 300) ;Listview erstellen
_GUICtrlListView_AddColumn($idListview, "Cover", 105) ;Spalten einfügen und auf passende Bereite einstellen
_GUICtrlListView_AddColumn($idListview, "Titel", 350)
_GUICtrlListView_AddColumn($idListview, "Details", 270)
$starten = GUICtrlCreateButton("Film abspielen", 10, 570, 100, 35)
GUISetState(@SW_SHOW)


Ini_einlesen() ;Pfad aus Ini Lesen
Global $array_dateien = _ordner_rekursiv($pfad, 1, True, False, "bmp|mkv|avi|mp4") ;Alle Dateien auflisten lassen
_ArrayDisplay($array_dateien) ;Zeig es


ListView_erzeugen() ;Liste füllen lassen
_WinAPI_RedrawWindow($bloodmoon) ;Fenster neu zeichnen




While 1
	$nMsg = GUIGetMsg()


	If $nMsg = $GUI_EVENT_CLOSE Then Exit
	If $nMsg = $starten Then Film_starten()


WEnd




Func Film_starten()
	$gewahltezeile = _GUICtrlListView_GetSelectedIndices($idListview, True)


	If UBound($gewahltezeile) > 1 Then ;überprüft ob eine zeilenangabe vohanden ist (zweiter platz)
		$gewahlteselement = $gewahltezeile[1] ;Dann die Zeilennummer raussuchen
		;MsgBox(0,"",$gewahlteselement) ; Ausgewähltes Element
		ShellExecute($arrayscollandfilepath[$gewahlteselement])
	Else
		MsgBox(64, "Auswahl fehlt", "Bitte den gewünschten Film auswählen!")
	EndIf


EndFunc   ;==>Film_starten




Func Ini_einlesen()
	If FileExists($ini) Then
		;Nothing
	Else
		IniWrite($ini, "Filmbibliothek", "Pfad", "C:\Filmbibliothek") ;Ini erstellen
	EndIf


	$pfad = IniRead($ini, "Filmbibliothek", "Pfad", "") ;Ini Lesen
	If $pfad == "" Then MsgBox(16, "Fehler!", "Ein fehler beim Lesen der config.ini ist aufgetreten.") ;Fehler ausgeben wenn kein Pfad angegeben
	If FileExists($pfad) == 0 Then MsgBox(16, "Fehler!", "Bitte Pfadangeben in config.ini anpassen.") ;Fehler ausgeben wenn Pfad nicht existiert


EndFunc   ;==>Ini_einlesen




Func ListView_erzeugen() ;==>Listview erzeugen


	; Load images
	$hImage = _GUIImageList_Create()
	_GUIImageList_SetIconSize($hImage, 100, 150)




	Global $anzahl_zeile = 0
	For $anzahl_array = 1 To UBound($array_dateien) - 1 Step 1
		;Msgbox(0,"",$array_dateien[$anzahl_array][1])




		If FileExists($array_dateien[$anzahl_array][0] & "#cover.bmp") And ($array_dateien[$anzahl_array][0] <> $array_dateien[$anzahl_array + 1][0]) Then ;Überprüfen ob ein Cover vorhanden ist und ein Film dazu vorhanden
			$filmvorhanden = 0 ;Kein Film vorhanden
			;MsgBox(0,"Es existiert kein Film","")
		Else
			$filmvorhanden = 1 ;Film vorhanden
		EndIf


		If FileExists($array_dateien[$anzahl_array][0] & "#cover.bmp") Then ;Überprüfen ob in dem Ordner ein Cover vorhanden ist
			_GUIImageList_AddBitmap($hImage, $array_dateien[$anzahl_array][0] & "#cover.bmp") ;Bild hinzufügen
			If $filmvorhanden == 1 Then $anzahl_array = $anzahl_array + 1 ;Nur wenn Film vorhanden zähle Bild eingefügt zähle eine Zeile weiter zum Film
		Else
			_GUIImageList_AddBitmap($hImage, "cover_fehlt.bmp") ;Wenn nicht, das fehlen des Covers als Bild wählen
		EndIf


		If $filmvorhanden = 0 Then ;Kein Film vorhanden
			_GUICtrlListView_AddItem($idListview, "", $anzahl_zeile) ;Leerer Text für "Cover"


			_GUICtrlListView_AddSubItem($idListview, $anzahl_zeile, "Kein Film vorhanden !", 1, 1) ;Film Titel


			$arrayscollandfilepath[$anzahl_zeile] = "-" ; Schreibt den gesammten Pfad des Filmes in die 1zu1 ArrayTabelle


		Else ;Film vorhanden
			_GUICtrlListView_AddItem($idListview, "", $anzahl_zeile) ;Leerer Text für "Cover"
			$filmtitel = StringSplit($array_dateien[$anzahl_array][1], ".", 2) ;Filmtitel von Dateityp abtrennen
			$typ = $filmtitel[1]
			_GUICtrlListView_AddSubItem($idListview, $anzahl_zeile, $filmtitel[0], 1, 1) ;Film Titel


			$dateigrose = Round(FileGetSize($array_dateien[$anzahl_array][0] & $array_dateien[$anzahl_array][1]) / 1048576, 2)
			_GUICtrlListView_AddSubItem($idListview, $anzahl_zeile, "Dateityp: " & $typ & @CRLF & "Dateigröße: " & $dateigrose & "MB", 2, 1) ;Film Titel


			$arrayscollandfilepath[$anzahl_zeile] = $array_dateien[$anzahl_array][0] & $array_dateien[$anzahl_array][1] ; Schreibt den gesammten Pfad des Filmes in die 1zu1 ArrayTabelle
		EndIf


		$anzahl_zeile = $anzahl_zeile + 1 ;Am Ende die geschriebene Zeile um eins erhöhen
	Next
	_ArrayDisplay($arrayscollandfilepath)


	;Weist die Bilderliste dem Listview zu
	Local $hPrevImageList = _GUICtrlListView_SetImageList($idListview, $hImage, 1)




EndFunc   ;==>ListView_erzeugen

Alles anzeigen

**Kanashius**

Ich hab mal so etwas in der Art geschrieben (schon Jahre her). Vielleicht kannst du dir da ein paar Ideen holen
http://kanashius.de/?page=filmVerwaltung

**BugFix**

Zitat von AutoTim

_GUICtrlListView_AddColumn hinzu, weil ich deren Breite dann gleich mit angeben kann.

Was ist das für eine Logik?
Das erledigt man doch beim Erstellen mit:

AutoIt

$hLV = GuiCtrlCreateListView('Spalte_1|Spalte_2', 5, 50, 495, 500)
_GUICtrlListView_SetColumnWidth($hLV, 0, 240)
_GUICtrlListView_SetColumnWidth($hLV, 1, $LVSCW_AUTOSIZE_USEHEADER)  ; Restbreite

AutoTim

Danke BuxFix.
Habe mein Code nun angepasst. Ich denke jetzt kann man es schon eher als ListView bezeichnen

Dennoch habe ich das Problem, dass dies nichts damit zu tun hat, das die Scrollbar nicht angezeigt bekomme.
Die Reihenfolge passt ja nun. Woran liegt das ?

Grüße Tim

**BugFix**

Also ich kann deinen Fehler nicht erkennen. Reduziere dein Skript mal soweit, dass nur noch das Listview mit dem Verhalten übrigbleibt. Lagere erst mal nicht in eine Funktion aus, ich denke dabei entsteht das Problem. Allerdings hat mir bisher _WinAPI_RedrawWindow($hLV) jedes Listview ordentlich neu gezeichnet.
Mit meinem Minimalskript kann ich deinen Fehler nicht abbilden.

Spoiler anzeigen

AutoIt

#include <GuiListView.au3>
_Test()


Func _Test()
	Local $hGui = GUICreate('Test')
	Local $hLV = GuiCtrlCreateListView('A|B|C', 10, 10, 300, 100)
	_GUICtrlListView_SetColumnWidth($hLV, 0, 100)
	_GUICtrlListView_SetColumnWidth($hLV, 1, 100)
	_GUICtrlListView_SetColumnWidth($hLV, 2, $LVSCW_AUTOSIZE_USEHEADER)
	For $i = 1 To 50
		GUICtrlCreateListViewItem(StringFormat('Zeile_%i - Spalte_A|Zeile_%i - Spalte_B|Zeile_%i - Spalte_C', $i, $i, $i), $hLV)
	Next
	GUISetState()
	Do
	Until GUIGetMsg() = -3
EndFunc

Alles anzeigen

AutoTim

Danke das du dir mein Problem angenommen hast.
Ich habe jetzt einmal alles raus geschmissen was nicht benötigt wird.

So sieht es aus:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include "list_stuktur.au3"
#include <Array.au3>
#include <WinAPI.au3>




Global $hImage, $idListview ;Wird für Listview gebraucht
Global $pfad = "F:\Filme\Filmbibliothek";Pfad zum Bibliotheks Ordner


$bloodmoon = GUICreate("BloodMoon", 800, 620)
$idListview = GUICtrlCreateListView("Cover", 2, 2, 796, 550) ;Listview erstellen
_GUICtrlListView_SetColumnWidth($idListview, 0, 105)




Global $array_dateien = _ordner_rekursiv($pfad, 1, True, False, "bmp|mkv|avi|mp4") ;Alle Dateien auflisten lassen


$hImage = _GUIImageList_Create()
_GUIImageList_SetIconSize($hImage, 100, 150)


Global $anzahl_zeile = 0
For $anzahl_array = 1 To UBound($array_dateien) - 1 Step 1


	_GUIImageList_AddBitmap($hImage, $array_dateien[$anzahl_array][0] & "#cover.bmp") ;Bild hinzufügen
	$anzahl_array = $anzahl_array + 1 ;Nur wenn Film vorhanden zähle Bild eingefügt zähle eine Zeile weiter zum Film
	_GUICtrlListView_AddItem($idListview, "", $anzahl_zeile) ;Leerer Text für "Cover"
	$anzahl_zeile = $anzahl_zeile + 1 ;Am Ende die geschriebene Zeile um eins erhöhen


Next


Local $hPrevImageList = _GUICtrlListView_SetImageList($idListview, $hImage, 1)


GUISetState(@SW_SHOW)


While 1
	$nMsg = GUIGetMsg()
	If $nMsg = $GUI_EVENT_CLOSE Then Exit
WEnd

Alles anzeigen

Nun habe ich zudem noch ein einfaches Beispiel gemacht was du auch testen können solltest (es werden keine eiteren Dateien benötigt):

AutoIt

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>


_Main()


Func _Main()
    Local $hImage, $hListView


    GUICreate("ListView: Setzt die Imagelist", 800, 620)
    $hListView = GUICtrlCreateListView("test", 2, 2, 750, 550)
	_GUICtrlListView_SetColumnWidth($hListview, 0, 105)




    $hImage = _GUIImageList_Create()
	_GUIImageList_SetIconSize($hImage, 100, 150)


	for $i = 0 to 20
		_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 100, 150))
		_GUICtrlListView_AddItem($hListView, "Item 1", $i)
	next


	Local $hPrevImageList = _GUICtrlListView_SetImageList($hListView, $hImage, 1)


    GUISetState()


    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Alles anzeigen

So sieht es nach dem Starten aus:

Spoiler anzeigen

[Blockierte Grafik: http://www.imgbox.de/users/public/images/wNRsDw6vbG.png]

**BugFix**

Mangels Bildern kann ich mit deinem Code wenig anfangen. Du solltest versuchen, ein auf jedem PC lauffähiges Musterskript zu erstellen, das deinen Fehler beinhaltet.
Meiner Meinung nach verursachen die Images das Verhalten.
Übrigens brauchst du die Images nicht zählen. Beim Hinzufügen zur Imagelist wird der Index für dieses Image zurückgegeben (Hilfe lesen hilft).

AutoIt

Global $anzahl_zeile = 0  ; Wozu??


For $anzahl_array = 1 To UBound($array_dateien) - 1
	_GUIImageList_AddBitmap($hImage, $array_dateien[$anzahl_array][0] & "#cover.bmp") ;Bild hinzufügen  
	; BESSER:
	$iNewIndex = _GUIImageList_AddBitmap($hImage, $array_dateien[$anzahl_array][0] & "#cover.bmp") ;Bild hinzufügen 
;~ 	$anzahl_array = $anzahl_array + 1 ;Nur wenn Film vorhanden zähle Bild eingefügt zähle eine Zeile weiter zum Film
;~ 	_GUICtrlListView_AddItem($idListview, "test", $anzahl_zeile) ;Leerer Text für "Cover"
	_GUICtrlListView_AddItem($idListview, "", $iNewIndex) ;Leerer Text für "Cover"
	; wozu soll $anzahl_zeile gut sein?
	$anzahl_zeile = $anzahl_zeile + 1 ;Am Ende die geschriebene Zeile um eins erhöhen
Next

Alles anzeigen

AutoTim

Zitat von BugFix

Mangels Bildern kann ich mit deinem Code wenig anfangen. Du solltest versuchen, ein auf jedem PC lauffähiges Musterskript zu erstellen, das deinen Fehler beinhaltet.

Das habe ich in meinem Post über dir gemacht Ich habe zudem noch ein Bild eingefügt wie es bei mir nach dem Ausführen aussieht.

Hier noch einmal das Script was du auch testen können solltest:

AutoIt

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
_Main()
Func _Main()
    Local $hImage, $hListView
    GUICreate("ListView: Setzt die Imagelist", 800, 620)
    $hListView = GUICtrlCreateListView("test", 2, 2, 750, 550)
	_GUICtrlListView_SetColumnWidth($hListview, 0, 105)
    $hImage = _GUIImageList_Create()
	_GUIImageList_SetIconSize($hImage, 100, 150)
	for $i = 0 to 20
		_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 100, 150))
		_GUICtrlListView_AddItem($hListView, "Item 1", $i)
	next
	Local $hPrevImageList = _GUICtrlListView_SetImageList($hListView, $hImage, 1)
    GUISetState()
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Alles anzeigen

**BugFix**

So, ich hab den Fehler gefunden.
Die Imagelist muss dem Listview zugeordnet werden bevor Item hinzugefügt werden:

AutoIt

#include <GuiImageList.au3>
#include <GuiListView.au3>


_Main()


Func _Main()
    Local $hImage, $hListView
    GUICreate("ListView: Setzt die Imagelist", 800, 620)
    $hListView = GUICtrlCreateListView("test", 2, 2, 750, 550)
	_GUICtrlListView_SetColumnWidth($hListview, 0, 105)


    $hImage = _GUIImageList_Create(100, 150)
;~ 	_GUIImageList_SetIconSize($hImage, 100, 150)
	For $i = 0 To 20
		_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, _RandomRGB(), 100, 150))
	Next
	Local $hPrevImageList = _GUICtrlListView_SetImageList($hListView, $hImage, 1)  ;== ImageList muss zugeordnet werden bevor!! Item zugefügt werden


	For $i = 0 To 20
		_GUICtrlListView_AddItem($hListView, "Item " & $i, $i)
	Next
    GUISetState()


    Do
    Until GUIGetMsg() = -3
    GUIDelete()
EndFunc   ;==>_Main


Func _RandomRGB()
	Local $iR = Random(0,255,1), $iG = Random(0,255,1), $iB = Random(0,255,1)
	Return "0x" & Hex($iR,2) & Hex($iG,2) & Hex($iB,2)
EndFunc

Alles anzeigen

AutoTim

Exact. Genau das war der Fehler.
Danke BugFix!

Grüße
Tim