Beiträge von eukalyptus

#AutoIt3Wrapper_Autoit3Dir=c:\Program Files (x86)\AutoIt3\Beta

#include <Screencapture.au3>

Opt('GUIOnEventMode', 1)

Global $iSize = 32, $iW = 576, $iH = 576

Global $hGUI, $hGFX, $hBMP, $hBUF, $hBmps[$iSize][$iSize], $hBRU, $iFrame, $iTimer = TimerInit(), $iFPS, $iFrameTimer = TimerInit(), $iCount = 0, _
$hHBitmap, $hBitmap, $x, $y

_GDIPlus_Startup()

$sFile = FileOpenDialog("Select an image", "", "Images (*.bmp;*.png;*.jpg;*.gif;*.tif)")
If @error Or Not FileExists($sFile) Then Exit
$hImage = _GDIPlus_ImageLoadFromFile($sFile)
$iImgW = _GDIPlus_ImageGetWidth($hImage)
$iImgH = _GDIPlus_ImageGetHeight($hImage)

$hGUI = GUICreate('Text', $iW, $iH)
$hGFX = _GDIPlus_GraphicsCreateFromHWND($hGUI)
$hBMP = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGFX)
$hBUF = _GDIPlus_ImageGetGraphicsContext($hBMP)
;$hHBitmap = _ScreenCapture_Capture("", 0, 0, $iSize^2, $iSize^2)

$hBitmap = _GDIPlus_BitmapCreateFromScan0($iSize^2, $iSize^2)
$hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsDrawImageRect($hContext, $hImage, 0, 0, $iSize^2, $iSize^2)
_GDIPlus_GraphicsDispose($hContext)
_GDIPlus_ImageDispose($hImage)

;_WinAPI_DeleteObject($hHBitmap)

$tCM = _GDIPlus_ColorMatrixCreateScale(0,0,0)
$hImgAttr = _GDIPlus_ImageAttributesCreate()
Local $aResult, $fValue
$fSizeInv = 1 / $iSize

For $y = 0 To $iSize - 1
For $x = 0 To $iSize - 1
$hBmps[$y][$x] = _GDIPlus_BitmapCreateFromScan0($iSize, $iSize)
$hCtxt = _GDIPlus_ImageGetGraphicsContext($hBmps[$y][$x])

$fValue = BitXOR($x, $y) * $fSizeInv
$tCM.m(1) = $fValue
$tCM.m(13) = 1-$fValue
_GDIPlus_ImageAttributesSetColorMatrix($hImgAttr, 0, True, $tCM)

$aResult = DllCall($ghGDIPDll, "int", "GdipCreateTextureIA", "handle", $hBitmap, "handle", $hImgAttr, "float", $x * $iSize, "float", $y * $iSize, "float", $iSize, "float", $iSize, "handle*", 0)
_GDIPlus_GraphicsFillRect($hCtxt, 0, 0, $iSize, $iSize, $aResult[7])
_GDIPlus_GraphicsDispose($hCtxt)
_GDIPlus_BrushDispose($aResult[7])
Next
Next
_GDIPlus_ImageAttributesDispose($hImgAttr)

GUISetOnEvent(-3, '_Exit', $hGUI)
GUIRegisterMsg(0xF, 'WM_PAINT')
GUISetState(@SW_SHOW, $hGUI)

While Sleep(10)
_XOR_Tex()
WEnd

Func _XOR_Tex()
Local $iCol, $iTMP
Local Static $iSin = 0, $iMulti = 256 / $iSize, $2Multi = 2 * $iMulti
$iSin += 5 / (1000 / TimerDiff($iFrameTimer))
$iFrameTimer = TimerInit()
_GDIPlus_GraphicsClear($hBUF, 0xA0808080)
For $x = 0 To $iSize - 1
$iTMP = 2 * $x * $iMulti
For $y = 0 To $iSize - 1
_GDIPlus_GraphicsDrawImageRectF($hBUF, $hBmps[$y][$x], _
25 + 15 * Sin($y * $iMulti / 64 + $iSin) + $iTMP, _
15 * Cos($x * $iMulti / 64 + $iSin) + 25 + $y * $2Multi, _
$2Multi * 1.1, _
$2Multi * 1.1)
Next
Next
$iFPS += 1
If TimerDiff($iTimer) > 1000 Then
$iTimer = TimerInit()
WinSetTitle($hGUI, '', 'XOR Textur (' & $iFPS & 'FPS - ' & $iSize & 'x' & $iSize & ')')
$xFPS = $iFPS
$iFPS = 0
EndIf
WM_PAINT()
EndFunc ;==>_XOR_Tex

Func WM_PAINT()
_GDIPlus_GraphicsDrawImage($hGFX, $hBMP, 0, 0)
EndFunc ;==>WM_PAINT

Func _Exit()
_GDIPlus_GraphicsDispose($hBUF)
_GDIPlus_BitmapDispose($hBMP)
_GDIPlus_GraphicsDispose($hGFX)
For $y = 0 To $iSize - 1
For $x = 0 To $iSize - 1
_GDIPlus_BitmapDispose($hBmps[$y][$x])
Next
Next
_GDIPlus_Shutdown()
Exit
EndFunc ;==>_Exit

#AutoIt3Wrapper_UseX64=n
#include "Bass.au3"
#include "BassExt.au3"
#include "BassMix.au3"
#include "BassEnc.au3"

;Opt("MustDeclareVars", 1)

OnAutoItExitRegister("OnAutoItExit")

_BASS_Startup()
_BASS_EXT_Startup()
_BASS_MIX_Startup()
_BASS_ENCODE_Startup()

_BASS_Init(0, -1, 44100, 0, "")

Global $sFile_Opener = @ScriptDir & "\Opener.mp3"
Global $sFile_Main = @ScriptDir & "\Main.mp3"
Global $sFile_Closer = @ScriptDir & "\Closer.mp3"

