Zeile für Zeile (geht das irgendwie schneller?)

P1xelfehler

Hallo,

mein Programm soll Zeile für Zeile eine Datei durchlaufen, und in einem anderen Format in einer anderen Datei speichern.

Aber es dauert eeeewig. Und als ich vorhin ausversehen die ganze Zeit die gleiche Zeile in die Zieldatei geschrieben habe, ging das wesentlich schneller.

Geht das irgendwie schneller?
Hier der Code:

Code

#include <File.au3>


$Path = "C:\Users\testdatei.xyz"
$Datei = FileOpen($Path)
$Zieldatei = FileOpen("C:\Documents\Projekte\fertig_testdatei.xyz",1)
$Lines = _FileCountLines ($Path)
$Counter = 0


While $Counter < $Lines
   $ZeileNow = FileReadLine($Datei,$Counter)
   $X = StringTrimRight($ZeileNow, 19)
   $Y = StringTrimLeft(StringTrimRight($ZeileNow, 8), 12)
   $Z = StringTrimLeft($ZeileNow, 25)


   FileWriteLine($Zieldatei, $X & ";" & $Y & ";" & $Z & @CRLF)


   $Counter = $Counter + 1
WEnd

Alles anzeigen

Zeitriss

Hi,

Du darfst nicht für jede Zeile immer neu auf die Datei zugreifen.
Lese sie in einem schwung mit Fileread aus, um die Datei einfacher zu bearbeiten kannst du dann Stringsplit benützen.
Vor dem Schreiben der Zieldatei dann alles in ein String packen und mit einem Filewrite in die Datei schreiben.

Ist das der aufbau der Datei?
xxxxxxx.....yyyyyy.......z
xxxxxxx.....yyyyyy.......z

Wenn ja sollte auch folgendes funktionieren:

AutoIt

$sInput = FileRead("...")
   $sOutput = StringRegExpReplace($sInput, "(?m)^(.{7}).{5}(.{6}).{7}(.)$", "$1;$2;$3")
   FileWrite("...", $sOutput)

mfg
Zeitriss

P1xelfehler

Vielen Dank! Nur verstehe ich das nicht so ganz:

Code

$sOutput = StringRegExpReplace($sInput, "(?m)^(.{7}).{5}(.{6}).{7}(.)$", "$1;$2;$3")

Zeitriss

Hi,

Siehe dir hierzu die Hilfe von StringRegExp und StringRegExpReplace an.
Es gibt hierzu auch min. ein Tutorial hier im Forum.
Hier nur eine kurze Beschreibung wie ich es hier versucht habe.

"(?m)^(.{7}).{5}(.{6}).{7}(.)$"

(?m) - Gibt an das der Multiline-Modus benützt wird (s. Hilfe StringRegExp)
.{7} - 7 Beliebige Zeichen die den X-Wert ergeben
.{5} - 5 Beliebige Zeichen die wir nicht brauchen
.{6} - 6 Beliebige Zeichen die den Y-Wert ergeben
.{7} - 7 Beliebige Zeichen die wir nicht brauchen
. - 1 Beliebiges Zeichen welches den Z-Wert ergibt
^ - Start einer Zeile
$ - Ende einer Zeile
() - Schließen die Werte ein die wir später noch brauchen, also X,Y und Z (back-reference)

"$1;$2;$3"

Hier nützen wird die "back-reference" (s. Hilfe StringRegExpReplace)
$1 - referenziert auf die erste Klammer (also den X-Wert)
$2 - referenziert auf die zweite Klammer (also den Y-Wert)
$3 - referenziert auf die dritte Klammer (also den Z-Wert)

Wir ersetzen also die Zeile durch die Platzhalter mit den Werten, welche wir oben eingeklammert haben.
Das Semikolon ist nur das Trennzeichen im Endergebniss.

P1xelfehler

Danke sehr!

**AspirinJunkie**

Du musst auch nicht die ganze Datei in den Speicher hauen und dann dort zerlegen.
Du kannst auch problemlos weiter die Datei Zeile für Zeile (speichersparend) abarbeiten.
Nur halt nicht ganz so wie du es gemacht hast, denn dann wird es wirklich langsam.
Wo lag der Fehler?
Beim Benutzen des Zeilennummerparameter von FileReadLine.

Was passiert wenn man eine Zeilennummer dort angibt?:

Die Datei wird geöffnet.
Es wird an den Anfang der Datei gesprungen.
Es wird die Datei von Anfang an durchgearbeitet bis die Anzahl an Zeilenumbrüchen erreicht wurde.
Diese Zeile wird dann zurückgegeben.
Die Datei wird geschlossen.

Und warum ist das langsam? - Nun das wird bei jedem einzelnen Aufruf erneut gemacht.
Aber wenn wir die erste Zeile schon haben wollen wir für die Zweite Zeile nur die nächste haben. Er soll nicht wieder an den Anfang springen.
Und das erreicht man wenn man die Datei öffnet und die Datei mit FileReadLine durchgeht ohne den Zeilenparameter zu verwenden.

Kurz - so sollte es bedeutend schneller vonstatten gehen:

AutoIt

Global $s_SourceFile = "C:\Users\testdatei.xyz"


; Datei zum Lesen öffnen
Global $h_FileRead = FileOpen($s_SourceFile, 0)
; Datei zum Schreiben öffnen:
Global $h_FileWrite = FileOpen("C:\Documents\Projekte\fertig_testdatei.xyz", 1)


Global $s_Line


; Datei zeilenweise durchgehen
Do
	; nächste Zeile lesen
	$s_Line = FileReadLine($h_FileRead)
	If @error Then ExitLoop ; z.B. Ende der Datei erreicht


	$X = StringTrimRight($s_Line, 19)
	$Y = StringTrimLeft(StringTrimRight($s_Line, 8), 12)
	$Z = StringTrimLeft($s_Line, 25)


	FileWriteLine($h_FileWrite, $X & ";" & $Y & ";" & $Z)
Until 0


FileClose($h_FileRead)
FileClose($h_FileWrite)

Alles anzeigen