Beiträge von autoBert

#include <Array.au3>
#include <String.au3>


$sString = 'class="adress">Rathausplatz 5<br/>90403 Nürnberg<br/><a href=" ' & @CRLF & _
		'Kontakt</h3><p class="adress">Äußere Bayreuther Str. 121<br/>90409 Nürnberg<br/><a href="' & @CRLF & _
		'</span></p><h3>Kontakt</h3><p class="adress">Wallensteinstraße 28<br/>90439 Nürnberg<br/><a href="' & @CRLF & _
		'</span></p><h3>Kontakt</h3><p class="adress">Glogauer Str. 30 - 38<br/>90473 Nürnberg<br/><a href="'
$aAdress=_StringBetween($sString,'"adress">','<br/><a href="')
;ergibt jede adresszeile also z.B.:   Rathausplatz 5<br/>90403 Nürnberg
_ArrayColInsert($aAdress,1)	;Spalte einfügen
_ArrayColInsert($aAdress,1)	;Spalte einfügen
For $i=0 To UBound($aAdress)-1
	$aSplit=StringSplit($aAdress[$i][0],'<br/>',$STR_ENTIRESPLIT)
	;ergibt Array mit 3 Feldern
	;0 = Anzahl der Einträge
	;1 = Straße HausNr
	;2 = PLZ Ort
	if @error Then ContinueLoop
	If $aSplit[0]<1 Then ContinueLoop
	$aAdress[$i][0]=$aSplit[1]
	;Straße HausNr in 2D Array speichern
	If $aSplit[0]<2 Then ContinueLoop
	$aAdress[$i][1]=StringLeft($aSplit[2],5)
	;PLZ in 2D Array speichern
	$aAdress[$i][2]=StringMid($aSplit[2],7)
	;Ort in 2D Array speichern
Next
_ArrayDisplay($aAdress)

#include <Array.au3>


Global $aDrives[26][10]
_CreateDriveItems()