Global $fdB_Opener = _MP3Gain_GetdB($sFile_Opener)
Global $fdB_Main = _MP3Gain_GetdB($sFile_Main)
Global $fdB_Closer = _MP3Gain_GetdB($sFile_Closer)
ConsoleWrite(StringFormat("+ Opener: %.2f dB", $fdB_Opener) & @CRLF)
ConsoleWrite(StringFormat("+ Main: %.2f dB", $fdB_Main) & @CRLF)
ConsoleWrite(StringFormat("+ Closer: %.2f dB", $fdB_Closer) & @CRLF)

_Audio_Mix(@ScriptDir & "\Mix.mp3", 89, $sFile_Opener, $fdB_Opener, $sFile_Main, $fdB_Main, $sFile_Closer, $fdB_Closer)

Func _MP3Gain_GetdB($sFile)
Local $sStdOut, $aRegExp, $iValue, $fdB

ProgressOn("Analyzing Audiofile", $sFile)

Local $hPID = Run(@ScriptDir & '\mp3gain -s sr -c "' & $sFile & '"', "", @SW_HIDE, 0x8)
While 1
$sStdOut = StdoutRead($hPID)
If @error Then ExitLoop
If $sStdOut Then
$aRegExp = StringRegExp($sStdOut, "(?i)\r\h*(\d+)%\h+of\h+\d+\h+bytes\h+analyzed", 3)
If IsArray($aRegExp) Then ProgressSet(Number($aRegExp[0]))

$aRegExp = StringRegExp($sStdOut, '(?mi)^\h*Recommended\h+"Track"\h+dB\h+change:\h*(-?\d+.\d+)', 3)
If IsArray($aRegExp) Then $fdB = Number($aRegExp[0])
EndIf
WEnd

ProgressOff()

Return 89 - $fdB
EndFunc ;==>_MP3Gain_GetdB

Func _Audio_Mix($sFile_Mix, $fdB_Studio, $sFile_Opener, $fdB_Opener, $sFile_Main, $fdB_Main, $sFile_Closer, $fdB_Closer, $fTH_Silence = -30, $fXFade = 0.3, $bLimit = True)
Local $hStream_Opener = _BASS_StreamCreateFile(False, $sFile_Opener, 0, 0, $BASS_STREAM_DECODE)
Local $hStream_Main = _BASS_StreamCreateFile(False, $sFile_Main, 0, 0, $BASS_STREAM_DECODE)
Local $hStream_Closer = _BASS_StreamCreateFile(False, $sFile_Closer, 0, 0, $BASS_STREAM_DECODE)

Local $iByteStart = 0, $iByteEnd = _BASS_ChannelGetLength($hStream_Main, $BASS_POS_BYTE)
If $fTH_Silence < 0 Then _Audio_FindSilence($hStream_Main, $iByteStart, $iByteEnd, $fTH_Silence)

$fdB_Gain_Opener = $fdB_Studio - $fdB_Opener
$fdB_Gain_Main = $fdB_Studio - $fdB_Main
$fdB_Gain_Closer = $fdB_Studio - $fdB_Closer
ConsoleWrite(StringFormat("> Gain Opener: %.2f dB", $fdB_Gain_Opener) & @CRLF)
ConsoleWrite(StringFormat("> Gain Main : %.2f dB", $fdB_Gain_Main) & @CRLF)
ConsoleWrite(StringFormat("> Gain Closer: %.2f dB", $fdB_Gain_Closer) & @CRLF)

Local $fdB_MaxPeak_Opener = _Audio_CalcMaxPeak($hStream_Opener)
Local $fdB_MaxPeak_Main = _Audio_CalcMaxPeak($hStream_Main)
Local $fdB_MaxPeak_Closer = _Audio_CalcMaxPeak($hStream_Closer)
ConsoleWrite(StringFormat("> Max Peak Opener: %.2f dB", $fdB_MaxPeak_Opener) & @CRLF)
ConsoleWrite(StringFormat("> Max Peak Main : %.2f dB", $fdB_MaxPeak_Main) & @CRLF)
ConsoleWrite(StringFormat("> Max Peak Closer: %.2f dB", $fdB_MaxPeak_Closer) & @CRLF)

Local $hFX_Opener, $hFX_Main, $hFX_Closer

If $fdB_MaxPeak_Opener + $fdB_Gain_Opener > 0 Then
ConsoleWrite(StringFormat("! Opener Peaks %.2f dB im Clippingbereich", $fdB_MaxPeak_Opener + $fdB_Gain_Opener) & @CRLF)
If $bLimit Then
ConsoleWrite(StringFormat("+ Opener Compressor auf %.2f dB, Ratio = 2.1:1", $fdB_MaxPeak_Opener - ($fdB_MaxPeak_Opener + $fdB_Gain_Opener) * 2) & @CRLF)
$hFX_Opener = _BASS_ChannelSetFX($hStream_Opener, $BASS_FX_DX8_COMPRESSOR, 1)
_BASS_FXSetParameters($hFX_Opener, "0|0.01|20|" & $fdB_MaxPeak_Opener - ($fdB_MaxPeak_Opener + $fdB_Gain_Opener) * 2 & "|2.1|0")
EndIf
EndIf

If $fdB_MaxPeak_Main + $fdB_Gain_Main > 0 Then
ConsoleWrite(StringFormat("! Main Peaks %.2f dB im Clippingbereich", $fdB_MaxPeak_Main + $fdB_Gain_Main) & @CRLF)
If $bLimit Then
ConsoleWrite(StringFormat("+ Main Compressor auf %.2f dB, Ratio = 2.1:1", $fdB_MaxPeak_Main - ($fdB_MaxPeak_Main + $fdB_Gain_Main) * 2) & @CRLF)
$hFX_Main = _BASS_ChannelSetFX($hStream_Main, $BASS_FX_DX8_COMPRESSOR, 1)
_BASS_FXSetParameters($hFX_Main, "0|0.01|20|" & $fdB_MaxPeak_Main - ($fdB_MaxPeak_Main + $fdB_Gain_Main) * 2 & "|2.1|0")
EndIf
EndIf

