MAC Array mit einem FileArray vergleichen

CoDeX2k

Hallo liebe AutoITler,

ich habe mich an einem Script versucht welches wohl eine Nummer zu gross war für mich alleine. Desshalb hat mich peethebee da ein wenig unterstütz jedoch gibt es mir immoment immer eine Fehlermeldung aus wenn ich es duchlaufen lasse.

C

#include <array.au3>
#include <file.au3>


$filename = "C:\ipconfig.txt"
$source_filename = "C:\macs.txt"


; Macs auslesen
RunWait(@ComSpec & " /c ipconfig /all > " & $filename, "", @SW_HIDE)
Dim $array
_FileReadToArray($filename, $array)
$text = _ArrayToString($array, ";")
$macs = StringRegExp($text, ":\s((?:\A\A-){5}\A\A);", 3)
_ArrayDisplay($macs, "Macs")


; Macs vergleichen
Dim $filearray
_FileReadToArray($source_filename, $filearray)
;~ _ArrayDisplay($filearray, "filearray")
For $i = 1 To UBound($filearray)
$filearray_splitted = StringSplit($filearray[$i], ":")
For $j = 0 To UBound($macs)
 If $filearray_splitted[3] = $macs[$j] Then
  MsgBox(0, "MAC-Adresse gefunden", "Ihre MAC-Adresse wurde gefunden")
 Else
  MsgBox(0, "MAC-Adresse wurde nicht gefunden", "Ihre MAC-Adresse wurde nicht gefunden")
 EndIf
Next
Next

Alles anzeigen

Die Datei macs.txt sieht wie folgt aus:

test1:test1:00-0C-6E-CE-75-48:2006/07/30
test2:test2:00-15-A4-60-EE-48:2006/07/27

Leider kriege ich diese Fehlermeldung:

