Beiträge von Bitnugger

;-- TIME_STAMP   2017-11-25 01:09:42   v 0.1

#Region    ;************ Includes ************
#Include <WinAPI.au3>
#include <WinAPIFiles.au3>
#EndRegion ;************ Includes ************

If Not HotKeySet('{ESC}', '_Exit') Then Exit 1

Global $g_bLock = False, $g_hFile, $g_iOffset = 0, $g_iLength = FileGetSize(@ScriptFullPath)
Global $g_iCreation = $OPEN_EXISTING, $g_iAccess = $GENERIC_READ, $g_iShare = BitOR($FILE_SHARE_READ, $FILE_SHARE_WRITE)
;~ _WinAPI_CreateFileEx ( $sFilePath, $iCreation [, $iAccess = 0 [, $iShare = 0 [, $iFlagsAndAttributes = 0 [, $tSecurity = 0 [, $hTemplate = 0]]]]] )
$g_hFile = _WinAPI_CreateFileEx(@ScriptFullPath, $g_iCreation, $g_iAccess, $g_iShare) ; [, $iFlagsAndAttributes = 0 [, $tSecurity = 0 [, $hTemplate = 0]]]]] )
If $g_hFile = -1 Then Exit -1
ConsoleWrite('$g_hFile = ' & $g_hFile & @CRLF)

If _WinAPI_LockFile($g_hFile, $g_iOffset, $g_iLength) Then
    ConsoleWrite('! File ist now locked!' & @CRLF & _
        '> Now you can even try to open, change or delete the file ... you will not succeed as long as the lock has not been released! ;-)' & @CRLF & _
        '- Press ESC for UnLock File and Exit!' & @CRLF & @CRLF)
    $g_bLock = True

    ; notepad darf die Datei öffnen... aber nichts ändern! ;-)
    Run('notepad.exe ' & @ScriptFullPath)

    ; wir selbst dürfen Daten an das Ende des Files anhängen!
    Local $hFile = FileOpen(@ScriptFullPath, $FO_APPEND)
    FileWrite($hFile, "ConsoleWrite('Test' & @CRLF)")

    ; aber nicht innerhalb des gelockten Bereichs!
    FileSetPos($hFile, $g_iLength - 100, $FILE_BEGIN)
    Local $iWrite = FileWrite($hFile, @CRLF & @CRLF & "; ########################################################################################################" & @CRLF)
    ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iWrite --> " & $iWrite & @CRLF & "!@ " & @TAB & "#Error: " & @error & @CRLF)

    ; auch erstaunlich, dass FileSetPos die Position in der geöffneten Datei richtig setzt, obwohl Daten angehangen wurden.
    FileSetPos($hFile, 1, $FILE_END)
    Local $iWrite = FileWrite($hFile, @CRLF & @CRLF & "; ********************************************************************************************************" & @CRLF)
    FileClose($hFile)

    ; und bitte darauf achten, wie SciTE reagiert, nachdem die Datei geändert wurde!!!
Else
     ConsoleWrite("File can't locked!" & @CRLF & 'Error: ' & _WinAPI_GetLastError() & @CRLF & 'ErrorMessage: ' & _WinAPI_GetLastErrorMessage() & @CRLF)
    Exit 2
EndIf

While 1
    Sleep(1000)
WEnd

Func _Exit()
    If $g_bLock = True Then _WinAPI_UnLockFile($g_hFile, $g_iOffset, $g_iLength)
    ConsoleWrite('File ist unlocked!' & @CRLF)
    _WinAPI_CloseHandle($g_hFile)

    ; notepad can open the file! ;-)
    Run('notepad.exe ' & @ScriptFullPath)
    Exit
EndFunc

;-- TIME_STAMP   2017-11-24 13:30:30   v 0.1

#Region    ;************ Includes ************
#Include <WinAPI.au3>
#include <WinAPIFiles.au3>
#EndRegion ;************ Includes ************

If Not HotKeySet('{ESC}', '_Exit') Then Exit 1

Global $g_bLock = False, $g_hFile, $g_iOffset = 0, $g_iLength = 0
;~ _WinAPI_CreateFileEx ( $sFilePath, $iCreation [, $iAccess = 0 [, $iShare = 0 [, $iFlagsAndAttributes = 0 [, $tSecurity = 0 [, $hTemplate = 0]]]]] )
Global $iCreation = $OPEN_EXISTING, $iAccess = $GENERIC_READ, $iShare = $FILE_SHARE_DELETE
$g_hFile = _WinAPI_CreateFileEx(@ScriptFullPath, $iCreation, $iAccess, $iShare) ; [, $iFlagsAndAttributes = 0 [, $tSecurity = 0 [, $hTemplate = 0]]]]] )
If $g_hFile = -1 Then Exit -1
ConsoleWrite('$g_hFile = ' & $g_hFile & @CRLF)

