Countdown

r1fLeX

Hab mal ein kleines Script geschrieben welches die Zeit bis "morgen" und die Tage bis Silvester anzeigt.
Solltet ihr Verbesserungsvorschlage haben sollten diese bis spätestens 30.12 eingereicht werden :P.

Script

Spoiler anzeigen

[autoit]

#include <GUIConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

$heute1 = 23
$heute2 = 59
$heute3 = 59
$silvester = 32
$string = "Tage"
$Form1 = GUICreate("Uhrzeit", 278, 71, @DesktopHeight / 2, 0, $WS_POPUP)
GUISetBkColor(0xA0A0A4)
$Label1 = GUICtrlCreateLabel("Uhrzeit:", 23, 12, 40, 17)
$Label2 = GUICtrlCreateLabel("Countdown", 72, 30, 58, 17)
$Label3 = GUICtrlCreateLabel("Countdown:", 2, 30, 61, 17)
$Label4 = GUICtrlCreateLabel("Hier Uhrzeit", 72, 12, 59, 17)
$Label5 = GUICtrlCreateLabel("dann ist morgen!", 20, 48, 78, 14)
GUICtrlSetBkColor(-1, 0xFF0000)
$Group1 = GUICtrlCreateGroup("Tag", 0, 0, 119, 70)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("Silvester", 146, 0, 130, 70)
$Label6 = GUICtrlCreateLabel("Datum:", 170, 12, 38, 17)
$Label7 = GUICtrlCreateLabel("Hier Datum", 218, 12, 57, 17)
$Label8 = GUICtrlCreateLabel("Countdown:", 148, 30, 61, 17)
$Label9 = GUICtrlCreateLabel("Datum", 218, 30, 35, 17)
$Label10 = GUICtrlCreateLabel("dann ist Silvester!!!", 168, 48, 90, 14)
GUICtrlSetBkColor(-1, 0xFF0000)
GUICtrlCreateGroup("", -99, -99, 1, 1)

[/autoit] [autoit][/autoit] [autoit]

GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

While 1
Sleep(100)
$stunde = @HOUR
$Minute = @MIN
$Sekunde = @SEC
$monat = @MON
$tag = @MDAY
$jahr = @YEAR
GUICtrlSetData($Label4, @HOUR & ":" & @MIN & ":" & @SEC)
GUICtrlSetData($Label2, $heute1 - $stunde & ":" & $heute2 - $Minute & ":" & $heute3 - $Sekunde)
GUICtrlSetData($Label7, $tag & "." & $monat & "." & $jahr)
If $silvester - $tag = 1 Then
$string = "Tag"
Else
$string = "Tage"
EndIf
GUICtrlSetData($Label9, $silvester - $tag & " " & $string)
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd

[/autoit]

**Raupi**

Dein Countdown geht genau 1 Sekunde nach. Im Countdown werden die Sekunden unter 10 nicht richtig angezeigt,da gehört eine 0 davor. Contdown bis Sylvester ist auch falsch . Wieso 6 ?Wenn dann müßte das heißen bis Neujahr . Mach doch nen richtigen Countdown draus.

r1fLeX

Ok , das mit den Sekunden ist behoben.
Und mit Silvester meinte ich Neujahr -.-.
Mein Fehler...
Eine Frage hätte ich , wieso klappt

[autoit]

Case $choose
$farbe = _ChooseColor(1)
GUICtrlSetBkColor($Form1,$farbe)

[/autoit]

nicht?
Es wird immer 0x000000 zurückgegeben?

Habe nun auch ein Problem beim Umwandeln wie ihr im Script seht

Spoiler anzeigen

[autoit]

