Suche für Liste

WhiteHorse

Hallo, ich möchte gerne eine Suche erstellen, habe dies aber auch noch nie gemacht und habe nichts Passendes gefunden, was mir weiterhelfen kann. Da die Namen in einer Liste stehen, die mit einem Inputfeld gesucht werden sollen, sobald man die ersten Buchstaben eingibt.

Beispiel ich gebe den Namen Msgbox 5 in das Inputfeld ein, dann sollen die anderen Namen aus der Liste verschwinden und nur noch Msgbox 5 ist in der Liste zu finden.

Ich habe mal eine Test GUI erstellt

und habe auch in den Code beschrieben wie, was passieren soll und gemacht werden soll. Nur leider weiß ich gar nicht, wie man bei einer Suchfunktion überhaupt vorgeht.

Auf jeden Fall soll jeder Name, der in der Liste steht, eine eigene Funktion aufrufen.

Vielleicht habt ihr Ideen oder könnt mir auf die Sprünge helfen. Ich lerne gerne dazu

C

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1_1 = GUICreate("Suche Test", 616, 438, 192, 124)
$Suche = GUICtrlCreateInput("", 240, 32, 121, 21)
GUICtrlSetCursor (-1, 5)
$Label1 = GUICtrlCreateLabel("Suche", 272, 8, 47, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$SuchergebnisseBox = GUICtrlCreateList("", 56, 80, 121, 67)
GUICtrlSetData(-1, "Msgbox 1|Msgbox 2|Msgbox 3|Msgbox 4|Msgbox 5|Msgbox 6|Msgbox 7|Msgbox 8|Test Moin") ;Gibt es hier eine Möglichkeit, das besser anzuordnen. Da es vorkommen kann das etliche Namen noch dazu kommen und die liste im Code zu lang wird?
GUICtrlSetCursor (-1, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
            
        Case $SuchergebnisseBox

    EndSwitch
WEnd


;Funktion ist nur eine Vorbereitung von mir, weiß aber nicht, ob das überhaupt so funktioniert?
Func 
    ;hier ggf. mit einem If Befehl arbeiten???
    ;ich möchte jede MsgBox einzeln ansteuern im Code, ist einfacher für mich.
MsgBox ("", "INFO", "Ich komme von Msgbox 1") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

MsgBox ("", "INFO", "Ich komme von Msgbox 2") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

MsgBox ("", "INFO", "Ich komme von Msgbox 3") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

MsgBox ("", "INFO", "Ich komme von Msgbox 4") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

MsgBox ("", "INFO", "Ich komme von Msgbox 5") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

MsgBox ("", "INFO", "Ich komme von Msgbox 6") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

MsgBox ("", "INFO", "Ich komme von Msgbox 7") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

MsgBox ("", "INFO", "Ich komme von Msgbox 8") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

MsgBox ("", "INFO", "Ich komme von Test Moin") ;Diese Nachricht soll erst erscheinen, wenn ich in der GUI den Namen in das Inputfeld eingegeben habe und ich auf den Namen in der Liste geklickt habe!

EndFunc

Alles anzeigen

**Kanashius**

Hi,

so würde ich das umsetzen.

Ein Array mit allen Actions (2D mit Name zum anklicken, Function zum Aufrufen und ein Bool, ob der Index übergeben werden soll.

Wenn man sich für WM_COMMAND Messages registriert, wird die Methode unten aufgerufen, wenn mit einem Control interagiert wird; Hier das anklicken in der Listbox und das Tippen im Inputfeld.

Die Funktionen _ActionListSelect($iIndex=Default) und _FilterList($sSearch="") werden dann aufgerufen. Sie sind aber gleichzeitig auch so gestaltet, dass sie auch manuell aufgerufen werden können.

Das mach ich z.B. um am Anfang die Liste zu füllen.

AutoIt

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <ListBoxConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global $iWidth = 800, $iHeight = 600, $iSpace = 10, $iCtrlHeight = 25
Global $arActions = [["Msgbox 1", "_msgbox", True], ["Msgbox 2", "_msgbox", True], ["Msgbox 3", "_msgbox", True], _
                     ["Msgbox 4", "_msgbox", True], ["Msgbox 5", "_msgbox", True], ["Msgbox 6", "_msgbox", True], _
                     ["Msgbox 7", "_msgbox", True], ["Msgbox 8", "_msgbox", True], ["Test Moin", "_testmoin", False], _
                     ["Just do", "_justdo"]]

$hGui = GUICreate("Search test", $iWidth, $iHeight)
GUISetFont(10, 800, 0, "MS Sans Serif")


GUICtrlCreateLabel("Suche: ", $iSpace, $iSpace+5, 45, $iCtrlHeight-5)
$iInputSearch = GUICtrlCreateInput("", 45+$iSpace*2, $iSpace, ($iWidth-45)-3*$iSpace, $iCtrlHeight)
$hInputSearch = GUICtrlGetHandle($iInputSearch)
GUICtrlSetCursor (-1, 5)

$iListActions = GUICtrlCreateList("", $iSpace, $iSpace*2+$iCtrlHeight, $iWidth-2*$iSpace, $iHeight-3*$iSpace-$iCtrlHeight, BitOR($WS_BORDER, $WS_VSCROLL))
$hListActions = GUICtrlGetHandle($iListActions)
_FilterList()
GUICtrlSetCursor (-1, 0)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _msgbox($iIndex)
    MsgBox(64, "Info", $arActions[$iIndex][0]&" >> At list index "&$iIndex&" was pressed.")
EndFunc

Func _testmoin()
    MsgBox(64, "Info", "Test Moin")
EndFunc

Func _justdo()
    MsgBox(64, "Info", "Just Do")
EndFunc

; Error: 1 -> Illegal index argument
; Error: 2 -> No item selected
; Error: 3 -> Index not specified in action array
Func _ActionListSelect($iIndex=Default)
    If $iIndex<>Default Then
        ; Check if the index is a number and in range
        If Not IsInt($iIndex) Or $iIndex<0 Or $iIndex>=_GUICtrlListBox_GetCount($iListActions) Then Return SetError(1, 0, -1)
        _GUICtrlListBox_SetCurSel($iListActions, $iIndex)
    EndIf
    $iIndex = _GUICtrlListBox_GetCurSel($iListActions)
    If $iIndex<0 Then Return SetError(2, 0, -1)
    _GUICtrlListBox_SetCurSel($iListActions, -1)
    If Not $iIndex<UBound($arActions) Then SetError(3, 0, -1)
    If $arActions[$iIndex][1]<>"" Then
        If $arActions[$iIndex][2]<>"" Or $arActions[$iIndex][2] Then
            Call($arActions[$iIndex][1], $iIndex)
        Else
            Call($arActions[$iIndex][1])
        EndIf
    EndIf
EndFunc

Func _FilterList($sSearch="")
    _GUICtrlListBox_BeginUpdate($iListActions)
    _GUICtrlListBox_ResetContent($iListActions)
    If $sSearch="" Then
        For $i=0 To UBound($arActions)-1 Step 1
            _GUICtrlListBox_AddString($iListActions, $arActions[$i][0])
        Next
    Else
        For $i=0 To UBound($arActions)-1 Step 1
            If StringInStr($arActions[$i][0], $sSearch, 0) Then _GUICtrlListBox_AddString($iListActions, $arActions[$i][0])
        Next
    EndIf
    _GUICtrlListBox_EndUpdate($iListActions)
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $iIDFrom = _WinAPI_LoWord($iwParam), $iCode = _WinAPI_HiWord($iwParam)
    Switch $ilParam
        Case $hInputSearch
            Switch $iCode
                Case $EN_CHANGE
                    _FilterList(GUICtrlRead($iInputSearch))
            EndSwitch
        Case $hListActions
            If $iCode=$LBS_NOTIFY Then
                _ActionListSelect()
                If @error Then
                    Switch @error ; 1 cannot happen; no index provided
                        Case 2
                            MsgBox(16, "Error", "No Action was selected!")
                        Case 3
                            MsgBox(16, "Error", "There is no Action for the index of the selected item!")
                    EndSwitch
                EndIf
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Ich hoffe, das hilft dir weiter.

Mfg, Kanashius

WhiteHorse

Zitat von Kanashius

Hi,

so würde ich das umsetzen.

Ein Array mit allen Actions (2D mit Name zum anklicken, Function zum Aufrufen und ein Bool, ob der Index übergeben werden soll.

Wenn man sich für WM_COMMAND Messages registriert, wird die Methode unten aufgerufen, wenn mit einem Control interagiert wird; Hier das anklicken in der Listbox und das Tippen im Inputfeld.

Die Funktionen _ActionListSelect($iIndex=Default) und _FilterList($sSearch="") werden dann aufgerufen. Sie sind aber gleichzeitig auch so gestaltet, dass sie auch manuell aufgerufen werden können.

Das mach ich z.B. um am Anfang die Liste zu füllen.

AutoIt

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <ListBoxConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global $iWidth = 800, $iHeight = 600, $iSpace = 10, $iCtrlHeight = 25
Global $arActions = [["Msgbox 1", "_msgbox", True], ["Msgbox 2", "_msgbox", True], ["Msgbox 3", "_msgbox", True], _
                     ["Msgbox 4", "_msgbox", True], ["Msgbox 5", "_msgbox", True], ["Msgbox 6", "_msgbox", True], _
                     ["Msgbox 7", "_msgbox", True], ["Msgbox 8", "_msgbox", True], ["Test Moin", "_testmoin", False], _
                     ["Just do", "_justdo"]]

$hGui = GUICreate("Search test", $iWidth, $iHeight)
GUISetFont(10, 800, 0, "MS Sans Serif")


GUICtrlCreateLabel("Suche: ", $iSpace, $iSpace+5, 45, $iCtrlHeight-5)
$iInputSearch = GUICtrlCreateInput("", 45+$iSpace*2, $iSpace, ($iWidth-45)-3*$iSpace, $iCtrlHeight)
$hInputSearch = GUICtrlGetHandle($iInputSearch)
GUICtrlSetCursor (-1, 5)

$iListActions = GUICtrlCreateList("", $iSpace, $iSpace*2+$iCtrlHeight, $iWidth-2*$iSpace, $iHeight-3*$iSpace-$iCtrlHeight, BitOR($WS_BORDER, $WS_VSCROLL))
$hListActions = GUICtrlGetHandle($iListActions)
_FilterList()
GUICtrlSetCursor (-1, 0)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _msgbox($iIndex)
    MsgBox(64, "Info", $arActions[$iIndex][0]&" >> At list index "&$iIndex&" was pressed.")
EndFunc

Func _testmoin()
    MsgBox(64, "Info", "Test Moin")
EndFunc

Func _justdo()
    MsgBox(64, "Info", "Just Do")
EndFunc

; Error: 1 -> Illegal index argument
; Error: 2 -> No item selected
; Error: 3 -> Index not specified in action array
Func _ActionListSelect($iIndex=Default)
    If $iIndex<>Default Then
        ; Check if the index is a number and in range
        If Not IsInt($iIndex) Or $iIndex<0 Or $iIndex>=_GUICtrlListBox_GetCount($iListActions) Then Return SetError(1, 0, -1)
        _GUICtrlListBox_SetCurSel($iListActions, $iIndex)
    EndIf
    $iIndex = _GUICtrlListBox_GetCurSel($iListActions)
    If $iIndex<0 Then Return SetError(2, 0, -1)
    _GUICtrlListBox_SetCurSel($iListActions, -1)
    If Not $iIndex<UBound($arActions) Then SetError(3, 0, -1)
    If $arActions[$iIndex][1]<>"" Then
        If $arActions[$iIndex][2]<>"" Or $arActions[$iIndex][2] Then
            Call($arActions[$iIndex][1], $iIndex)
        Else
            Call($arActions[$iIndex][1])
        EndIf
    EndIf
EndFunc

Func _FilterList($sSearch="")
    _GUICtrlListBox_BeginUpdate($iListActions)
    _GUICtrlListBox_ResetContent($iListActions)
    If $sSearch="" Then
        For $i=0 To UBound($arActions)-1 Step 1
            _GUICtrlListBox_AddString($iListActions, $arActions[$i][0])
        Next
    Else
        For $i=0 To UBound($arActions)-1 Step 1
            If StringInStr($arActions[$i][0], $sSearch, 0) Then _GUICtrlListBox_AddString($iListActions, $arActions[$i][0])
        Next
    EndIf
    _GUICtrlListBox_EndUpdate($iListActions)
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $iIDFrom = _WinAPI_LoWord($iwParam), $iCode = _WinAPI_HiWord($iwParam)
    Switch $ilParam
        Case $hInputSearch
            Switch $iCode
                Case $EN_CHANGE
                    _FilterList(GUICtrlRead($iInputSearch))
            EndSwitch
        Case $hListActions
            If $iCode=$LBS_NOTIFY Then
                _ActionListSelect()
                If @error Then
                    Switch @error ; 1 cannot happen; no index provided
                        Case 2
                            MsgBox(16, "Error", "No Action was selected!")
                        Case 3
                            MsgBox(16, "Error", "There is no Action for the index of the selected item!")
                    EndSwitch
                EndIf
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Ich hoffe, das hilft dir weiter.

Mfg, Kanashius

Alles anzeigen

Top ich danke dir

WhiteHorse

Zitat von Kanashius

AutoIt

Func _msgbox($iIndex)
    MsgBox(64, "Info", $arActions[$iIndex][0]&" >> At list index "&$iIndex&" was pressed.")
EndFunc

Func _testmoin()
    MsgBox(64, "Info", "Test Moin")
EndFunc

Func _justdo()
    MsgBox(64, "Info", "Just Do")
EndFunc

Alles anzeigen

hey, ich hab noch ein kleines Problem gefunden in dem Code, das ist mir jetzt leider erst aufgefallen

und zwar, wenn ich den Namen suche zb. Test Moin und ich den in der liste aufrufe, dann führt er die Funktion Func _msgbox($iIndex) aus, er soll aber dennoch die Func _testmoin () abrufen sie gehört ja schließlich zu ihr und nicht zu Func _msgbox($iIndex) wenn ich nicht in die Suche schreibe und gleich auf den Namen klicke, dann führt er auch die richtige Funktion auf.

Wäre dir sehr dankbar, wenn du mir das noch ggf. fixen kannst

Gruß Whitey

**Kanashius**

Hi
Das hab ich tatsächlich übersehen

Hier eine Lösung:

AutoIt

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <ListBoxConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global $iWidth = 800, $iHeight = 600, $iSpace = 10, $iCtrlHeight = 25
Global $arActions = [["Msgbox 1", "_msgbox", True], ["Msgbox 2", "_msgbox", True], ["Msgbox 3", "_msgbox", True], _
                     ["Msgbox 4", "_msgbox", True], ["Msgbox 5", "_msgbox", True], ["Msgbox 6", "_msgbox", True], _
                     ["Msgbox 7", "_msgbox", True], ["Msgbox 8", "_msgbox", True], ["Test Moin", "_testmoin", False], _
                     ["Just do", "_justdo"]]
Global $arActionsCurr[UBound($arActions)]
;Local $arActions[300][3]
;For $i=0 To UBound($arActions)-1 Step 1
    ;$arActions[$i][0] = "Msgbox "&$i
    ;$arActions[$i][1] = "_msgbox"
    ;$arActions[$i][2] = True
;Next


$hGui = GUICreate("Search test", $iWidth, $iHeight)
GUISetFont(10, 800, 0, "MS Sans Serif")


GUICtrlCreateLabel("Suche: ", $iSpace, $iSpace+5, 45, $iCtrlHeight-5)
$iInputSearch = GUICtrlCreateInput("", 45+$iSpace*2, $iSpace, ($iWidth-45)-3*$iSpace, $iCtrlHeight)
$hInputSearch = GUICtrlGetHandle($iInputSearch)
GUICtrlSetCursor (-1, 5)

$iListActions = GUICtrlCreateList("", $iSpace, $iSpace*2+$iCtrlHeight, $iWidth-2*$iSpace, $iHeight-3*$iSpace-$iCtrlHeight, BitOR($WS_BORDER, $WS_VSCROLL))
$hListActions = GUICtrlGetHandle($iListActions)
_FilterList()
GUICtrlSetCursor (-1, 0)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _msgbox($iIndex)
    MsgBox(64, "Info", $arActions[$iIndex][0]&" >> At list index "&$iIndex&" was pressed.")
EndFunc

Func _testmoin()
    MsgBox(64, "Info", "Test Moin")
EndFunc

Func _justdo()
    MsgBox(64, "Info", "Just Do")
EndFunc

; Error: 1 -> Illegal index argument
; Error: 2 -> No item selected
; Error: 3 -> Index not specified in action array
Func _ActionListSelect($iIndex=Default)
    If $iIndex<>Default Then
        ; Check if the index is a number and in range
        If Not IsInt($iIndex) Or $iIndex<0 Or $iIndex>=_GUICtrlListBox_GetCount($iListActions) Then Return SetError(1, 0, -1)
        _GUICtrlListBox_SetCurSel($iListActions, $iIndex)
    EndIf
    $iIndex = _GUICtrlListBox_GetCurSel($iListActions)
    If $iIndex<0 Then Return SetError(2, 0, -1)
    _GUICtrlListBox_SetCurSel($iListActions, -1)
    If Not $iIndex<UBound($arActionsCurr) Then SetError(3, 0, -1)
    ConsoleWrite($iIndex&":"&$arActionsCurr[$iIndex]&@crlf)
    $iIndex = $arActionsCurr[$iIndex] ; map index from filtered to original
    If $arActions[$iIndex][1]<>"" Then
        If $arActions[$iIndex][2]<>"" Or $arActions[$iIndex][2] Then
            Call($arActions[$iIndex][1], $iIndex)
        Else
            Call($arActions[$iIndex][1])
        EndIf
    EndIf
EndFunc

Func _FilterList($sSearch="")
    _GUICtrlListBox_BeginUpdate($iListActions)
    _GUICtrlListBox_ResetContent($iListActions)
    Local $iCount = 0
    If $sSearch="" Then
        For $i=0 To UBound($arActions)-1 Step 1
            _GUICtrlListBox_AddString($iListActions, $arActions[$i][0])
            $arActionsCurr[$iCount] = $i
            $iCount+=1
        Next
    Else
        For $i=0 To UBound($arActions)-1 Step 1
            If StringInStr($arActions[$i][0], $sSearch, 0) Then
                _GUICtrlListBox_AddString($iListActions, $arActions[$i][0])
                $arActionsCurr[$iCount] = $i
                $iCount+=1
            EndIf
        Next
    EndIf
    _GUICtrlListBox_EndUpdate($iListActions)
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $iIDFrom = _WinAPI_LoWord($iwParam), $iCode = _WinAPI_HiWord($iwParam)
    Switch $ilParam
        Case $hInputSearch
            Switch $iCode
                Case $EN_CHANGE
                    _FilterList(GUICtrlRead($iInputSearch))
            EndSwitch
        Case $hListActions
            If $iCode=$LBS_NOTIFY Then
                _ActionListSelect()
                If @error Then
                    Switch @error ; 1 cannot happen; no index provided
                        Case 2
                            MsgBox(16, "Error", "No Action was selected!")
                        Case 3
                            MsgBox(16, "Error", "There is no Action for the index of the selected item!")
                    EndSwitch
                EndIf
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

MfG,

Kanashius

Suche für Liste

Ähnliche Themen

DecToBin (Adaptive)

Auto markieren / excel starter

TV Senderliste bearbeiten