If _WinAPI_LockFile($g_hFile, $g_iOffset, $g_iLength) Then
    ConsoleWrite('! File ist now locked!' & @CRLF & _
        '> Now you can even try to open, change or delete the file ... you will not succeed as long as the lock has not been released! ;-)' & @CRLF & _
        '- Press ESC for UnLock File and Exit!' & @CRLF & @CRLF)
    $g_bLock = True

    ; notepad can not open the file! ;-)
    Local $iPID = Run('notepad.exe ' & @ScriptFullPath)
Else
     ConsoleWrite("File can't locked!" & @CRLF & 'Error: ' & _WinAPI_GetLastError() & @CRLF & 'ErrorMessage: ' & _WinAPI_GetLastErrorMessage() & @CRLF)
    Exit 2
EndIf

While 1
    Sleep(1000)
WEnd

Func _Exit()
    If $g_bLock = True Then _WinAPI_UnLockFile($g_hFile, $g_iOffset, $g_iLength)
    ConsoleWrite('File ist unlocked!' & @CRLF)
    _WinAPI_CloseHandle($g_hFile)

    ; notepad can open the file! ;-)
    Run('notepad.exe ' & @ScriptFullPath)
    Exit
EndFunc

;-- TIME_STAMP   2017-11-22 15:37:15   v 0.1

#Region    ;************ Includes ************
#Include <Misc.au3>
#Include <WindowsConstants.au3>
#Include <Process.au3>
#include <ScreenCapture.au3>
#EndRegion ;************ Includes ************

Global $g_tStruct = DllStructCreate($tagPOINT) ; Create a structure that defines the point to be checked.
Global $g_hDll = DllOpen("user32.dll")

_SetHotKey('^{F12}', '_Screenshot') ;__ Ctrl + F12               (kompletten Window)
_SetHotKey('^+{F12}', '_Screenshot') ;_ Ctrl + Shift + F12       (Ränder rechts/links abschneiden)
_SetHotKey('^!+{F12}', '_Screenshot') ; Ctrl + Shift + Alt + F12 (alle Ränder abschneiden)
_SetHotKey('^!x', '_Exit') ; __________ Ctrl + Alt + x
;~ Send()

While Sleep(1000)
WEnd