If $fdB_MaxPeak_Closer + $fdB_Gain_Closer > 0 Then
ConsoleWrite(StringFormat("! Closer Peaks %.2f dB im Clippingbereich", $fdB_MaxPeak_Closer + $fdB_Gain_Closer) & @CRLF)
If $bLimit Then
ConsoleWrite(StringFormat("+ Closer Compressor auf %.2f dB, Ratio = 2.1:1", $fdB_MaxPeak_Closer - ($fdB_MaxPeak_Closer + $fdB_Gain_Closer) * 2) & @CRLF)
$hFX_Closer = _BASS_ChannelSetFX($hStream_Closer, $BASS_FX_DX8_COMPRESSOR, 1)
_BASS_FXSetParameters($hFX_Closer, "0|0.01|20|" & $fdB_MaxPeak_Closer - ($fdB_MaxPeak_Closer + $fdB_Gain_Closer) * 2 & "|2.1|0")
EndIf
EndIf

_Audio_MixFiles($sFile_Mix, $hStream_Opener, $fdB_Gain_Opener, $hStream_Main, $fdB_Gain_Main, $iByteStart, $iByteEnd, $hStream_Closer, $fdB_Gain_Closer, $fXFade)

If $hFX_Opener Then _BASS_ChannelRemoveFX($hStream_Opener, $hFX_Opener)
If $hFX_Main Then _BASS_ChannelRemoveFX($hStream_Main, $hFX_Main)
If $hFX_Closer Then _BASS_ChannelRemoveFX($hStream_Closer, $hFX_Closer)

_BASS_StreamFree($hStream_Opener)
_BASS_StreamFree($hStream_Main)
_BASS_StreamFree($hStream_Closer)

EndFunc ;==>_Audio_Mix

Func _Audio_MixFiles($sFile_Mix, $hStream_Opener, $fdB_Gain_Opener, $hStream_Main, $fdB_Gain_Main, $iByteStart, $iByteEnd, $hStream_Closer, $fdB_Gain_Closer, $fXFade = 1)
_BASS_ChannelSetPosition($hStream_Opener, 0, $BASS_POS_BYTE) ;Auf Anfang setzen
_BASS_ChannelSetPosition($hStream_Main, $iByteStart, $BASS_POS_BYTE) ;Auf Anfang (minus Stille) setzen
_BASS_ChannelSetPosition($hStream_Closer, 0, $BASS_POS_BYTE) ;Auf Anfang setzen

Local $hMixer = _BASS_Mixer_StreamCreate(44100, 2, BitOR($BASS_MIXER_END, $BASS_STREAM_DECODE))

Local $iByteXFade = _BASS_ChannelSeconds2Bytes($hMixer, $fXFade)

Local $iByteLen_Opener = _BASS_ChannelGetLength($hStream_Opener, $BASS_POS_BYTE)
Local $iByteLen_Main = _BASS_ChannelGetLength($hStream_Main, $BASS_POS_BYTE)
Local $iByteLen_Closer = _BASS_ChannelGetLength($hStream_Closer, $BASS_POS_BYTE)

;Crossfade darf maximal die Hälfte eines Audiofiles sein
If $iByteXFade >= $iByteLen_Opener * 0.5 Then $iByteXFade = Floor($iByteLen_Opener * 0.5)
If $iByteXFade >= $iByteLen_Main * 0.5 Then $iByteXFade = Floor($iByteLen_Main * 0.5)
If $iByteXFade >= $iByteLen_Closer * 0.5 Then $iByteXFade = Floor($iByteLen_Closer * 0.5)

;Opener an Position 0
_BASS_Mixer_StreamAddChannelEx($hMixer, $hStream_Opener, BitOR($BASS_MIXER_FILTER, $BASS_STREAM_AUTOFREE), _
0, $iByteLen_Opener)

;Main an Position OpenerEnde - Crossfade
Local $iOffset = $iByteLen_Opener - $iByteXFade
_BASS_Mixer_StreamAddChannelEx($hMixer, $hStream_Main, BitOR($BASS_MIXER_FILTER, $BASS_STREAM_AUTOFREE), _
$iOffset, $iByteEnd - $iByteStart)

;Closer an Position MainEnde - Crossfade
$iOffset += $iByteEnd - $iByteStart - $iByteXFade
_BASS_Mixer_StreamAddChannelEx($hMixer, $hStream_Closer, BitOR($BASS_MIXER_FILTER, $BASS_STREAM_AUTOFREE), _
$iOffset, $iByteLen_Closer)

Local $iByteXFade2 = Round($iByteXFade / 2)

Local $aVol_O[5][2] = [[4]]
$aVol_O[1][0] = 0
$aVol_O[1][1] = _BASS_EXT_dB2Level($fdB_Gain_Opener, False)
$aVol_O[2][0] = $iByteLen_Opener - $iByteXFade ;ab hier ausfaden
$aVol_O[2][1] = _BASS_EXT_dB2Level($fdB_Gain_Opener, False)
$aVol_O[3][0] = $iByteLen_Opener - $iByteXFade2 ;bis hier -3dB
$aVol_O[3][1] = _BASS_EXT_dB2Level($fdB_Gain_Opener - 3, False)
$aVol_O[4][0] = $iByteLen_Opener
$aVol_O[4][1] = 0

_BASS_Mixer_ChannelSetEnvelope($hStream_Opener, $BASS_MIXER_ENV_VOL, $aVol_O)

