Combobox mit mehreren Spalten

atomas

Hallo,

ich habe eine Datenbank die ich gerne in Autoit bearbeiten bzw. anzeigen möchte

Jetzt läuft es gerade unter Access und ich möchte das gerne anders haben und mit Autoit damit arbeiten

In Access habe ich eine Combobox bzw Kominationsbox heißt es da ja,

die aufgeteilt ist, leider habe ich das nicht unter Autoit hinbekommen.

Die Liste, wenn man auf die Combobox klickt, sollte dann so aussehen wie auf dem Bild

Zeile 1 steht Hersteller

Zeile 2 steht Artikel

Zeile 3 steht Preis

Zeile 4 steht Bestand

In der Combobox steht dann z. B. Intel und im Feld daneben steht die CPU, kann ich diese Anzeige auch mit

Autoit realisieren?

Danke für die Unterstützung

**Oscar**

Zitat von atomas

In der Combobox steht dann z. B. Intel und im Feld daneben steht die CPU, kann ich diese Anzeige auch mit
Autoit realisieren?

Als Combobox nicht, aber als Listview in einem Child-Window wäre sowas möglich.

atomas

Deswegen finde ich dazu auch nichts, habe ich mir fast gedacht.

Dann werde ich damit mal mein Glück versuchen. Danke

**Oscar**

Sag Bescheid, wenn Du Hilfe brauchst!

**Oscar**

Ich hatte gerade mal Lust sowas zu programmieren:

AutoIt

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>

Opt('GUIOnEventMode', 1)

Global $g_bShowLV = False

Global $g_hGui = GUICreate('test', 800, 480)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
Global $g_idCombo = GUICtrlCreateCombo('', 10, 10, 100, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL, $WS_VSCROLL))

Global $g_idLV = GUICtrlCreateListView('Hersteller|Artikel|Preis|Bestand', 10, 33, 780, 440)
GUICtrlCreateListViewItem('AMD|AMD Ryzen 5|128.00|328', $g_idLV)
GUICtrlCreateListViewItem('AMD|AMD Ryzen 7|198.00|58', $g_idLV)
GUICtrlCreateListViewItem('Intel|Intel Celeron G5900|211.00|167', $g_idLV)
GUICtrlSetState($g_idLV, $GUI_HIDE)

GUISetState(@SW_SHOW, $g_hGui)
GUIRegisterMsg($WM_COMMAND, '_WM_COMMAND')
GUIRegisterMsg($WM_NOTIFY, '_WM_NOTIFY')

WinWaitClose($g_hGui)

Func _CloseGui()
	GUIDelete($g_hGui)
EndFunc   ;==>_CloseGui

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg, $wParam
	Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
	Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, 'hWndFrom'))
	Local $iCode = DllStructGetData($tNMHDR, 'Code')
	Local $tItemActivate, $sItem
	Switch $hWndFrom
		Case GUICtrlGetHandle($g_idLV)
			Switch $iCode
				Case $NM_CLICK
					$tItemActivate = DllStructCreate($tagNMITEMACTIVATE, $lParam)
					$sItem = _GUICtrlListView_GetItemTextString($g_idLV, $tItemActivate.index)
					GUICtrlSetState($g_idLV, BitOR($GUI_HIDE, $GUI_FOCUS))
					$g_bShowLV = False
					ConsoleWrite('Listview CLICK Index:' & $tItemActivate.index  & ' "' & $sItem & '"' & @CRLF)
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg, $lParam
	Local $iIDFrom = BitAND($wParam, 0xFFFF)
	Local $iCode = BitShift($wParam, 16)
	Switch $iIDFrom
		Case $g_idCombo
			Switch $iCode
				Case $CBN_DROPDOWN
					GUICtrlSetState($g_idLV, $g_bShowLV ? BitOR($GUI_HIDE, $GUI_FOCUS) : BitOR($GUI_SHOW, $GUI_FOCUS))
					ConsoleWrite('Combo DROPDOWN, LV-State:' & $g_bShowLV & @CRLF)
					$g_bShowLV = Not $g_bShowLV
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND

