wie kann ich dateien durchsuchen

Friso

Hallo

Ich versuche ein Suchprogramm für Textdateien zu basteln welches folgende Funktionen hat

1. Suche nach Dateierweiterung und bestimmten Inhalt (*.453 enthaltender Text 65756896)
2. nach erfolgreicher suche sollen die in frage kommenden Dateien dem User zum Öffnen angeboten werden. Da mir bisher keine Möglichkeit bekannt ist das in einem Fenster darzustellen war die Überlegung am, am rechten Bildschirmrand eine Variable Buttenliste zu generieren. Hinter jedem Butten befindet sich eine Textdatei die damit geöffnet werden kann, da für meine zwecke das Datum der Datei wichtig ist wird das als Buttentext verwendet.
3. das war es auch schon

die Dateien mit der richtigen Dateierweiterung zu finden ist kein Problem
das mache ich mit
FileFindFirstFile ( "filename" ) und FileFindNextFile ( search )
Die Dateinamen habe ich dann in einem Array

die Schwierigkeit vor der ich Stehe ist dann die Dateien zu finden die den richtigen text enthalten

da fehlt einfach „if TextInFileExist then “

bei der Masse an Funktionen die Autoit bietet muss es da doch was geben

besten dank schon mal Friso

Rechtschreibfehler sind geistiges Eigentum des Verfassers

Sclot

warum öffnest du die datei in der schleife nicht und schast da mit einem if rein ob der string drin steckt?

**peethebee**

Hallo!

Darstellung in einem Fenster:
Nimm ein ListView, damit kannst du dann mehrere Informationen in Spalten anzeigen, in deinem Fall Dateiname, Ordner, Datum oder so.
Siehe: GUICTRLCreateListView, GUICTRLCreateListViewItem, und die UDF <GUIListView>.

Durchsuchen der Dateien:
Wie gesagt entweder durch zweckentfremden von _ReplaceStringInFile und seinem Rückgabewert oder man durchsucht mit FileOpen, FileReadLine, StringInStr, FileClose per Hand, was etwas langsamer und aufwändiger sein dürfte.

peethebee

**Xenobiologist**

Hi,

schreib dieses Programm ein bißchen um, sollte schnell gehen.

Spoiler anzeigen

PHP

#include <GuiConstants.au3>
#Include <File.au3>
#Include <Array.au3>
#Include <GuiList.au3>