; CaptureWnd mit/ohne Titelleiste und Rahmen oder nur ohne Rahmen rechts/links
Func _Screenshot()
    Local Static $sSaveDir = StringReplace(@ScriptDir & '\' & @UserName & '\', '\\', '\')
    If Not FileExists($sSaveDir) Then DirCreate($sSaveDir)

    Local $aMousePos = MouseGetPos()
    DllStructSetData($g_tStruct, "x", $aMousePos[0])
    DllStructSetData($g_tStruct, "y", $aMousePos[1])
    Local $hWnd = _WinAPI_WindowFromPoint($g_tStruct), $bCursor = False
    Local $hParent = _WinAPI_GetAncestor($hWnd, $GA_ROOT)
    $hWnd = ($hParent = 0) ? $hWnd : $hParent
    Local $sWinName = _ProcessGetName(WinGetProcess($hWnd))

    Local $sSaveAs, $iScreenshotNr = 0
    Do
        $iScreenshotNr += 1
        $sSaveAs = StringFormat('%s_%03i.jpg', $sSaveDir & $sWinName, $iScreenshotNr)
        ConsoleWrite('$sSaveAs = ' & $sSaveAs & @CRLF)
    Until FileExists($sSaveAs) = 0

    Local $iCaption = _WinAPI_GetSystemMetrics($SM_CYCAPTION) ; Höhe der Titelleiste
    Local $iFrameX = _WinAPI_GetSystemMetrics($SM_CXFRAME) ; Breite der Fensterrahmen rechts/links
    Local $iFrameY = _WinAPI_GetSystemMetrics($SM_CYFRAME) ; Höhe des Fensterrahmen unten

    Local $aWinPos = WinGetPos($hWnd)

    Switch @HotKeyPressed
        Case '^{F12}'    ; Ctrl + Shift + F12       (kompletten Window)
            ConsoleWrite('kompletten Window' & @CRLF)
            Local $iLeft = 0, $iTop = 0, $iRight = $aWinPos[2], $iBottom = $aWinPos[3]
        Case '^+{F12}' ; Ctrl + Shift + F12        (Ränder rechts/links abschneiden)
            ConsoleWrite('Ränder rechts/links abschneiden' & @CRLF)
            Local $iLeft = $iFrameX, $iTop = 0, $iRight = $aWinPos[2] - $iFrameY, $iBottom = $aWinPos[3] ; __________________ rechten und linken Rahmen entfernen
        Case '^!+{F12}' ; Ctrl + Shift + Alt + F12 (alle Ränder abschneiden)
            ConsoleWrite('alle Ränder abschneiden' & @CRLF)
            Local $iLeft = $iFrameX, $iTop = $iCaption, $iRight = $aWinPos[2] - $iFrameY, $iBottom = $aWinPos[3] - $iFrameX ; alle Rahmen entfernen
    EndSwitch

    If _ScreenCapture_CaptureWnd($sSaveAs, $hWnd, $iLeft, $iTop, $iRight, $iBottom, $bCursor) Then
        ToolTip($sSaveAs, Default, Default, 'Screenshot', 1, 5)
    Else
        ToolTip('Fehler! CaptureWnd konnte nicht gespeichert werden.', Default, Default, 'Screenshot', 3, 5)
    EndIf
    AdlibRegister('_CloseToolTip', 2000)

    ; Warten bis die Ctrl-Taste nicht mehr gedrückt ist!
    While _IsPressed('11', $g_hDll) ; CTRL key
        Sleep(250)
    WEnd
EndFunc   ;==>_Screenshot

Func _CloseToolTip()
    ToolTip('')
    AdlibUnRegister()
EndFunc   ;==>_CloseToolTip

Func _SetHotKey($sKey, $sFunction)
    Local $iHotKey = HotKeySet($sKey, $sFunction)
    If $iHotKey = 0 Then Exit MsgBox(262144,'ScreenCapture', 'Hotkey "' & $sKey & '" konnte nicht gesetzt werden - bitte wähle eine andere Tastenkombination!')
EndFunc

Func _Exit()
    DllClose($g_hDll)
    Exit
EndFunc   ;==>_Exit

;-- TIME_STAMP   2017-11-22 14:33:08   v 0.1

#Region    ;************ Includes ************
#Include <WinAPISys.au3>
#include <ScreenCapture.au3>
#EndRegion ;************ Includes ************

_SetHotKey('^{F12}', '_Screenshot') ;__ Ctrl + F12               (kompletten Screen)
_SetHotKey('^+{F12}', '_Screenshot') ;_ Ctrl + Shift + F12       (WorkAera des Screen)
_SetHotKey('^!+{F12}', '_Screenshot') ; Ctrl + Shift + Alt + F12 (Ränder abschneiden)
_SetHotKey('^!x', '_Exit') ; __________ Ctrl + Alt + x
;~ Send()

While Sleep(1000)
WEnd

Func _Screenshot()
    Local Static $sSaveDir = StringReplace(@ScriptDir & '\' & @UserName & '\', '\\', '\'), $bCursor = False
    If Not FileExists($sSaveDir) Then DirCreate($sSaveDir)

    ; Dateiname mit Timestamp generieren
    Local $sSaveAs = $sSaveDir & StringFormat('Screenshot_%i%i%i_%i%i%i.jpg', @YEAR, @MON, @MDAY, @HOUR, @MIN, @SEC)

    ; Koordinaten des Mauszeigers ermitteln
    Local $tPOINT = _WinAPI_GetMousePos()

    ; Koordinaten des Monitors ermitteln, auf dem sich der Mauszeiger befindet
    Local $hMonitor = _WinAPI_MonitorFromPoint($tPOINT, $MONITOR_DEFAULTTONULL)
    Local $aMonitorInfo = _WinAPI_GetMonitorInfo($hMonitor)
    Local $aRectangle = [DllStructGetData($aMonitorInfo[0], 1), DllStructGetData($aMonitorInfo[0], 2), DllStructGetData($aMonitorInfo[0], 3), DllStructGetData($aMonitorInfo[0], 4)] ; $tagRECT structure des kompletter Screen in Array kopieren
    Local $aWorkArea  = [DllStructGetData($aMonitorInfo[1], 1), DllStructGetData($aMonitorInfo[1], 2), DllStructGetData($aMonitorInfo[1], 3), DllStructGetData($aMonitorInfo[1], 4)] ; $tagRECT structure des Arbeitsbereich des Screens in Array kopieren

    ; Hier musst du die Offsets evtl. noch korrigieren
    Switch @HotKeyPressed
        Case '^{F12}'    ; Ctrl + Shift + F12       (kompletten Screen)
            Local $iLeft = $aRectangle[0], $iTop = $aRectangle[1], $iRight = $aRectangle[2], $iBottom = $aRectangle[3]
        Case '^+{F12}'    ; Ctrl + Shift + F12       (WorkAera des Screen)
            Local $iLeft = $aWorkArea[0] + 100, $iTop = $aWorkArea[1] + 100, $iRight = $aWorkArea[2] - 100, $iBottom = $aWorkArea[3] - 100
        Case '^!+{F12}' ; Ctrl + Shift + Alt + F12 (Ränder abschneiden)
            Local $iLeft = $aRectangle[0] + 100, $iTop = $aRectangle[1] + 100, $iRight = $aRectangle[2] - 100, $iBottom = $aRectangle[3] - 100
    EndSwitch

    If _ScreenCapture_Capture($sSaveAs, $iLeft, $iTop, $iRight, $iBottom, $bCursor) Then
        ToolTip($sSaveAs, Default, Default, 'Screenshot', 1, 5)
    Else
        ToolTip('Fehler! ScreenCapture konnte nicht gespeichert werden.', Default, Default, 'Screenshot', 3, 5)
    EndIf
    AdlibRegister('_CloseToolTip', 2000)
EndFunc   ;==>_Screenshot

Func _CloseToolTip()
    ToolTip('')
    AdlibUnRegister()
EndFunc   ;==>_CloseToolTip

Func _SetHotKey($sKey, $sFunction)
    Local $iHotKey = HotKeySet($sKey, $sFunction)
    If $iHotKey = 0 Then Exit MsgBox(262144,'ScreenCapture', 'Hotkey "' & $sKey & '" konnte nicht gesetzt werden - bitte wähle eine andere Tastenkombination!')
EndFunc

Func _Exit()
    Exit
EndFunc   ;==>_Exit

;-- TIME_STAMP   2017-11-22 13:24:29   v 0.1

#Region    ;************ Includes ************
#Include <Process.au3>
#include <ScreenCapture.au3>
#EndRegion ;************ Includes ************

Global $g_tStruct = DllStructCreate($tagPOINT) ; Create a structure that defines the point to be checked.

HotKeySet('^+{F12}', '_Screenshot') ;_ Ctrl + Shift + F12       (komplettes Fenster)
HotKeySet('^!+{F12}', '_Screenshot') ; Ctrl + Shift + Alt + F12 (Ränder abschneiden)
HotKeySet('^!x', '_Exit') ; __________ Ctrl + Alt + x
;~ Send()

While Sleep(1000)
WEnd

Func _Screenshot()
    Local Static $sSaveDir = StringReplace(@ScriptDir & '\' & @UserName & '\', '\\', '\')
    If Not FileExists($sSaveDir) Then DirCreate($sSaveDir)

    Local $aMousePos = MouseGetPos()
    DllStructSetData($g_tStruct, "x", $aMousePos[0])
    DllStructSetData($g_tStruct, "y", $aMousePos[1])
    Local $hWnd = _WinAPI_WindowFromPoint($g_tStruct), $bCursor = False
    Local $hParent = _WinAPI_GetParent($hWnd)
    $hWnd = ($hParent = 0) ? $hWnd : $hParent
    Local $sWinName = _ProcessGetName(WinGetProcess($hWnd))

    Local $sSaveAs, $iScreenshotNr = 0
    Do
        $iScreenshotNr += 1
        $sSaveAs = StringFormat('%s_%03i.jpg', $sSaveDir & $sWinName, $iScreenshotNr)
        ConsoleWrite('$sSaveAs = ' & $sSaveAs & @CRLF)
    Until FileExists($sSaveAs) = 0

    Switch @HotKeyPressed
        Case '^+{F12}'    ; Ctrl + Shift + F12       (komplettes Fenster)
            Local $iLeft = 0, $iTop = 0, $iRight = -1, $iBottom = -1
        Case '^!+{F12}' ; Ctrl + Shift + Alt + F12 (Ränder abschneiden)
            Local $aWinPos = WinGetPos($hWnd), $iLeft = 100, $iTop = 100, $iRight = $aWinPos[2] - 100, $iBottom = $aWinPos[3] - 100
    EndSwitch

    If _ScreenCapture_CaptureWnd($sSaveAs, $hWnd, $iLeft, $iTop, $iRight, $iBottom, $bCursor) Then
        ToolTip($sSaveAs, Default, Default, 'Screenshot', 1, 5)
    Else
        ToolTip('Fehler! CaptureWnd konnte nicht gespeichert werden.', Default, Default, 'Screenshot', 3, 5)
    EndIf
    AdlibRegister('_CloseToolTip', 2000)
EndFunc   ;==>_Screenshot

Func _CloseToolTip()
    ToolTip('')
    AdlibUnRegister()
EndFunc   ;==>_CloseToolTip

Func _Exit()
    Exit
EndFunc   ;==>_Exit