#include <GUIConstants.au3>
#include <Misc.au3>
Opt("TrayMenuMode", 1)
AdlibEnable("_func", 150)
$auswaehlen = TrayCreateMenu("GUI Hintergrundfarbe")
$choose = TrayCreateItem("Auswählen", $auswaehlen)
$in = TrayCreateItem("Per Eingabe", $auswaehlen)
TrayCreateItem("")
$exit = TrayCreateItem("Exit")
$heute1 = 23
$heute2 = 59
$heute3 = 60
$silvester = 32
$string = "Tage"
$Form1 = GUICreate("Uhrzeit", 278, 71, @DesktopHeight / 2, 0, $WS_POPUP)
GUISetBkColor(0xA0A0A4)
$Label1 = GUICtrlCreateLabel("Uhrzeit:", 23, 12, 40, 17)
$Label2 = GUICtrlCreateLabel("Countdown", 72, 30, 58, 17)
$Label3 = GUICtrlCreateLabel("Countdown:", 2, 30, 61, 17)
$Label4 = GUICtrlCreateLabel("Hier Uhrzeit", 72, 12, 59, 17)
$Label5 = GUICtrlCreateLabel("dann ist morgen!", 20, 48, 78, 14)
GUICtrlSetBkColor(-1, 0xFF0000)
$Group1 = GUICtrlCreateGroup("Tag", 0, 0, 119, 70)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("Neujahr", 146, 0, 130, 70)
$Label6 = GUICtrlCreateLabel("Datum:", 170, 12, 38, 17)
$Label7 = GUICtrlCreateLabel("Hier Datum", 218, 12, 57, 17)
$Label8 = GUICtrlCreateLabel("Countdown:", 148, 30, 61, 17)
$Label9 = GUICtrlCreateLabel("Datum", 218, 30, 35, 17)
$Label10 = GUICtrlCreateLabel("dann ist Neujahr!!!", 168, 48, 90, 14)
GUICtrlSetBkColor(-1, 0xFF0000)
GUICtrlCreateGroup("", -99, -99, 1, 1)

[/autoit] [autoit][/autoit] [autoit]

GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

Func _func()
$stunde = @HOUR
$Minute = @MIN
$Sekunde = @SEC
$monat = @MON
$tag = @MDAY
$jahr = @YEAR
$1 = $heute1 - $stunde
$2 = $heute2 - $Minute
$3 = $heute3 - $Sekunde
If $3 = 1 Then
$3 = 01
EndIf
If $3 = 2 Then
$3 = 02
EndIf
If $3 = 3 Then
$3 = 03
EndIf
If $3 = 4 Then
$3 = 04
EndIf
If $3 = 5 Then
$3 = 05
EndIf
If $3 = 6 Then
$3 = 06
EndIf
GUICtrlSetData($Label4, @HOUR & ":" & @MIN & ":" & @SEC)
GUICtrlSetData($Label2, $1 & ":" & $2 & ":" & $3)
GUICtrlSetData($Label7, $tag & "." & $monat & "." & $jahr)
If $silvester - $tag = 1 Then
$string = "Tag"
Else
$string = "Tage"
EndIf
GUICtrlSetData($Label9, $silvester - $tag & " " & $string)
EndFunc ;==>_func
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
$tray = TrayGetMsg()
Switch $tray
Case $exit
Exit
Case $choose
$farbe = _ChooseColor(2, 0, 0, $Form1)
MsgBox(0, "", $farbe)
EndSwitch

[/autoit] [autoit][/autoit] [autoit]

WEnd

[/autoit]

**Raupi**

Check this out:

Spoiler anzeigen

[autoit]

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Date.au3>
Global $hour, $Mins, $secs, $hour1, $mins1, $secs1
$Form1 = GUICreate("Uhrzeit", 278, 71, -1, 0, $WS_POPUP)
GUISetBkColor(0xA0A0A4)
$Label1 = GUICtrlCreateLabel("Uhrzeit:", 23, 12, 40, 17)
$Label2 = GUICtrlCreateLabel("Countdown", 72, 30, 58, 17)
$Label3 = GUICtrlCreateLabel("Countdown:", 2, 30, 61, 17)
$Label4 = GUICtrlCreateLabel("Hier Uhrzeit", 72, 12, 59, 17)
$Label5 = GUICtrlCreateLabel("dann ist morgen!", 20, 48, 78, 14)
GUICtrlSetBkColor(-1, 0xFF0000)
$Group1 = GUICtrlCreateGroup("Tag", 0, 0, 119, 70)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("Silvester", 146, 0, 130, 70)
$Label6 = GUICtrlCreateLabel("Datum:", 170, 12, 38, 17)
$Label7 = GUICtrlCreateLabel("Hier Datum", 218, 12, 57, 17)
$Label8 = GUICtrlCreateLabel("Countdown:", 148, 30, 61, 17)
$Label9 = GUICtrlCreateLabel("Datum", 218, 30, 55, 17)
$Label10 = GUICtrlCreateLabel("dann ist Neujahr!!!", 168, 48, 90, 14)
GUICtrlSetBkColor(-1, 0xFF0000)
GUICtrlCreateGroup("", -99, -99, 1, 1)

