ListView Drag&Drop und WM_NOTIFY

Gremlin78

Hallo Leute,
ich muss nochmal mein Beispiel-Script aufgreifen, da sich ein neues Problem ergeben hat.
Ich wollte gern die Doubleclick-Funktion von ChaosKeks verwenden und musste leider feststellen, dass dadurch leider kein Drag&Drop im ListView mehr möglich ist.

Spoiler anzeigen

C

#include <GUIConstantsEx.au3>
#include <GUIListViewEx.au3>
#include <WindowsConstants.au3>
Global $idListView
Example()
Func Example()
	Local $hGUI=GUICreate("listview items", 250, 300, -1, -1)
	$idListview = GUICtrlCreateListView("col_1 |col_2|col_3 ", 0, 0, 250, 260)
	Local $idButton = GUICtrlCreateButton("add entry", 10, 270, 230, 20)
	$i = 1
	GUISetState(@SW_SHOW)
	_GUIListViewEx_MsgRegister()
	Local $idLV = _GUIListViewEx_Init($idListview, '', 0, 0, True)
	GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $idButton
				_GUIListViewEx_Close($idLV)
				GUICtrlCreateListViewItem("item_1_"&$i&"|item_2_"&$i&"|item_3_"&$i, $idListview)
				$idLV = _GUIListViewEx_Init($idListview, '', 0, 0, True)
				$i=$i+1
		EndSwitch
	WEnd
EndFunc   ;==>Example
Func WM_NOTIFY($hWnd, $MsgID, $wParam, $lParam) ;<================== Benachrichtigung Doppelklick (Original from Chaoskeks [in ChaosExecution])
	Local $tagNMHDR = "hwnd hWndFrom;uint_ptr IDFrom;INT Code"
	Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
	Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	Local $iCode = DllStructGetData($tNMHDR, "Code")
	$tagNMHDR = DllStructCreate("int;int;int", $lParam)
	If @error Then Return 0
	Local $Ycode = DllStructGetData($tagNMHDR, 3)
	If $wParam = $idListView Then
		Select
			Case $hWndFrom = GUICtrlGetHandle($idListView)
				Select
					Case $iCode = $NM_DBLCLK
						If _GUICtrlListView_GetSelectedCount($idListView) > 0 Then
							For $i = 0 To _GUICtrlListView_GetItemCount($idListView)
								If _GUICtrlListView_GetItemSelected($idListView, $i) Then
									$aItem = _GUICtrlListView_GetItemTextArray($idListView, $i)
									MsgBox(0, 'Beispiel', $aItem[1] & @CRLF & $aItem[2]& @CRLF& $aItem[3])
								EndIf
							Next
						EndIf
				EndSelect
		EndSelect
	EndIf
	Return $GUI_RUNDEFMSG
	$tagNMHDR = 0
	$lParam = 0
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

Hat jemand ne Idee, wo mein Fehler liegt?
Grüße Gremlin

**Kanashius**

Du musst nur in deiner WM_NOTIFY($hWnd, $MsgID, $wParam, $lParam) Methode
_GUIListViewEx_WM_NOTIFY_Handler($hWnd, $MsgID, $wParam, $lParam)
aufrufen (am besten direkt am Anfang).

Das Problem ist, dass dein GUIRegisterMsg die Registrierung der UDF überschreibt (in _GUIListViewEx_MsgRegister() wird WM_NOTIFITY registiert).
Somit musst du nur die Funktion, die dort registriert wird manuell aufrufen.
Dort wird neben $WM_NOTIFY auch $WM_MOUSEMOVE,$WM_LBUTTONUP und $WM_SYSCOMMAND registriert. Fall du also eine davon registrieren musst, musst du auch die entsprechenden Funktionen aufrufen.
Du darfst auf keinen Fall dein GuiRegisterMsg hinter dem _GUIListViewEx_MsgRegister schreiben, andernfalls wird deine Registrierung überschrieben -> nur der kram der UDF funktioniert. Dort willst du deine Aufrufe ja nicht reinschreiben, denke ich

MfG Kanashius

Gremlin78

Vielen Dank Kanashius,
Du bist Spitze. Es funktioniert 1A.
Ich hatte die Funktion in der GUIListViewEx UDF gefunden und dachte ich muss die WM_NOTIFY-Funktion gegen diese ersetzen, aber das hatte leider auch nicht funktioniert. Darauf, dass sie mit eingebunden werden muss wäre ich nicht gekommen.

Nochmals Danke,
Gruß Gremlin