Func _CreateDriveItems($bDelete = False)
	Local $aLdrives, $iFound, $hIcon
	$aLdrives = DriveGetDrive('ALL')
	_ArrayDelete($aLdrives, 0)
	;_ArrayDisplay($aLdrives)
	For $i = 25 To 0 Step -1
		If $bDelete And $aDrives[$i][0] <> '' Then
			;_GUICtrlTreeView_Delete($idTVLocal, $aDrives[$i][0])
			$aDrives[$i][0] = ''
		EndIf
		$iFound = _ArraySearch($aLdrives, Chr($i + 65) & ':')
		If @error Then
			If $aDrives[$i][0] <> '' Then
				;_GUICtrlTreeView_Delete($idTVLocal, $aDrives[$i][0])
				$aDrives[$i][0] = ''
			EndIf
		Else
			If $aDrives[$i][0] = '' Then
				$aDrives[$i][0] = Chr($i + 65)
				$aDrives[$i][1] = DriveGetType($aLdrives[$iFound] & '\')
				$aDrives[$i][2] = DriveGetType($aLdrives[$iFound] & '\', 2)
				$aDrives[$i][3] = DriveGetType($aLdrives[$iFound] & '\', 3)
				$aDrives[$i][4] = DriveStatus($aLdrives[$iFound] & '\')
				$aDrives[$i][5] = DriveGetSerial($aLdrives[$iFound] & '\')
				$aDrives[$i][6] = DriveGetLabel($aLdrives[$iFound] & '\')
				$aDrives[$i][7] = DriveGetFileSystem($aLdrives[$iFound] & '\')
				$aDrives[$i][8] = DriveSpaceFree($aLdrives[$iFound] & '\')
				$aDrives[$i][9] = DriveSpaceTotal($aLdrives[$iFound] & '\')
				#cs
					Switch $aDrives[$i][1]
					Case 'Unknown'
					$hIcon = $UNKNOWN_ICON_INDEX
					Case 'RAMDisk'
					$hIcon = $Ram_ICON_INDEX
					Case 'CDRom'
					$hIcon = $CDRom_ICON_INDEX
					Case 'Fixed'
					$hIcon = $HDD_ICON_INDEX
					Case 'Removavle'
					$hIcon = $Removable_ICON_INDEX
					Case 'Network'
					$hIcon = $Network_ICON_INDEX
					EndSwitch
					If $bDelete Then
					$aDrives[$i][0] = _GUICtrlTreeView_AddChildFirst($idTVLocal, $hLocal, Chr($i + 65) & ':\', $hIcon, $hIcon)
					Else
					$aDrives[$i][0] = _GUICtrlTreeView_AddChild($idTVLocal, $hLocal, Chr($i + 65) & ':\', $hIcon, $hIcon)
					EndIf
					_GUICtrlTreeView_SetItemParam($idTVLocal, $aDrives[$i][0], $aDrives[$i][0])
					_AddFolderLocal($aLdrives[$iFound] & '\', $aDrives[$i][0])
					_GUICtrlTreeView_Expand($idTVLocal, $aDrives[$i][0], False)
				#ce
			EndIf
		EndIf
	Next
	_ArrayInsert($aDrives,0)
	$aDrives[0][1] = 'Drive Type'
	$aDrives[0][2] = 'SSD Status'
	$aDrives[0][3] = 'Bus Type'
	$aDrives[0][4] = 'Drive Status'
	$aDrives[0][5] = 'Windows Volume ID'
	$aDrives[0][6] = 'Label'
	$aDrives[0][7] = 'File System Type'
	$aDrives[0][8] = 'Free Space'
	$aDrives[0][9] = 'Space Total'
	_ArrayDisplay($aDrives)
EndFunc   ;==>_CreateDriveItems

#RequireAdmin
#include <Array.au3>


Global $aLang[5][2]	;Größe anpassen
;in diesem Array werden in Spalte 0 die User abhängige Landeslocale
;					und in Spalte 1 das zu suchende Wort gespeichert
;es müssen nur die Ausnahmen gespeichert werden in denen NICHT das vorbelgete Wort vorkommt!!
;MsgBox(64,'Locale',@OSLang)	;Eintrag in Spalte 0
$sText='(Sysprep)'
$iFound=_ArraySearch($aLang,@OSLang)
If $iFound<>-1 Then $sText=$aLang[$iFound][1]
$Hwnd = WinGetHandle('[CLASS:#32770]',$sText)
;MsgBox(64, 'Sysprep', 'Hwnd: ' & $Hwnd)
$aPos=WinGetPos($Hwnd)
WinMove($Hwnd,'',@DesktopWidth-$aPos[2]-5,@DesktopHeight-$aPos[3]-35)

; #FUNCTION# ====================================================================================================================
; Author ........: limette, Prog@ndy
; Modified.......: jchd
; Änderungsvorschlag autoBert
; ===============================================================================================================================
Func _MyFTP_ProgressUpload($hFTPSession, $sLocalFile, $sRemoteFile, $MyTitle = '', $MyText = '', $hFunctionToCall = 0)
	If $__g_hWinInet_FTP = -1 Then Return SetError(-2, 0, 0)


	Local $hFile = FileOpen($sLocalFile, $FO_BINARY)
	If @error Then Return SetError(-1, _WinAPI_GetLastError(), 0)


	Local $ai_FtpOpenfile = DllCall($__g_hWinInet_FTP, 'handle', 'FtpOpenFileW', 'handle', $hFTPSession, 'wstr', $sRemoteFile, 'dword', $GENERIC_WRITE, 'dword', $FTP_TRANSFER_TYPE_BINARY, 'dword_ptr', 0)
	If @error Or $ai_FtpOpenfile[0] = 0 Then Return SetError(-3, _WinAPI_GetLastError(), 0)
	If $MyTitle = '' Then $MyTitle = "FTP Upload"
	If $MyText = '' Then $MyText = "Uploading " & $sLocalFile
	If Not IsFunc($hFunctionToCall) Then ProgressOn($MyTitle, $MyText)


	Local $iLen = FileGetSize($sLocalFile)
	Local Const $iChunkSize = 256 * 1024
	Local $iLast = Mod($iLen, $iChunkSize)


	Local $iParts = Ceiling($iLen / $iChunkSize)
	Local $tBuffer = DllStructCreate("byte[" & $iChunkSize & "]")


	Local $aDone, $ai_FtpWrite, $iOut, $iRet, $iLasterror
	Local $x = $iChunkSize
	Local $iDone = 0
	For $i = 1 To $iParts
		If $i = $iParts And $iLast > 0 Then
			$x = $iLast
		EndIf
		DllStructSetData($tBuffer, 1, FileRead($hFile, $x))


		$ai_FtpWrite = DllCall($__g_hWinInet_FTP, 'bool', 'InternetWriteFile', 'handle', $ai_FtpOpenfile[0], 'struct*', $tBuffer, 'dword', $x, 'dword*', $iOut)
		If @error Or $ai_FtpWrite[0] = 0 Then
			$iLasterror = _WinAPI_GetLastError()
			$aDone = DllCall($__g_hWinInet_FTP, 'bool', 'InternetCloseHandle', 'handle', $ai_FtpOpenfile[0])
			; No need to test @error.
			FileClose($hFile)


			If Not IsFunc($hFunctionToCall) Then ProgressOff()
			Return SetError(-4, $iLasterror, 0)
		EndIf
		$iDone += $x


		If Not IsFunc($hFunctionToCall) Then
			ProgressSet(($iDone / $iLen) * 100)
		Else
			$iRet = $hFunctionToCall(($iDone / $iLen) * 100)
			If $iRet <= 0 Then
				$iLasterror = @error
				$aDone = DllCall($__g_hWinInet_FTP, 'bool', 'InternetCloseHandle', 'handle', $ai_FtpOpenfile[0])
				; No need to test @error.
				DllCall($__g_hWinInet_FTP, 'bool', 'FtpDeleteFileW', 'handle', $hFTPSession, 'wstr', $sRemoteFile)
				; No need to test @error.
				FileClose($hFile)
				If Not IsFunc($hFunctionToCall) Then ProgressOff()
				Return SetError(-6, $iLasterror, $iRet)
			EndIf
		EndIf
		Sleep(10)
	Next


	FileClose($hFile)


	If Not IsFunc($hFunctionToCall) Then ProgressOff()


	$aDone = DllCall($__g_hWinInet_FTP, 'bool', 'InternetCloseHandle', 'handle', $ai_FtpOpenfile[0])
	; No need to test @error.
	If @error Or $aDone[0] = 0 Then Return SetError(-5, _WinAPI_GetLastError(), 0)


	Return 1
EndFunc   ;==>_MyFTP_ProgressUpload