GUICtrlSetOnEvent funktioiert in zweiter GUI nicht

Psychologist

Guten Tag liebe Community,

ich hatte AutoIt vor Jahren entdeckt, einige kleine Projekte damit bewerkstelligt und es dann leider eine ganze Weile wieder vergessen.
Nun bin ich im Studium und muss ein kleines Programm für eine Studie von mir schreiben.

Nach langen Googlesuchen und mit Hilfe des Koda Form Designer habe ich nun den Anfang gemacht.
Erstmal soll das Ganze funktionieren, das Aussehen kommt danach.

Mein Problem ist, dass sich der $Button11 der zweiten GUI ($Anleitung) zwar drücken lääst, aber nicht die nächste Function triggert.
Alleinstehend ohne den Rest des Projektes funktioniert es....

Edit: Da das Highlighting hier anscheinend nicht zu 100% funktioniert ... -> http://pastebin.com/3CQw5ccD

Spoiler anzeigen

AutoIt: Problem

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Add_Constants=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#include <File.au3>


$dll = DllOpen("user32.dll") ; _isPressed wird sicher noch gebraucht


DirCreate(@ScriptDir & "\Save\")
_FileCreate(@ScriptDir & "\Save\Save.ini")


Start()




Func Start()


	#include <ButtonConstants.au3>
	#include <EditConstants.au3>
	#include <GUIConstantsEx.au3>
	#include <StaticConstants.au3>
	#include <WindowsConstants.au3>
	#Region ### START Koda GUI section ### Form=
	Opt("GUIOnEventMode", 1)
	Global $Form1_1 = GUICreate("Form1", 1002, 802, 360, 76)
	$Label1 = GUICtrlCreateLabel("Bitte beantworten Sie folgende Fragen. Alle Daten werden vertraulich behandelt.", 56, 56, 889, 35)
	GUICtrlSetFont(-1, 20, 400, 0, "Times New Roman")
	Global $Alter = GUICtrlCreateInput("", 520, 232, 249, 21)
	$Label2 = GUICtrlCreateLabel("Alter:", 176, 232, 28, 17)
	Global $male = GUICtrlCreateCheckbox("maennlich", 272, 152, 73, 33)
	Global $female = GUICtrlCreateCheckbox("Weiblich", 496, 152, 121, 41)
	$Label3 = GUICtrlCreateLabel("Matrikelnummer:", 168, 272, 81, 17)
	Global $Matrikel = GUICtrlCreateInput("", 520, 280, 249, 21)
	$Button1 = GUICtrlCreateButton("Fertig!", 784, 736, 137, 33)
	GUICtrlSetOnEvent(-1, "Func_1")
	GUISetState(@SW_SHOW)
	#EndRegion ### END Koda GUI section ###


	While 1
		Sleep(20)
	WEnd


EndFunc   ;==>Start




Func Func_1()










	If GUICtrlRead($Matrikel) = "" Then ;Matrielnummer erzwingen
		MsgBox(0, "Fehler", "Bitte alle Felder ausfüllen!")
	ElseIf GUICtrlRead($Alter) = "" Then ;Alter erzwingen
		MsgBox(0, "Fehler", "Bitte alle Felder ausfüllen!")
	ElseIf GUICtrlRead($male) == GUICtrlRead($female) Then ;Checkboxauswahl erzwingen
		MsgBox(0, "Fehler", "Bitte alle Felder ausfüllen!")
	Else
		IniWrite(@ScriptDir & "\Save\Save.ini", "Identifizierung", "Matrikelnummer", GUICtrlRead($Matrikel))
		IniWrite(@ScriptDir & "\Save\Save.ini", "Demographie", "Alter", GUICtrlRead($Alter))
		If GUICtrlRead($male) = $GUI_CHECKED Then
			IniWrite(@ScriptDir & "\Save\Save.ini", "Demographie", "Geschlecht", "maennlich")
		Else
			IniWrite(@ScriptDir & "\Save\Save.ini", "Demographie", "Geschlecht", "weiblich")
		EndIf
		GUIDelete($Form1_1)
		Func_2()


	EndIf




EndFunc   ;==>Func_1


Func Func_2() ;CODE (verhindern von Fortfahren ohne Versuchsleiter)
	$code = InputBox("Code", "Bitte geben Sie den Code ein um fortzufahren", "")
	If $code == "019" Then
		Anleitung()
	Else
		MsgBox(0, "Fehler", "Falscher Code")
		Func_2()
	EndIf


EndFunc   ;==>Func_2


Anleitung()


Func Anleitung()


	#include <ButtonConstants.au3>
	#include <EditConstants.au3>
	#include <GUIConstantsEx.au3>
	#include <StaticConstants.au3>
	#include <WindowsConstants.au3>
	#Region ### START Koda GUI section ### Form=
	Opt("GUIOnEventMode", 1)
	$Anleitung = GUICreate("Anleitung", 1001, 801, 192, 124)
	$Im = GUICtrlCreateLabel("Im folgenden werden Sie Tabellen mit '0' und '1' sehen. Ihre Aufgabe ist es, die Anzahl der '1'en zu bestimmen. Sie haben 10 Minuten Zeit um soviele Tabellen wie moeglich zu loesen.", 64, 128, 868, 17)
	$Label1 = GUICtrlCreateLabel("Verbleibende Zeit", 680, 240, 135, 25)
	GUICtrlSetFont(-1, 14, 400, 0, "Times New Roman")
	$Label2 = GUICtrlCreateLabel("Beispiel", 432, 192, 92, 36)
	GUICtrlSetFont(-1, 18, 800, 0, "Nirmala UI")
	$Label3 = GUICtrlCreateLabel("1010010101", 128, 272, 134, 33)
	GUICtrlSetFont(-1, 18, 400, 0, "MS Sans Serif")
	$Label4 = GUICtrlCreateLabel("0101010101", 128, 304, 134, 33)
	GUICtrlSetFont(-1, 18, 400, 0, "MS Sans Serif")
	$Label5 = GUICtrlCreateLabel("1101011011", 128, 336, 134, 33)
	GUICtrlSetFont(-1, 18, 400, 0, "MS Sans Serif")
	$Label6 = GUICtrlCreateLabel("0110101010", 128, 368, 134, 33)
	GUICtrlSetFont(-1, 18, 400, 0, "MS Sans Serif")
	$Label7 = GUICtrlCreateLabel("1111000100", 128, 400, 134, 33)
	GUICtrlSetFont(-1, 18, 400, 0, "MS Sans Serif")
	$Loesung = GUICtrlCreateInput("Loesung", 504, 392, 265, 21)
	$Label8 = GUICtrlCreateLabel("Die Aufgabe beginnt mit einem Klick auf folgenden Button:", 344, 592, 279, 17)
	$Button11 = GUICtrlCreateButton("Verstanden", 424, 648, 105, 57)
	GUICtrlSetOnEvent(-1, "Aufgabe_1") ; Funktioniert leider nicht
	GUISetState(@SW_SHOW)


	#EndRegion ### END Koda GUI section ###


	While 1
		Sleep(20)
	WEnd


EndFunc   ;==>Anleitung


Func Aufgabe_1()
	MsgBox(0, "!", "!")
	Exit
EndFunc   ;==>Aufgabe_1

Alles anzeigen

P.S.: Ich bin mir sicher, vieles geht besser und einfacher. Für Verbesserungen bin ich immer offen

Danke schonmal,
Nico

**Kanashius**

Der kram:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Opt("GUIOnEventMode", 1)

hat in Funktionen so nichts verloren (Zeile 7 nur in Ausnahmen zum wechseln des Modus). Das solltest du an den Anfang der Datei packen und aus den beiden Funktionen, wo die Guis erstellt werden, entfernen. Nur weil Koda das mitgibt heißt es noch lange nicht, dass es dahin gehört...
Wenns schick werden soll rate ich persönlich auch von Koda ab. Wenn man die Controls selbst erstellt wird es oft ordentlicher (auch vom Code her).

Dein Problem kommt auch vom Copy&Paste aus Koda. Deine 2te Gui (Anleitung) wird mit einem Event betreten. In dem Event befindet sich eine while-Schleife. Events sollten aber so schnell wie möglich verlassen werden. Wenn du die Schleife weglässt sollte es funktionieren. Events werden nacheinander abgearbeitet, deshalb muss das vorherige Event verlassen werden, bevor das nächste bearbeitet werden kann.
Im normalfall hat man im OnEventModus auch nur EINE While-Schleife die die ganze Zeit läuft.
Standartaufbau:

AutoIt

#include ;...
Opt();z.B. OnEventmode


global $var ;Variablen deklaration (wenn nötig, gerade bei Guis im OnEventMode 
            ; für alle Controls notwendig, die auch außerhalb der 
            ; Gui-Funktion verwendet werden sollen. )
global $SomeControl,$GuiAnleitung


;HauptGui starten (Kann auch in eine Funktion geschrieben werden
$gui=GuiCreate("blub",100,100)
guisetstate(@SW_Show)


;Hauptschleife, damit das Programm an bleibt.
While sleep(10)
WEnd


;Funktionen
Func _Anleitung()
    $GuiAnleitung=GuiCreate("Anleitung",200,200)
    $SomeControl=GuiCtrlCreateButton("msg1",10,10)
    GuiCtrlSetOnEvent(-1,"_switchMsg")
    GuiSetOnEvent(-3,"_CloseAnleitung")
    GuiSetState(@SW_SHOW)
EndFunc


Func _switchMsg()
    GuiCtrlSetDate($SomeControl,"close now")
EndFunc


Func _CloseAnleitung()
    GuiDelete($GuiAnleitung)
EndFunc

Alles anzeigen

(Kann kleinere Syntax-Fehler enthalten, bin grad auf Linux->kein AutoIt)

MfG Kanashius

Psychologist

Vielen Dank Patrick!

Ich werde mal versuchen, das Ganze umzusetzen

Psychologist

Kleines Update: Alles umgesetzt und es funktioniert einwandfrei

Dankeschön!