Local $aVol_M[7][2] = [[6]]
$aVol_M[1][0] = 0
$aVol_M[1][1] = 0
$aVol_M[2][0] = $iByteXFade2 ;bis hier auf -3dB einfaden
$aVol_M[2][1] = _BASS_EXT_dB2Level($fdB_Gain_Main - 3, False)
$aVol_M[3][0] = $iByteXFade ;bis hier komplett einfaden
$aVol_M[3][1] = _BASS_EXT_dB2Level($fdB_Gain_Main, False)

$aVol_M[4][0] = $iByteEnd - $iByteStart - $iByteXFade ;ab hier auf -3dB ausfaden
$aVol_M[4][1] = _BASS_EXT_dB2Level($fdB_Gain_Main, False)
$aVol_M[5][0] = $iByteEnd - $iByteStart - $iByteXFade2 ;ab hier komplett ausfaden
$aVol_M[5][1] = _BASS_EXT_dB2Level($fdB_Gain_Main - 3, False)

$aVol_M[6][0] = $iByteEnd - $iByteStart
$aVol_M[6][1] = 0

_BASS_Mixer_ChannelSetEnvelope($hStream_Main, $BASS_MIXER_ENV_VOL, $aVol_M)

Local $aVol_C[4][2] = [[3]]
$aVol_C[1][0] = 0
$aVol_C[1][1] = 0
$aVol_C[2][0] = $iByteXFade ;bis hier auf -3dB einfaden
$aVol_C[2][1] = _BASS_EXT_dB2Level($fdB_Gain_Closer - 3, False)
$aVol_C[3][0] = $iByteXFade ;bis hier komplett einfaden
$aVol_C[3][1] = _BASS_EXT_dB2Level($fdB_Gain_Closer, False)

_BASS_Mixer_ChannelSetEnvelope($hStream_Closer, $BASS_MIXER_ENV_VOL, $aVol_C)

Local $hEncoder
If StringRight($sFile_Mix, 3) = "mp3" Then
$hEncoder = _BASS_Encode_Start($hMixer, '"' & @ScriptDir & '\lame" -r -x -b320 -h - "' & $sFile_Mix & '"', 0);MP3 erstellen
Else
$hEncoder = _BASS_Encode_Start($hMixer, $sFile_Mix, $BASS_ENCODE_PCM);Wav erstellen
EndIf

Local $iPos, $iLen = $iByteEnd

Local $tBuffer = DllStructCreate("byte[88200];")
Local $pBuffer = DllStructGetPtr($tBuffer)
Local $iBuffer = DllStructGetSize($tBuffer)

Local $iByteLen_Mix = $iOffset + $iByteLen_Closer

Local $iBytesDone = 0, $iBytesBuffer
ProgressOn("Mix", "Mixing Audiofiles")
Local $iTimer = TimerInit()
While _BASS_ChannelIsActive($hMixer)
$iBytesBuffer = _BASS_ChannelGetData($hMixer, $pBuffer, $iBuffer);Daten holen und so Enkodierprozess ausführen
$iBytesDone += $iBytesBuffer
If TimerDiff($iTimer) > 250 Then
ProgressSet($iBytesDone * 100 / $iByteLen_Mix)
$iTimer = TimerInit()
EndIf
WEnd
ProgressOff()
_BASS_Encode_Stop($hEncoder)

_BASS_StreamFree($hMixer)
EndFunc ;==>_Audio_MixFiles

Func _Audio_CalcMaxPeak($hStream)
_BASS_ChannelSetPosition($hStream, 0, $BASS_POS_BYTE) ;Auf Anfang setzen

Local $iLevel
Local $fLeft, $fRight
Local $fPeak = 0
Local $iByteLen = _BASS_ChannelGetLength($hStream, $BASS_POS_BYTE)

ProgressOn("Get Max Peak", "Get Max Peak")
Local $iTimer = TimerInit()
While 1
$iLevel = _BASS_ChannelGetLevel($hStream)
If @error Then ExitLoop
$fLeft = _BASS_LoWord($iLevel)
$fRight = _BASS_HiWord($iLevel)

If $fLeft > $fPeak Then $fPeak = $fLeft
If $fRight > $fPeak Then $fPeak = $fRight

If TimerDiff($iTimer) > 250 Then
ProgressSet(_BASS_ChannelGetPosition($hStream, $BASS_POS_BYTE) * 100 / $iByteLen)
$iTimer = TimerInit()
EndIf
WEnd
ProgressOff()

Return _BASS_EXT_Level2dB($fPeak / 32768, False)
EndFunc ;==>_Audio_CalcMaxPeak

Func _Audio_FindSilence($hStream, ByRef $iByteStart, ByRef $iByteEnd, $fThrsHld = -30)
_BASS_ChannelSetPosition($hStream, 0, $BASS_POS_BYTE) ;Auf Anfang setzen

$iByteStart = 0
$iByteEnd = _BASS_ChannelGetLength($hStream, $BASS_POS_BYTE)

$fThrsHld = _BASS_EXT_dB2Level($fThrsHld, False)

Local $iLevel, $fLeft, $fRight
Local $iBytePos = 0
Local $bStart = False

Local $iByteLen = _BASS_ChannelGetLength($hStream, $BASS_POS_BYTE)

ProgressOn("Cut Silence", "Find Silence")
Local $iTimer = TimerInit()
While 1
$iLevel = _BASS_ChannelGetLevel($hStream)
If @error Then ExitLoop

$iBytePos = _BASS_ChannelGetPosition($hStream, $BASS_POS_BYTE) ;aktuelle Postition ermitteln
If TimerDiff($iTimer) > 250 Then
ProgressSet($iBytePos * 100 / $iByteLen)
$iTimer = TimerInit()
EndIf

$fLeft = _BASS_LoWord($iLevel) / 32768
$fRight = _BASS_HiWord($iLevel) / 32768

