Alternative Hash Funktion für MD4, MD5 & SHA-1

kaesereibe

Alternative Hash Funktion für MD4, MD5 & SHA-1
(MSDN stellt leider nicht sehr viel Informationen zu diesen Funktionen zur Verfügung)

Wie hier (MD5 Hasher optimieren | 0xf Level 20) schon beschrieben gibt es ja neben _CryptHashData() noch eine Alternative einen Hashstring zu generieren.
Ich habe das mal für MD4 und SHA erweitert. Es lässt sich (leicht umgeschrieben) auch ein File-Hash mit diesen Funktionen erstellen (leider siegt hier die Faulheit :D)

AutoIt: MD4.au3

MsgBox(0, "MD4", _MD4("test"))


Func _MD4($string)
    Static Local $hDLL = DllOpen("advapi32.dll")
    Static Local $MD4_CTX = DllStructCreate("dword i[2];dword buf[4];ubyte in[64];ubyte digest[16]")
    DllCall($hDLL, "none", "MD4Init", "ptr", DllStructGetPtr($MD4_CTX))
    DllCall($hDLL, "none", "MD4Update", "ptr", DllStructGetPtr($MD4_CTX), "str", $string, "dword", StringLen($string))
    DllCall($hDLL, "none", "MD4Final", "ptr", DllStructGetPtr($MD4_CTX))
    return Hex(DllStructGetData($MD4_CTX, "digest"))
EndFunc

Alles anzeigen

AutoIt: MD5.au3

MsgBox(0, "MD5", _MD5("test"))


Func _MD5($string)
    Static Local $hDLL = DllOpen("advapi32.dll")
    Static Local $MD5_CTX = DllStructCreate("dword i[2];dword buf[4];ubyte in[64];ubyte digest[16]")
    DllCall($hDLL, "none", "MD5Init", "ptr", DllStructGetPtr($MD5_CTX))
    DllCall($hDLL, "none", "MD5Update", "ptr", DllStructGetPtr($MD5_CTX), "str", $string, "dword", StringLen($string))
    DllCall($hDLL, "none", "MD5Final", "ptr", DllStructGetPtr($MD5_CTX))
    return Hex(DllStructGetData($MD5_CTX, "digest"))
EndFunc

Alles anzeigen

AutoIt: SHA.au3

MsgBox(0, "SHA", _SHA("test"))


Func _SHA($string)
    Static Local $hDLL = DllOpen("advapi32.dll")
    Static Local $SHA_CTX = DllStructCreate("dword unknown[6];dword state[5];dword count[2];ubyte buffer[64];ubyte digest[20]")
    DllCall($hDLL, "none", "A_SHAInit", "ptr", DllStructGetPtr($SHA_CTX))
    DllCall($hDLL, "none", "A_SHAUpdate", "ptr", DllStructGetPtr($SHA_CTX), "str", $string, "dword", StringLen($string))
    DllCall($hDLL, "none", "A_SHAFinal", "ptr", DllStructGetPtr($SHA_CTX), "ptr", DllStructGetPtr($SHA_CTX) + 0x74)
    return Hex(DllStructGetData($SHA_CTX, "digest"))
EndFunc

Alles anzeigen

Runa

Gute Arbeit. Ist sowohl auf dem Arbeitsrechner als auch auf dem zu Hause (über 500.000 Durchläufe) deutlich schneller und momentan die Schnellste (die für mich auch verständlich funktioniert) auf beiden Systemen. Nach dem angepassten Benchmark-Script (Anzahl der Läufe erhöht) von AspirinJunkie:

Code

_Crypt_HashData:    0.105 ms
             crypt-api manuell:    0.058 ms
                          _MD5:    0.023 ms
           advapi inkrementell:    0.022 ms

Es ergibt sich demnach - auf diesen Systemen (i5 und i7) kein nennenswerter Unterschied zwischen der Methode _MD5 und advapi inkrementell. Benchmark von zu Hause (über 2.500.000.000 Läufe) reiche ich nach, wenn ich wieder zu Hause am Rechner bin.

**AspirinJunkie**

Die inkrementelle Methode ist nur eine Abwandlung für den Sonderfall, dass ein zusammengesetztes Wort gehasht werden soll dessen Anfang über viele Iterationen hinweg konstant ist.
Steht also nicht wirklich in Konkurrenz zur hier vorgestellten _MD5-Funktion.
Bei meinen Tests (500.000 Durchläufe) konnte ich durch die inkrementelle Berechnung etwa 20%-30% noch rausholen:

Code

i3-4130 @ x64:
               _Crypt_HashData:    0.069 ms
             crypt-api manuell:    0.033 ms
                          _MD5:    0.021 ms
           advapi inkrementell:    0.015 ms


i3-4130 @ x86:
               _Crypt_HashData:    0.084 ms
             crypt-api manuell:    0.042 ms
                          _MD5:    0.025 ms
           advapi inkrementell:    0.018 ms


Xeon X5675 @ x64:
               _Crypt_HashData:    0.094 ms
             crypt-api manuell:    0.043 ms
                          _MD5:    0.026 ms
           advapi inkrementell:    0.021 ms


Xeon X5675 @ x86:
               _Crypt_HashData:    0.120 ms
             crypt-api manuell:    0.055 ms
                          _MD5:    0.031 ms
           advapi inkrementell:    0.023 ms

Alles anzeigen

Runa

Sorry - gestern größeres Projekt gehabt.

Code

i7-4790 @ x86:
               _Crypt_HashData:    0.069 ms
             crypt-api manuell:    0.034 ms
                          _MD5:    0.020 ms
           advapi inkrementell:    0.014 ms


i7-4790 @ x64:
               _Crypt_HashData:    0.053 ms
             crypt-api manuell:    0.025 ms
                          _MD5:    0.015 ms
           advapi inkrementell:    0.010 ms

Alles anzeigen

kaesereibe

Dann weiß ich ja, dass ich zukünftig die Crypt-Lib nicht mehr benutze, wenn ich einen einfachen Hash wie MD5 oder SHA-1 brauche.

Taz77

Super Tipp

Ich hab den Code noch ein bisschen geändert, das hat bei mir nochmal, ein paar Tausend aufrufe die Sekunde mehr gebracht

AutoIt

; #CONSTANTS# ===================================================================================================================
Global Const $__g_tMD5_CTX = DllStructCreate("dword i[2];dword buf[4];ubyte in[64];ubyte digest[16]")
Global Const $__g_pMD5_CTX = DllStructGetPtr($__g_tMD5_CTX), $__g_hDllAdvapi = DllOpen('advapi32.dll')
; ===============================================================================================================================
OnAutoItExitRegister('__Md5_Exit')


Func _Md5($sString)
	DllCall($__g_hDllAdvapi, 'none', 'MD5Init', 'ptr', $__g_pMD5_CTX)
	DllCall($__g_hDllAdvapi, 'none', 'MD5Update', 'ptr', $__g_pMD5_CTX, 'str', $sString, 'dword', StringLen($sString))
	DllCall($__g_hDllAdvapi, 'none', 'MD5Final', 'ptr', $__g_pMD5_CTX)
	Return Hex(DllStructGetData($__g_tMD5_CTX, 'digest'))
EndFunc
Func __Md5_Exit()
	DllClose($__g_hDllAdvapi)
EndFunc

Alles anzeigen