CPU Auslastung verringern - objwmiservice.execquery( select * from win32_service")

TheDeath24

Hi zusammen,

Ich habe mir ein kleines Programm geschrieben womit ich den aktuellen Zustand mehrer Windows Dienste ausliest.
Doch leider ist die CPU Auslastung hoch und ich wollte mal fragen ob es dort Verbesserung Potenzial gibt?

Funktion die momentan verwendet wird.

Spoiler anzeigen

AutoIt: Auslesen des Zustandes

#Region Statusmode
Func _statusmode()
For $i = 0 To _GUICtrlListView_GetItemCount($listview) -1
Local $objWMIService = ObjGet('winmgmts:\\.\root\cimv2')
Local $colItems = $objWMIService.ExecQuery("Select * From Win32_Service")
If IsObj($colItems) Then
	For $objItem In $colItems
	if _GUICtrlListView_GetItemText($listview, $i, 2) = $objItem.DisplayName Then
	   _GUICtrlListView_SetItemText($listview, $i, $objItem.StartMode,0)
	   _GUICtrlListView_SetItemText($listview, $i, $objItem.State,1)
   EndIf
	Next
 EndIf
Next
EndFunc
#EndRegion Statusmode

Alles anzeigen

_GUICtrlListView_GetItemCount($listview) = Dienste die Nachgeschaut werden

Versuch klappt aber nicht.

Spoiler anzeigen

AutoIt: Erster Versuch Direkt nach dem Dienst zu suchen

#Region Statusmode


#Region Statusmode


Func _statusmodetest()




For $i = 0 To _GUICtrlListView_GetItemCount($listview) -1


Local $objWMIService = ObjGet('winmgmts:\\.\root\cimv2')
Local $colItems = $objWMIService.ExecQuery('Select * From Win32_Service where Name=' & "'%" & _GUICtrlListView_GetItemText($listview, $i, 2) & "%'")




If IsObj($colItems) Then
	For $objItem In $colItems
	if _GUICtrlListView_GetItemText($listview, $i, 2) = $objItem.DisplayName Then
	   _GUICtrlListView_SetItemText($listview, $i, $objItem.StartMode,0)
	   _GUICtrlListView_SetItemText($listview, $i, $objItem.State,1)
    EndIf
	Next
EndIf


Next




EndFunc

Alles anzeigen

Irgendwie klappt das aber nicht so wie ich es gedachte habe.

Vielleicht kann mir da jemand weiterhelfen?

**autoBert**

liefert diese func:

Code

#Region Statusmode
Func _statusmode()
	Local $objWMIService = ObjGet('winmgmts:\\.\root\cimv2')
	Local $colItems = $objWMIService.ExecQuery("Select * From Win32_Service")
	If IsObj($colItems) Then
		For $objItem In $colItems
			For $i = 0 To _GUICtrlListView_GetItemCount($listview) - 1
				If _GUICtrlListView_GetItemText($listview, $i, 2) = $objItem.DisplayName Then
					_GUICtrlListView_SetItemText($listview, $i, $objItem.StartMode, 0)
					_GUICtrlListView_SetItemText($listview, $i, $objItem.State, 1)
				EndIf
			Next
		Next
	EndIf
EndFunc   ;==>_statusmode
#EndRegion Statusmode

Alles anzeigen

nicht das gleiche Ergenisse wie deine, nur etwas schneller?

**AspirinJunkie**

Dein Skript erzeugt schlicht keine Last.
Es kann auch keiner ausführen um es zu testen.
Mach doch am besten ein kleines Minimalbeispiel.

Ich vermute aber, dass du die Funktion in einer Endlosschleife immer wieder aufrufst.
Dabei wird immer ein neues WMI-Objekt erstellt und die Daten abgefragt - jedes mal aufs neue.
Eine Möglichkeit wäre daher wenigstens das WMI-Objekt immer wieder zu verwenden und die nächste Stufe wäre ein Refresher-Objekt zu verwenden.

Mal als Grundaufbau für deine Funktion:

AutoIt

Func _statusmode()
	Local Static $o_WMI = ObjGet("winmgmts:\\.\root\cimv2")
	Local Static $o_WMIRefresher = ObjCreate("WbemScripting.Swbemrefresher")
	Local Static $o_ServiceData = $o_WMIRefresher.AddEnum($o_WMI, "Win32_Service").objectSet


	$o_WMIRefresher.Refresh
	For $o_Service In $o_ServiceData
        ConsoleWrite($o_Service.DisplayName & @TAB & $o_Service.StartMode & @TAB & $o_Service.State & @CRLF)
	Next
EndFunc

Alles anzeigen

In der Endlosschleife sollte auch noch ein Sleep mit eingebaut werden um der CPU ne Pause zu gönnen.

TheDeath24

Danke euch beiden.

Beides hat mich weitergebracht. Das Ergebnis habe ich nun schneller und das mit dem Sleep befehl in der Schleife hat auch sehr viel gebracht.

Super danke euch beiden.