Countdown-, Jahreszähler-Skript

Anagastes

Moin,

ich habe vor ein Skript zu erstellen welches von einem angegebenem Datum die noch zu verstreichende Zeit anzeigt. Am besten als Countdown.

Z.b. 01.01.2020 ist das Ziel-Datum. Dann wird angezeigt wie viel Zeit noch verstreichen muss. In einem kleinen GUI-Fenster.

Ich habe bis jetzt nur die klassischen Countdowns hinbekommen, gebe aber auch zu dass ich da Anfänger bin.

Jemand ne Idee?

Grüße

**BugFix**

Dazu brauchst du nur _DateDiff

Anagastes

Stimmt. Damit bekomme ich jedoch nur eine einmalige Ausgabe hin. Für mich wäre ein fortlaufender Countdown aber sinnvoller. Und da habe ich echt null Plan.

Eine reine Anzeige mit der Differenz ist schnell gebastelt.

Spoiler anzeigen

AutoIt

#include <Date.au3>
#include <MsgBoxConstants.au3>
Local $hours = _DateDiff('h', _NowCalc(), "2017/01/01 00:00:00")
Local $seconds = _DateDiff('s', _NowCalc(), "2017/01/01 00:00:00")
MsgBox($MB_SYSTEMMODAL, "Countdown", "Zeit bis Rente in Stunden: "  & $hours&": " & "In Sekunden: " &$seconds)

Ich habe das hier z.b. gefunden. Klasse Idee. Aber auch hier ist es kein echter Countdown. Ich würde die Ausgabe gerne in Jahre, Tage, Stunden, Sekunden haben und mit einem Timer der herunter zählt.

Spoiler anzeigen

AutoIt

While 1
    $Diff = _DateDiff("D", _NowCalc(), "2017/01/15")
    $Time = _NowTime()
ToolTip($Time & @CRLF & $Diff&" Tage bis zur Rente", 0,0)
Sleep(10)
WEnd

**BugFix**

AutoIt

#include <Date.au3>


AdlibRegister('_RefreshTime', 1000)


$Zieldatum = '2016/01/01 00:00:00'
$hGUI = GUICreate('Countdown', 220, 120)
GUICtrlCreateLabel('Zeit bis zum Silvester-Feuerwerk', 10, 10, 200, 17)
$Time = GUICtrlCreateLabel('', 10, 40, 200, 40)
GUICtrlSetFont(-1, 16, 600, Default, 'Comic Sans MS')
GUICtrlSetColor(-1, 0x000080)


GUISetState()
Do
Until GUIGetMsg() = -3


Func _RefreshTime()
	Local $iDiff = _DateDiff('s', _NowCalcDate() & ' ' & _NowTime(5), $Zieldatum)
	GUICtrlSetData($Time, _FormatSeconds($iDiff))
EndFunc


Func _FormatSeconds($_sec)
	Return ( $_sec < 60 ? StringFormat('00:00:%02u', $_sec) : _
             $_sec < 60*60 ? StringFormat('00:%02u', Floor($_sec/60)) & ':' & _
			        StringFormat('%02u', Mod($_sec,60)) : _
			 $_sec < 60*60*24 ? StringFormat('%02u', Floor($_sec/3600)) & ':' & _
                    StringFormat('%02u', Floor(Mod($_sec,3600)/60)) & ':' & _
                    StringFormat('%02u', Mod(Mod($_sec,3600),60)) : _
			 ( $_sec = 86400 ? "24:00:00" : Floor($_sec/86400) & ' d / ' & _
					StringFormat('%02u', Floor(Mod($_sec,86400)/3600)) & ':' & _
					StringFormat('%02u', Floor(Mod(Mod($_sec,86400),3600)/60)) & ':' & _
					StringFormat('%02u', Mod(Mod(Mod($_sec,86400),3600),60)) & ' h') )
EndFunc

Alles anzeigen

Ich hatte meine Formatfunktion nur auf Tage ausgeweitet. Wenn du noch nach Jahren aufdröseln möchtest, musst du entsprechend erweitern. Wobei für ein genaues Ergebnis dann die Schaltjahre berücksichtigt werden müssen.

Anagastes

Jop, das kann ich modifizieren und ist super zum lernen. Danke