If $fLeft <= $fThrsHld And $fRight <= $fThrsHld Then ;Level unter Threshold
If Not $bStart Then;Noch immer Stille am Anfang
$iByteStart = $iBytePos
EndIf

Else ;Level über Treshold
$bStart = True
$iByteEnd = $iBytePos
EndIf

WEnd

ProgressOff()
EndFunc ;==>_Audio_FindSilence

Func OnAutoItExit()
_BASS_Free()
EndFunc ;==>OnAutoItExit

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>

Global $sText = 'Hallo' & @CRLF & 'Das sieht total seltsam aus...' & @CRLF & _
'Sowas möchte ich nicht zum Frühstück essen !' & @CRLF & _
'Dies is[s]t ein sehr krea[/s]tiver Text' & @CRLF & @CRLF & @CRLF & _
'[size=50]Hallo[y=10]du[y=0] Spaßvogel[/size]' & @CRLF & @CRLF & @CRLF & @CRLF & _
'[size=50]a[size=40]bcdefghijklmnopqrstuvwxyz[/size][/size]' & @CRLF & _
'

Far[size=30]big

[autoit]so [c=dunkelrot]mag[/code] i[/size]ch [c=80FF8040]das[/code] !' & _
@CRLF & @CRLF & '[c=ff0000]Das ist [y=-5]ein[y=0] Test[/code]' & @CRLF & @CRLF & _
'[x=100]Update auf Version 0.0.0.1[x=0]' & @CRLF & _
'' & @CRLF & _
'Neu:' & @CRLF & _
' - Account über Webseite registrieren' & @CRLF & _
' - Ingame Login' & @CRLF & _
' - Ingame Menu' & @CRLF & _
' - Ein Berg auf dem sich ein kleines Dorf mit allen' & @CRLF & _
' momentanen Models befindet.' & @CRLF & _
' - Leichte Vegetation' & @CRLF & _
' - Man kann sich die Landschaft ansehen' & @CRLF & _
'' & @CRLF & _
'[center]Bugfixes[/center]:' & @CRLF & _
' - Noch keine, da dies das "First Release" ist !' & @CRLF & _
'' & @CRLF & _
'[x=100]euer Team ;)[x=0]' & @CRLF & _
'' & @CRLF & _
'[y=-80][x=80][size=9]ich stehe einfach mittendrin :P'

Opt("GUIOnEventMode", 1)
Opt("MustDeclareVars", 1)

_GDIPlus_Startup()

Global $iWidth = 500
Global $iHeight = 700

Global $hGui = GUICreate("Test", $iWidth, $iHeight, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
Global $hBmpBuffer = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphics)
Global $hGfxBuffer = _GDIPlus_ImageGetGraphicsContext($hBmpBuffer)

GUIRegisterMsg($WM_SIZE, "_WM_SIZE")
GUIRegisterMsg($WM_PAINT, "_WM_PAINT")
GUISetState()

_GDIPlus_GraphicsClear($hGfxBuffer, 0xFFFFFFFF)
;_BBCode_Draw($sText, $hGfxBuffer, 10, 10, 780, 680, 4)
_BBCode_Draw($sText, $hGfxBuffer, 10, 10, $iWidth-20, $iHeight-20, 0)
_GDIPlus_GraphicsDrawImage($hGraphics, $hBmpBuffer, 0, 0)

While Sleep(10)
WEnd

Func _BBCode_GetColor($sFormat)
Local $aRegExp = StringRegExp($sFormat, "=\h*(.+)", 3)
If Not IsArray($aRegExp) Then Return "0xFF000000"

Local $iColor = $aRegExp[0]

