Problem mit den IE Functions in Virtualisierter Umgebung

lachi

Moin moin Leute,

ich hab da mal ein recht exotisches Problem.
Vorweg: Dieses Problem tritt bei mir nur in VMs auf, welche in ESXi oder im VMware Player 6.0.4 laufen.
Reale Hardware und in Virtual Box sind nicht von diesem Fehler betroffen.
OS: Windows 7 (32 und 64bit), Windows 8.1, Windows 10, Windows Server 2012
Die Sprache macht keinen Unterschied.
Es ist auch egal ob das System frisch Installiert ist (zuletzt getestet mit Windows 7) oder ob es schon eine Zeit läuft.
UAC und Sicherheitsoptionen des IE machen ebenfalls keinen Unterschied.
AutoIT: Getestet mit 3.3.8.1 und 3.3.14.1

Problem: In dem angehängten Beispielskript wird ein IE gestartet, Maximiert und anschließend zwei Websiten (nacheinander) aufgerufen. Bei dieser Website sucht er nach einem Searchtext -> Gefunden: MsgBox mit Quellcode der Seite | Nicht gefunden: Neuer Schleifendurchlauf bis Timeout (5sek) durch.

In diesem Beispiel sucht er erst nach USA auf aldi.de, anschließend bei bing.de nach Bing.
Bing.de wird nicht abgeschlossen. Hier bekomme ich jedesmal den Quellcode von Aldi.de, zusätzlich ist der ReadyStatus auf 1.

Setz ich Google als erste Seite, dann geht es.
Zusätzliches Problem:
Ich kann leider kein _IELoadWait nutzen, weil diese Funktion mehrfach gecrashed ist. Meine Vermutung ist, da er den IE am Ende auch nicht mehr schließt, dass das Objekt vom IE irgendwo/wann im Hintergrund verändert wird.

Hat hier einer eine Idee, was das Problem sein könnte?
Lösungsvorschläge?
Known Bug?
DAU und es ist ein ganz einfacher Fehler?

Mal gucken, vielleicht habt ihr eine Idee.
Danke euch
Mfg

"Beispielscript"

AutoIt: Beispielskript.au3

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseX64=n
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
;~ #AutoIt3Wrapper_Res_requestedExecutionLevel=highesAvailable
;~ #AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****


#include <IE.au3>
$oIE = _IECreate("about:blank", 0, 1, 0, 1)


$temp = WinWait("[CLASS:IEFrame]", "", 30)
WinActivate($temp)


; Maximize the Internet Explorer window.
WinSetState($temp, "", @SW_MAXIMIZE)


_n("http://www.aldi.de/")
_IEReady(0, "USA", $oIE, 5)


Sleep(4000)


_n("www.bing.de")
_IEReady(0, "Bing", $oIE, 5)


_IEQuit($oIE)