FileDelete(@TempDir & "\au3.txt")
Opt("OnExitFunc", "endscript")
Dim $TInfo, $R_[6], $Temp_File, $Temp_Type = StringSplit(".au3,.txt,.ini,.dat,.log",",")
Dim $Last_loc = "C:\Program Files\AutoIt3\Examples"
$Last_loc_tmp = IniRead(@ScriptDir & "\IE-library.ini","search","dir","")
If $Last_loc_tmp <> "" Then $Last_loc = $Last_loc_tmp
$AutoItBetaLocation = IniRead(@ScriptDir & "\IE-library.ini","exe","dir","")
If $AutoItBetaLocation = "" Then
    $AutoItBetaLocation = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt","betaInstallDir")
    If $AutoItBetaLocation = "" Then
        $AutoItBetaLocation = FileSelectFolder("Select Folder where the Beta AutoIt is installed","c:\",4,@ProgramFilesDir & "\AutoIt3\beta")
        If $AutoItBetaLocation = "" Then
            $iMsgBoxAnswer = MsgBox(262209, "IE.au3 Error #1", "Autoit3 Beta is required   " & @CRLF & "Download from www.Autoit3.com ?  ")
            If $iMsgBoxAnswer = 1 Then
                $web_loc = "http://www.autoitscript.com/forum/index.php?showtopic=19717#"
                Run(@ComSpec & " /c Start " & $web_loc, "", @SW_HIDE)
                MsgBox(262208, "Web Site", "The AutoIt3 Beta Link is at the top of this page...       " & @CRLF & @CRLF & "Please Download and Install   ", 10)
                $Dwait = 1
            EndIf
;Exit
        EndIf
    EndIf
    IniWrite(@ScriptDir & "\IE-library.ini","exe","dir",$AutoItBetaLocation)
EndIf
$Program_2 = $AutoItBetaLocation & "\Autoit3.exe"


$maingui = GUICreate("Script/Text Manager       v1.0.3" , 500, 365)
GUISetFont(9, 400, -1, "MS Sans Serif")
$vStatus = GUICtrlCreateLabel("View: Search Window", 0, 350, 130, 15, $SS_SUNKEN + $SS_CENTER)
GUICtrlCreateLabel("Manager Status:", 130, 350, 120, 15, $SS_SUNKEN + $SS_CENTER)
$Status = GUICtrlCreateLabel("System is Ready...", 250, 350, 250, 15, $SS_SUNKEN + $SS_CENTER)
GUICtrlSetColor(-1,0xff0000)
GUISetState()


$searchgui = GUICreate("Script Finder", 500, 350, 0, 0, $WS_CHILD + $WS_BORDER, "", $maingui)
GUISetFont(9, 400, -1, "MS Sans Serif")
$location = GUICtrlCreateInput($Last_loc, 20, 20, 340, 20)
$C_browse = GUICtrlCreateCheckbox( "All Sub-Folders", 380, 20, 100, 20)
GUICtrlSetState( -1, $GUI_CHECKED )
$browse_btn = GUICtrlCreateButton("Browse Folders", 380, 50, 100, 20)
$R_word = GUICtrlCreateRadio("", 20, 50, 20, 20)
GUICtrlSetState( -1, $GUI_CHECKED )
$word_search = GUICtrlCreateInput("Search word/phrase", 40, 50, 145, 20)
$R_title = GUICtrlCreateRadio("", 195, 50, 20, 20)
$title_search = GUICtrlCreateInput("Search FileName/Folder", 215, 50, 145, 20)
GUICtrlCreateGroup('File Type', 20, 78, 340, 38)
$R_[1] = GUICtrlCreateRadio(".au3", 50, 90, 50, 20)
GUICtrlSetState( -1, $GUI_CHECKED )
$R_[2] = GUICtrlCreateRadio(".txt", 110, 90, 50, 20)
$R_[3] = GUICtrlCreateRadio(".ini", 170, 90, 50, 20)
$R_[4] = GUICtrlCreateRadio(".dat", 230, 90, 50, 20)
$R_[5] = GUICtrlCreateRadio(".log", 290, 90, 50, 20)
$go_btn = GUICtrlCreateButton("Start Search", 380, 90, 100, 20)
GUICtrlSetState(-1, $GUI_DEFBUTTON)
$Edit1 = GUICtrlCreateList("Found File list", 20, 130, 460, 150, BitOR($LBS_SORT, $WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
_GUICtrlListSetHorizontalExtent($Edit1, 720)
$label = GUICtrlCreateLabel("Files Found with Phrase: None", 140, 290, 220, 20, $SS_SUNKEN + $SS_CENTER)
$label2 = GUICtrlCreateLabel("Files Found: None", 20, 290, 100, 20, $SS_SUNKEN + $SS_CENTER)
$manage_btn = GUICtrlCreateButton("Manage View", 20, 320, 100, 20)
$view_btn = GUICtrlCreateButton("View File", 140, 320, 100, 20)
$SciTE_btn = GUICtrlCreateButton("Open in SciTE", 260, 320, 100, 20)
$Run_btn = GUICtrlCreateButton("Run File", 380, 290, 100, 20)
$Exit_btn = GUICtrlCreateButton("Close", 380, 320, 100, 20)
GUISetState()


$filesgui = GUICreate("Script Finder", 500, 350, 0, 0, $WS_CHILD + $WS_BORDER, "", $maingui)
$Edit2 = GUICtrlCreateList("Searched File list", 20, 20, 460, 270, BitOR($LBS_SORT, $WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
_GUICtrlListSetHorizontalExtent($Edit2, 720)
$Search_btn = GUICtrlCreateButton("Search View", 20, 320, 100, 20)
$copy_btn = GUICtrlCreateButton("Copy File", 140, 320, 100, 20)
$rename_btn = GUICtrlCreateButton("Rename File", 260, 320, 100, 20)
$Delete_btn = GUICtrlCreateButton("Delete File", 380, 320, 100, 20)
$labelA = GUICtrlCreateLabel("Files Found with Phrase: None", 140, 290, 220, 20, $SS_SUNKEN + $SS_CENTER)
$label2A = GUICtrlCreateLabel("Files Found: None", 20, 290, 100, 20, $SS_SUNKEN + $SS_CENTER)
$Run_btnA = GUICtrlCreateButton("Run File", 380, 290, 100, 20)
GUISetState(@SW_HIDE)






While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE Or $msg = $Exit_btn
            Exit
        Case $msg = $browse_btn
            GUICtrlSetData( $status, "Selecting Folder to Search...")
            $find_loc = FileSelectFolder("Choose a Folder.", "")
            If $find_loc = "" Then ContinueLoop
            GUICtrlSetData($location, $find_loc)
            IniWrite(@ScriptDir & "\IE-library.ini","search","dir",$find_loc)
        Case $msg = $go_btn
            search_Folders()
            GUICtrlSetState($word_search, $GUI_FOCUS)
        Case $msg = $view_btn
            view()
        Case $msg = $copy_btn
            Set_Copy()
        Case $msg = $rename_btn
            Set_Rename()
        Case $msg = $Delete_btn
            Set_Delete()
        Case $msg = $run_btn
            $TInfo = GUICtrlRead($Edit1)
            Set_Run($TInfo)
        Case $msg = $run_btna
            $TInfo = GUICtrlRead($Edit2)
            Set_Run($TInfo)
        Case $msg = $SciTE_btn
            open_SciTE()
        Case $msg = $manage_btn
            GUICtrlSetData( $vstatus, "View: Manage Window")
            GUISetState( @SW_HIDE, $searchgui)
            GUISetState( @SW_SHOW, $filesgui)
            view_all()
        Case $msg = $Search_btn
            GUICtrlSetData( $vstatus, "View: Search Window")
            GUISetState( @SW_HIDE, $filesgui)
            GUISetState( @SW_SHOW, $searchgui)
    EndSelect
    GUICtrlSetData( $status,"System is Ready...")
    Sleep(20)
WEnd


Func search_Folders()
    GUICtrlSetData( $status, "Searching for Files...")   
    FileDelete(@TempDir & "\au3.txt")
    Set_File()
    $Found = 0
    $Searched = 0
    $title = 0
    GUICtrlSetData($label, "Files Found with Phrase: " & $Found)
    GUICtrlSetData($labelA, "Files Found with Phrase: " & $Found)
    GUICtrlSetData($label2, "Files Found: " & $Searched)
    GUICtrlSetData($label2A, "Files Found: " & $Searched)
    GUICtrlSetData($Edit1, "")
    GUICtrlSetData($Edit2, "")
    $Temp_Dir = (GUICtrlRead($location))
    If $Temp_Dir = "" Then
        GUICtrlSetData( $status,"No Folder Selected...")
        MsgBox(262208,"Sorry", "No Folders Selected.   ",2)
        Return
    EndIf
    If StringRight($Temp_Dir, 1) <> "\" Then $Temp_Dir = $Temp_Dir & "\"
    $Temp_Word = (GUICtrlRead($word_search))
    If GUICtrlRead($C_browse) = 1 Then
        GUICtrlSetData( $status, "Searching in Sub-Folders...PLEASE WAIT")   
        RunWait(@ComSpec & ' /c ' & 'dir "' & $Temp_Dir & $Temp_File & '" /a :h /b /s' & ' > "' & @TempDir & '\au3.txt"', '', @SW_HIDE)
    Else
        GUICtrlSetData( $status, "Searching in Local Folder...")   
        $FileList = _FileListToArray ($Temp_Dir, $Temp_File, 1)
        If (Not IsArray($FileList)) Or (@error = 1) Then
            GUICtrlSetData( $status, "No Files Found...")   
            MsgBox(262208,"Sorry", "No Files Found.",2)
            Return
        EndIf
        $F_File = FileOpen(@TempDir & "\au3.txt",2)
        For $x = 1 To $FileList[0]
            FileWriteLine($F_File, $Temp_Dir & $FileList[$x])
        Next
        FileClose($F_File)
    EndIf
    GUICtrlSetData( $status, "Listing...")
        If GUICtrlRead($R_title) = 1 Then
            $Temp_Word = (GUICtrlRead($title_search))
            $title = 1
        EndIf
    $hFile = FileOpen(@TempDir & "\au3.txt", 0)
    While 1
        $sLine = FileReadLine($hFile)
        If @error = -1 Then
            FileClose($hFile)
            Return
        EndIf
        $Temp_Dir = $sLine
        If $title = 0 Then $Temp_Search = FileRead($sLine, FileGetSize($sLine))
        If $title = 1 Then $Temp_Search = $sLine
        If StringInStr($Temp_Search, $Temp_Word) Then
            GUICtrlSetData($Edit1, $sLine, 1)
            $Found = $Found + 1
            GUICtrlSetData($label, "Files Found with Phrase: " & $Found)
            GUICtrlSetData($labelA, "Files Found with Phrase: " & $Found)
        EndIf
        $Searched = $Searched + 1
        GUICtrlSetData($label2, "Files Found: " & $Searched)
        GUICtrlSetData($label2A, "Files Found: " & $Searched)
        GUICtrlSetData( $status, "Searched:" & $sLine)   
    WEnd
    FileClose($hFile)
EndFunc 


Func view()
    GUICtrlSetData( $status, "Viewing in Notepad...")   
    $Temp_Edit = GUICtrlRead($Edit1)
    $Temp_Word = (GUICtrlRead($word_search))
    If $Temp_Edit = "" Or $Temp_Edit = "Found File list" Then
        GUICtrlSetData( $status, "No File/Folder Selected...")
        MsgBox(262208,"Sorry", "No Files\Folders Selected.   ",2)
        Return
    EndIf
    Run("notepad.exe " & $Temp_Edit)
    WinWaitActive("")
    If GUICtrlRead($R_title) = 1 Then Return
    GUICtrlSetData( $status, "Searching Notepad...")
    Sleep(200)
    Send("!EF")
    Sleep(200)
    Send($Temp_Word, 1)
    Sleep(200)
    Send("!f")
EndFunc 


Func view_all()
    GUICtrlSetData( $status, "Viewing Manager Window...")   
    If Not FileExists(@TempDir & "\au3.txt") Then
        GUICtrlSetData( $status, "No Searches Were Completed...")
        MsgBox(262208,"Sorry", "No Files\Folders Searched.   ",2)
        Return
    EndIf
    GUICtrlSetData($Edit2, "")
    $vFile = FileOpen(@TempDir & "\au3.txt", 0)
    While 1
        $vLine = FileReadLine($vFile)
        If @error = -1 Then ExitLoop
        GUICtrlSetData($Edit2, $vLine, 1)
        GUICtrlSetData( $status, "Setting Files: " & $vLine)
    WEnd
EndFunc 


Func Set_Run(ByRef $TInfo)
    GUICtrlSetData( $status, "Setting up Run Command...")
    If $TInfo = "" Or $TInfo = "Found File list" Or $TInfo = "Searched File list" Then
        GUICtrlSetData( $status, "No File Selected to Run...")
        MsgBox(262208,"Sorry", "No Run File was Selected.   ",2)
        Return
    EndIf
    If StringInStr($TInfo,".au3") = 0 Then
        GUICtrlSetData( $status, "File Not an Au3 Type...")
        MsgBox(262208,"Sorry", "Run File was NOT an *au3* Type.   " & @CRLF & @CRLF & "Opening File in Notepad   ",2)
        GUICtrlSetData( $status, "Viewing in Notepad...")
        Run("notepad.exe " & $TInfo)
        Return
    EndIf
    $TInfo = FileGetShortName($TInfo)
    GUICtrlSetData( $status, "Running File...")
    RunWait($Program_2 & " " & $TInfo)
    $TInfo = ""
EndFunc 


Func Set_Copy()
    GUICtrlSetData( $status, "Setting up Copy...")
    $CInfo = GUICtrlRead($Edit2)
    If $CInfo = "" Or $CInfo = "Found File list" Or $CInfo = "Searched File list" Then
        GUICtrlSetData( $status, "No File Selected to Copy...")
        MsgBox(262208,"Sorry", "No Copy File was Selected.   ",2)
        Return
    EndIf
    GUICtrlSetData( $status, "Find Destination Folder...")
    $Linfo = FileSelectFolder("Choose a Destination Folder.", "")
    If $LInfo = "" Then
        GUICtrlSetData( $status, "No Folder Selected...")
        MsgBox(262208,"Sorry", "No Destination Folder was Selected.   ",2)
        Return
    EndIf
    $NInfo = StringSplit($CInfo,"\")
    $NInfo = $LInfo & "\" & $NInfo[$NInfo[0]]
    GUICtrlSetData( $status, "Checking if file exists...")
    If FileExists($NInfo) Then
        $iMsgBoxAnswer = MsgBox(262212, "Overwrite Existing File?", "The File " & $NInfo & " was found    " & @CRLF & @CRLF & "Over-Write File?")
        If $iMsgBoxAnswer = 7 Then
            Return
        EndIf
    EndIf
    GUICtrlSetData( $status, "Copying File...")
    $var1 = FileCopy ($CInfo, $NInfo, 1)
    If $var1 = 1 Then
        MsgBox(262208,"Success",  "The file was Copied   ", 2)
    Else
        MsgBox(262208, "Fail", "The file was NOT Copied   ", 2)
    EndIf
EndFunc


Func Set_Rename()
    GUICtrlSetData( $status, "Setting Rename File...")
    $RInfo = GUICtrlRead($Edit2)
    If $RInfo = "" Or $RInfo = "Found File list" Or $RInfo = "Searched File list" Then
        GUICtrlSetData( $status, "No File Selected...")
        MsgBox(262208,"Sorry", "No Rename File was Selected.   ",2)
        Return
    EndIf
    GUICtrlSetData( $status, "Prompt for FileName...")
    $Minfo = InputBox("Rename File","Please Type a New FileName. ", "", "", -1, 150)
    If $MInfo = "" Then
        GUICtrlSetData( $status, "No Name Given...")
        MsgBox(262208,"Sorry", "No File Name was Selected.   ",2)
        Return
    EndIf
    $result = StringInStr($RInfo, "\", 0, -1)
    $NInfo = StringLeft($RInfo, $result) & $MInfo & StringRight($Temp_File, 4)
    GUICtrlSetData( $status, "Checking if File Exists...")
    If FileExists($NInfo) Then
        $iMsgBoxAnswer = MsgBox(262212, "Overwrite Existing File?", "The File " & $NInfo & " was found    " & @CRLF & @CRLF & "Over-Write File?")
        If $iMsgBoxAnswer = 7 Then
            Return
        EndIf
    EndIf
    GUICtrlSetData( $status, "Renaming File...")
    $var1 = FileMove ($RInfo, $NInfo, 1)
    If $var1 = 1 Then
        FileDelete ($RInfo)
        MsgBox(262208,"Success",  "The file was Renamed   ", 2)
    Else
        MsgBox(262208, "Fail", "The file was NOT Renamed   ", 2)
    EndIf
    $ret = _GUICtrlListFindString ($Edit2, $RInfo, 1)
    If ($ret == $LB_ERR) Then
        MsgBox(16, "Error #1", "Unknown error from _GUICtrlListFindString")
    Else
        $ret2 = _GUICtrlListDeleteItem ($Edit2, $ret)
        If ($ret2 == $LB_ERR) Then
            MsgBox(16, "Error #2", "Unknown error from _GUICtrlListDeleteItem")
        EndIf
    EndIf
EndFunc


Func Set_Delete()
    GUICtrlSetData( $status, "Setting up Delete...")
    $DInfo = GUICtrlRead($Edit2)
    If $DInfo = "" Or $DInfo = "Found File list" Or $DInfo = "Searched File list" Then
        GUICtrlSetData( $status, "No File Selected...")
        MsgBox(262208,"Sorry", "No Delete File was Selected.   ",2)
        Return
    EndIf
    GUICtrlSetData( $status, "Verify that File Exists...")
    If FileExists($DInfo) Then
        $iMsgBoxAnswer = MsgBox(262212, "Confirm - Delete File?", "The File " & $DInfo & " was found    " & @CRLF & @CRLF & "Delete File?")
        If $iMsgBoxAnswer = 7 Then
            Return
        EndIf
    EndIf
    GUICtrlSetData( $status, "Deleting File...")
    $var1 = FileDelete ($DInfo)
    If $var1 = 1 Then
        MsgBox(262208,"Success",  "The file was Deleted   ", 2)
    Else
        MsgBox(262208, "Fail", "The file was NOT Deleted   ", 2)
    EndIf
    $ret = _GUICtrlListFindString ($Edit2, $DInfo, 1)
    If ($ret == $LB_ERR) Then
        MsgBox(16, "Error #1", "Unknown error from _GUICtrlListFindString")
    Else
        $ret2 = _GUICtrlListDeleteItem ($Edit2, $ret)
        If ($ret2 == $LB_ERR) Then
            MsgBox(16, "Error #2", "Unknown error from _GUICtrlListDeleteItem")
        EndIf
    EndIf
EndFunc


Func Set_File()
    GUICtrlSetData( $status, "Checking File Type...")
    For $t = 1 to $Temp_Type[0]
        If GUICtrlRead($R_[$t]) = 1 Then
            $Temp_File = "*" & $Temp_Type[$t]
            Return
        EndIf
    Next
EndFunc


Func open_SciTE()
    GUICtrlSetData( $status, "Setting up SciTE...")   
    $Temp_Edit = GUICtrlRead($Edit1)
    If $Temp_Edit = "" Or $Temp_Edit = "Found File list" Then
        GUICtrlSetData( $status, "No File Selected for SciTE...")
        MsgBox(262208,"Sorry", "No Files\Folders Selected.   ",2)
        Return
    EndIf
    GUICtrlSetData( $status, "Checking for Au3 File...")
    If StringInStr($Temp_Edit,".au3") = 0 Then
        $iMsgBoxAnswer = MsgBox(262212, "Verify File Type", "The File " & $Temp_Edit & " is NOT an *au3* Type.    " & @CRLF & @CRLF & "Open in SciTE.exe?")
        If $iMsgBoxAnswer = 7 Then
            Return
        EndIf
    EndIf
    GUICtrlSetData( $status, "Check if SciTE is Running...")
    If ProcessExists("SciTE.exe") Then
        MsgBox(262208, "SciTE is Running", "Placing File in Scite.exe   ", 2)
        opt("WinTitleMatchMode", 4)
        $Temp_Text = FileRead($Temp_Edit, FileGetSize($Temp_Edit))
        WinActivate("classname=SciTEWindow")
        WinWaitActive("classname=SciTEWindow")
        ControlSend("classname=SciTEWindow", "", "", "^n")
        Sleep(50)
        ControlSetText("classname=SciTEWindow", "", "Scintilla1", $Temp_Text)
        opt("WinTitleMatchMode", 1)
        Return
    EndIf
    GUICtrlSetData( $status, "Running SciTE Now...")
    $Temp_Edit = FileGetShortName($Temp_Edit)
    Run(@ComSpec & " /c Start " & $Temp_Edit, "", @SW_HIDE)
EndFunc 


Func endscript()
    MsgBox(262208,"Thanks","... Mega   ", 1)
    FileDelete(@TempDir & "\au3.txt")
EndFunc

Alles anzeigen

So long,

Mega

**peethebee**

Wow - th.meger for Mod!

peethebee (for president :party4:)

**Xenobiologist**

Hi,

mod damit ich nachträglich spoiler einbauen kann, ohne das jemand bemerkt, dass ich es schon wieder vergessen habe? :hammer:

So long,

Mega