1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. Zeitriss

Beiträge von Zeitriss

  • Grafische Spielerei

    • Zeitriss
    • 10. August 2012 um 19:35

    Xorianator:

    Vielen dank für die vielen Seeds. Ich hab sie oben in den Spoiler gepackt damit sie sich jeder ansehen kann.

    Wegen des Problem mit "AutoIt" als Seed
    Wenn du AutoIt eingibst kommt ein Punkt weil du es direkt im Code geändert hast und dem Script so die Möglichkeit genommen hast das Wort in eine Zahl umzuwandeln.
    Da er jetzt einen String als Seed hat rechnet AutoIt mit 0 und dass klappt nicht.
    Benütze lieber die Eingabefunktion unter "Rechtsklick>>Neu>>Neu"

    @James1337:

    Danke wie du sehen kannst habe ich deine Seeds aufgenommen. :thumbup:

    @Name22/UEZ:

    Ego += 20 8)

    Andy:

    Würde mich sehr freuen wenn du die "guten" Seeds Posten könntest falls du welche findest. :D

  • Grafische Spielerei

    • Zeitriss
    • 10. August 2012 um 17:15

    Eigentlich war das Script nur ein Langeweile Projekt eines freien Nachmittages, aber weil es (meiner Meinung nach) doch recht gut aussieht stell ich es mal hier rein.

    Spoiler anzeigen
    [autoit]

    Global $iFrames = 150
    Global $iFPS = 20
    Global $iStars = Random(500,3000,1)
    Global $iSeed = Random(1,1000000,1)
    Global $iRadius = Random(50,200,1)
    Opt("GUIOnEventMode",1)
    Local Const $iRtoD = ACos(-1)/180
    #include<GDIPlus.au3>
    _GDIPlus_Startup()
    Local $hGUI = GUICreate("Grafik User Interface",500,500,-1,-1)
    GUISetOnEvent(-3,"_exit",$hGUI)
    $hCMenue = GUICtrlCreateContextMenu()
    $hCMenue_Neu = GUICtrlCreateMenu("Neu",$hCMenue)
    $hCMenue_Neu_Neu = GUICtrlCreateMenuItem("Neu",$hCMenue_Neu)
    GUICtrlSetOnEvent($hCMenue_Neu_Neu,"Neu")
    $hCMenue_Neu_Zufaellig = GUICtrlCreateMenuItem("Zufällig",$hCMenue_Neu)
    GUICtrlSetOnEvent($hCMenue_Neu_Zufaellig,"Zufallig")
    $hCMenue_FPS = GUICtrlCreateMenu("Bildrate",$hCMenue)
    $hCMenue_FPS_5 = GUICtrlCreateMenuItem("5",$hCMenue_FPS)
    GUICtrlSetOnEvent($hCMenue_FPS_5,"FPS_05")
    $hCMenue_FPS_10 = GUICtrlCreateMenuItem("10",$hCMenue_FPS)
    GUICtrlSetOnEvent($hCMenue_FPS_10,"FPS_10")
    $hCMenue_FPS_15 = GUICtrlCreateMenuItem("15",$hCMenue_FPS)
    GUICtrlSetOnEvent($hCMenue_FPS_15,"FPS_15")
    $hCMenue_FPS_20 = GUICtrlCreateMenuItem("20",$hCMenue_FPS)
    GUICtrlSetOnEvent($hCMenue_FPS_20,"FPS_20")
    $hCMenue_FPS_25 = GUICtrlCreateMenuItem("25",$hCMenue_FPS)
    GUICtrlSetOnEvent($hCMenue_FPS_25,"FPS_25")
    $hCMenue_FPS_30 = GUICtrlCreateMenuItem("30",$hCMenue_FPS)
    GUICtrlSetOnEvent($hCMenue_FPS_30,"FPS_30")
    $hCMenue_FPS_Mehr = GUICtrlCreateMenuItem("Mehr...",$hCMenue_FPS)
    GUICtrlSetOnEvent($hCMenue_FPS_Mehr,"FPS_")
    $hCMenue_Copy = GUICtrlCreateMenuItem("Kopieren",$hCMenue)
    GUICtrlSetOnEvent($hCMenue_Copy,"Copy")
    $hCMenue_Paste = GUICtrlCreateMenuItem("Einfügen",$hCMenue)
    GUICtrlSetOnEvent($hCMenue_Paste,"Paste")
    Local $hGrafik = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    Local $hBufferBitmap = _GDIPlus_BitmapCreateFromGraphics(500,500,$hGrafik)
    Local $hBufferContext = _GDIPlus_ImageGetGraphicsContext($hBufferBitmap)
    GUISetState(1,$hGUI)
    Global $aBitmaps = Create($iFrames,$iStars,$iSeed,$iRadius)

    [/autoit] [autoit][/autoit] [autoit]

    Local $iTimer = TimerInit()
    Local $iFrame = 0
    Do
    $iFrame = Mod(Timerdiff($iTimer)/(1000/$iFPS),$iFrames)
    _GDIPlus_GraphicsDrawImage($hGrafik,$aBitmaps[$iFrame],0,0)

    Until 0

    [/autoit] [autoit][/autoit] [autoit]

    Func Create($iFrames,$iStars,$iSeed,$iRadius)
    GUICtrlSetState($hCMenue_Neu,128)
    GUICtrlSetState($hCMenue_Paste,128)
    Local $iSSeed = 0, $iDistanz = 0, $iWinkel = 0,$iTife = 0, $iFarbe = 0, $hContext = 0x00
    Local $aBrush[7]
    Local $aBitmap[$iFrames]

    $aBrush[0] = _GDIPlus_BrushCreateSolid(0x999999FF)
    $aBrush[1] = _GDIPlus_BrushCreateSolid(0x99FFFF99)
    $aBrush[2] = _GDIPlus_BrushCreateSolid(0x99FFFFFF)
    $aBrush[3] = _GDIPlus_BrushCreateSolid(0x99FF9999)
    $aBrush[4] = _GDIPlus_BrushCreateSolid(0xFFFF9999)
    $aBrush[5] = _GDIPlus_BrushCreateSolid(0x99FF4444)
    $aBrush[6] = _GDIPlus_BrushCreateSolid(0xFF774444)

    If $iSeed = 4474194 Then
    $hBrush = _GDIPlus_BrushCreateSolid(0x88FF0000)
    Else
    $hBrush = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)
    EndIf
    $hPen = _GDIPlus_PenCreate(0xFFFFFFFF,2)
    _GDIPlus_GraphicsClear($hBufferContext,0xFF000000)
    _GDIPlus_GraphicsClear($hGrafik,0xFF000000)

    Local $iSeed2 = Mod(Round($iSeed,2),ACos(-1))*(100/ACos(-1))
    For $i = 0 to $iFrames-1
    $aBitmap[$i] = _GDIPlus_BitmapCreateFromGraphics(500,500,$hGrafik)
    $hContext = _GDIPlus_ImageGetGraphicsContext($aBitmap[$i])
    _GDIPlus_GraphicsClear($hContext,0xFF000000)
    For $ii = 1 to $iStars
    $iSSeed = $iSeed2*$ii
    $iDistanz = Mod($iSSeed,1)*$iRadius
    $iWinkel = Mod(Mod($iSSeed,0.36)*1000 + ($i+1)/$iFrames*360,360)
    $iTife = (Mod($iSSeed,0.5)-0.25)*Mod($iSSeed,100);$iSSeed/100
    If $iSeed = 4474194 Then
    $iFarbe = Int($iDistanz / $iRadius*2)+5
    Else
    $iFarbe = Int($iDistanz / $iRadius*5)
    EndIf
    _GDIPlus_GraphicsFillRect($hContext,250 + Sin($iRtoD*$iWinkel)*$iDistanz,250 + Cos($iRtoD*$iWinkel)*$iDistanz*0.50 + $iTife,1,1,$aBrush[$iFarbe])
    Next
    _GDIPlus_GraphicsDispose($hContext)
    If $i = 0 Then
    _GDIPlus_GraphicsDrawImage($hBufferContext,$aBitmap[0],0,0)
    _GDIPlus_GraphicsDrawRect($hBufferContext,175,240,150,20,$hPen)
    Local $aArray[5][2] = [[4]]
    $aArray[1][0] = 174
    $aArray[1][1] = 227
    $aArray[2][0] = 190+30
    $aArray[2][1] = 227
    $aArray[3][0] = 325
    $aArray[3][1] = 227+12
    $aArray[4][0] = 174
    $aArray[4][1] = 227+12
    _GDIPlus_GraphicsFillPolygon($hBufferContext,$aArray,$hBrush)
    _GDIPlus_GraphicsDrawString($hBufferContext,"Laden...",180,227,"Arial",8)
    EndIf
    _GDIPlus_GraphicsFillRect($hBufferContext,177,242,($i+1)/$iFrames*146,16,$hBrush)
    _GDIPlus_GraphicsDrawImage($hGrafik,$hBufferBitmap,0,0)
    Next
    For $i = 0 to 6
    _GDIPlus_BrushDispose($aBrush[$i])
    Next
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PenDispose($hPen)
    GUICtrlSetState($hCMenue_Neu,64)
    GUICtrlSetState($hCMenue_Paste,64)
    Return $aBitmap
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func Zufallig()
    For $i = 0 to UBound($aBitmaps)-1
    _GDIPlus_BitmapDispose($aBitmaps[$i])
    Next
    $iStars = Random(500,3000,1)
    $iSeed = Random(1,1000000,1)
    $iRadius = Random(50,200,1)
    $aBitmaps = Create($iFrames,$iStars,$iSeed,$iRadius)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func Neu()
    Opt("GUIOnEventMode",0)
    Local $hGUI2 = GUICreate("Neu",300,124,-1,-1)
    GUICtrlCreateLabel("Seed:",0,12,100,19,2)
    Local $hInput_Seed = GUICtrlCreateInput($iSeed,110,10,150,19,1)
    GUICtrlCreateLabel("Frames:",0,32,100,19,2)
    Local $hInput_Frames = GUICtrlCreateInput($iFrames,110,30,150,19,1)
    GUICtrlCreateLabel("Sterne:",0,52,100,19,2)
    Local $hInput_Stars = GUICtrlCreateInput($iStars,110,50,150,19,1)
    GUICtrlCreateLabel("Radius:",0,72,100,19,2)
    Local $hInput_Radius = GUICtrlCreateInput($iRadius,110,70,150,19,1)
    Local $hButton_Ok = GUICtrlCreateButton("Erstellen",100,95,100,22)
    GUISetState(1,$hGUI2)
    Do
    $msg = GUIGetMsg()
    sleep(25)
    If $msg = -3 Then
    Opt("GUIOnEventMode",1)
    GUIDelete($hGUI2)
    Return
    EndIf
    Until $msg = $hButton_Ok
    Opt("GUIOnEventMode",1)
    $iSeed = GUICtrlRead($hInput_Seed)
    If StringRegExp($iSeed,"[^0-9]") Then $iSeed = Int(StringToBinary($iSeed))
    $iFrames = GUICtrlRead($hInput_Frames)
    $iStars = GUICtrlRead($hInput_Stars)
    $iRadius = GUICtrlRead($hInput_Radius)
    GUIDelete($hGUI2)
    For $i = 0 to UBound($aBitmaps)-1
    _GDIPlus_BitmapDispose($aBitmaps[$i])
    Next
    $aBitmaps = Create($iFrames,$iStars,$iSeed,$iRadius)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func FPS_05()
    $iFPS = 5
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func FPS_10()
    $iFPS = 10
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func FPS_15()
    $iFPS = 15
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func FPS_20()
    $iFPS = 20
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func FPS_25()
    $iFPS = 25
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func FPS_30()
    $iFPS = 30
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func FPS_()
    Local $iNewFPS = InputBox("Bildrate","",$iFPS)
    If @error > 0 Then Return
    $iNewFPS = Int($iNewFPS)
    If $iNewFPS <= 0 Then
    Msgbox(16,"Fehler","Der Eingabewert muss über 0 sein")
    Else
    $iFPS = $iNewFPS
    EndIf
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func Copy()
    ClipPut(String($iSeed)&"+"&String($iFrames)&"+"&String($iStars)&"+"&String($iRadius))
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func Paste()
    Local $aArray = StringSplit(ClipGet(),"+")
    If Not IsArray($aArray) or $aArray[0] <> 4 Then
    msgbox(16,"Fehler","String konnte nicht eigefügt werden")
    Return
    EndIf
    $iSeed = Int($aArray[1])
    $iFrames = Int($aArray[2])
    $iStars = Int($aArray[3])
    $iRadius = Int($aArray[4])
    For $i = 0 to UBound($aBitmaps)-1
    _GDIPlus_BitmapDispose($aBitmaps[$i])
    Next
    $aBitmaps = Create($iFrames,$iStars,$iSeed,$iRadius)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    For $i = 0 to UBound($aBitmaps)-1
    _GDIPlus_BitmapDispose($aBitmaps[$i])
    Next
    _GDIPlus_GraphicsDispose($hBufferContext)
    _GDIPlus_BitmapDispose($hBufferBitmap)
    _GDIPlus_GraphicsDispose($hGrafik)
    _GDIPlus_Shutdown()
    exit
    EndFunc

    [/autoit]


    Dies ist einfach nur eine grafische Spielerei, welche ich heute nebenbei geschrieben habe.
    Wenn man das Script startet einfach einen Moment warten bis es fertig geladen hat.

    Über das Kontextmenü(Rechtsklick) bekommt man folgende Optionen:

    [Neu]
    Lädt eine neue Grafik mit zufälligen oder festgelegten Daten.

    [Bildrate]
    Über dieses Menü stellt man ein wie oft die Bilder pro Sekunde gewechselt werden.

    [Kopieren]
    Kopiert einen String aus welchem die Grafik Rekonstruiert werden kann.

    [Einfügen]
    Rekonstruiert anhand des durch [Kopieren] erhaltenen Strings eine Grafik

    Und wenn jemand gute Seeds findet, könnte wir sie ja hier auch sammeln, dann geht der Thred auch hoffentlich nicht so schnell unter^^


    Interessante Seeds


    ;---------------------------------------------------------------
    Seed: AutoIt
    Sterne: 500 - 1000
    Radius: 151
    Code: 127858751337793+150+1000+151


    ;----------------{Xorianator-Flügel }-------------------------
    Autor: Xorianator
    Seed: 881111141059711097116111114
    Sterne: 1000
    Radius: 150
    Code: 881111141059711097116111114+150+1000+150


    ;-------------------------------------------------------------------
    Autor: Xorianator
    Seed:
    66928340
    Sterne: 2513
    Radius: 164
    Code: 66928340+150+2513+164


    ;-------------------------------------------------------------------
    Autor: Xorianator
    Seed: 20348746193
    Sterne: 2513
    Radius: 164
    Code: 20348746193+150+2513+164


    ;-------------------------------------------------------------------
    Autor: James1337
    Seed: 477907
    Sterne: 2513
    Radius: 164
    Code: 477907+150+2513+164


    ;-------------------------------------------------------------------
    Autor: James1337
    Seed: 204327
    Sterne: 1108
    Radius: 140
    Code: 204327+150+1108+140


    ;--------------------------{ enormis }---------------------------
    Autor:
    chesstiger
    Seed: 845034036
    Sterne: 1108
    Radius: 140
    Code:
    845034036+150+1108+140


    ;-------------------------------------------------------------------
    Autor: chesstiger
    Seed: 9223372036854775807
    Sterne: 1405
    Radius: 195
    Code: 9223372036854775807+150+1405+195


    [Edit:] Ich schreib einfach mal alle Seeds die hier gepostet werden in den Spoiler

  • Zeilen in Datei ersetzen ohne die ganze Datei neu zu schreiben

    • Zeitriss
    • 6. Dezember 2011 um 20:16

    Natürlich geht das mit String befehlen aber wenn ich z.B. in diesen String:

    Code
    ..."Hallo Welt"...


    Wenn jetzt an beiden Seiten c.a. 4Gb kommen und ich "Hallo Welt" in "Hi Welt" ändern möchte müsste ich wieder die ganze Datei( bezieungsweise die halbe) in eine Variable lesen, wobei der String viel zu groß ist um in eine Variable zu passen.
    Ich breuchte mehrere Variablen, also ein Array (Wenn der Arbeitsspeicher überhaupt reicht, wenn nicht müsste ich auslagern), dann müsste ich in dem oben genannten Fall min. 4Gb in eine Datei schreiben.
    Das braucht einfach zu lange.

    Das bearbeiten mit Stringbefehlen ist einfach aber das Zeitsparende einfügen in die Datei bekomme ich nicht hin solange der Neue String kürzer ist als der Alte.

    Beispiel:

    Code
    ...Hallo Welt...


    (Die "..." sind 4 Gb Beliebiger Text)
    Das will ich nun durch "Hi Welt" ersetzen

    Code
    ...Hi Weltelt...

    Leider ist "Hi Welt" kurzer deshalb bleibt ein teil von "Hallo Welt" übrig.

    [Edit:] Das soll direkt in der Datei geändert werden, ich nütze dazu die Befehle "FileSetPos" und "FileWrite"(Im überschreibmodus)

    Um das wegzukriegen müsste ich wieder allen in eine Variable laden, und exakt das will ich vermeiden.

  • Zeilen in Datei ersetzen ohne die ganze Datei neu zu schreiben

    • Zeitriss
    • 6. Dezember 2011 um 19:14

    Mit Filesetpos() ist es möglich dinge in die Text Datei einzufügen, aber wenn ich jetzt z.B. eine "12" durch eine 7 ersetzen möchte müsste ich auch noch etwas herauslöschen, dies ist einfach wenn beide gleichlang sind oder der neue String länger, aber sobald der alte String länger ist habe ich ein Problem.

    Ich müsste also Zeichen auch noch irgentwie löschen können ohne sie zu überschreiben, gibt es da eine Möglichkeit?


    Mit _FileWriteToLine() gibt es das Problem zwar nicht aber Filesetpos() ist ansonsten besser für mich geeignet.

  • [GDI+ Spiel] BlockFight pre v1.0

    • Zeitriss
    • 6. Dezember 2011 um 18:06

    Wenn ich diagonal zu einem 1Feld entfernten Gegner stehe bewegt sich keiner mehr, ist das so gedacht?

    [Blockierte Grafik: http://img52.imageshack.us/img52/6873/bild1jf.jpg]

    Uploaded with ImageShack.us

  • Zeilen in Datei ersetzen ohne die ganze Datei neu zu schreiben

    • Zeitriss
    • 6. Dezember 2011 um 17:50

    Filewriteline ist mir bekannt, hilft mir aber nicht:
    http://translation.autoit.de/onlinehilfe/fu…leWriteLine.htm

    Zitat

    Fügt eine Zeile Text an das Ende einer zuvor geöffneten Textdatei.

    Dies geht nur am ende der Datei.

  • GUICtrlSetImage braucht zu lange

    • Zeitriss
    • 6. Dezember 2011 um 17:47

    Direkt zum verschnellern habe ich zwar keinen vorschlag, aber vll solltest du einfach mal erzählen wozu du so viele bilder brauchst und deinen Code zeigen, vll kann man noch an deiner Syntax schrauben oder GDIPlus verwenden.

  • Zeilen in Datei ersetzen ohne die ganze Datei neu zu schreiben

    • Zeitriss
    • 6. Dezember 2011 um 17:38

    Tag,

    Ich habe ein Problem dabei einzelne Texte/Zeichen in einer Text-Datei zu ändern, genau genommen hänge ich dabei es zu machen ohne die ganze Datei in eine Varriable zu packen und dann zu bearbeiten.

    Die Datei kann z.B. so aussehen:

    Code
    Grünkohla|2|Grünkohlb|5|Grünkohlc|1
    23hallo1

    Nun kann da aber eine ganz schön große menge an Daten zusammen kommen, z.B. 4Gb.

    Nehmen wir an in der Datei wären 4Gb Daten drin und ich will eine bestimmte "1" in eine "7" ändern, dass Problem dabei ist selbst wenn ich mit "Filereadline()"
    nur die richtige Zeile bearbeite, müsste ich den ganzen Text haben um ihn neu wieder in die Datei zu schreiben.
    Wenn ich nun häufiger Dinge in der Datei verändern müsste wäre das sehr langwierig!

    Gibt es da nicht irgendeine andere Möglichkeit, so etwas wie Filewriteline für zeilen mittendrin so dass ich nur die eine Zeile bearbeiten müsste?


    [Edit:] Ok Thx...

  • ini-datei durchsuchen

    • Zeitriss
    • 6. Dezember 2011 um 17:12

    Wenn du die Ini so aufbaust wie du am Anfang sagtest würde ich es so machen:

    Spoiler anzeigen
    Spoiler anzeigen
    [autoit]


    Opt("MustDeclareVars",1)
    Opt("GUIOnEventMode",1)
    If Not FileExists("Freunde.ini") Then
    IniWrite("Freunde.ini","Freizeit","Freund1","Grünkohl")
    IniWrite("Freunde.ini","Freizeit","Freund2","Grünkohl")
    IniWrite("Freunde.ini","Freizeit","Freund3","Grünkohl")
    IniWrite("Freunde.ini","Freizeit","Freund4","Grünkohl")
    IniWrite("Freunde.ini","Arbeit","Kollege1","Grünkohl")
    IniWrite("Freunde.ini","Arbeit","Kollege2","Grünkohl")
    IniWrite("Freunde.ini","Arbeit","Freund5","Grünkohl")
    IniWrite("Freunde.ini","Arbeit","Kollege3","Grünkohl")
    IniWrite("Freunde.ini","Privat","Freundin1","Grünkohl")
    IniWrite("Freunde.ini","Privat","Freundin2","Grünkohl")
    EndIf
    Local $hGUI = GUICreate("Title",430,220,-1,-1)
    Local $hList_Gruppe = GUICtrlCreateList("",10,10,200,200)
    Local $hList_Freunde = GUICtrlCreateList("",220,10,200,200)
    Local $aGruppen = IniReadSectionNames("Freunde.ini")
    GUICtrlSetOnEvent($hList_Gruppe,"Wahl")
    GUISetOnEvent(-3,"_Exit")
    For $i = 1 to $aGruppen[0]
    GUICtrlSetData($hList_Gruppe,$aGruppen[$i])
    Next
    GUISetState(1,$hGUI)

    [/autoit] [autoit][/autoit] [autoit]

    While Sleep(1000)
    Wend

    [/autoit] [autoit][/autoit] [autoit]

    Func Wahl()
    Local $sSection = GUICtrlRead($hList_Gruppe)
    Local $aKey = IniReadSection("Freunde.ini",$sSection)
    GUICtrlSetData($hList_Freunde,"")
    For $i = 1 to $aKey[0][0]
    GUICtrlSetData($hList_Freunde,$aKey[$i][0])
    Next
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    exit
    EndFunc

    [/autoit]

    Vermutlich reicht es aber dir die Funktion zum auslesen von Gruppen zu geben, denn da scheint dein Problem zu sein:

    [autoit]


    IniReadSectionNames()

    [/autoit]


    Wie du die Keys ausliest weist du oder?

    [Edit:] Natürlich hat Protex das Problem gelöst, aber es erscheit mir doch wichtig, dir zu zeigen dass man die Sectionen auch mit den Ini funktionen raussuchen kann.

  • _GUICtrlListBox_FindInText - nächsten Eintrag finden

    • Zeitriss
    • 14. September 2011 um 15:05

    Hast du dir mal die Hilfe zu angesehen

    [autoit]


    _GUICtrlListBox_FindInText

    [/autoit]


    sieh dir mal den dritten Parameter genau an.
    Ich kanns grade nicht Testen aber der sollte helfen.

  • mathematik frage

    • Zeitriss
    • 6. Februar 2011 um 11:15

    Ich würde dass einfach direkt mit dem verhältiss machen warum verwendest du Prozent???

    Spoiler anzeigen
    [autoit]


    $Schritt = 30
    $h = 100
    $b = 55
    $array = Laenge($b,$h,$Schritt)
    msgbox(0,"",$Array[0]&" "&$array[1])
    msgbox(0,"","Zum überprüfen:"& ($array[0]^2+$array[1]^2)^(1/2))

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; $ib = X differenz $ih = Y differenz $ientfernung = entfernung
    Func Laenge($ib,$ih,$ientfernung)
    Local $Differenz = (Abs($ih)^2+Abs($ib)^2)^(1/2)
    Local $Verhaeltniss = $ientfernung/$Differenz
    Local $Array[2] = [$ib*$Verhaeltniss,$ih*$Verhaeltniss]
    Return $Array
    EndFunc

    [/autoit] [autoit][/autoit] [autoit][/autoit]
  • Grafiken auf andere PCs im Netzwerk

    • Zeitriss
    • 30. Januar 2011 um 00:55

    Dass könnte man mit TCP regeln.

    Ich habe mal ein Beispiel geschrieben:

    Client:

    Spoiler anzeigen
    [autoit]


    #RequireAdmin
    $Pic = false
    $Ip = FileRead("Ip.txt")
    TCPStartup()
    $Connect = TCPConnect($Ip,1234)
    If $Connect = -1 or $Connect = 0 Then
    Do
    $Ip = InputBox("","Bitte Ip des Leher PCs angeben")
    If @error > 0 Then exit
    If FileExists("Ip.txt") Then FileDelete("Ip.txt")
    FileWrite("Ip.txt",$Ip)
    $Connect = TCPConnect($Ip,1234)
    Until ($Connect <> -1 and $Connect <> 0)
    EndIf
    TCPSend($Connect,@UserName)
    $hGUI = GUICreate("",@DesktopWidth,@DesktopHeight,-1,-1)
    While 1
    $Recv = TCPRecv($Connect,2048)
    If $Recv <> "" and $Recv <> "Back" Then
    If $Pic = false Then
    $hPic = GUICtrlCreatePic($Recv,0,0,@DesktopWidth,@DesktopHeight)
    $Pic = True
    Else
    GUICtrlSetImage($hPic,$Recv)
    EndIf
    GUISetState(1,$hGUI)
    Do
    sleep(500)
    Until TCPRecv($Connect,2048) = "Back"
    GUISetState(0,$hGUI)
    EndIf

    sleep(1000)
    If TCPSend($Connect,"Probe") = 0 Then
    TCPCloseSocket($Connect)
    TCPShutdown()
    exit
    EndIf
    Wend

    [/autoit]

    Server:

    Spoiler anzeigen
    [autoit]


    TCPStartup()
    $hGUI = GUICreate(@IPAddress1,320,50)
    $hCombo = GUICtrlCreateCombo("",10,12,100,23)
    $hInputbox = GUICtrlCreateInput("",120,14,100,19)
    $hButton_Send = GUICtrlCreateButton("Send",240,3,70,22)
    $hButton_SendAll = GUICtrlCreateButton("Send all",240,25,70,22)
    Local $Connect[1][2] = [[0]]
    $Listen = TCPListen(@Ipaddress1,1234)
    GUISetState(1,$hGUI)
    While 1
    $Accept = TCPAccept($Listen)
    If $Accept <> -1 Then
    Do
    $Name = TCPRecv($Accept,2048)
    Until $Name <> ""
    ReDim $Connect[$Connect[0][0]+2][2]
    $Connect[0][0] +=1
    $Connect[$Connect[0][0]][0] = $Name
    $Connect[$Connect[0][0]][1] = $Accept
    GUICtrlSetData($hCombo,$Name)
    EndIf
    $msg = GUIGetMsg()
    sleep(30)
    If $hButton_Send = $msg Then TCPSend(NameToIP(GUICtrlRead($hCombo)),GUICtrlRead($hInputbox))

    If $hButton_SendAll = $msg Then
    $nachricht = GUICtrlRead($hInputbox)
    For $I = 1 to $Connect[0][0]
    TCPSend($Connect[$i][1],$nachricht)
    Next
    EndIf
    If $msg = -3 Then
    For $I = 1 to $Connect[0][0]
    TCPCloseSocket($Connect[0][1])
    Next
    TCPShutdown()
    exit
    EndIf
    WEnd
    Func NameToIP($Name)
    For $I = 1 to $Connect[0][0]
    If $Connect[$i][0] = $name Then Return $Connect[$i][1]
    Next
    EndFunc

    [/autoit]


    Dies ist natürlich ein Beispiel und wird niemanden der den Task-manager benützen kann ernsthaft davon abhalten weiter zu surfen, die GUI ist auch nicht On Top (kann man aber schnell einfügen).


    Vorbereitung

    - Den Server auf dem eigenen PC starten
    - Den Client auf den Schüler PCs starten
    - Ip von dem eigenen PC angeben

    Bedienung (Server):

    - Name des PCs in der linken Combobox auswählen an den man den Befehl senden möchte
    - Name des Bildes (welches im selben Ordner wie der Client sein muss) in die Inputbox mittig eingeben o. "back" um die GUI Verschwinden zu lassen
    - "Send" Button drücken und Fertig


    Vll hilft es dir etwas weiter

    Noch ein Link zum ausschalten des Bildschirmes

  • Multidownloader

    • Zeitriss
    • 29. Januar 2011 um 20:21

    Zitate aus den Nutzungsbedingungen:

    Zitat

    Sie erklären sich damit einverstanden, auf Nutzerübermittlungen (wie unten definiert) oder andere auf der Webseite verfügbar gemachte Inhalte (einschließlich YouTube-Inhalte wie unten definiert) nicht über irgendwelche andere Technologien oder Mittel als die Video-Wiedergabeseiten der Webseite selbst, den YouTube-Player oder solche anderen Mittel zuzugreifen, die YouTube ausdrücklich für diesen Zweck bestimmt;

    Zitat

    Sie erklären sich damit einverstanden, Zugriff auf Nutzervideos nur in der Form des Streamings und zu keinen anderen Zwecken als der rein persönlichen, nicht-kommerziellen Nutzung, und nur in dem Rahmen zu nehmen, der durch die normale Funktionalität der Dienste vorgegeben und erlaubt ist. „Streaming“ bezeichnet eine gleichzeitige digitale Übertragung des Materials über das Internet durch YouTube auf ein nutzerbetriebenes internetfähiges Endgerät in einer Weise, bei der die Daten für eine Echtzeitansicht bestimmt sind, nicht aber für einen (permanenten oder vorübergehenden) Download, ein Kopieren, ein Speichern oder einen Weitervertrieb durch den Nutzer.


    Ich glaube, dass die Nutzungsbedingungen dagegen sprechen oder?

  • GUIOnEvent mit Parametern

    • Zeitriss
    • 8. Januar 2011 um 23:34

    Ich habe mir mal gedacht ich schreibe mal ein paar Funktionen, die es ermöglichen bei GUIOnEvent und GUICtrlOnEvent Parameter mitzugeben.

    Die Funktionen "GUICtrlSetOnEventEx" und "GUISetOnEventEx" welche fast genauso wie die Funktionen GUICtrlSetOnEvent und GUISetOnEvent funktionieren nur, dass sie einen weiteren Parameter haben in den ein Array mit Parametern für die aufzurufende Funktion reinkommt.

    Das Array muss so aufgebaut sein:

    Array[0] = Erster Parameter
    Array[1] = Zweiter Parameter
    Array[2] = Dritter Parameter
    usw...

    Die Funktionen werden so aufgerufen:

    [autoit]


    GUISetOnEventEx(ID,"Funktion",$aParameter)

    [/autoit]


    oder

    [autoit]


    GUICtrlSetOnEventEx(ID,"Funktion",$aParameter)

    [/autoit]

    Bei der Funktion GUISetOnEventEx fehlt noch das Winhandle, aber dass kommt später, denn ich werde eine ganze weile kein Internet mehr haben und dachte mir ich stelle die Funktion noch rein bevor ich morgen wegfahre, meistens brauch man eh nur ein Fenster und wie oft muss man bei Systembuttons Parameter mitgeben. :rolleyes:

    Bevor ich es vergesse, hier noch die Funktionen:

    Spoiler anzeigen
    [autoit]


    Global $oOnEventDict = ObjCreate("Scripting.Dictionary")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ====================================================================================================================
    ; Name...........: GUICtrlSetOnEventEx
    ; Description ...: Ruft eine benutzerdefinierte Funktion mit Parametern auf, wenn das GUI-Control angeklickt wurde.
    ; Syntax.........: GUICtrlSetOnEventEx($controlID,[$Function,[$aParameter]])
    ; Parameters ....: $controlID - ID des Controls
    ; $Function - Der Name der Funktion als String
    ; $aParameter - Die Parameter als eindimensionales Array
    ; Author ........: Zeitriss
    ; ===============================================================================================================================
    Func GUICtrlSetOnEventEx($controlID,$Function = Default,$aParameter = Default)
    If $Function <> Default Then
    Local $Data[2]
    If $aParameter = Default Then
    $Data[1] = ""
    Else
    ReDim $aParameter[Ubound($aParameter)+1]
    For $i = Ubound($aParameter)-2 to 0 step -1
    $aParameter[$i+1] = $aParameter[$i]
    Next
    $aParameter[0] = "CallArgArray"
    $Data[1] = $aParameter
    EndIf
    $Data[0] = $Function
    If $oOnEventDict.Contains (String($controlID)) Then $oOnEventDict.remove (String($controlID))
    $oOnEventDict.add (String($controlID),$Data)
    GUICtrlSetOnEvent($controlID,"GUICtrlSetOnEventBuffer")
    Else
    If $oOnEventDict.Contains (String($controlID)) Then $oOnEventDict.remove (String($controlID))
    EndIf
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ====================================================================================================================
    ; Name...........: GUICtrlSetOnEventEx
    ; Description ...: Ruft eine benutzerdefinierte Funktion mit Parametern auf, wenn ein Systembutton geklickt wurde.
    ; Syntax.........: GUICtrlSetOnEventEx($controlID,[$Function,[$aParameter]])
    ; Parameters ....: $controlID - ID des Systembuttons
    ; $Function - Der Name der Funktion als String
    ; $aParameter - Die Parameter als eindimensionales Array
    ; Author ........: Zeitriss
    ; ===============================================================================================================================
    Func GUISetOnEventEx($controlID,$Function = Default,$aParameter = Default)
    If $Function <> Default Then
    Local $Data[2]
    If $aParameter = Default Then
    $Data[1] = ""
    Else
    ReDim $aParameter[Ubound($aParameter)+1]
    For $i = Ubound($aParameter)-2 to 0 step -1
    $aParameter[$i+1] = $aParameter[$i]
    Next
    $aParameter[0] = "CallArgArray"
    $Data[1] = $aParameter
    EndIf
    $Data[0] = $Function
    If $oOnEventDict.Exists (String($controlID)) Then $oOnEventDict.remove (String($controlID))
    $oOnEventDict.add (String($controlID),$Data)
    GUISetOnEvent($controlID,"GUICtrlSetOnEventBuffer")
    Else
    If $oOnEventDict.Exists (String($controlID)) Then $oOnEventDict.remove (String($controlID))
    EndIf
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func GUICtrlSetOnEventBuffer()
    If Not $oOnEventDict.Exists(String(@GUI_CtrlId)) Then Return
    Local $Data = $oOnEventDict(String(@GUI_CtrlId))
    Call($Data[0],$Data[1])
    EndFunc

    [/autoit]

    [Edit:] Und das Beispiel welches ich ganz vergessen hatte gestern :D

    Beispiel
    [autoit]


    #include<GUICtrlSetOnEvent.au3>
    Opt("GUIOnEventMode", 1)

    [/autoit] [autoit][/autoit] [autoit]

    $hGUI = GUICreate("GUI",500,500,-1,-1)
    For $i = 1 to 3
    Local $Parameter[1] = [$i]
    GUICtrlSetOnEventEx(GUICtrlCreateButton("Button "&$i,10+100*$i,100,50,22),"ButtonKlick",$Parameter)
    Next
    Local $Parameter[2]
    $Parameter[0] = 16
    $Parameter[1] = "Fenster wurde geschlossen!"
    GUISetOnEventEx(-3,"Fenster_Schliessen",$Parameter)
    GUISetState(1,$hGUI)
    While 1
    sleep(2000)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func ButtonKlick($ButtonId)
    msgbox(0,"","Button "&$ButtonId&" wurde gedrückt")
    EndFunc
    Func Fenster_Schliessen($flag,$sString)
    msgbox($flag,"",$sString)
    exit
    EndFunc

    [/autoit]

    Sinn macht es aber eigentlich nur bei vielen Buttons, welche ähnliche Funktionen haben, dann brauch man nicht für jeden eine eigene Funktion.

    Ich hoffe die Funktionen gibt es noch nicht irgendwo in einer UDF versteckt. :P

    mfg Zeitriss

  • Spiel erstellen

    • Zeitriss
    • 8. Januar 2011 um 05:21

    Hier mal ein kleines Pingpong Spiel mit AutoIt, sehr simpel gemacht aber es funktioniert.
    Beschreibung im Script enthalten

    Spiel mit GUI
    [autoit]


    $hGUI = GUICreate("Titel",300,300);Erstellt ein Fenster welches noch unsichtbar ist
    $Ball = GUICtrlCreateCheckbox("",10,10,10,10,1);Erstellt eine Checkbox welche fast wie ein Ball aussieht
    $Spieler = GUICtrlCreateButton("",10,175,20,50);Erstellt ein Button mit dem der Spieler den Ball abwehrt
    $Gegner = GUICtrlCreateButton("",270,175,20,50);Erstellt ein Button mit dem der NPC(Nicht-Spieler-Charakter) den Ball abwehrt
    Global $SpielerPos = 175;Dort ist der Schläger des Spielers
    $NPCPos = 175;Und hier der des NPC's
    $Ball_Pos_X = 145;Hier ist die Breiten Koordinate des Balles, welche möglicht in der Mitte sein sollte
    $Ball_Pos_Y = 145;Hier ist die höhen Koordinate des Balles, welche möglicht in der Mitte sein sollte
    ;Die mitte von 300 (den so breit und hoch ist die GUI) wäre natürlich 150 aber wir müssen noch die hälfte des Balles abziehen(10/2=5)(300/2-5=145)

    [/autoit] [autoit][/autoit] [autoit]

    $Ball_X_Bewegung = (Random(0,1,1)-0.5)*10; Gibt dem Ball schwung in eine beliebige richtung
    ;Die Funktion Random gibt einen "Zufälligen wert zwischen den ersten beiden Parametern aus(0 und 1) dieser wert ist auf eine Ggnze Zahl gerundet...
    ;weil der Dritte Parameter eine 1 ist aber vergiss den dritten Parameter erstmal, der ist zimlich egal. Zumindest wirde eine 0 oder eine 1 -0.5 genommen (=-0.5 o. =0.5)...
    ; und dan mal 10 damit der Ball gut schwung kriegt (=-5 o. =5). Der schwung wird dem Ball später in jeden Schleifen durchgang zur höhen oder breiten Koordinate hinzugefügt.
    ;Beispiel: ein Schleifen durchgang dauert 0.2 sekunden und der Ball hat eine Geschwindigkeit von (X:5 ,Y:2) dann würde er in einer sekunde sich 25 Koordinaten nach Rechts...
    ;Bewegt haben( 1/0.2*5) und 10 nach unten( 1/0.2*2 )
    $Ball_Y_Bewegung = Random(-5,5,1); wird genause festgelegt nur dass es dieses mal sich nicht zwingend bewegen muss sondern einen Beliebigen wert zwischen -5 und 5 haben kann
    GUISetState(1,$hGUI); Macht das Fenster sichtbar damit der Spieler etwas sehen kann^^
    HotKeySet("{Down}","Spieler_bewegt_nach_unten");Wenn der Spieler auf Down(Steuerkreuz) drückt wird die Funktion "Spieler_bewegt_nach_unten" aufgerufen
    HotKeySet("{Up}","Spieler_bewegt_nach_oben");Wenn der Spieler auf Up(Steuerkreuz) drückt wird die Funktion "Spieler_bewegt_nach_oben" aufgerufen
    While 1;Hier beginnt das Spiel
    ;Hier wird die Position des Balles neu berechnet (wie oben erklärt)
    $Ball_Pos_X = $Ball_Pos_X+$Ball_X_Bewegung
    $Ball_Pos_Y = $Ball_Pos_Y+$Ball_Y_Bewegung
    GUICtrlSetPos($Ball,$Ball_Pos_X,$Ball_Pos_Y);Hier wird der Ball(Checkbox) an die neue Position gesetzt

    ;Hier wird überprüft ob der Ball den schläger des Spielers berührt

    If $Ball_Pos_X < 30 Then; Ist der Ball nah genug an deiner Seite um deinen Schläger berühren zu können
    If $Ball_Pos_Y+10 > $SpielerPos Then ;Ist dein Schläger hoch genug um den Ball zu erwischen
    If $Ball_Pos_Y < $SpielerPos+50 Then ;Ist dein Schläger tief genug um den Ball zu erwischen
    $Ball_Pos_X = 30 ; Setzt den Ball vor den Schläger um zu verhindern das dieser im schläger hängen bleibt
    $Ball_X_Bewegung = $Ball_X_Bewegung * -1;Dreht die Bewegung um
    $Ball_X_Bewegung = $Ball_X_Bewegung * 1.3;macht den Ball etwas schneller
    EndIf
    EndIf
    EndIf

    ;Hier wird überprüft ob der Ball den schläger des NPCs berührt

    If $Ball_Pos_X > 260 Then
    If $Ball_Pos_Y+10 > $NPCPos Then
    If $Ball_Pos_Y < $NPCPos+50 Then
    $Ball_Pos_X = 260
    $Ball_X_Bewegung = $Ball_X_Bewegung * -1
    EndIf
    EndIf
    EndIf

    ;Hier kommt der extem Intelligente NPC^^
    If $Ball_Pos_Y < $NPCPos +25 Then ;ist der Ball höher als der Mittelpunkt des Schlägers
    $NPCPos = $NPCPos - 5
    GUICtrlSetPos($Gegner,270,$NPCPos)
    EndIf

    If $Ball_Pos_Y > $NPCPos +25 Then ;ist der Ball tiefer als der Mittelpunkt des Schlägers
    $NPCPos = $NPCPos + 5
    GUICtrlSetPos($Gegner,270,$NPCPos)
    EndIf

    If $Ball_Pos_Y <0 Then ; Wenn der Ball oben gegen den Rand stößt, prallt er ab
    $Ball_Pos_Y = 0
    $Ball_Y_Bewegung = $Ball_Y_Bewegung * -1
    EndIf

    If $Ball_Pos_Y > 290 Then ; Wenn der Ball unten gegen den Rand stößt, prallt er ab
    $Ball_Pos_Y = 290
    $Ball_Y_Bewegung = $Ball_Y_Bewegung * -1
    EndIf

    If $Ball_Pos_X < 0 Then ; Wenn der Ball bei deiner Seite den Rand berührt dann...
    HotKeySet("{Down}")
    HotKeySet("{Up}");Dardurch wird verhindert dass du den Schläger(Button) immernoch bewegen kannst, ist natürlich nicht zwingend nötig sieht aber besser aus
    msgbox(0,"","Du hast Verloren.")
    exit;Beendet das Script
    EndIf

    If $Ball_Pos_X > 290 Then ; Wenn der Ball bei deiner Seite den Rand berührt dann...
    HotKeySet("{Down}")
    HotKeySet("{Up}");Dardurch wird verhindert dass du den Schläger(Button) immernoch bewegen kannst, ist natürlich nicht zwingend nötig sieht aber besser aus
    msgbox(0,"","Du hast Gewonnen.")
    exit;Beendet das Script
    EndIf


    sleep(100)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func Spieler_bewegt_nach_unten()
    $SpielerPos = $SpielerPos+5;Der Button des Spielers bewegt sich 5 Pixel nach unten
    GUICtrlSetPos($Spieler,10,$SpielerPos);Dies neue Position wurde zwar bestimmt aber davon hat der Butten nichts gemerkt, wir müssen ihn erst darauf hinweisen^^
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func Spieler_bewegt_nach_oben()
    $SpielerPos =$SpielerPos-5;Der Button des Spielers bewegt sich 5 Pixel nach oben
    GUICtrlSetPos($Spieler,10,$SpielerPos);Dass selbe wie oben
    EndFunc

    [/autoit]

    Ich habe leider keine Ahnung wie viel du über AutoIt schon weißt, wenn du etwas nicht verstehst frag einfach.

    Dieses Script soll nur einen Anstoß geben es ist natürlich viel mehr möglich auch mit besserem Interface, dass beste Beispiel ist dafür(wie schon erwähnt wurde)
    "Doodle Jump für Pc" von Ubuntu.

  • 2 Fragen

    • Zeitriss
    • 28. Dezember 2010 um 23:23

    Mit " beginnst und beendest du ein String. Wenn du es in einem String verwenden möchtest musst du zum beginnen und beenden ' verwenden:

    [autoit]


    $text = InputBox(" ",'Schreibe das Wort "MsgBox"?')

    [/autoit]

    Edit: War zu langsam ;(

  • Problem mit TCP-Kommunikation zwischen zwei Rechnern im Internet

    • Zeitriss
    • 28. Dezember 2010 um 02:14

    Was mir zuerst auffällt ist dass du im Client ein paar schritte hast die ich nicht nachvollziehen kann:


    [autoit]


    $MainSocket = TCPListen(@IPAddress1, 33891)
    $ConnectedSocket = TCPAccept($MainSocket)

    [/autoit]


    und kurz darauf:

    [autoit]


    $ConnectedSocket = TCPConnect($Empfaenger_IP, $Port)

    [/autoit]

    das obere kannst du ganz weglassen, falls du damit nichts anderes vorhast.

    Desweiteren brauch der Server deine Globale Ip wenn du es nicht im Lokalen Netzwerk machst.

    [autoit]


    $MainSocket = TCPListen(@IPAddress1, 33891);so nicht
    $MainSocket = TCPListen(_GetIP(), 33891)

    [/autoit]
  • _IsPressed

    • Zeitriss
    • 25. Dezember 2010 um 21:14

    Nach deiner meinung dürfte dieses Script dann wenn man Strg+Space drückt nichts anzeigen oder, denn es werden ja zwei tasten gleichzeitig gedrückt?

    Spoiler anzeigen
    [autoit]


    #include<Misc.au3>
    HotKeySet("{esc}","_exit")
    $dll = DllOpen("user32.dll")
    While 1
    If _IsPressed("20",$dll) and _IsPressed("11",$dll) Then
    ToolTip("Space und Strg wurde gedrückt")
    ElseIf _IsPressed("20",$dll) Then
    ToolTip("Space wurde gedrückt")
    EndIf
    WEnd
    Func _Exit()
    DllClose($dll)
    exit
    EndFunc

    [/autoit]
  • _IsPressed

    • Zeitriss
    • 25. Dezember 2010 um 21:07

    Erstmal ist bei Hotkeyset eine Sleep pause sinnlos da Hotkeyset das sozusagen drin hat.
    Bei IsPressed können doch bis zu zwei andere Tasten gedrückt werden oder? Viel mehr brauch man doch selten.

    [Edit] Benütze besser mal nicht nur Spoiler sondern auch AutoIt Code (rechts neben dem Spoilerbutton).

  • _IsPressed

    • Zeitriss
    • 25. Dezember 2010 um 20:51

    Wenn man Hotkeyset länger gedrückt hält wird es doch auch mehrmals ausgeführt.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™