(23) : ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
MsgBox(0,$macs[$j],"")
MsgBox(0,^ ERROR

Grüsse
CoDeX

**peethebee**

Antwore kommt gleich, ist ja z.T. mein Skript

Edit:

C

#include <array.au3>
#include <file.au3>


$filename = "C:\ipconfig.txt"
$source_filename = "C:\macs.txt"


Global $found = ""


; Macs auslesen
RunWait(@ComSpec & " /c ipconfig /all > " & $filename, "", @SW_HIDE)
Dim $array
_FileReadToArray($filename, $array)
$text = _ArrayToString($array, ";")
$macs = StringRegExp($text, ":\s((?:\A\A-){5}\A\A);", 3)
_ArrayDisplay($macs, "Macs")


; Macs vergleichen
Dim $filearray
_FileReadToArray($source_filename, $filearray)
;~ _ArrayDisplay($filearray, "filearray")
For $i = 1 To UBound($filearray)-1
$filearray_splitted = StringSplit($filearray[$i], ":")
For $j = 0 To UBound($macs)-1
If $filearray_splitted[3] = $macs[$j] Then
$found = $macs[$j]
ExitLoop
EndIf
Next
Next


; Ausgabe
If $found <> "" Then
MsgBox(0, "MAC-Adresse gefunden", "Ihre MAC-Adresse wurde gefunden ("&$found&")")
Else
MsgBox(0, "MAC-Adresse nicht gefunden", "Ihre MAC-Adresse wurde nicht gefunden.")
EndIf


; temporäre Datei löschen
FileDelete($filename)

Alles anzeigen

Es fehlte zweimal das -1 bei den Ubounds. Außerdem habe ich die Ausgabe wieder so gebaut, dass er auch sagt, wenn er nichts gefunden hat. Bei Fund zeigt er die entsprechende MAC-Adresse an (allerdigns max. eine).

peethebee

CoDeX2k

Genau, 99.99% davon sind von dir und meine 00.01% hätten eh ned funktioniert

CoDeX2k

Öhm irgendwas läuft da noch schief....

(24) : ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
If $filearray_splitted[3] = $macs[$j] Then
If ^ ERROR

btw. mein Notebook hat zwei Mac Adressen

**peethebee**

Hast du eine Leerzeile unten in deiner MAC-Adressen-Datei?

peethebee

CoDeX2k

hatte ich jetzts geht's sorry...

EDIT:
Es es möglich zu schauen ob der Username und das Passwort zu der MAC Adresse passen? Ich hatte sowas früher mal gemacht habe den Code noch jedoch war es da nur mit einer MAC er musste nicht mehrere Mac Adressen vergleichen.

Code

If StringInStr($text,$Username & ":")=0 Then

		MsgBox(0,"Username/Passwort","Sie haben Username/Passwort falsch eingegeben!")
		Exit
	Else
		If StringInStr($text,$Username & ":" & $Password & ":")=0 Then

			MsgBox(0,"Username/Passwort","Sie haben Username/Passwort falsch eingegeben!")
			Exit
		Else
			If StringInStr($text,$Username & ":" & $Password & ":" & $Mac & ":")=0 Then

				MsgBox(0,"MAC-Adresse","Sie haben die falsche MAC-Adresse um die Applikation auszuführen!")
				Exit
			Else
				If _DateDiff("D",$now,$datum)>=0 Then
					If $looping=0 Then
						MsgBox(0,"Erfolgreich","Ihre Daten konnten erfolgreich verifiziert werden." & @LF &"Klicken Sie auf OK und warten Sie bis das Interface gestartet ist.")
						$looping=1
					Else
						$looping=1
					EndIf
				Else

					MsgBox(0,"Abgelaufen","Ihr Account ist inaktiv!")
					Exit
				EndIf
			EndIf
              EndIf
   Endif

Alles anzeigen

**peethebee**

Wo kommen Username und Passwort her?
Und wieso stehen die scheinbar im Klartext in der Datei?

peethebee

CoDeX2k

weil sie aus der datei kommen und inzwischen MD5 Crypted sind. Aber das ist ja für das Beispiel ziemlich egal. Ich kann die ja nachträglich MD5 Crypten und Decrypten.

Grüsse
CoDeX

**peethebee**

Muss der User User/Pass eingeben? Per Inputbox, oder wie?
Sonst habe ich ja nichts zum gegenchecken...

peethebee

CoDeX2k

Genau. Das ganze ist schon gescriptet. Funktioniert auch super. Jedoch möchte ich diese eben verbessern da wir Probleme bezüglich MAC Adresse hatten. Das wir die nicht zu ordnen konnten wenn mehrere Vorhanden wahren und ein User mal per WLAN und mal per LAN das Tool benutzen wollte.

Grüsse
CoDeX

**bernd670**

Hallo!

Um dir zu helfen bnötige ich noch folgende Information. Die Variable $text enthält die bereits die gültige Kombination aus Username, Passwort und Mac-Adresse oder kann es mehrere gültige Kombinationen geben die aus einer Datei gelesen werder müssen.

Wenn es nur eine gültige Kombination gibt und die bereits in $text steht sollte die Lösung funktionieren:

Spoiler anzeigen

C

#include <array.au3>
#include <file.au3>


Global $filename = @TempDir & "\ipconfig.txt"
Global $found = False


; Macs auslesen
RunWait(@ComSpec & " /c ipconfig /all > " & $filename, "", @SW_HIDE)
Dim $array
_FileReadToArray($filename, $array)
$text = _ArrayToString($array, ";")
$macs = StringRegExp ($text, ":\s((?:\A\A-){5}\A\A);", 3)
;~ _ArrayDisplay($macs, "Macs")


If StringInStr($text, $Username & ":") = 0 Then

	MsgBox(0, "Username/Passwort", "Sie haben Username/Passwort falsch eingegeben!")
	Exit
Else
	If StringInStr($text, $Username & ":" & $Password & ":") = 0 Then

		MsgBox(0, "Username/Passwort", "Sie haben Username/Passwort falsch eingegeben!")
		Exit
	Else
		For $j = 0 To UBound($macs) - 1
			If StringInStr($text, $Username & ":" & $Password & ":" & $macs[$j] & ":") Then
				$found = True
				ExitLoop
			EndIf
		Next

		If Not $found Then
			MsgBox(0, "MAC-Adresse", "Sie haben die falsche MAC-Adresse um die Applikation auszuführen!")
			Exit
		Else
			If _DateDiff("D", $now, $datum) >= 0 Then
				If $looping = 0 Then
					MsgBox(0, "Erfolgreich", "Ihre Daten konnten erfolgreich verifiziert werden." & @LF & "Klicken Sie auf OK und warten Sie bis das Interface gestartet ist.")
					$looping = 1
				Else
					$looping = 1
				EndIf
			Else
				MsgBox(0, "Abgelaufen", "Ihr Account ist inaktiv!")
				Exit
			EndIf
		EndIf
	EndIf
EndIf


FileDelete($filename)

Alles anzeigen

**peethebee**

Meine Version:

C

#include <array.au3>
#include <file.au3>
#include <Date.au3>


$filename = "C:\ipconfig.txt"
$source_filename = "C:\macs.txt"




; Macs auslesen
RunWait(@ComSpec & " /c ipconfig /all > " & $filename, "", @SW_HIDE)
Dim $array
_FileReadToArray($filename, $array)
$text = _ArrayToString($array, ";")
$macs = StringRegExp($text, ":\s((?:\A\A-){5}\A\A);", 3)
_ArrayDisplay($macs, "Macs")


; Macs vergleichen
Dim $filearray
_FileReadToArray($source_filename, $filearray)
For $i = 1 To UBound($filearray) - 1
	$filearray_splitted = StringSplit($filearray[$i], ":")
	For $j = 0 To UBound($macs) - 1
		If $filearray_splitted[3] = $macs[$j]Then
			; Benutzernamen checken
			If $filearray_splitted[1] <> _hash(InputBox("Benutzername", "Benutzernamen eingeben:")) Then
				MsgBox(0, "Benutzername inkorrekt", "Sie haben einen falschen Benutzernamen eingegeben!")
				Exit
			EndIf
			; Passwort checken
			If $filearray_splitted[2] <> _hash(InputBox("Passwort", "Passwort eingeben:", "", "*")) Then
				MsgBox(0, "Passwort inkorrekt", "Sie haben ein falsches Passwort eingegeben!")
				Exit
			EndIf
			; Ablauf checken
			If _DateDiff("D", _NowCalcDate(), $filearray_splitted[4]) < 0 Then
				MsgBox(0, "Abgelaufen", "Ihr Account ist abgelaufen!")
				Exit
			EndIf
		EndIf
	Next
Next


; temporäre Datei löschen
FileDelete($filename)




Func _hash($_hash_string)
	; Testfunktion, die nicht hashed
	Return $_hash_string
EndFunc   ;==>_hash

Alles anzeigen

peethebee

p.s. 3:1 für bernd

bernd: dabei habe extra ne 1/2 Stunde gewartet ob jemand antwortet bevor ich mit meiner Lösung angefangen habe!

**peethebee**

Hallo!

Hier eine verbesserte Version, die auch mit 2 MAC-Adressen in einem Rechner klarkommt und dennoch nur einmal User und Pass abfragt.

C

#include <array.au3>
#include <file.au3>
#include <Date.au3>


$filename = "C:\ipconfig.txt"
$source_filename = "C:\macs.txt"




; Macs auslesen
RunWait(@ComSpec & " /c ipconfig /all > " & $filename, "", @SW_HIDE)
Dim $array
_FileReadToArray($filename, $array)
$text = _ArrayToString($array, ";")
$macs = StringRegExp($text, ":\s((?:\A\A-){5}\A\A);", 3)


; Benutzernamen holen:
$user = InputBox("Username", "Bitte geben Sie ihren Benutzernamen ein:", "")
If $user <> "" Then ; Fehler abfangen		
	Dim $filearray
	; Datei mit den Daten einlesen in das Array filearray
	_FileReadToArray($source_filename, $filearray)
	; Alle Einträge durchgehen
	For $i = 1 To UBound($filearray) - 1
		; Einträge aufsplitten, sodass Zugriff auf die Einzelteile komfortable wird
		$filearray_splitted = StringSplit($filearray[$i], ":")
		; Die Zeile mit dem richtigen Username finden
		If $filearray_splitted[1] = $user Then
			; Mac checken
			; alle im Rechner gefundenen MACs durchgehen
			For $j = 0 to UBound($macs)
				; wenn keine Mac zum Schleifenverlassen geführt hat, dann Exit
				If $j = UBound($macs) Then
					MsgBox(0, "raus", "nichts gefunden")
					Exit
				EndIf
				; Mac aus Datei mit vorhandener Mac verlgeichen
				If $filearray_splitted[3] = $macs[$j] Then
					ExitLoop
				EndIf
			Next
			; Passwort checken
			If $filearray_splitted[2] <> _hash(InputBox("Passwort", "Passwort eingeben:", "", "*")) Then
				MsgBox(0, "Passwort inkorrekt", "Sie haben ein falsches Passwort eingegeben!")
				Exit
			EndIf
			; Ablauf checken
			If _DateDiff("D", _NowCalcDate(), $filearray_splitted[4]) < 0 Then
				MsgBox(0, "Abgelaufen", "Ihr Account ist abgelaufen!")
				Exit
			EndIf
			; Alles korrekt
			MsgBox(0, "Online", "Zugangsdaten korrekt, verbinde mit Service...")
			; hier käme alles hin, was geht, wenn man eingeloggt ist. Eventuell der Übersichtlichkeit halber in eine Funktion auslagern
		EndIf
	Next	
EndIf


; temporäre Datei löschen
FileDelete($filename)




Func _hash($_hash_string)
	; Testfunktion, die nicht hashed
	Return $_hash_string
EndFunc   ;==>_hash

Alles anzeigen

peethebee