PNG->Hex

; ============================================================================================================================
; Purpose  : Converts any file to HEX binary string
; Author   : Ward / UEZ
; ============================================================================================================================


Local $VarName = StringStripWS(InputBox("Convert to Binary String", "Select a name for the variable." & @CRLF & @CRLF & "$ will automatically added to the beginning of the variable!:", "BinaryString"), 3)
If $VarName = "" Then Exit


Local $FileName = FileOpenDialog("Open a file", @ScriptDir, "DLL file (*.*)")
If $FileName = "" Then Exit


Local $Handle = FileOpen($FileName, 16)
Local $BinaryString = FileRead($Handle)
FileClose($Handle)


Local $LineLen = 1024
Local $DllString = String($BinaryString)


Local $Script = "Func " & $VarName & "()" & @CRLF & @TAB & "Local _" & @CRLF & @TAB & "$" & $VarName & " = '" & StringLeft($DllString, $LineLen) & "'" & @CRLF
$DllString = StringTrimLeft($DllString, $LineLen)




While StringLen($DllString) > $LineLen
    $Script &= "    $" & $VarName & " &= '" & StringLeft($DllString, $LineLen) & "'" & @CRLF
    $DllString = StringTrimLeft($DllString, $LineLen)
WEnd


If StringLen($DllString) <> 0 Then $Script &= "    $" & $VarName & " &= '" & $DllString & "'" & @CRLF
 $Script &= @TAB & "Return Binary($" & $VarName & ")" & @CRLF & "EndFunc"
;~ ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $Script = ' & $Script & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
ClipPut($Script)


MsgBox(64, "Convert to Binary String", "The result is in the clipboard, you can paste it to your script.")