GUIOnEventMode

pauLee

Hallo Leute,

ich warne gleich vorab: ich hab noch nicht viel Ahnung von AutoIt!!

Ich habe eine kleine Anwendung gestrickt die eine Menüleiste besitzt und ein paar Buttons die auf ein paar Funktionen hören.

Ich hab die Applikation mit...

#NoTrayIcon
#include <GUIConstants.au3>
Opt("GUIOnEventMode", 1)

...begonnen. Damit laufen die Funktionen der Buttons wunderbar.

In der Menüleiste will ich aber einen Punkt "Exit" einfügen. Dieser soll über...

Code

$Msg = GUIGetMsg()	
Select Case $msg = $GUI_EVENT_CLOSE
Exit
Case $msg = $exititem
Exit
EndSelect

...angesprochen werden. Funktioniert aber nicht. Ich hab schon gecheckt, daß dies an "GUIOnEventMode" liegt. Ich hab nur nicht das Grundverständnis dafür was dieser GUI-Event-Mode alles macht bzw. worauf er hört.
Kann mir jemand die Zweckmäßigkeit dessen erklären? (Sagt jetzt nicht ich soll die Doku lesen, denn das hab ich schon gemacht, ist mir aber zu umständlich).

Grüße
Paul

**Xenobiologist**

HI,

am einfachsten ist, du entscheidest dich für einen Mode. Entweder MsgLoop oder EventMode.

So long,

Mega

**peethebee**

Code

GUISetOnEvent($GUI_EVENT_CLODE, "quit")
GUICTRLSetOnEvent($exititem, "quit")


Func quit()
   Exit
EndFunc

Das ist die Entsprechung im OnEventMode, den ich empfehlen würde.

peethebee

**bernd670**

Hallo und :willkommen:,