Alles anzeigen

Wobei ich jetzt doch kein Child-Window benutzt habe, sondern das Listview nur anhand des Status der Combobox angezeigt/versteckt habe.

atomas

Oh, das sieht ja super aus

ich hatte auch was zum testen gemacht. (siehe unten)

Allerdings klappt das nicht so, wenn ich die Combobox anklicke, dann öffnet sich wohl das Fenster, allerdings muss ich dann 2x in die Listbox klicken, bei dir geht die dann weg sobald man irgendwo hinklickt.

Besten Dank, ich werde mal schauen ob ich das erweitern kann, so wie ich das möchte.

C

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$Main = GUICreate("Main", 1174, 843, 361, 105)
$ID1 = GUICtrlCreateCombo("", 139, 86, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
$ID2 = GUICtrlCreateCombo("", 147, 46, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
$ID3 = GUICtrlCreateCombo("", 115, 118, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
$1LISTE = GUICtrlCreateCombo("Auswahl", 432, 48, 180, 25);, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
$2LISTE = GUICtrlCreateCombo("", 467, 78, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
$3LISTE = GUICtrlCreateCombo("", 459, 110, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
$IP1 = GUICtrlCreateInput("", 640, 48, 313, 21)
$IP2 = GUICtrlCreateInput("", 635, 86, 313, 21)
$IP3 = GUICtrlCreateInput("", 635, 110, 313, 21)


;Child1
$Child1 = GUICreate("Auswahl", 450, 300, 432, 73,$WS_POPUP,$WS_EX_MDICHILD,$Main)  ;$WS_POPUPWINDOW
				$LVTEST = GUICtrlCreateListView("Wert1|Wert2|Wert3",0,0,450,300)

				_GUICtrlListView_SetColumnWidth($LVTEST,0,300)
				_GUICtrlListView_SetColumnWidth($LVTEST,1,50)
				_GUICtrlListView_SetColumnWidth($LVTEST,2,70)


GUISetState(@SW_SHOW,$Main)

Local $aArray_Base[20][3]
For $i = 0 To 19
    For $j = 0 To 2
        $aArray_Base[$i][$j] = "Item" & $i & " - " & $j
    Next
Next
$auswahl = ""
$auswahlset = ""

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch

				$auswahl = _GUICtrlListView_GetItemText($LVTEST,_GUICtrlListView_GetSelectionMark($LVTEST),0)

				;if $auswahl = "ID1" then $auswahl = ""

				if  $auswahl <> $auswahlset then
					GUISetState(@SW_hide, $Child1)
					GUICtrlSetData($IP1,_GUICtrlListView_GetItemText($LVTEST,_GUICtrlListView_GetSelectionMark($LVTEST),0))
					$auswahlset = $auswahl
				endif


WEnd



Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    If _WinAPI_HiWord($wParam) = $CBN_DROPDOWN Then
        Switch _WinAPI_LoWord($wParam)
            Case $1LISTE
                ConsoleWrite("Combo_1 Dropped" & @CRLF)
				_GUICtrlListView_AddArray($LVTEST, $aArray_Base)
				GUISetState(@SW_SHOW,$Child1)

            Case $2LISTE
                ConsoleWrite("Combo_2 Dropped" & @CRLF)
            Case $3LISTE
                ConsoleWrite("Combo_3 Dropped" & @CRLF)
        EndSwitch
    EndIf
EndFunc

Alles anzeigen

**Oscar**

Zitat von atomas

Besten Dank, ich werde mal schauen ob ich das erweitern kann, so wie ich das möchte.

Gern geschehen!

Ja, es kommt noch darauf an, was Du mit dem Listview vor hast. Wenn es nicht nur eine Auswahlbox sein soll, muss man da evtl. noch zusätzliche GUI-Elemente ein-/ausblenden.

Wenn Du Hilfe brauchst, sag Bescheid!