Letzte Seite von PDF Dokument erkennen

hypestar

Hallo zusammen,
ich bin neu hier im Forum und hoffe, dass ich hier richtig bin mit meiner Problematik.

Zum Projekt:
Im Rahmen eines Projektes müssen wir messen, wie lange es dauert eine PDF Datei zu öffnen, diese einmal durchzublättern (mit der Taste "Ende" ans Ende der Datei springen) und zu schließen.

Zur Problematik:
Natürlich müssen dabei einige mögliche Fehler abgefangen werden. Das Skript läuft soweit einwandfrei, nur einen Fehler kriegen wir leider nicht abgefangen. Bis jetzt ist das Skript immer schön ans Ende des PDF-Dokumentes gesprungen, allerdings wollen wir natürlich für den Fall gewappnet sein, dass das Skript einmal (aus welchen Gründen auch immer) nicht ans Ende springt.

Unsere Idee:
Wir wollen so wenig externe Software wie möglich verwenden, daher dachten wir an eine Texterkennung, da es sich um ein festes PDF-Dokument (es wird nie geändert) handelt. Wir könnten auch ein Bild ans Ende des PDF-Dokumentes setzen, um mit einer Bilderkennung zu arbeiten.
Bei der Bilderkennung werden wir wohl nicht um eine externe Software rumkommen, daher stelle ich das erst einmal hinten an.
Bei der Texterkennung ist mir unklar wie man hier vorgehen soll, da man keinen Klartext aus einer PDF-Datei lesen kann und mit strg+a, strg+c können wir auch nicht arbeiten, da das Dokument mehrere 100 Seiten groß ist und es nur um einen Auszug von Text auf der letzten Seite geht der kontrolliert werden muss.

Gibt es eine Möglichkeit irgendwie zu überprüfen, ob wir auf der letzten Seite angekommen sind?
Hoffe ihr versteht die Problematik und könnt mir weiterhelfen.

MfG

Runa

Grundsätzlich ist das möglich.

Jetzt ist die Frage, wie - und dazu muss erst die Frage geklärt werden, welches Programm ihr zum Anzeigen der PDF im Augenblick verwendet...

Zum Anzeigen von PDF-Dateien gibt es ja unzählige - auch kostenlose - Programme, die alle einen anderen Lösungsweg erfordern würden... und bei manchen Kandidaten könntest du dort auch noch versionsbedingt zu Problemen kommen, die man hier nicht abfangen kann. Hier mal eine Liste an PDF-Viewern, die ich alleine vom Umgang mit unseren Kunden kenne:

Adobe Acrobat Reader DC
Foxit Reader
PDF-XChange Viewer
Adobe Acrobat XI Pro

....

Schon diese vier hätten grundlegend andere Ansätze um dieses Problem zu beseitigen...

hypestar

Entschuldigung, das habe ich total aus den Augen verloren.

Wir benutzen den Adobe Acrobat X Standard in der Version 10.1.15.

Runa

mhm... den habe ich zum Testen gerade nicht da ... eventuell klappt es aber mit der Lösung für den Adobe Acrobat Reader DC ... müsstest du mal testen:

AutoIt

#include <String.au3>
;// Datei die eingelesen wird
$sFile = 'O:\C# Tutorial - Uni Trier.pdf'
;// Reader-Spezifische Variablen
$sAdobeClass = "AcrobatSDIWindow"
$sAdobeEdit_Class = "Edit"
$iAdobeEdit_Instance = "2"
;// Öffnen der PDF-Datei im Reader
ShellExecute($sFile)
;// Warten bis das Fenster aktiv ist
WinWaitActive("[CLASS:" & $sAdobeClass & "]")
;// Ende an das Fenster senden
Send("{END}")
;// Liest die aktuelle Seite aus dem Adobe Reader DC aus
$iActualPage = ControlGetText("[CLASS:" & $sAdobeClass & "]", "", "[CLASS:" & $sAdobeEdit_Class & "; INSTANCE:" & $iAdobeEdit_Instance& "]")
;// Ausgabe ob letzte Seite oder nicht
If $iActualPage = ReadFile($sFile) Then
	MsgBox(64, "", "Letzte Seite")
Else
	MsgBox(16, "", "Nicht die letzte Seite")
EndIf
;// Gibt die Anzahl der Seiten innerhalb der PDF-Datei zurück - je größer die Datei, desto länger dauert es.
Func ReadFile($file)
	ToolTip("Reading amount of pages...")
	Local $xCtPg = 0
	$fsz = FileGetSize($file)
	$fileHd = FileOpen($file, 16)
	$Fch = FileRead($fileHd, $fsz)
	FileClose($fileHd)
	$objNr = GetObj($Fch, "/Root")
	$objCon = ReadObj($Fch, $objNr)
	If StringInStr($objCon, "/Pages") > 0 Then
		$xon = GetObj(_StringToHex($objCon), "/Pages")
		$xoc = ReadObj($Fch, $xon) ;$xon)
		$xCtPg = GetCount($xoc)
	EndIf
	ToolTip("")
	Return $xCtPg
EndFunc   ;==>ReadFile
Func GetObj($fc, $type)
	$typeh = _StringToHex($type)
	$x = StringMid($fc, StringInStr($fc, $typeh), 80)
	$x = _HexToString($x)
	$xct = StringLen($type)
	$xon = StringMid($x, $xct + 2, StringInStr($x, " R") - $xct - 2)
	Return $xon
EndFunc   ;==>GetObj
Func ReadObj($fc, $xon)
	$objh = _StringToHex(" obj")
	$objendh = _StringToHex("endobj")
	$xonh = _StringToHex($xon)
	$xonhs = "0D" & $xonh & $objh
	$x = StringMid($fc, StringInStr($fc, $xonhs, 0, -1))
	If $x = "" Then $x = StringMid($fc, StringInStr($fc, "0A" & $xonh & $objh, 0, -1))
	$xoch = StringMid($x, 1, StringInStr($x, $objendh) - 1)
	$xoc = _HexToString($xoch)
	Return $xoc
EndFunc   ;==>ReadObj
Func GetCount($xoc)
	$xocx = StringMid($xoc, StringInStr($xoc, "/Count ") + 7)
	$xct = ""
	For $i = 1 To 5
		$x = StringMid($xocx, $i, 1)
		$y = StringIsInt($x)
		If $y = 1 Then
			$xct &= $x
		Else
			ExitLoop
		EndIf
	Next
	Return $xct
EndFunc   ;==>GetCount

Alles anzeigen

Falls das nicht funktioniert, musst du drei Variablen auswechseln ... alle unter dem Kommentar "Reader-Spezifische Variablen". Diese Informationen bekommst du alle mit dem Tool "AU3Info", welches Du im Editor unter "Tools" findest, sofern du ihn von dieser Seite bezogen hast. Ich hoffe, du weißt, wie du damit umgehen musst?

$sAdobeClass => Die Klasse des Adobe-Fensters
$sAdobeEdit_Class => Die Klasse des Inputfeldes in dem die aktuelle Seite steht
$iAdobeEdit_Instance => Die Instanz des Inputfeldes

Bitte denk daran, die gewünschte Datei auch anzugeben - ich bin mir nicht sicher, ob du das Laufwerk "O:\" mit dieser PDF besitzt...

hypestar

Funktioniert bestens, vielen dank für deine Mühen!

Mache mich dann mal ans verstehen der Funktionen GetObj, ReadObj und GetCount