Func _IEReady($ier_id, $ier_searchtext, $ier_handler, $ier_timeout = 20)
	Local $ier_current_runtime = TimerInit()
	Local $ier_time_delta = 0


	If Not (IsNumber($ier_timeout) == 1) Then
		; If the timeout is no number (Integer or Float) set a default value
		$ier_timeout = 20
	EndIf


	;DEV
	Local $ie_readystate
	Do
		$ie_readystate = _IEPropertyGet($ier_handler, "readystate")
		$ier_time_delta = TimerDiff($ier_current_runtime)
		_p(StringFormat("Timer: %s - Readystate: %s", $ier_time_delta, $ie_readystate))
	Until $ie_readystate >= 1 Or ($ier_time_delta >= $ier_timeout * 1000)
	;DEV


	Local $ier_clipboard = ""
	Local $ier_fail = True
	Do
		$ier_clipboard = ""


		; Gets the source code of the website
		$ier_clipboard = _IEDocReadHTML($ier_handler)


		; Gets the readystate of the website
		$ie_readystate = _IEPropertyGet($ier_handler, "readystate")
		$ier_time_delta = TimerDiff($ier_current_runtime)
		_p(StringFormat("Timer: %s - Readystate: %s || (Write HTML into Error Log)", $ier_time_delta, $ie_readystate))
		_p($ier_clipboard) ;DEV


		; Checks if the searchtext is in the source code
		If StringInStr($ier_clipboard, $ier_searchtext, 0) <> 0 Then
			; Searchtext is in the Source code. Print a measage (MsgBox)
			$ier_fail = False
			_m($ier_clipboard)
		Else
			; No match
			$ier_fail = True
		EndIf


		$ier_time_delta = TimerDiff($ier_current_runtime)
		Sleep(125) ;DEV
	Until ($ier_fail == False) Or ($ier_time_delta >= $ier_timeout * 1000)
	If $ier_fail = False Then
		; String Found
		_p(StringFormat("Website Test: String %s found on Website", $ier_searchtext))
		Return True
	Else
		; String not found
		_p(StringFormat("Website Test: could not find string: %s", $ier_searchtext))
		Return False
	EndIf
EndFunc   ;==>_IEReady


Func _p($m)
	ConsoleWrite($m & @CRLF)
EndFunc   ;==>_p


Func _m($m)
	MsgBox(0, "", "String Found " & $m)
EndFunc   ;==>_m


Func _n($m)
	_p(_IENavigate($oIE, $m, 0))
	Sleep(500)
EndFunc   ;==>_n

Alles anzeigen

**Kanashius**

Du nutzt da irgendwie nen paar umwege... Bei _IENavigate($oIE, $m, 0) sagst du mit der 0, dass er nicht warten soll... Danach wartest du kompliziert mit dem Readystate...
Sag doch einfach _IENavigate($oIE, $m, 1), oder sonst _IELoadWait(), dafür sind diese Funktionen ja gedacht...
Generell, wenn du nur den Quelltext der Seite willst, brauchst du garkeinen IE, das geht viel einfacher:
$html=BinaryToString(InetRead($URL,4),4)
So kann man dein Script auf weniger als 20 zeilen kürzen:

AutoIt

_showCheckMsg("http://www.aldi.de/","USA")
_showCheckMsg("http://www.bing.de/","Bing")
_showCheckMsg("http://www.bing.de/","blub")


Func _showCheckMsg($sUrl,$sSearchText)
	if _checkWordInUrl($sUrl,$sSearchText) then
		msgbox(48,"Info",'"'&$sSearchText&'" auf "'&$sUrl&'" gefunden!')
	else
		msgbox(16,"Error",'"'&$sSearchText&'" auf "'&$sUrl&'" nicht gefunden!')
	endif
EndFunc


Func _checkWordInUrl($sUrl,$sSearchText)
	$sHtml=BinaryToString(InetRead($sUrl,4),4)
	If StringInStr($sHtml, $sSearchText) <> 0 Then
		return true
	EndIf
	return false
EndFunc

Alles anzeigen

Warum das mit dem IE mal funktioniert und mal nicht, kann ich dir auch nicht sagen, ich kann dir nur sagen, dass du da sehr viele unnötige und komplizierte Wege genommen hast, statt vorhandene Funktionen
Ich glaub ich will garnicht wissen, wo du den kram her hast

MfG Kanashius

lachi

Moin,

ja... hälfte der Informationen vergessen
Hab das Script schon zusammen gekürzt.
Dieses Script nutze ich um Websiten zu messen. Also wie lange brauch ich um diese zu öffnen.
Da aber zwischen dem Navigieren und dem fertig geladen noch andere Operation durchgeführt werden (Teilweise) und andererseits die _IELoadWait() Funktion auch Probleme bereitet, nutze ich nicht das warten von _IENavigate().

Die Seite soll gerendert werden, deswegen kann ich auch kein InetRead verwenden.
Zum Beispiel auch um weiter zu Navigieren auf der Website.