in der deutschen Hilfe ist eingentlich schon ganz gut beschrieben wie die beiden Modi arbeiten (http://autoit.aufwaerts.de/dokumentation/guiref/GUIRef.htm) Stichwort "GUI-Ereignis-Modi".

Das ist eine der wenigen Optionen bei denen es sinnvoll ist einen einmal gewählten Modus nicht mehr umzuschalten! Am einfachsten ist es wohl deinem Exit-Menüeintrag auch eine Eventfunktion zuzuweisen!

pauLee

Zitat

Original von th.meger
am einfachsten ist, du entscheidest dich für einen Mode. Entweder MsgLoop oder EventMode

Das habe ich schonmal gelesen, nur weiss ich leider überhaupt nicht welcher Mode für was gut ist

Zitat

peethebeeDas ist die Entsprechung im OnEventMode, den ich empfehlen würde.

Ich habe schon eine "exit"-Funktion. Aber das funktioniert nicht im Menü bzw. weiss ich nicht wie ich es dort anstellen soll.

Zitat

bernd670in der deutschen Hilfe ist eingentlich schon ganz gut beschrieben wie die beiden Modi arbeiten (http://autoit.aufwaerts.de/dokumentation/guiref/GUIRef.htm) Stichwort "GUI-Ereignis-Modi".

Das ist eine der wenigen Optionen bei denen es sinnvoll ist einen einmal gewählten Modus nicht mehr umzuschalten! Am einfachsten ist es wohl deinem Exit-Menüeintrag auch eine Eventfunktion zuzuweisen!

Die Hilfe habe ich dort schon gelesen aber so richtig geholfen hat es mir nicht.

Ich habe schon versucht den Exit-Menüeintrag durch eine Eventfunktion zu realisieren...aber das funktionierte auch nicht oder ich weiss wiedermal nicht wie ich das zu machen habe. :irre:

**peethebee**

Hallo!

Menüitems legst du mit GUICtrlCreateMenuItem an.
Dann setzte du mit GUICtrlSetOnEvent($ctrl_id, "funktion") die Funktion, die aufgerufen werden soll, wenn man darauf klickt.
Mein Code oben tut genau das für den Teil, den du gepostet hattest.
Ich finde den OnEventMode generell übersichtlicher, bei größeren Projekten ist er unerlässlich.

peethebee

**Xenobiologist**

HI,

also ich bevorzuge ganz klar den MsgLoopMode. Wenn du dein Skript postest, dann kann man das sicher schnell umschreiben.

So long,

Mega

**bernd670**

Ich habe mal ein kleines Beispiel für dich (unvollständig):

Spoiler anzeigen

Code

#include <GUIConstants.au3>


Opt("GUIOnEventMode",1)


GUICreate("My GUI menu",300,200)
Global $defaultstatus = "Ready"
Global $status


$filemenu = GUICtrlCreateMenu ("&File")
$fileitem = GUICtrlCreateMenuitem ("Open",$filemenu)
GUICtrlSetState(-1,$GUI_DEFBUTTON)
$helpmenu = GUICtrlCreateMenu ("?")
$saveitem = GUICtrlCreateMenuitem ("Save",$filemenu)
GUICtrlSetState(-1,$GUI_DISABLE)
$infoitem = GUICtrlCreateMenuitem ("Info",$helpmenu)
$exititem = GUICtrlCreateMenuitem ("Exit",$filemenu)
$recentfilesmenu = GUICtrlCreateMenu ("Recent Files",$filemenu,1)


$separator1 = GUICtrlCreateMenuitem ("",$filemenu,2)	; create a separator line


$viewmenu = GUICtrlCreateMenu("View",-1,1)	; is created before "?" menu
$viewstatusitem = GUICtrlCreateMenuitem ("Statusbar",$viewmenu)
GUICtrlSetState(-1,$GUI_CHECKED)
$okbutton = GUICtrlCreateButton ("OK",50,130,70,20)
GUICtrlSetState(-1,$GUI_FOCUS)
$cancelbutton = GUICtrlCreateButton ("Cancel",180,130,70,20)
$statuslabel = GUICtrlCreateLabel ($defaultstatus,0,165,300,16,BitOr($SS_SIMPLE,$SS_SUNKEN))


;~ Schliessen-Button im Systemmenü
GUISetOnEvent($GUI_EVENT_CLOSE, "ByeBye")


;~ Menüeintrag Exit und Cancel-Button
GUICtrlSetOnEvent($exititem,"ByeBye")
GUICtrlSetOnEvent($cancelbutton,"ByeBye")


;~ Menüeintrag info
GUICtrlSetOnEvent($infoitem,"_info")




GUISetState ()
While 1
    Sleep(100)
WEnd


Func ByeBye()
    GUIDelete()
    Exit
EndFunc


Func _info()
    Msgbox(0,"Info","Only a test...")
EndFunc

Alles anzeigen

pauLee

Zitat

Original von peethebee
Hallo!

Menüitems legst du mit GUICtrlCreateMenuItem an.
Dann setzte du mit GUICtrlSetOnEvent($ctrl_id, "funktion";) die Funktion, die aufgerufen werden soll, wenn man darauf klickt.

Hmmm?

$exititem = GUICtrlCreateMenuitem ("Exit",$filemenu)
GUICtrlSetOnEvent($exititem, "Exit")

Das macht für mich keinen Sinn und funktioniert auch nicht

Zitat

Mein Code oben tut genau das für den Teil, den du gepostet hattest.
Ich finde den OnEventMode generell übersichtlicher, bei größeren Projekten ist er unerlässlich.

Hab ich dort etwas im MsgLoopMode gemacht?

**bernd670**

Du kannst die Exit-Funktion von AutoIt nicht direkt mit GUICtrlSetOnEvent aufrufen.

so wäre es richtig:

Code

$exititem = GUICtrlCreateMenuitem ("Exit",$filemenu)
GUICtrlSetOnEvent($exititem, "myExit")


Func myExit()
    Exit
EndFunc

pauLee

Hi Bernd,

vielen Dank für den Tipp. Ich bin erst heute dazu gekommen es auszuprobieren aber es funktioniert!!

Grüße