RGB (Grün)Farbenmischer besserer Speed möglich?

Texos

Moin,

Weiß jemand zufällig wie ich diesen Code in der Berechnung schneller machen könnte? Gibt es vlt. Dll's auf die man da zurückgreifen kann oder habt ihr eine Idee?

Die Funktion ermittelt in einem angegebenen Bereich die Grünwerte und verrechnet diese zu einem "Mittelwert".

Die Funktion benötigt derzeit für ein (5x5 Feld 25 Pixel) 643ms und für ein (10x10 Feld 100 Pixel) 2565ms

Edit: Durch ändern der inneren Funktion auf $green += Dec(StringMid(PixelGetColor($x, $y), 3, 2)) komme ich auf 2069ms bei 100 Pixel

Code

Func get_gcolor_checksum($start_x, $start_y, $end_x, $end_y)
    Local $sum = abs($end_x-$start_x+1)*abs($end_y-$start_y+1)
    Local $green = 0
    For $y = $start_y To $end_y
        For $x = $start_x To $end_x
            $green += Dec(StringMid(PixelGetColor($x, $y), 3, 2))
        Next
    Next
    Return "00"&Hex(BitAND($green/$sum, 255), 2)&"00"
EndFunc

Texos

Hat sich schon erledigt.

Code

Func get_gcolor_checksum($start_x, $start_y, $end_x, $end_y)
    _GDIPlus_Startup()

    Local $hBMP = _ScreenCapture_Capture("", $start_x, $start_y, $end_x, $end_y)
    Local $pBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)

    Local $iWidth = abs($end_x-$start_x+1)
    Local $iHeight = abs($end_y-$start_y+1)
    Local $iSum = $iWidth*$iHeight
    Local $iGreen = 0

    Local $tBitmapData = _GDIPlus_BitmapLockBits($pBitmap, 0, 0, $iWidth, $iHeight, $GDIP_ILMREAD, $GDIP_PXF32RGB)
    Local $tPixel = DllStructCreate("dword[" & $iWidth * $iHeight & "];", DllStructGetData($tBitmapData, "Scan0"))
    For $iX = 0 To $iWidth - 1
        For $iY = 0 To $iHeight - 1
            $iGreen += Dec(StringMid(Hex(BitAND(DllStructGetData($tPixel, 1, $iY * $iWidth + $iX + 1), 0xFFFFFF), 6), 3, 2))
        Next
    Next
    _GDIPlus_BitmapUnlockBits($pBitmap, $tBitmapData)

    _GDIPlus_BitmapDispose($pBitmap)
    _WinAPI_DeleteObject($hBMP)
    _GDIPlus_Shutdown()
    Return "00" & Hex(BitAND($iGreen/$iSum, 255), 2) & "00"
EndFunc

Alles anzeigen