InetGet Funktioniert einach nicht...

AlucardXtreme

Moin,

und zwar habe ich schon dutzende arten versucht, das irgendwie hinzubekommen.... aber ich schaffe es einach nicht.

Es soll einfach nur die URL aufrufen, den Text abspeichern und mit dem denn das InetGet ausführen.

die .php gibt nur 2 strings aus und nicht mehr.

Biite um Hilfe

Mit freundlichen Grüßen

C

#include <InetConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>
#include <AutoItConstants.au3>
#include <Inet.au3>
Global $FertigSumme = 0
Global $hDownload = 0
Global $DownRead = 0
Global $Downsize = 0


Func Example()

Global $string
$string = StringSplit( _INetGetSource('http://www.zockery.de/huch.php'), ";")

Global $DownLoadSelect =  $string[2]
Global $DownLoadLocation =  $string[1]
        $hDownload = InetGet($DownLoadLocation,$DownLoadSelect, 1, 1)
Sleep(5000)

        ProgressOn("Download" & @CRLF & "..." , "0%", -1, -1, BitOR($DLG_NOTONTOP, $DLG_MOVEABLE))
        Do



$DownRead = InetGetInfo ( $hDownload, 0 )
$DownSize = InetGetInfo ( $hDownload, 1 )






$FertigSumme = ($DownRead*100)/$DownSize




                ProgressSet(round($FertigSumme,1), round($FertigSumme,1) & "%")

If InetGetInfo ( $hDownload, $INET_DOWNLOADSIZE ) == InetGetInfo ( $hDownload, $INET_DOWNLOADREAD ) Then
        ProgressSet(100, "Download", "Complete")
                Sleep(5000)

        ProgressOff()
        EndIf



        Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)


        InetClose($hDownload)
     EndFunc






Example()

Alles anzeigen

AlucardXtreme

Zum Verständnis noch mal. Es handelt sich NICHT um irgendeine Illegale Tätigkeit. Ich möchte nur eine von mir geschaffene Datei von meinem Server runterladen.

Und alle Daten habe ich auch.

Bin auch der Meinung, dass es mittels ftp oder sftp oder ftps geht. Nur fehlt mir dazu noch die Kenntniss da eine Fortschrittsanzeige zu haben um das Script solange zu pausieren, bis der Download fertig ist.

Mit freundlichen Grüßen

oh-ha

Warum nimmst du nicht einfach das Beispiel aus der Hilfe und passt es etwas an?

C

; Script Start - Add your code below here
#include <InetConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

; InetGet downloaded eine Datei im Hintergrund.
; Das AutoIt Skript prüft in einer Schleife, ob der Download vollständig ist.

Example()

Func Example()
    ; Speichert die heruntergeladene Datei in den temporären Ordner.
    Local $sFilePath = _WinAPI_GetTempFileName(@TempDir)
FileOpen($sFilePath)
    ; Lädt die Datei im Hintergrund mit den ausgewählten Optionen von 'Erzwingt ein erneutes Laden von der Remote-Seite' herunter.
    Local $hDownload = InetGet("http://www.zockery.de/huch.php", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

    ; Wartet bis der Download komplett ist. Dabei wird solange gewartet, bis der zweite Wert von InetGetInfo True zurückgibt.
    Do
        Sleep(250)
    Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)

    ; Ermittelt die übertragenen Bytes und die Dateigröße.
    Local $iBytesSize = InetGetInfo($hDownload, $INET_DOWNLOADREAD)
    Local $iFileSize = FileGetSize($sFilePath)

    ; Schließt das durch InetGet zurückgegebene Handle.
    InetClose($hDownload)

    ; Zeigt Details über die gelesenen Bytes und die Dateigröße.
    MsgBox($MB_SYSTEMMODAL, "", "heruntergeladene Bytes: " & $iBytesSize & @CRLF & _
            "gesamte Dateigröße: " & $iFileSize)
; Datei öffnen
ShellExecute($sFilePath)
EndFunc   ;==>Example

Alles anzeigen

**Kanashius**

