StringRegExp String finden und erstezten

ruby

Hallo Leute,

haben unten stehen Code und der funktioniert nicht so richtig wie ich will.

In der Datei stehen mehrere Zeilen die so aussehen: style="animation: EJicyqvP_draw 55ms linear 2900ms forwards"

Hier möchte

- das der Name nach animation: ausgetauscht wird in Variable $sReplace

- der Wert vor linear ausgetauscht wird in Variable $zeit

- der Wert nach linear ausgetauscht wird in Variable $zeit * $i

Aber igendwie verschluckt sich der Code beim Austauschen der Variable nach liniear.

Mit den Suchmusterstring stehe ich auf Kriegsfuß "(?U)xxxxxxxx:\h+(\H+)\h", 3) ????

Könnte man mir helfen?

Gruß

Code

Local $sFileName = "test.txt"


Local $sText = FileRead($sFileName)


;Name der neuen animation:
Local $sReplace = "myani"
Local $zeit = "500ms"


; ändert Name nach animation:
$aArray = StringRegExp($sText, "(?U)animation:\h+(\H+)\h", 3)
For $i = 0 To UBound($aArray) - 1
ConsoleWrite("animationname: " & $aArray[$i] & @CRLF)
$sResult = StringRegExpReplace($sText, $aArray[$i], $sReplace)
Next

$animationname = $aArray[0] ;braucht man noch einmal für den animationsname, siehe unten

; das ist der gefundene wert vor linear und wird gloabl in 500ms geändert, das ist die zeitdauer für einen gezeichneten path
$aArray = StringRegExp($sResult, "(?U)" & "animation: " &  $sReplace & "\h+(\H+)\h", 3)
For $i = 0 To UBound($aArray) - 1
ConsoleWrite("zeit: " & $aArray[$i] & @CRLF)
$sResult = StringRegExpReplace($sResult, $aArray[$i], $zeit)
Next

; gesamte zeit für svg
$aArray = StringRegExp($sResult, "(?U)linear\h+(\H+)\h", 3) ;suche wert nach linear
For $i = 0 To UBound($aArray) - 1
ConsoleWrite("linearezeit: " & $aArray[$i] & @CRLF)
$sResult = StringRegExpReplace($sResult, $aArray[$i], $i * $zeit)
Next

;ändert diese Einträge, kommen auch nur einmal vor
$sResult = StringRegExpReplace($sResult,"<style data-made-with=""vivus-instant"">", "<style>")
$sResult = StringRegExpReplace($sResult, "94.44444444444444%", "100%")
$sResult = StringRegExpReplace($sResult, StringTrimRight($animationname, 5), $sReplace)

ConsoleWrite($sResult)

Alles anzeigen

**AspirinJunkie**

AutoIt

$sFile = FileRead("test.txt")

$sReplace = "myani"
$iZeit = 500
$i = 20

$sFile = StringRegExpReplace($sFile, 'style="animation:\h*\K\w+', $sReplace)
$sFile = StringRegExpReplace($sFile, '\d+ms\h+linear\h+\d+ms', $iZeit & "ms linear " & $iZeit * $i & "ms")

ConsoleWrite($sFile)

ruby

Hallo AspirinJunkie,

vielen Dank, aber warum muss da keine Schleife drum?

Die Zeit hinter linear sollte immer um eins erhöht werden, so oft wie der Wert vorkommt.

erster Wert = 0, zweiter Wert = linear 500ms, dritter Wert = linear 1000ms , vierter Wert = 1500ms usw.

Deswegen habe ich bei meinem Code immer eine Schleife gewählt.

Wie kann kann ich jetzt mit Deinem Code hier eine Schleife machen.

Gruß

**AspirinJunkie**

Zitat von ruby

warum muss da keine Schleife drum?
Die Zeit hinter linear sollte immer um eins erhöht werden, so oft wie der Wert vorkommt.

Weil du das nicht geschrieben hast.

Damit wird es nun ein bisschen aufwendiger.
Ich habe mal für meinen Ansatz den Offset-Parameter von StringRegEx genutzt. Damit kann man sich schrittweise durch den String arbeiten:

AutoIt

$sFile = FileRead("test.txt")

$sReplace = "myani"
$iZeit = 500

$sFile = StringRegExpReplace($sFile, 'style="animation:\h*\K\w+', $sReplace)

Local $iPos = 0, $iZeit2 = $iZeit
Do
    $aMatch = StringRegExp($sFile, '\d+ms\h+linear\h+\d+ms', 1, $iPos)
    If @error Then ExitLoop
    $iPos = @extended

    $sFile = StringLeft($sFile, $iPos - StringLen($aMatch[0]) - 1) & $iZeit & "ms linear " & $iZeit2 & "ms " & StringTrimLeft($sFile, $iPos)

    $iZeit2 += $iZeit
Until False

ConsoleWrite($sFile)

Alles anzeigen

ruby

Ahh, vielen Dank funktioniert.

Klasse Forum, tolle Hilfe.

**AspirinJunkie**

Zitat von ruby

Ahh, vielen Dank funktioniert.

Ja aber im Grunde ist das gar nicht mal so toll wenn ich genauer darüber nachdenke.

SVG ist XML und sollte daher auch entsprechend behandelt werden.
Folgendes ist die bessere Variante:

AutoIt

Global $oXML = ObjCreate("Microsoft.XMLDOM")
Global $sReplace = "myani", $iZeit = 500, $iZeit2 = 0

$oXML.load("test.txt")

For $oPath In $oXML.selectNodes("/svg/path[@style]")
    $oPath.setattribute('style', StringFormat('animation: %s %dms linear %dms forwards', $sReplace, $iZeit, $iZeit2))
    $iZeit2 += $iZeit
Next

$oXML.save("test2.txt")

Alles anzeigen

ruby

Du bist der Hammer.

11 Zeilen Code, Wahnsinn

Ich muss noch viel viel lernen. An deine Programmierkünste werde ich eh nie herankommen.

Tausend Dank.

Ich traue moch garnicht zu fragen, da ich noch was vergessen habe.

In dem Text muss auch noch der String EJicyqvP ausgewechselt werden in myani_draw und myani_fade.

Aber ich will es mal versuchen.

@keyframes EJicyqvP_draw {

to {

stroke-dashoffset: 0;

}

@keyframes EJicyqvP_fade {

0%,

94.44444444444444% {

stroke-opacity: 1;

}

to {

stroke-opacity: 0;

}

</style>

**AspirinJunkie**

Zitat von ruby

In dem Text muss auch noch der String EJicyqvP ausgewechselt werden in myani_draw und myani_fade.

Hm hier muss man eher wieder auf StringRegEx zurück, da der Inhalt ne eigene Struktur aufweist.
Aber zumindest die Elementauswahl kann man über XML-Funktionen lösen:

AutoIt

Global $oXML = ObjCreate("Microsoft.XMLDOM")
Global $sReplace = "myani", $iZeit = 500, $iZeit2 = 0

$oXML.load("test.txt")

For $oPath In $oXML.selectNodes("/svg/path[@style]")
    $oPath.setattribute('style', StringFormat('animation: %s %dms linear %dms forwards', $sReplace, $iZeit, $iZeit2))
    $iZeit2 += $iZeit
Next

$oStyle = $oXML.SelectSingleNode("/svg/style")
$oStyle.text = StringRegExpReplace($oStyle.text, '@keyframes\h\K\w+(?=\_(?:draw|fade))', $sReplace)

$oXML.save("test2.txt")

Alles anzeigen

ruby

Alles klar, nochmal vielen Dank.

Kann abgeschlossen werden