Messagebox Fenster schließen

AutoMit

Hallo,

wie im Beispiel zu sehen ist, habe ich ein Hauptfenster, welches es beim Klick auf den "Button 0" ein Kindfenster aufrufen soll (benutzerdefinierte Message Box).

Das Kindfenster soll (optional) im Vordergrund bleiben, bis es geschlossen wird. Wie kann ich das realisieren?

Wenn ich auf den Button "Ende" bzw. das x im Messagebox-Fenster klicke, soll nur das Messagebox-Fenster geschlossen werden, ohne dass das Hauptfenster geschlossen wird.

Was muss ich im Script ändern, damit das funktioniert?

Welche besseren Möglichkeiten gibt es, von einem Hauptfenster eine benutzerdefinierte, positionierbare Messagebox zu erstellen, ohne den msgbox Befehl zu benutzen?

Code

#include <GUIConstantsEx.au3>


MainGUI()


Func MainGUI()
	Local $Button0, $msg0
   GUICreate("Hauptfenster", 800, 600)
   Opt("GUICoordMode", 2)
   $Button0 = GUICtrlCreateButton("Button 0", 10, 30, 90, 50)
	GUISetState()
   While 1
	 $msg0 = GUIGetMsg()
	 Select
	  Case $msg0 = $GUI_EVENT_CLOSE
		ExitLoop
	  Case $msg0 = $Button0		;	hier wird das Messagebox Fenster aufgerufen
			ButtonGUI()
	  EndSelect
   WEnd


EndFunc






Func ButtonGUI()
   Local $Button1, $Button2, $Button3, $Button4, $msg2
   GUICreate("Messagebox", 400, 200)
   Opt("GUICoordMode", 2)
   $Button1 = GUICtrlCreateButton("Button 1", 10, 30, 90, 50)
   $Button2 = GUICtrlCreateButton("Button 2", 0, -1)
   $Button3 = GUICtrlCreateButton("Button 3", 0, -1)
   $Button4 = GUICtrlCreateButton("Ende", 0, -1)
   GUISetState()


   While 1
	 $msg2 = GUIGetMsg()
	 Select
	  Case $msg2 = $GUI_EVENT_CLOSE
		ExitLoop
	  Case $msg2 = $Button1
		MsgBox(0, 'Button 1', 'Button 1 was pressed')
	  Case $msg2 = $Button2
		MsgBox(0, 'Button 2', 'Button 2 was pressed')
	  Case $msg2 = $Button3
		MsgBox(0, 'Button 3', 'Button 3 was pressed')
	  Case $msg2 = $Button4
			WinClose("[ACTIVE]")														; so funktioniert das nicht
	  EndSelect
   WEnd


EndFunc

Alles anzeigen

Übrigens - unabhängig von obigem Script - gibt es einen Trick, ein msgbox Fenster zu positionieren, so dass es nicht mittig angezeigt wird?

Danke

**autoBert**

Hier mal ein Skript aus der Konserve (Grundprinzip siehe: letzes Beispiel von https://www.autoitscript.com/wiki/Managing_…essageLoop_Mode)

AutoIt

#include <GUIConstantsEx.au3>
#include<WindowsConstants.au3>


Global $hGui1, $hGui2 = -99, $idMsgBox, $idZurueck, $idbtnExit2
;_CreateGui2() ;entweder hier oder erst wenn benötigt ($idbtmToGui2 Klick)
#Region GUI1 #####################################################################################
$hGui1 = GUICreate('GUI 1', 400, 280, 140, 150, BitOR($WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SIZEBOX),$WS_EX_TOPMOST)
;erzeugt eine GUI , das zurückgebebene Handle wird in der Variablen $hGui1 gespeichert
;die GUI hat BOXen für Mininmieren, Maximieren und ist in der Größe frei änderbar


$idbtnToGui2 = GUICtrlCreateButton('&Aufruf GUI 2', 20, 20, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKLEFT + $GUI_DOCKTOP)
;verankert den Button "Aufruf Gui 2" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand


$idbtnICQ = GUICtrlCreateButton('&ICQ', 20, 50, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKLEFT + $GUI_DOCKTOP)
;verankert den Button "ICQ" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand


$idbtnExit1 = GUICtrlCreateButton('be&enden', 280, 225, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKBOTTOM)
;verankert den Button "beenden" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand


GUISetState(@SW_SHOW, $hGui1)
#EndRegion ###########################################################################################


While 1
	$nMsg = GUIGetMsg(1) ;extended Modus wichtig!!
	Switch $nMsg[1] ;für welches Fenster ist die Message
		Case $hGui1 ;ab hier ist Gui 1 dran
			Switch $nMsg[0] ;welche Message wurde ausgelöst
				Case $idbtnToGui2
					GUISetState(@SW_DISABLE, $hGui1) ;Gui 1 gegen Benutzereingaben sperren
					If $hGui2 = -99 Then _CreateGui2() ;nur wenn noch nicht erzeugt
					GUISetState(@SW_SHOW, $hGui2) ;Gui 2 anzeigen
				Case $idbtnICQ
					MsgBox(0, "", "Jetzt würde ICQ gestartet", 0, $hGui1)
					;Run("C:\Program Files\ICQ7.0\ICQ.exe")
				Case $idbtnExit1, $GUI_EVENT_CLOSE
					_end()
			EndSwitch
		Case $hGui2 ;ab hier ist Gui 2 dran
			Switch $nMsg[0] ;welche Message wurde ausgelöst
				Case $idMsgBox
					MsgBox(0, 'Test', 'Test', 0, $hGui2)
				Case $idZurueck, $GUI_EVENT_CLOSE
					GUISetState(@SW_ENABLE, $hGui1) ;Gui 1 wieder entsperren
					GUISetState(@SW_HIDE, $hGui2) 	;Gui 2 verstecken
				Case $idbtnExit2
					_end()
			EndSwitch
	EndSwitch
WEnd


Func _CreateGui2()
	$hGui2 = GUICreate('GUI 2', 400, 280, 200, 50, -1, -1, $hGui1) ;wichtig ist der letzte Parameter
	;erzeugt eine GUI als Child von Gui1, das zurückgebebene Handle wird in der Variablen $hGui2 gespeichert
	$idMsgBox = GUICtrlCreateButton('&MsgBox', 20, 20, 100, 21)
	$idZurueck = GUICtrlCreateButton('&Zurück zu GUI 1', 20, 50, 100, 21)
	$idbtnExit2 = GUICtrlCreateButton('be&enden', 280, 250, 100, 21)
	GUISetState(@SW_HIDE, $hGui2) ;Gui 2 vorerst verstecken
EndFunc   ;==>_CreateGui2


Func _end()
	GUIDelete($hGui2)
	GUIDelete($hGui1)
	Exit
EndFunc   ;==>_end

Alles anzeigen

zum positionieren der MsgBox fällt mir nur ein nachträgliches WinMove ein.

mfg (auto)Bert

**Kanashius**

Damit es vor dem Hauptfenster bleibt: Beim erstellen beim Parent das Hauptfenster übergeben. Sonst WinSetOnTop.
Für die Messagebox: unsichtbare gui erstellen, die an der passenden position sitzt und der msgbox den parent mitgeben, die box wird dann mittig von dem fenster positioniert, sonst mit winmove verschieben.
Zum schließen: Vor dem ExitLoop ein GuiDelete nutzen.

AutoMit

Vielen Dank Euch zwei.

Die Lösung steckt in "GuiDelete".

Grünen Haken gesetzt.