Hi, ich hab das Script umgeschrieben und Fehlerbehandlung hinzugefügt. Sollte man generell bei allen Scripts machen, um Fehler schneller zu finden.

AutoIt

#include <InetConstants.au3>
#include <AutoItConstants.au3>

_downloadFile()
If @error Then
    MsgBox(16, "Error downloading", @error&" => "&@extended)
Else
    MsgBox(64, "Info", "Download done.")
EndIf

Func _downloadFile()
    Local $bLocationData = InetRead('http://www.zockery.de/huch.php')
    If @error Then Return SetError(1, @error, False)
    Local $sLocationData = BinaryToString($bLocationData)
    ; Should be 0: URL, 1: Target-File
    Local $arLocationData = StringSplit($sLocationData, ";", BitOr(1, 2))
    If UBound($arLocationData)<>2 Then Return SetError(2, UBound($arLocationData), False)
    $arLocationData[0] = "http://"&$arLocationData[0]
    ConsoleWrite($arLocationData[0]&@TAB&$arLocationData[1]&@CRLF)
    ; Create parent directory
    DirCreate(StringRegExpReplace($arLocationData[1], "(.*)/[^/]*", "$1"))

    Local $hDownload = InetGet($arLocationData[0], $arLocationData[1], 1, 1)
    ProgressOn("Download" & @CRLF & "..." , "0%", -1, -1, BitOR($DLG_NOTONTOP, $DLG_MOVEABLE))
    Local $iDownloadSize = InetGetInfo($hDownload, $INET_DOWNLOADSIZE)
    Local $iProgress
    Do
        $iDownloadSize = InetGetInfo($hDownload, $INET_DOWNLOADSIZE)
        If $iDownloadSize=0 Then
            ProgressSet(50, InetGetInfo($hDownload, $INET_DOWNLOADREAD) & "/? bytes", "Downloading File")
        Else
            $iProgress = InetGetInfo($hDownload, $INET_DOWNLOADREAD)/$iDownloadSize*100
            ProgressSet($iProgress, round($iProgress,1) & "%", "Downloading File")
        EndIf
        Sleep(100)
    Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)

    ConsoleWrite(InetGetInfo($hDownload, $INET_DOWNLOADERROR)&" : "&InetGetInfo($hDownload, $INET_DOWNLOADEXTENDED)&@crlf)
    ; Got Extended Error: 12006
    ; Look up at https://learn.microsoft.com/en-us/windows/win32/wininet/wininet-errors => ERROR_INTERNET_UNRECOGNIZED_SCHEME

    If InetGetInfo($hDownload, $INET_DOWNLOADERROR) Then Return SetError(3, InetGetInfo($hDownload, $INET_DOWNLOADERROR)&" : "&InetGetInfo($hDownload, $INET_DOWNLOADEXTENDED), False)
    InetClose($hDownload)
    ProgressSet(100, "100%", "Download Complete")
    Sleep(1000)
    ProgressOff()

    Return True
EndFunc

Alles anzeigen

Ich hab mehrere Problemstellen gefunden:

1. Bei InetGet muss der Ordner, in den die Datei heruntergeladen werden soll, bereits existieren => Ich erstell den Parent-Folder vorher.

2. Bei InetGet muss das Schema der URL passen. Beim auslesen von $INET_DOWNLOADEXTENDED hab ich den Fehler 12006 bekommen. Nachgeschaut auf https://learn.microsoft.com/en-us/windows/…/wininet-errors steht der Fehler für ERROR_INTERNET_UNRECOGNIZED_SCHEME. Irgendetwas stimmt also mit der URL nicht. Dabei ist mir aufgefallen, dass http:// am Anfang fehlt und ich habs hinzugefügt. (InetGet fügt das nicht automatisch hinzu, so wie Browser, die annehmen, dass normalerweise eine http anfrage gemeint ist.)

Jetzt läuft es bei mir (habs aber nicht bis zum Ende laufen lassen; keine Lust auf >100GB download :D)

AlucardXtreme

Danke,

Es funktioniert.... ENDLICH

Ganz Ganz Gaaaaaaaaaanz lieben Dank