Den Readystate lese ich aus, da ich _IENavigate nicht zuverlässig verwenden kann.

Trotzdem danke für deine Hilfe!
Mfg

Runa

Das Problem tritt auch auf realer Hardware auf - zumindestens mit der aktuellen AutoIt-Version.

Das Problem ist einfach und ein typischer "DAU"-Fehler: Du verwechselt AutoIt mit einer Hochsprache. Dein Fehler im Script lässt sich mit einem Zeichen zu viel erklären: Du verwendest in Zeile 32 "==" um zu prüfen, ob $ier_timeout 1 zurückgibt. Dies ist in AutoIt allerdings nicht zulässig. Glaube in AutoIt steht "==" für "identisch".

"If Not (IsNumber($ier_timeout) = 1) Then" wäre korrekt und führt nicht mehr zu dem oben beschriebenen Problem.

lachi

Moin,

Kanashius: Ich habe es noch mal mit _p(_IENavigate($oIE, $m, 1)) anstelle von _p(_IENavigate($oIE, $m, 0)) getestet. Hier hängt er sich dann aber für lange auf. Bei meiner Methode habe ich wenigstens nach 5 Sekunden den Timeout.

Runa: Das wäre zu schön gewesen, leider hilft dies auch nicht
Habe zum Test auch sämtliche "==" entfernt, nur bringt es keine Besserung.
Mein Fehler tritt ja nicht an der Stelle auf. Der Timeout hat die ganze Zeit über hervorragend Funktioniert.

Hier die letzten Zeilen aus der Console. Ein Stück Quellcode von der Aldi Website ist gekürzt.

AutoIt: Ausgabe aus der Console

Timer: 5095.8121 - Readystate: 1 || (Write HTML into Error Log)
<html xmlns="http://www.w3.org/1999/xhtml"><head>
	<title>Welcome to ALDI</title>
[...]
</body></html>
Website Test: could not find string: Bing
+>14:30:11 AutoIt3.exe ended.rc:0
+>14:30:11 AutoIt3Wrapper Finished.
>Exit code: 0    Time: 15.52

Danke euch!

Mfg lachi

Runa

Sehe gerade: Das ist kein "zuverlässiges" Problem: Es tritt mal auf und mal nicht. Es hat nichts mit der eigentlichen Installation zu tun. Es ist wurscht ob es VM oder RM ist. Bei beiden tritt das Problem gleichermaßen auf.

Das einzige, was mir aufgefallen ist, ist, dass das Problem SEHR offensichtlich von Aldi.de verursacht wird. Denn EGAL welche Webseite ich dahinter setze, das Problem tritt weiter auf. Setze ich hingegen eine andere beliebige Seite ein - zum Beispiel autoit.de mit dem Suchwort "autoit" - funktioniert alles fehlerfrei. Das Problem scheint zu sein, dass Aldi niemals den "complete" - Status erreicht, was etwas unglücklich ist.

Das Problem ließe sich grundsätzlich dadurch lösen, dass eben nur eine Seite abgehandelt wird pro Object - an deinem Beispiel oben:

C

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseX64=n
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
;~ #AutoIt3Wrapper_Res_requestedExecutionLevel=highesAvailable
;~ #AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****


#include <IE.au3>


_n("http://www.aldi.de/")
_IEReady(0, "http://www.aldi.de/", "USA", 5)


_n("http://www.bing.de/")
_IEReady(0, "http://www.bing.de/", "Bing", 5)


_n("http://www.autoit.de/")
_IEReady(0, "http://www.autoit.de/", "autoit", 5)