Local Static $aDosCol[16] = [0xFF000000, 0xFF800000, 0xFF008000, 0xFF808000, 0xFF000080, 0xFF800080, 0xFF008080, 0xFFC0C0C0, 0xFF808080, 0xFFFF0000, 0xFF00FF00, 0xFFFFFF00, 0xFF0000FF, 0xFFFF00FF, 0xFF00FFFF, 0xFFFFFFFF]
Local Static $aNamenEn[16] = ['black', 'maroon', 'green', 'olive', 'navy', 'purple', 'teal', 'silver', 'gray', 'red', 'lime', 'yellow', 'blue', 'fuchsia', 'aqua', 'white']
Local Static $aNamenDe[16] = ['schwarz', 'dunkelrot', 'dunkelgrün', 'oliv', 'dunkelblau', 'lila', 'türkis', 'hellgrau', 'grau', 'rot', 'grün', 'gelb', 'blau', 'pink', 'hellblau', 'weiß']
If StringIsXDigit($iColor) Then
Switch StringLen($iColor)
Case 1, 2
$iColor = Int($iColor)
$iColor -= Int($iColor / 16) * 16
Return "0x" & Hex($aDosCol[$iColor],
Case 6
Return "0xFF" & $iColor
Case 8
Return "0x" & $iColor
Case 10
Return $iColor
EndSwitch

Else
For $i = 0 To 15 Step 1
If ($iColor = $aNamenEn[$i]) Or ($iColor = $aNamenDe[$i]) Then
Return "0x" & Hex($aDosCol[Int($i)],
EndIf
Next
EndIf
Return "0xFF000000"
EndFunc ;==>_BBCode_GetColor

Func _BBCode_Format(ByRef $aFormat, $sFormat, $hFormat, ByRef $hFamily, ByRef $hFont, ByRef $hBrush, ByRef $fXOff, ByRef $fYOff)
Local $aRegExp = StringRegExp($sFormat, "[^=]+", 3)
If Not IsArray($aRegExp) Then
MsgBox(0, "", "Error")
Return
EndIf
Local $sCode = $aRegExp[0]
Local $sFirst = StringLeft($sCode, 1)

Local $iStyle = 0, $fSize = 10, $iColor = 0xFF000000, $sFont = "Arial"

Switch $sFirst
Case "/"
$sCode = StringTrimLeft($sCode, 1)

Switch $sCode
Case "i", "b", "u", "s" ;restore last style
$aFormat[1] = StringRegExpReplace($aFormat[1], "([^;]*;)", "", 1)
$aRegExp = StringRegExp($aFormat[1], "([^;]*)", 3)
If IsArray($aRegExp) Then $iStyle = $aRegExp[0]
$aRegExp = StringRegExp($aFormat[0], "([^;]*)", 3)
If IsArray($aRegExp) Then $fSize = $aRegExp[0]

ConsoleWrite("! old Style: " & $iStyle & " size: " & $fSize & @CRLF)

_GDIPlus_FontDispose($hFont)
$hFont = _GDIPlus_FontCreate($hFamily, $fSize, $iStyle, 2)

Case "size" ;restore last size
$aFormat[0] = StringRegExpReplace($aFormat[0], "([^;]*;)", "", 1)
$aRegExp = StringRegExp($aFormat[1], "([^;]*)", 3)
If IsArray($aRegExp) Then $iStyle = $aRegExp[0]
$aRegExp = StringRegExp($aFormat[0], "([^;]*)", 3)
If IsArray($aRegExp) Then $fSize = $aRegExp[0]

ConsoleWrite("! old Size: " & $fSize & " style: " & $iStyle & @CRLF)

_GDIPlus_FontDispose($hFont)
$hFont = _GDIPlus_FontCreate($hFamily, $fSize, $iStyle, 2)

Case "c" ;restore last color
$aFormat[2] = StringRegExpReplace($aFormat[2], "([^;]*;)", "", 1)
$aRegExp = StringRegExp($aFormat[2], "([^;]*)", 3)
If IsArray($aRegExp) Then $iColor = $aRegExp[0]

_GDIPlus_BrushSetSolidColor($hBrush, $iColor)

ConsoleWrite("! old color: " & $iColor & @CRLF)

Case "font"
$aFormat[3] = StringRegExpReplace($aFormat[3], "([^;]*;)", "", 1)
$aRegExp = StringRegExp($aFormat[3], "([^;]*)", 3)
If IsArray($aRegExp) Then $sFont = $aRegExp[0]

$aRegExp = StringRegExp($aFormat[0], "([^;]*)", 3)
If IsArray($aRegExp) Then $fSize = $aRegExp[0]
$aRegExp = StringRegExp($aFormat[1], "([^;]*)", 3)
If IsArray($aRegExp) Then $iStyle = $aRegExp[0]

ConsoleWrite("! old Font: " & $sFont & @CRLF)

_GDIPlus_FontDispose($hFont)
_GDIPlus_FontFamilyDispose($hFamily)
$hFamily = _GDIPlus_FontFamilyCreate($sFont)
$hFont = _GDIPlus_FontCreate($hFamily, $fSize, $iStyle, 2)

#cs
Case "center"
$iStyle = 0
$aFormat[4] = StringRegExpReplace($aFormat[4], "([^;]*;)", "", 1)
$aRegExp = StringRegExp($aFormat[4], "([^;]*)", 3)
If IsArray($aRegExp) Then $iStyle = $aRegExp[0]

ConsoleWrite("! Old Align: " & $iStyle & @CRLF)

_GDIPlus_StringFormatSetAlign($hFormat,$iStyle)
#ce

EndSwitch

Case Else
Switch $sCode
Case "i", "b", "u", "s" ;Set new Style
$aRegExp = StringRegExp($aFormat[1], "([^;]*)", 3)
If IsArray($aRegExp) Then $iStyle = $aRegExp[0]
$aRegExp = StringRegExp($aFormat[0], "([^;]*)", 3)
If IsArray($aRegExp) Then $fSize = $aRegExp[0]

Switch $sFirst
Case "i" ;Kursiv
$iStyle = BitOR($iStyle, 2)
Case "b" ;Fett
$iStyle = BitOR($iStyle, 1)
Case "u" ;Unterstrichen
$iStyle = BitOR($iStyle, 4)
Case "s" ;Durchgestrichen
$iStyle = BitOR($iStyle,
EndSwitch
$aFormat[1] = $iStyle & ";" & $aFormat[1]

ConsoleWrite("! new Style: " & $iStyle & " size: " & $fSize & @CRLF)

_GDIPlus_FontDispose($hFont)
$hFont = _GDIPlus_FontCreate($hFamily, $fSize, $iStyle, 2)

Case "size"
$aRegExp = StringRegExp($aFormat[1], "([^;]*)", 3)
If IsArray($aRegExp) Then $iStyle = $aRegExp[0]

$aRegExp = StringRegExp($sFormat, "=\h*(.*)", 3)
If IsArray($aRegExp) Then $fSize = StringStripWS($aRegExp[0],

$aFormat[0] = $fSize & ";" & $aFormat[0]

ConsoleWrite("! new Size: " & $fSize & " style: " & $iStyle & @CRLF)

_GDIPlus_FontDispose($hFont)
$hFont = _GDIPlus_FontCreate($hFamily, $fSize, $iStyle, 2)

Case "c" ;set new color
$iColor = _BBCode_GetColor($sFormat)
$aFormat[2] = $iColor & ";" & $aFormat[2]
_GDIPlus_BrushSetSolidColor($hBrush, $iColor)

ConsoleWrite("! new color: " & $iColor & @CRLF)

Case "x"
$aRegExp = StringRegExp($sFormat, "=\h*(.*)", 3)
If IsArray($aRegExp) Then $fXOff = $aRegExp[0]

Case "y"
$aRegExp = StringRegExp($sFormat, "=\h*(.*)", 3)
If IsArray($aRegExp) Then $fYOff = $aRegExp[0]

Case "font"
$aRegExp = StringRegExp($aFormat[0], "([^;]*)", 3)
If IsArray($aRegExp) Then $fSize = $aRegExp[0]
$aRegExp = StringRegExp($aFormat[1], "([^;]*)", 3)
If IsArray($aRegExp) Then $iStyle = $aRegExp[0]

$aRegExp = StringRegExp($sFormat, "=\h*(.*)", 3)
If IsArray($aRegExp) Then $sFont = $aRegExp[0]

$aFormat[3] = $sFont & ";" & $aFormat[3]

ConsoleWrite("! new Font: " & $sFont & @CRLF)

_GDIPlus_FontDispose($hFont)
_GDIPlus_FontFamilyDispose($hFamily)
$hFamily = _GDIPlus_FontFamilyCreate($sFont)
$hFont = _GDIPlus_FontCreate($hFamily, $fSize, $iStyle, 2)

#cs
Case "center"
$iStyle = 1
$aFormat[4] = $iStyle & ";" & $aFormat[4]

ConsoleWrite("! Set Align: " & $iStyle & @CRLF)

ConsoleWrite("Error: " & _GDIPlus_StringFormatSetAlign($hFormat,$iStyle) & @CRLF)
#ce

EndSwitch
EndSwitch
EndFunc ;==>_BBCode_Format

Func _BBCode_CalcDim($sChar, $hGraphics, $hFormat, $hFamily, $hFont, $tRectF)
Local $aResult = DllCall($ghGDIPDll, "uint", "GdipGetFontStyle", "hwnd", $hFont, "int*", 0)
Local $iStyle = $aResult[2]

$aResult = DllCall($ghGDIPDll, "uint", "GdipGetFontSize", "hwnd", $hFont, "float*", 0)
Local $fSize = $aResult[2]

$aResult = DllCall($ghGDIPDll, "uint", "GdipGetEmHeight", "hwnd", $hFamily, "int", $iStyle, "ushort*", 0)
Local $iEMHeight = $aResult[3]

$aResult = DllCall($ghGDIPDll, "uint", "GdipGetCellAscent", "hwnd", $hFamily, "int", $iStyle, "ushort*", 0)
Local $fAsc = $fSize / $iEMHeight * $aResult[3]

$aResult = DllCall($ghGDIPDll, "uint", "GdipGetCellDescent", "hwnd", $hFamily, "int", $iStyle, "ushort*", 0)
Local $fDesc = $fSize / $iEMHeight * $aResult[3]

$aResult = DllCall($ghGDIPDll, "uint", "GdipGetLineSpacing", "hwnd", $hFamily, "int", $iStyle, "ushort*", 0)
Local $fLnSpac = $fSize / $iEMHeight * $aResult[3]

$aResult = DllCall($ghGDIPDll, "uint", "GdipCreateRegion", "int*", 0)
Local $hRegion = $aResult[1]

$aResult = DllCall($ghGDIPDll, "uint", "GdipMeasureCharacterRanges", "hwnd", $hGraphics, "wstr", $sChar, "int", -1, "hwnd", $hFont, "ptr", DllStructGetPtr($tRectF), "hwnd", $hFormat, "int", 1, "hwnd*", $hRegion)

Local $tBounds = DllStructCreate($tagGDIPRECTF)
$aResult = DllCall($ghGDIPDll, "uint", "GdipGetRegionBounds", "hwnd", $hRegion, "hwnd", $hGraphics, "ptr", DllStructGetPtr($tBounds))

DllCall($ghGDIPDll, "uint", "GdipDeleteRegion", "hwnd", $hRegion)

Local $aRet[7]
$aRet[0] = DllStructGetData($tBounds, "X")
$aRet[1] = DllStructGetData($tBounds, "Y")
$aRet[2] = DllStructGetData($tBounds, "Width")
$aRet[3] = DllStructGetData($tBounds, "Height")
$aRet[4] = $fAsc
$aRet[5] = $fDesc
$aRet[6] = $fLnSpac

Return $aRet
EndFunc ;==>_BBCode_CalcDim

Func _BBCode_Draw($sBBCode, $hGraphics, $iX, $iY, $iW, $iH, $iRenteringHint)

Local $aRegExp = StringRegExp($sBBCode, "\[(.*?)\]([^[]*)", 3)
If Not IsArray($aRegExp) Then Return SetError(1, 1, False)

Local $aFormat[6]
$aFormat[0] = "12.5;" ;Size
$aFormat[1] = "0;" ;Style
$aFormat[2] = "0xFF000000;" ;Color
$aFormat[3] = "Courier New;" ;Font
$aFormat[4] = "0" ;Alignment = Left

Local $hBmpText = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
Local $hGfxText = _GDIPlus_ImageGetGraphicsContext($hBmpText)

Local $hPen = _GDIPlus_PenCreate(0xFFAA0000)
_GDIPlus_GraphicsDrawRect($hGfxText, 0, 0, $iW - 1, $iH - 1, $hPen)

Local $hBrush = _GDIPlus_BrushCreateSolid(0xFF000000)
Local $hFormat = _GDIPlus_StringFormatCreate()
Local $hFamily = _GDIPlus_FontFamilyCreate("Courier New")
Local $tRectFZero = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
Local $tRectF = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
Local $hFont = _GDIPlus_FontCreate($hFamily, 12.5, 0, 2)

Local $tRanges = DllStructCreate("int Pos; int Cnt;")
DllStructSetData($tRanges, "Pos", 0)
DllStructSetData($tRanges, "Cnt", 1)
DllCall($ghGDIPDll, "uint", "GdipSetStringFormatMeasurableCharacterRanges", "hwnd", $hFormat, "int", 1, "ptr", DllStructGetPtr($tRanges))

Local $hBmpLine = _GDIPlus_BitmapCreateFromGraphics($iW, $iH * 2, $hGfxText)
Local $hGfxLine = _GDIPlus_ImageGetGraphicsContext($hBmpLine)
DllCall($ghGDIPDll, "uint", "GdipSetTextRenderingHint", "hwnd", $hGfxLine, "int", $iRenteringHint)

Local $iCnt = Ceiling(UBound($aRegExp) / 2)

Local $fPosX = 0, $fPosY = 0
Local $fLineSpacing = 0
Local $fPosXOff = 0, $fPosYOff = 0
Local $fXOff = 0, $fYOff = 0

Local $aSplit, $aDim[7]
For $i = 0 To UBound($aRegExp) - 1 Step 2
ConsoleWrite("+ " & $aRegExp[$i] & @CRLF)

_BBCode_Format($aFormat, $aRegExp[$i], $hFormat, $hFamily, $hFont, $hBrush, $fXOff, $fYOff)

$aSplit = StringSplit(StringStripCR($aRegExp[$i + 1]), "")
For $j = 1 To $aSplit[0]
Switch $aSplit[$j]
Case @LF
$fPosY += $fPosYOff
$fPosX = 0
_GDIPlus_GraphicsDrawImage($hGfxText, $hBmpLine, 0, -$iH + $fPosY)
_GDIPlus_GraphicsDispose($hGfxLine)
_GDIPlus_BitmapDispose($hBmpLine)
;_GDIPlus_GraphicsDrawLine($hGfxText, 0, $fPosY, 10, $fPosY, $hPen)
$hBmpLine = _GDIPlus_BitmapCreateFromGraphics($iW, $iH * 2, $hGfxText)
$hGfxLine = _GDIPlus_ImageGetGraphicsContext($hBmpLine)
DllCall($ghGDIPDll, "uint", "GdipSetTextRenderingHint", "hwnd", $hGfxLine, "int", $iRenteringHint)
$fPosYOff = 0
$fPosXOff = 0
$aDim = _BBCode_CalcDim("-", $hGfxLine, $hFormat, $hFamily, $hFont, $tRectFZero)
$aDim[0] = 0
$aDim[2] = 0
Case " "
$aDim = _BBCode_CalcDim("-", $hGfxLine, $hFormat, $hFamily, $hFont, $tRectFZero)
Case Else
$aDim = _BBCode_CalcDim($aSplit[$j], $hGfxLine, $hFormat, $hFamily, $hFont, $tRectFZero)
EndSwitch

$fPosX += $fPosXOff
$fPosXOff = $aDim[2]

If $fPosX + $fPosXOff + $fXOff >= $iW Then
$fPosY += $fPosYOff
$fPosX = 0
_GDIPlus_GraphicsDrawImage($hGfxText, $hBmpLine, 0, -$iH + $fPosY)
_GDIPlus_GraphicsDispose($hGfxLine)
_GDIPlus_BitmapDispose($hBmpLine)
$hBmpLine = _GDIPlus_BitmapCreateFromGraphics($iW, $iH * 2, $hGfxText)
$hGfxLine = _GDIPlus_ImageGetGraphicsContext($hBmpLine)
DllCall($ghGDIPDll, "uint", "GdipSetTextRenderingHint", "hwnd", $hGfxLine, "int", $iRenteringHint)
$fPosYOff = 0
;$fPosXOff = 0
$aDim = _BBCode_CalcDim("-", $hGfxLine, $hFormat, $hFamily, $hFont, $tRectFZero)
;$aDim[0] = 0
$aDim[2] = 0
EndIf

DllStructSetData($tRectF, "X", $fPosX - $aDim[0] + $fXOff)
DllStructSetData($tRectF, "Y", $iH - $aDim[4] + $fYOff)
If $aDim[6] > $fPosYOff Then $fPosYOff = Ceiling($aDim[6])
_GDIPlus_GraphicsDrawStringEx($hGfxLine, $aSplit[$j], $hFont, $tRectF, $hFormat, $hBrush)
Next

Next

_GDIPlus_FontDispose($hFont)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
_GDIPlus_BrushDispose($hBrush)

_GDIPlus_PenDispose($hPen)

_GDIPlus_GraphicsDispose($hGfxLine)
_GDIPlus_BitmapDispose($hBmpLine)
_GDIPlus_GraphicsDispose($hGfxText)

_GDIPlus_GraphicsDrawImage($hGraphics, $hBmpText, $iX, $iY)
_GDIPlus_BitmapDispose($hBmpText)
EndFunc ;==>_BBCode_Draw

Func _ReDraw()
AdlibUnRegister("_ReDraw")
_GDIPlus_GraphicsClear($hGfxBuffer, 0xFFFFFFFF)
_BBCode_Draw($sText, $hGfxBuffer, 10, 10, $iWidth-20, $iHeight-20, 4)
_GDIPlus_GraphicsDrawImage($hGraphics, $hBmpBuffer, 0, 0)
AdlibUnRegister("_ReDraw")
EndFunc

Func _WM_SIZE($hWnd, $iMsg, $wParam, $lParam)
$iWidth = _WinAPI_LoWord($lParam)
$iHeight = _WinAPI_HiWord($lParam)
_GDIPlus_GraphicsDispose($hGfxBuffer)
_GDIPlus_BitmapDispose($hBmpBuffer)
_GDIPlus_GraphicsDispose($hGraphics)

$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
$hBmpBuffer = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphics)
$hGfxBuffer = _GDIPlus_ImageGetGraphicsContext($hBmpBuffer)

AdlibRegister("_ReDraw", 100)

Return $GUI_RUNDEFMSG
EndFunc

Func _WM_PAINT($hWnd, $iMsg, $wParam, $lParam)
_GDIPlus_GraphicsDrawImage($hGraphics, $hBmpBuffer, 0, 0)
Return $GUI_RUNDEFMSG
EndFunc ;==>_WM_PAINT

Func _Exit()
_GDIPlus_GraphicsDispose($hGfxBuffer)
_GDIPlus_BitmapDispose($hBmpBuffer)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()
GUIDelete($hGui)
Exit
EndFunc ;==>_Exit