[/autoit] [autoit][/autoit] [autoit]

GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

While 1
Sleep(500)
GUICtrlSetData($Label4, StringFormat("%02i:%02i:%02i", @HOUR, @MIN, @SEC))
_TicksToTime(_DateDiff('s', _NowCalc(), _DateAdd('d', 1, _NowCalcDate())& " 00:00:00") * 1000, $hour1, $mins1, $secs1)
GUICtrlSetData($Label2,StringFormat("%02i:%02i:%02i", $hour1, $mins1, $secs1))
_TicksToTime(_DateDiff('s', _NowCalc(), "2009/01/01 00:00:00") * 1000, $hour, $Mins, $secs)
GUICtrlSetData($Label9, StringFormat("%02i:%02i:%02i", $hour, $Mins, $secs))
GUICtrlSetData($Label7, @MDAY & "." & @MON & "." & @YEAR)

[/autoit] [autoit][/autoit] [autoit]

$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd

[/autoit]

r1fLeX

Öhm , funktioniert bei mir nicht!
Bei dir?

**Raupi**

Was kommt für ein Fehler ? Hast du die neue Autoit 3.3.0.0?Denkst du ich würde es posten, wenn ich des net zum laufen bekomme?
Edit zu deiner anderen Frage ,probier mal das

Spoiler anzeigen

[autoit]

Case $choose
$farbe = _ChooseColor(2)
GUISetBkColor($farbe,$Form1)

[/autoit]

Edit dein fehler oder besser 2 sind _ChooseColor mußt du mit 2 aufrufen und GuiSetBkColor statt GuiCtrlSetBkColor für die Gui nehmen.

**Raupi**

Da mir gerade Langweilig ist hier noch mal eine Minimalistische Version:

Spoiler anzeigen

[autoit]

#include <Date.au3>
#include <WindowsConstants.au3>
Global $hour, $Mins, $secs, $hour1, $mins1, $secs1
$Form1 = GUICreate("Uhrzeit", 655, 20, -1, 0, $WS_POPUP, $WS_EX_TOPMOST)
GUICtrlCreateLabel("Uhrzeit:", 5, 3, 40, 17)
$Label1 = GUICtrlCreateLabel("", 53, 3, 59, 17)
GUICtrlCreateLabel("Datum:", 120, 3, 38, 17)
$Label2 = GUICtrlCreateLabel("", 168, 3, 57, 17)
GUICtrlCreateLabel("Countdown bis Mitternacht:", 240, 3, 150, 17)
$Label3 = GUICtrlCreateLabel("", 380, 3, 58, 17)
GUICtrlSetColor(-1, 0xFF0000)
GUICtrlCreateLabel("Countdown bis Neujahr :", 440, 3, 150, 17)
$Label4 = GUICtrlCreateLabel("", 570, 3, 55, 17)
GUICtrlSetColor(-1, 0xFF0000)
$Button1 = GUICtrlCreateButton("X", 635, 1, 17, 17)
GUISetState(@SW_SHOW)
_Update()
AdlibEnable("_Update", 1000)
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $Button1
Exit
EndSwitch
WEnd
Func _Update()
GUICtrlSetData($Label1, StringFormat("%02i:%02i:%02i", @HOUR, @MIN, @SEC))
GUICtrlSetData($Label2, @MDAY & "." & @MON & "." & @YEAR)
_TicksToTime(_DateDiff('s', _NowCalc(), _DateAdd('d', 1, _NowCalcDate()) & " 00:00:00") * 1000, $hour1, $mins1, $secs1)
GUICtrlSetData($Label3, StringFormat("%02i:%02i:%02i", $hour1, $mins1, $secs1))
_TicksToTime(_DateDiff('s', _NowCalc(), "2009/01/01 00:00:00") * 1000, $hour, $Mins, $secs)
GUICtrlSetData($Label4, StringFormat("%02i:%02i:%02i", $hour, $Mins, $secs))
EndFunc ;==>_Update

[/autoit]