Func _IEReady($ier_id, $ier_target, $ier_searchtext, $ier_timeout = 20)
	$ier_handler = _IECreate("about:blank", 0, 1, 0, 1)


	$temp = WinWait("[CLASS:IEFrame]", "", 30)


	ConsoleWrite("> Starting..." & @CRLF)
	_IENavigate($ier_handler, $ier_target, 0)
	Local $ier_current_runtime = TimerInit()
	Local $ier_time_delta = 0


	If Not (IsNumber($ier_timeout) == 1) Then
		; If the timeout is no number (Integer or Float) set a default value
		$ier_timeout = 20
	EndIf


	;DEV
	Local $ie_readystate
	Do
		$ie_readystate = _IEPropertyGet($ier_handler, "readystate")
		$ier_time_delta = TimerDiff($ier_current_runtime)
		_p(StringFormat("Timer: %s - Readystate: %s", $ier_time_delta, $ie_readystate))
	Until $ie_readystate >= 1 Or ($ier_time_delta >= $ier_timeout * 1000)
	;DEV
	Local $ier_clipboard = ""
	Local $ier_fail = True
	Do
		$ier_clipboard = ""


		; Gets the source code of the website
		$ier_clipboard = _IEBodyReadHTML($ier_handler)


		; Gets the readystate of the website
		$ie_readystate = _IEPropertyGet($ier_handler, "readystate")
		$ier_time_delta = TimerDiff($ier_current_runtime)
		_p(StringFormat("Timer: %s - Readystate: %s || (Write HTML into Error Log)", $ier_time_delta, $ie_readystate))
		_p($ier_clipboard) ;DEV


		; Checks if the searchtext is in the source code
		If StringInStr($ier_clipboard, $ier_searchtext) <> 0 Then
			; Searchtext is in the Source code. Print a measage (MsgBox)
			$ier_fail = False
			_m($ier_clipboard)
		Else
			; No match
			$ier_fail = True
		EndIf


		$ier_time_delta = TimerDiff($ier_current_runtime)
		Sleep(125) ;DEV
	Until ($ier_fail = False) Or ($ier_time_delta >= $ier_timeout * 1000)
	If $ier_fail = False Then
		; String Found
		ConsoleWrite(StringFormat("+ Website Test: String %s found on Website", $ier_searchtext) & @CRLF)
		_IEQuit($ier_handler)
		Return True
	Else
		; String not found
		ConsoleWrite(StringFormat("! Website Test: could not find string: %s", $ier_searchtext) & @CRLF)
		_IEQuit($ier_handler)
		Return False
	EndIf
EndFunc   ;==>_IEReady


Func _p($m)
	;ConsoleWrite($m & @CRLF)
EndFunc   ;==>_p


Func _m($m)
	;MsgBox(0, "", "String Found " & $m)
EndFunc   ;==>_m


Func _n($m)
	ConsoleWrite("- " & $m & @CRLF)
EndFunc   ;==>_n

Alles anzeigen

Das klärt zwar nicht, wo das Problem herkommt, aber es klärt zumindest, wie das Problem gekonnt ignoriert wird.

lachi

Moin moin,

dein Weg wäre eine Lösung, nur finde ich die leider nicht wirklich schön
Du schriebst, dass Aldi niemals den complete Status erreicht. Ja, anscheinend nicht, aber Aldi ist damit nicht die einzige Seite.
Hier folgt gleich der Quellcode einer "umfassenden" Website (13 Zeilen inkl. Header) welche das Problem auch hat.
Es gibt Head, Title, Body, Div, B, code und br.
Kein Javascript, kein Css, kein irgendetwas.
Verwende ich diese Seite als Seite 1 (getestet auf unterscheidlichen Webservern), dann kann Seite 2 nicht genutzt werden.

Vielleicht kannst du das Problem mit der Datei in deiner Umgebung Reproduzieren.

HTML

<html>
	<head>
		<title>
			Herzlich Willkommen
		</title>
	</head>
	<body>
		<div>
            <b>Dies ist eine </b> kurze Testseite.<br>
            Der Qullcode ist h&ouml;chst <code>Komplex</code>!! 
		</div>
	</body>
</html>

Alles anzeigen