1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. Zeitriss

Beiträge von Zeitriss

  • Functions abbrechen

    • Zeitriss
    • 18. August 2016 um 20:06

    Hi,

    Zitat von Lanealine

    häufen sich die abfragen vor den einzelene functions so langsam und es wird unübersichtlich


    Hierbei wäre sehr günstig dein Script sehen zu können :)

    Statt Globalen Varriablen würde ich allerdings vorschagen mit Returnwerten bzw. der SetError() oder SetExtended() Funktion zu arbeiten, über diese können Informationen weitergeben werden, du kannst dann auf @Error (Fehler/Abbruche), @Extended (erweiterte Rückgabe), oder dem normalen "Return Value" reagieren.

    mfg
    Zeitriss

  • Inputbox OK Button gibt keinen Text zurück?

    • Zeitriss
    • 12. August 2016 um 20:04
    Zitat von BlutigerAnfänger

    Wird automatisch ein Zeilenvorschub und CReturn gesendet!

    Dann müsste man doch nur das <Enter> durch ein Zeilenvorschub(@lf) ersetzen oder?

    Probier es mal so:

    AutoIt: Script von Kanashius (leicht verändert)
    #include<Array.au3>
    
    
    Global $GRetoure[20][2]
    ScanPZN($GRetoure)
    Exit
    
    
    Func ScanPZN(ByRef $arGRetoure)
    	local $width=400,$height=105
    	$hGui=GUICreate("Erfassungsmaske",$width,$height)
    	GUICtrlCreateLabel("Tippen Sie die PZN ein und drücken Sie auf OK oder scannen Sie die Artikel ab. Korrekturen können später vorgenommen werden!",5,5,$width-10,35)
    	$inputNumber=GUICtrlCreateInput("",5,$height-65,$width-10,25)
    	GUICtrlSendMsg(-1, 0x1501, 0, "Menge * PZN")
    	$buttonOK=GUICtrlCreateButton("OK",5,$height-35,($width-10)/2)
    	$buttonCancel=GUICtrlCreateButton("Fertig",10+($width-15)/2,$height-35,($width-15)/2)
    	Local $aAccelKeys[1][2] = [["{" & @lf &" }", $buttonOK]]
        GUISetAccelerators($aAccelKeys)
    	GUISetState()
    	local $count=0
    	while 1
    		$msg=GUIGetMsg()
    		Switch $msg
    			Case $buttonOK
    				$arRes=StringRegExp(GUICtrlRead($inputNumber),"(^((?:(?:[0-9]+)(?:-*))+)$)|(?:^([0-9]+)(?:\W*?)\*(?:\W*?)((?:(?:[0-9]+)(?:-*))+)$)",3)
    				;_ArrayDisplay($arRes)
    				if UBound($arRes)=4 then
    					$arGRetoure[$count][0]=int($arRes[2])
    					$arGRetoure[$count][1]=int(StringReplace($arRes[3], "-",""))
    				Elseif UBound($arRes)=2 then
    					$arGRetoure[$count][0]=1
    					$arGRetoure[$count][1]=int(StringReplace($arRes[0], "-", ""))
    				Else
    					MsgBox(16,"Error","Eingabe fehlerhaft!")
    				EndIf
    				_ArrayDisplay($arGRetoure)
    				$count+=1
    				if $count=UBound($arGRetoure) then
    					ReDim $arGRetoure[UBound($arGRetoure)+20][2]
    				endif
    			Case  $buttonCancel
    				ExitLoop
    			Case -3
    				ExitLoop
    		EndSwitch
    	WEnd
    	ReDim $arGRetoure[$count][2]
    	_ArrayDisplay($arGRetoure)
    EndFunc
    Alles anzeigen
  • Dynamischen "Visable Text" (mit Platzhaltern?) abfangen?

    • Zeitriss
    • 12. August 2016 um 19:37

    Hi,

    Sinnvoll wäre es zu sehen wie du bisher versucht hast das Problem zu lösen.

    Zitat von hansiii

    Die Nach-Komma-Stellen des Prozentwertes sind willkürlich, d.h. das Programm springt z.B. von 21.36% auf 22.19%.

    Hierbei sollte man besser eine Methode wählen die auch funktioniert wenn das Programm den Prozentwert ganz überspringt.
    Möglich wäre es wenn man den Wert rausfiltert und prüft ob er den Schwellwert überschritten hat.

    Hier mal eine allgemeine Möglichkeit dafür:

    AutoIt
    $iThresholdPercent = 20 ; Der Schwellenwert ab dem Die Aktion ausgeführt werden soll
    $iLastPercent = 0 ; Der Prozentwert von der voherigen überprüfung
    $iNewPercent = 0 ; Der aktuelle Prozentwert
    While $iNewPercent < 100
       $iNewPercent += Random(0.5,2) ; Lese den Neuen Prozentwert aus, hier dann die Ensprechenden Funktionen einfügen
       If $iLastPercent < $iThresholdPercent and $iNewPercent > $iThresholdPercent Then
    	  ; Überprüfe ob der Schwellwert in diesem Schleifendurchlauf überschritten wurde
    	  ; führe dann die Entsprechende Aktion aus Aktion
    	  MsgBox(0,"", $iNewPercent & "%")
       EndIf
       $iLastPercent = $iNewPercent ; Setze den $iLastPercent auf den aktuellen Prozentwert
    WEnd
    Alles anzeigen


    Zum rausfiltern der Werte kann man Stringregexp oder _StringBetween verwenden, hier mal ein Beispiel mit RegExp: (gibt mindestens ein Tutorial dazu hier im Forum)

    AutoIt
    #include<Array.au3>
    $sVisibleText = '21.36% von Vorgang 01 ist abgeschlossen.'
    $aData = StringRegExp($sVisibleText,"([0-9\.]*)% von (.*) ist abgeschlossen.",3)
    MsgBox(0,"Title",'Prozent: ' & $aData[0] & '%' & @CRLF & 'Vorgang: "' & $aData[1] & '"' )

    _StringBetween ist etwas einfacher und wäre am Anfang warscheinlich die bessere Methode.

    mfg


    Zeitriss

  • simple berechnung - eingabe wird abgerundet dabei brauche ich zur berechnung den gesamten eingegeben wert

    • Zeitriss
    • 8. August 2016 um 19:15

    @autoBert

    Zitat von autoBert

    Sorry. ich hatte Tippfehler, muß natürlich >10000% heisen. Denn wenn etwas was im Monat mehr als das 10 fache des Jahresbeitrags kostet hat effektiv einen Zuschlag größer 11000 %. Auch hieran zu erkennen:

    Ich vermute das Script rechnet von der Zahlungshöhe (mit Ratenzahlungszuschlag) des Gewählten Intervalles zum Jahresbeitrag(ohne Ratenzahlungszuschlag).
    Also:

    Netto(Jährlich) = Brutto(Monatlich, mit Ratenzahlungszuschlag) / Ratenzahlungszuschlag * Intervalle

    Brutto(Monatlich, mit Ratenzahlungszuschlag) = 220€
    Ratenzahlungszuschlag = 1,06 (0% Jährlich, 3% halbjährig, 5% vierteljährig, 6% Monatlich)
    Intervalle = 12
    Netto(Jährlich) = 2490,566037€

    mfg
    Zeitriss

  • simple berechnung - eingabe wird abgerundet dabei brauche ich zur berechnung den gesamten eingegeben wert

    • Zeitriss
    • 8. August 2016 um 17:23

    Ok versuch es mal so:

    AutoIt
    #include <ButtonConstants.au3>
    #include <EditConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <StaticConstants.au3>
    #include <WindowsConstants.au3>
    #Region ### START Koda GUI section ### Form=C:\Users\Videoschnitt\Desktop\autoit\läuft\rechner.kxf
    $Form1_1 = GUICreate("Form1", 267, 227, 469, 145)
    GUISetBkColor(0xFFFFFF)
    
    
    
    
    $Button_plus = GUICtrlCreateButton("Netto Jährlich", 144, 48, 113, 25)
    
    
    $Button_minus = GUICtrlCreateButton("Netto Halbjährlich", 144, 80, 113, 25)
    
    
    $Button_durch = GUICtrlCreateButton("Netto Vierteljährlich", 144, 112, 113, 25)
    
    
    $Button_mal = GUICtrlCreateButton("Netto Monatlich", 144, 144, 113, 25)
    
    
    $Label1 = GUICtrlCreateLabel("0", 136, 184, 116, 25)
    GUICtrlSetFont(-1, 14, 800, 0, "MS Sans Serif")
    $Input1 = GUICtrlCreateInput("0", 8, 8, 129, 32)
    GUICtrlSetFont(-1, 14, 800, 0, "MS Sans Serif")
    $Label2 = GUICtrlCreateLabel("Brutto Betrag eingeben", 144, 16, 113, 17)
    GUISetState(@SW_SHOW)
    #EndRegion ### END Koda GUI section ###
    
    
    
    
    Global $operation = ""
    Global $merk_zahl = 0
    
    
    While 1
    	$nMsg = GUIGetMsg()
    	Switch $nMsg
    
    
    
    
    
    
    		Case $Button_plus
    
    
    			$operation = "bj"
    
    
    			berechnen()
    
    
    		Case $Button_mal
    
    
    			$operation = "bq"
    
    
    			berechnen()
    
    
    		case $Button_durch
    
    
    			$operation = "bm"
    
    
    			berechnen()
    
    
    		Case $Button_minus
    
    
    			$operation = "bh"
    
    
    			berechnen()
    
    
    		Case $GUI_EVENT_CLOSE
    			Exit
    		Case $Label1
    	EndSwitch
    WEnd
    
    
    func button_zahl($int)
    	if GUICtrlRead($Input1) = 0 then
    		GUICtrlSetData($Input1 , $int)
    	Else
    		GUICtrlSetData($Input1 ,GUICtrlRead($Input1) & $int)
    	EndIf
    
    
    
    
    EndFunc
    
    
    Func berechnen()
       Local $sEingabe = GUICtrlRead($input1)
       Local $iEingabe = Number( StringReplace($sEingabe, ",", ".") )
       ;Ersetzt "," durch "."
    
    
    	Switch $operation
    
    
    				Case "bj"
    
    
    					$merk_zahl = $iEingabe
    					GUICtrlSetData($Input1 ,"")
    
    
    				Case "bq"
    
    
    					$merk_zahl = $iEingabe / 1.06 * 12
    					GUICtrlSetData($Input1 ,"")
    
    
    
    
    				Case "bh"
    
    
    					$merk_zahl =  $iEingabe / 1.03 * 2
    					GUICtrlSetData($Input1 ,"")
    
    
    				Case "bm"
    
    
    					$merk_zahl =  $iEingabe / 105*400
    					GUICtrlSetData($Input1 ,"")
    
    
    
    
    
    
    				Case "nj"
    
    
    					$merk_zahl =  $iEingabe / 1.19 /1.03 *2
    					GUICtrlSetData($Input1 ,"")
    
    
    				Case "nq"
    
    
    					$merk_zahl =  $iEingabe / 1.19 / 1.05 * 4
    					GUICtrlSetData($Input1 ,"")
    
    
    
    
    				Case "nh"
    
    
    					$merk_zahl = $iEingabe / 1.19 / 1.06 * 12
    					GUICtrlSetData($Input1 ,"")
    
    
    				Case "nm"
    
    
    					$merk_zahl =  $iEingabe / 1.19
    					GUICtrlSetData($Input1 ,"")
    
    
    		case Else
    			MsgBox(0,"","es gab eine nicht definierte Funktion")
    
    
    	EndSwitch
    
    
    	GUICtrlSetData($Label1,$merk_zahl)
    
    
    EndFunc
    Alles anzeigen
  • simple berechnung - eingabe wird abgerundet dabei brauche ich zur berechnung den gesamten eingegeben wert

    • Zeitriss
    • 8. August 2016 um 17:07

    Hi,


    Da ist kein Rundungsfehler, ich denke immernoch das der Fehler bei der Eingabe liegt.
    "220.19" als Eingabe ergibt exakt das, was ich, von dem Script erwarten würde:

    220.19


    Netto Jährlich: 220.19
    Netto Halbjährlich: 0 (427.5533980)
    Netto Vierteljährlich: 838.8190476
    Netto Monatlich: 2492.716981


    "220" ergibt logischerweise ein leicht geringeres Ergebniss:

    220

    Netto Jährlich: 220
    Netto Halbjährlich: 0 (427.1844660)
    Netto Vierteljährlich: 838.0952380
    Netto Monatlich: 2490.566037


    Versuch mal den Rundungsfehler mit folgendem Script zu erzeugen und Poste die Konsolenausgabe:

    AutoIt
    #include <ButtonConstants.au3>
    #include <EditConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <StaticConstants.au3>
    #include <WindowsConstants.au3>
    #Region ### START Koda GUI section ### Form=C:\Users\Videoschnitt\Desktop\autoit\läuft\rechner.kxf
    $Form1_1 = GUICreate("Form1", 267, 227, 469, 145)
    GUISetBkColor(0xFFFFFF)
    
    
    
    
    $Button_plus = GUICtrlCreateButton("Netto Jährlich", 144, 48, 113, 25)
    
    
    $Button_minus = GUICtrlCreateButton("Netto Halbjährlich", 144, 80, 113, 25)
    
    
    $Button_durch = GUICtrlCreateButton("Netto Vierteljährlich", 144, 112, 113, 25)
    
    
    $Button_mal = GUICtrlCreateButton("Netto Monatlich", 144, 144, 113, 25)
    
    
    $Label1 = GUICtrlCreateLabel("0", 136, 184, 116, 25)
    GUICtrlSetFont(-1, 14, 800, 0, "MS Sans Serif")
    $Input1 = GUICtrlCreateInput("0", 8, 8, 129, 32)
    GUICtrlSetFont(-1, 14, 800, 0, "MS Sans Serif")
    $Label2 = GUICtrlCreateLabel("Brutto Betrag eingeben", 144, 16, 113, 17)
    GUISetState(@SW_SHOW)
    #EndRegion ### END Koda GUI section ###
    
    
    
    
    Global $operation = ""
    Global $merk_zahl = 0
    
    
    While 1
    	$nMsg = GUIGetMsg()
    	Switch $nMsg
    
    
    
    
    
    
    		Case $Button_plus
    
    
    			$operation = "bj"
    
    
    			berechnen()
    
    
    		Case $Button_mal
    
    
    			$operation = "bq"
    
    
    			berechnen()
    
    
    		case $Button_durch
    
    
    			$operation = "bm"
    
    
    			berechnen()
    
    
    		Case $Button_minus
    
    
    			$operation = "bh"
    
    
    			berechnen()
    
    
    		Case $GUI_EVENT_CLOSE
    			Exit
    		Case $Label1
    	EndSwitch
    WEnd
    
    
    func button_zahl($int)
    	if GUICtrlRead($Input1) = 0 then
    		GUICtrlSetData($Input1 , $int)
    	Else
    		GUICtrlSetData($Input1 ,GUICtrlRead($Input1) & $int)
    	EndIf
    
    
    
    
    EndFunc
    
    
    Func berechnen()
       ConsoleWrite( _
       "$operation: " & $operation & @crlf & _
       "GUICtrlRead($input1): " & GUICtrlRead($input1) & @crlf & _
       "Number(GUICtrlRead($input1)): " & Number(GUICtrlRead($input1)) & @crlf _
       )
    	Switch $operation
    
    
    				Case "bj"
    
    
    					$merk_zahl = GUICtrlRead($input1)
    					GUICtrlSetData($Input1 ,"")
    
    
    				Case "bq"
    
    
    					$merk_zahl = GUICtrlRead($input1) / 1.06 * 12
    					GUICtrlSetData($Input1 ,"")
    
    
    
    
    				Case "bh"
    
    
    					$merk_zahl =  GUICtrlRead($input1) / 1.03 * 2
    					GUICtrlSetData($Input1 ,"")
    
    
    				Case "bm"
    
    
    					$merk_zahl =  GUICtrlRead($input1) / 105*400
    					GUICtrlSetData($Input1 ,"")
    
    
    
    
    
    
    				Case "nj"
    
    
    					$merk_zahl =  GUICtrlRead($input1) / 1.19 /1.03 *2
    					GUICtrlSetData($Input1 ,"")
    
    
    				Case "nq"
    
    
    					$merk_zahl =  GUICtrlRead($input1) / 1.19 / 1.05 * 4
    					GUICtrlSetData($Input1 ,"")
    
    
    
    
    				Case "nh"
    
    
    					$merk_zahl = GUICtrlRead($input1) / 1.19 / 1.06 * 12
    					GUICtrlSetData($Input1 ,"")
    
    
    				Case "nm"
    
    
    					$merk_zahl =  GUICtrlRead($input1) / 1.19
    					GUICtrlSetData($Input1 ,"")
    
    
    		case Else
    			MsgBox(0,"","es gab eine nicht definierte Funktion")
    
    
    	EndSwitch
       ConsoleWrite( _
       "$merk_zahl: " & $merk_zahl & @crlf & _
       "--------------------------------" & @crlf _
       )
    	GUICtrlSetData($Label1,$merk_zahl)
    
    
    EndFunc
    Alles anzeigen
  • Bild in GUI löschen?

    • Zeitriss
    • 4. August 2016 um 18:44

    Hi,

    Versuche es mal mit GUICtrlDelete()

    AutoIt
    $idPic = _GUICtrlPic_Create("...", 10, 10)
    GUICtrlDelete($idPic)

    Es handelt sich dabei um ein "Picture control", daher kann es über die controlID "gelöscht" werden.

    mfg
    Zeitriss

  • Aus CVS Datei erste Zeile löschen

    • Zeitriss
    • 4. August 2016 um 17:18
    Zitat von iCrypto

    ich versuche seit Stunden ein Script zu machen, welches aus einer txt Pfade rausliest von einer csv File, dort die erste Zeile löscht und die nöchste macht

    Das System mit dem aus der TXT lesen ist natürlich sehr simpel, aber die CSV zu bearbeiten fällt mir sehr sehr schwer

    Wozu ist der Rest von deinem Script? Vor allem das Filedelete und direkt in der nächsten Zeile der versuch die soeben gelöschte Datei umzubennen ?(

    Zitat von iCrypto

    FileDelete($l2)
    Run(@ComSpec&'\c ren '& $l2 & ' " ' & $ub3 )


    Folgende Zeilen aus deinem Code (leicht abgeändert) sollten das oben beschriebene erfüllen, der Rest deines Scriptes erschließt sich mir nicht.

    AutoIt
    #include <file.au3>
    $iLines = _FileCountLines(@DesktopDir & "\dateien.txt"); hier vielleicht ein Fileread + Stringsplit in erwägung ziehen
    MsgBox(0,"",$iLines)
    for $i = 1 to $iLines
       $sPath_CSVFile = FileReadLine(@DesktopDir & "\dateien.txt",$i)
       _FileWriteToLine($sPath_CSVFile,1,"",1)
    Next
  • simple berechnung - eingabe wird abgerundet dabei brauche ich zur berechnung den gesamten eingegeben wert

    • Zeitriss
    • 4. August 2016 um 15:52

    Hi,

    Hast du die Zahlen vielleicht mit einem Komma als Dezimaltrennzeichen eingegeben, in diesem fall würde er die Nachkommastellen ignorieren.

    mfg
    Zeitriss

  • Tastatur entprellen / Keyboard anti bouncing

    • Zeitriss
    • 2. August 2016 um 19:15

    Hi,

    Warum der Umweg über einen Hook, zum Blocken von doppelten Eingaben sollte ein Hotkey völlig ausreichend sein, oder?

    Folgende Variablen sind übrigens alle Global, dass Local davorsteht ist ändert daran nichts:

    AutoIt
    Global $g_hHook, $g_hStub_KeyProc, $g_sBuffer = ""
    Local $DelayTime = IniRead(@WorkingDir & "\Settings.ini", "Delay", "Time_ms", "5")
    Local $Keys = IniRead(@WorkingDir & "\Settings.ini", "Used_Chars", "Chars", "")
    Local $Auto = IniRead(@WorkingDir & "\Settings.ini", "Autostart", "Enable", "")
    local $BlockedHotkey
    local $pause = 0

    Lokale Variablen können nur innerhalb von Funktionen erstellt werden.

    mfg

    Zeitriss

  • If not Fileexists Then

    • Zeitriss
    • 1. August 2016 um 19:49
    Zitat von Lanealine

    mehrere autoit programme gleichzeitig laufen lasse

    Wie viele sind mehrere?

    Du hast kein Sleep in deiner "Warteschleife", daher überprüfen deine Programme sehr oft ob die Datei exestiert.
    Wenn nun mehrere Programme in der Schleife warten wärend das aktive die Datei löscht überprüfen die wartenen Programme die Datei fast gleichzeitig.
    Alle Programme die zuvor gewartet haben denken nun gleichzeitig, dass sie an der Reihe sind. Die Datei wird viel zu spät erzeugt.

    Wenn ich richtig liege sollte dann folgendes die Fehlerwarscheinlichkeit drastisch reduzieren:

    AutoIt
    Func Arbeitet()
    	While 1
    	   sleep( Random(250,350,1) )
    		If Not FileExists($DirArbeitet) Then
    			FileWrite($DirArbeitet, "")
    			Return
    		EndIf
    	WEnd
    EndFunc
    Func Fertig()
    	FileDelete($DirArbeitet)
    EndFunc
    Alles anzeigen

    Dies ist natürlich keine Lösung für das Problem, ich hatte zuvor schon Möglichkeiten beschrieben wie sich das Problem warscheinlich lösen lässt, ich möchte nur sichergehen dass ich den Fehler richtig verstanden habe.

    mfg,

    Zeitriss

  • If not Fileexists Then

    • Zeitriss
    • 29. Juli 2016 um 19:25

    Hier nochmal ein bisschen Balstelwerk mit TCP, hierbei verwaltet ein Server die Reihenfolge.
    Solltest aber, falls du es nützen möchtest, den Code nicht einfach übernehmen, er ist noch ziemlich verbesserungsbedürftig z.B. ist ein Array vielleicht nicht unbedingt die Optimale Wahl.

    AutoIt: Server
    #include<Array.au3>
    TCPStartup()
    Global $iListenSocket = TCPListen("127.0.0.1",65432)
    Global $aQueue[1] = [0]
    Global $iSocket = 0
    Global $sRecv = ""
    HotKeySet("{Esc}","_Exit")
    While 1
       $iSocket = TCPAccept($iListenSocket)
       If $iSocket <> -1 Then
    	  $aQueue[0] += 1
    	  ReDim $aQueue[ $aQueue[0] + 1 ]
    	  $aQueue[$aQueue[0]] = $iSocket
    	  If $aQueue[0] = 1 Then
    		 TCPSend($iSocket,"Start")
    	  EndIf
       EndIf
       For $i = 1 to $aQueue[0]
    	  $sRecv = TCPRecv($aQueue[$i],1024)
    	  If @error Then
    		 MsgBox(16,0,"Verbindung zu Client verloren!")
    		 _ArrayDelete($aQueue,$i)
    		 $aQueue[0] -= 1
    		 If $i = 1 and $aQueue[0] > 0 Then
    			TCPSend($aQueue[1],"Start")
    		 EndIf
    		 exitloop
    	  EndIf
    	  If $sRecv = "Done" Then
    		 TCPCloseSocket($aQueue[$i])
    		 _ArrayDelete($aQueue,$i)
    		 $aQueue[0] -= 1
    		 If $aQueue[0] > 0 Then
    			TCPSend($aQueue[1],"Start")
    		 EndIf
    		 ExitLoop
    	  EndIf
       Next
    WEnd
    
    
    Func _Exit()
       TCPCloseSocket($iListenSocket)
       For $i = 1 to $aQueue[0]
    	  TCPCloseSocket($aQueue[$i])
       Next
       TCPStartup()
       exit
    EndFunc
    Alles anzeigen
    AutoIt: Client
    TCPStartup()
    Global $sTime = @min & ":" & @SEC & ":" & @MSEC
    $iSocket = TCPQueue_Wait()
    ;~ sleep(5000); Arbeite
    MsgBox(0,0,$sTime)
    TCPQueue_Done($iSocket)
    TCPShutdown()
    Func TCPQueue_Wait()
       Local $iSocket = TCPConnect("127.0.0.1",65432)
       Local $sRecv = ""
       If $iSocket = -1 Then
    	  MsgBox(16,"","Keine Anwort vom Server!")
    	  Return SetError(1)
       EndIf
       Do
    	  sleep(100)
    	  $sRecv = TCPRecv($iSocket,1024)
    	  If @error Then
    		 MsgBox(16,"","Verbindung zu Server verloren!")
    		 Return SetError(1)
    	  EndIf
       Until $sRecv = "Start"
       Return $iSocket
    EndFunc
    Func TCPQueue_Done($iSocket)
       TCPSend($iSocket,"Done")
       TCPCloseSocket($iSocket)
    EndFunc
    Alles anzeigen

    mfg,

    Zeitriss

  • If not Fileexists Then

    • Zeitriss
    • 29. Juli 2016 um 16:54

    Hi,

    Klappt bei mir problemlos, selbst wenn ich 2 Instanzen in sehr kurzem Interwall(ca. 50ms) Starte.
    Stell am besten mal ein funktionierendes Script zur verfügung, welches diesen Fehler aufweist.

    Edit: Wenn es mehr als zwei Instanzen sind, werden nachdem die erste fertig ist logischerweise alle verbeibenen gleichzeitig ausgeführt, das ist vermutlich dein Problem oder?

    Edit2: Versuch es mal so:

    AutoIt
    Local $sStartTime = @MIN & ":" & @SEC & ":" & @MSEC
    If Not @Compiled Then
       MsgBox(16,"", "Programm funktioniert nicht als Script!")
       exit
    EndIf
    Do
       sleep(50)
    Until ProcessList(@ScriptName)[1][1] == @AutoItPID; Eine Fehlerabfrage ist nicht wirklich notwendig, sollte aber vll trozdem eingebaut werden.
    MsgBox(0,"","Startzeit des Prozesses: "& $sStartTime)


    Edit3:
    Sorry hatte die Frage etwas falsch verstanden, das Script aus Edit2 war passt nicht ganz.

    Hier noch ein Paar Ideen:

    1) Eine mögliche Lösung wäre für dich warscheinlich das über ein "drittes" Programm zu regeln, bei welchem die anderen Prozesse dann(z.B. per TCP) die Start Erlaubniss anfragen/erhalten können.
    2 )Die Programme könnten auch alle Seperate Dateien erstellen sobald sie anfangen zu Warten, wenn dann die Prozess Id als Dateiname benützt wird könnte man z.B. sagen dass erst angefangen werden darf, wenn keine Datei mit einer niedrigeren Id(Dateiname) mehr da ist.
    3) Pack alles in ein Programm, nach deiner Beschreibug erscheint mir das als naheliegendste Lösung.

    mfg,

    Zeitriss

  • Hexacode einer Zugangskarte in eine Dezimalzahl umwandeln

    • Zeitriss
    • 13. Juli 2016 um 19:16

    Hi,

    du kannst in AutoIt auch eigene Fenster erstellen, dies ist insbesondere praktisch wenn das Programm länger benützt werden soll, also in diesem fall mehrere Hex zahlen umgewandelt werden sollen.

    Wenn du dich länger mit AutoIt befassen möchtest kannst du dir hierzu eines der vielen GUI Tutoriale ansehen.
    Hier ein kleines Beispiel für eine eigene Grafische Oberfläche:

    (Alles hinter den ";" sind Kommentare)

    AutoIt
    #include <EditConstants.au3>; Läd Konstanten für EditControls, in diesem fall wird eine Konstante benötigt um ein Eingabefeld(InputControl) auf "nur lesen" zu stellen
    Opt("MustDeclareVars",1); erzwingt das Deklarieren von Variablen vor Benützung, ist völlig optional.
    Global $msg, $sClip, $sDec, $iDec, $sHex ; Deklariert Variablen die wir im Laufe des Scriptes noch brauchen
    Global $hGUI = GUICreate("My Hex to Dec Converter",350,100); erstellt eine GUI (Grafik User Interface) also ein Windows-Fenster
    GUICtrlCreateLabel("Hex:",10,11,30,18); Erstellt ein Textfeld auf diesem Fenster, wir beschriften hiermit das Hex Eingabefeld
    Global $idInput_Hex = GUICtrlCreateInput("",50,10,240,19); Hier wird das Hex-Eingabefeld erstellt
    Global $idButton_Past = GUICtrlCreateButton("Paste",300,10,40,21); Erstellt einen Button mit der aufschrift "Paste"
    GUICtrlCreateLabel("Dec:",10,41,30,18); Erstellt ein Textfeld auf diesem Fenster, wir beschriften hiermit das Dec Eingabefeld
    Global $idInput_Dec =  GUICtrlCreateInput("",50,40,240,19,$ES_READONLY); Hier wird das Dec-Eingabefeld erstellt, welches aufgrund des Stils $ES_READONLY keine eingaben vom benützer akzeptiert
    Global $idButton_Copy = GUICtrlCreateButton("Copy",300,40,40,21); Erstellt einen Button mit der aufschrift "Copy"
    Global $idButton_Convert = GUICtrlCreateButton("Convert",75,70,200,22); Erstellt einen Button mit der aufschrift "Convert"
    Global $aAccelKeys[1][2] = [["{Enter}", $idButton_Convert]]; Erstellt ein Array mit der Tastenbelegung in dem Fenster, siehe hilfe zu GUISetAccelerators()
    GUISetAccelerators($aAccelKeys, $hGUI); Beim drücken der {Enter} Taste wird quasi wie ein klicken auf den Button "Convert" gewertet
    GUISetState(@SW_SHOW, $hGUI); Mach das Fenster, dessen Handle oben in der Variable $hGUI abgespeichert wurde sichtbar(@SW_SHOW)
    Do; Begin einer Schleife, alles zwischen dieser Zeile und Until wird unbegrenzt oft wiederholt werden
       $msg = GUIGetMsg(); Wenn ein Fensterelement z.B. ein Button angeklickt wird, gibt GUIGetMsg() die id dieses Fensterelementes in die Variable $msg
       Switch $msg; Hier wird die id des angeklickten Fensterelements mit unseren Buttons verglichen um, im falle einer Übereinstimmung zu reagieren, zur Funktionsweise von Switch-Case-EndShitch siehe Hilfe
       Case $idButton_Past; Im fall das der Paste-Button angeklickt wurde...
    	  $sClip = ClipGet(); Speichert den Inhalt Zwischenablage (Clip) in der Variable $sClip
    	  GUICtrlSetData($idInput_Hex, $sClip); Schreibt den Inhalt der Zwischenablage in das Hex-Eingabefeld
    	  $iDec = Dec($sClip); Convertiert die Eingabe ins 10er Zahlensystem
    	  If Not @error Then; Sollte die Umwandlung erfolgreich sein, also nicht fehlschlagen (Not @error), wird der umgewandelte Wert in das Dec-Eingabefeld geschrieben
    		 GUICtrlSetData($idInput_Dec, $iDec)
    	  EndIf
       Case $idButton_Copy; Im fall das der Copy-Button angeklickt wurde...
    	  $sDec = GUICtrlRead($idInput_Dec); Speichere den Inhalt des Dec-Eingabefeld (welches nur der Ausgabe dient) in die Variable $sDec
    	  ClipPut( $sDec ); Schreibe den Inhalt des Dec-Eingabefeld in die Zwischenablage (Clip)
       Case $idButton_Convert; Im fall das der Convert-Button angeklickt wurde...
    	  $sHex = GUICtrlRead($idInput_Hex); Lese den Inhalt des Hex-Eingabefeld in die Variable $sHex
    	  $iDec = Dec($sHex); Wandelt die Variable $sHex ins 10er Zahlensystem um und speichert es in der Variable $iDec
    	  If @error Then; Im Fehlerfall wird das Hex-Eingabefeld rötlich(0xFF9999) gefärbt
    		 GUICtrlSetBkColor($idInput_Hex,0xFF9999)
    	  Else; Im Erfolgsfall...
    		 GUICtrlSetBkColor($idInput_Hex,0xFFFFFF); wird das Hex-Eingabefeld weiß(0xFFFFFF) gefärbt, dies wird jedesmal gemacht, falls das Feld zuvor durch eine ungültige Eingabe rot gefärbt wurde
    		 GUICtrlSetData($idInput_Dec, $iDec); Schreibt den Konvertierten Wert in das Dec-Eingabefeld
    	  EndIf
       Case -3; Die id -3($GUI_EVENT_CLOSE) enspricht dem Fenster schließen event, in diesem Fall wird das Script beendet (exit)
    	  exit
       EndSwitch
    Until False; Ab hier springt das Programm wieder zum Start der Schleife (Do)
    Alles anzeigen

    Vielleicht kannst du das Wissen in späteren Projekten brauchen.

    @Andy:
    Ich denke das soll ein Übungsprojekt sein um sich in die Materie reinzufinden.

    Zitat von DZZprogramm

    Er meinte, dass dieses Programm gut ist, um ein bisschen damit zurecht zu kommen

    mfg

    Zeitriss

  • Icon - Tooltip und Variablennamen abfragen - eindeutige unverwechselbare Icon-Eigenschaft - bei rechtem Mausklick

    • Zeitriss
    • 5. Juli 2016 um 17:45

    Hi,

    Ich bin mir nicht ganz sicher ob ich verstehe was hier gesucht wird.

    Zitat von AutoMit

    (ID geht nicht, ist veränderlich von Script A zu Script B ...)

    Deshalb speichert man diese bei der Erstellung in einer Variable deren Bezeichnung immer Identisch ist.

    Zitat von AutoMit

    Bei Abfrage mit der rechten Maustaste, worauf ich rechts geklickt habe, kann ich "nur" die Position auslesen neben der veränderlichen ID sowie Handle und daher braucht das Icon an der Mausposition eine eindeutige Eigenschaft, die es in allen Scripten als Alleinstellungsmerkmal hat.

    Dieses "Alleinstellungsmerkmal" wäre die tatsache dass die ID mit dem Inhalt der Variable übereinstimmt, das reicht zur Identifizierung.

    Sieh dir dass mal an vielleicht hiflt es dir, obwohl ich wie gesagt nicht sicher bin was gesucht wird:

    AutoIt
    Global $hGUI = GUICreate("interface",300,300,-1,-1)
    Global $hIcon_Exit = GUICtrlCreateIcon("C:\Windows\system32\shell32.dll",-100,250,250,32,32)
    Global $hIcon_Msg = GUICtrlCreateIcon("C:\Windows\system32\shell32.dll",-74,250,200,32,32)
    GUISetState(1,$hGUI)
    Do
       $aInfo = GUIGetCursorInfo($hGUI)
       If $aInfo[3] Then
    	  Switch $aInfo[4]
    	  Case $hIcon_Exit
    		 Exit
    	  Case $hIcon_msg
    		 MsgBox(0,"Msg","Hallo Welt")
    	  EndSwitch
       EndIf
    Until GUIGetMsg() = -3
    Alles anzeigen

    mfg

    Zeitriss

  • Reguläre Ausdruck. Komme nicht weiter

    • Zeitriss
    • 5. Juli 2016 um 11:51

    Hi

    Versuch es mal so:

    AutoIt
    $sString = 'class="adress">Rathausplatz 5<br/>90403 Nürnberg<br/><a href="
    ' & @crlf & _
    'Kontakt</h3><p class="adress">Äußere Bayreuther Str. 121<br/>90409 Nürnberg<br/><a href="
    ' & @crlf & _
    '</span></p><h3>Kontakt</h3><p class="adress">Wallensteinstraße 28<br/>90439 Nürnberg<br/><a href="
    ' & @crlf & _
    '</span></p><h3>Kontakt</h3><p class="adress">Glogauer Str. 30 - 38<br/>90473 Nürnberg<br/><a href="
    '
    $aArray = StringRegExp($sString,'class="adress">(.*?)<br\/>(.*?)<br/>',3)
    For $i = 0 to UBound($aArray) -2 step + 2
       MsgBox(0,"",$aArray[$i] & @crlf & $aArray[$i +1])
    Next
    Alles anzeigen


    mfg

    Zeitriss

  • Software Autobackup mit popup windows menues

    • Zeitriss
    • 4. Juli 2016 um 18:50

    Hi,

    Da du anscheinend weißt wie man Controlclick benützt frage ich mich wieso du einen "AutoIt recorder" benützt?

    Benütze WinWaitActive() statt "WinWaitActivate" oder "_WinWaitActivate".
    Letztere gibt es nicht, ich weiß nicht wie du oder der Recorder auf diese Funktionsnamen gekommen seid.

    Zudem Funktioniert so etwas schon garnicht:

    AutoIt
    _WinWaitActivate("Die Konfigurationsdaten wurden erfolgreich gesichert.
    
    
    14 Dateien im Ordner:
    'oC Backup from 2016-07-04 13-45-16'","")


    Ein Zeilenumbruch kann nicht auf diese weise in einen String geschrieben werden, benütze hier ein @CRLF.

    AutoIt
    "Erste Zeile" & @CRLF & "Zweite Zeile"


    Zudem kann ich mir nicht vorstellen, dass diese Zeilen absicht waren:

    AutoIt
    _WinWaitActivate("(Untitled) * SciTE","")
    Send("{SHIFTDOWN}")
    _WinWaitActivate("Program Manager","")
    MouseClick("left",1207,799,2)
    Send("{SHIFTUP}")


    Also zusammengefasst: vergiss den Recorder und benütz AutoIt Window Info x86/x64, oder etwas vergleichbares und schreibe dein Script Manuel, das Ergebniss kann nur besser werden.

    mfg

    Zeitriss

  • In einem Loop die Mausposition verändern

    • Zeitriss
    • 3. Juli 2016 um 13:30

    Hi,

    Man wird dir hier so kaum helfen können.

    Wie Oscar schon sagte:

    Zitat von Oscar

    Eine Maussteuerung um Daten aus Excel auszulesen ist die denkbar schlechteste Lösung!
    Es gibt eine leistungsstarke Excel-UDF (wird mit AutoIt installiert). In der Hilfe findest Du zahlreiche Beispiel-Skripte.
    Ansonsten gibt es noch ein Wiki und ein paar zusätzliche Beispiele.

    Selbes gilt für die Eingabe vom Daten auf Internetseiten und das Abspeichern von Screen Capture.
    Zumal alle Funktionen dafür schon existieren.

    Sie dir mal die Hilfe und Beispiele zu folgenden Funktionen an:

    AutoIt
    #include<IE.au3>
    #include<Excel.au3>
    #include<ScreenCapture.au3>
    
    
    _IECreate()
    _IEFormGetObjByName()
    _IEFormElementGetObjByName()
    _IEFormElementSetValue()
    _IEFormSubmit()
    _IEQuit()
    
    
    _Excel_Open()
    _Excel_BookOpen()
    _Excel_RangeRead()
    _Excel_BookClose()
    _Excel_Close()
    
    
    _ScreenCapture_Capture()
    Alles anzeigen


    mfg

    Zeitriss

  • BricsCAD UDF - Automatisierung von BricsCAD

    • Zeitriss
    • 1. Juli 2016 um 18:10

    Hi,

    BricsCAD ist ein CAD Programm welches genauso wie AutoCAD auf der IntelliCAD Engine basiert.

    https://de.wikipedia.org/wiki/Bricscad

    Ich habe einige Funktionen zum automatisieren von BricsCAD mal in einer UDF umgesetzt.
    Man kann z.B Layer verwalten(erstellen, löschen, ändern, anzeigen), Objekte Zeichnen und Bearbeiten, Zeichnungen öffnen und Schließen, Einstellungen ändern und Befehle in der Commandline ausführen, usw...
    Wenn jemand mit BricsCAD arbeitet kann er es vielleicht ja gebrauchen.

    Es ist das erste mal das ich mich an COM versucht habe, es könnten also ein paar Fehler drin sein ^^
    Freue mich auf eure Meinung, falls es hier überaupt BricsCAD-Nützer gibt.

    BricsCAD.au3

    Beispiele
    AutoIt: Beispiel: Eigenen Layer erzeugen
    #include<BricsCAD.au3>
    
    
    $oBrics = _BricsCAD_Create( True )
    $oDoc = _BricsCAD_GetActiveDocument($oBrics)
    $oMyLayer =_BricsCAD_Layer_Create($oDoc, "MyOwnLayer")
    
    
    _BricsCAD_Layer_SetLinetype($oMyLayer, "MITTE")
    _BricsCAD_Layer_SetLineWeight($oMyLayer, 35)
    _BricsCAD_Layer_SetPlottable($oMyLayer, False)
    
    
    $oColor = _BricsCAD_Layer_GetColor($oMyLayer)
    $oColor.SetRGB(200,0,200)
    _BricsCAD_Layer_SetColor($oMyLayer, $oColor)
    $oColor = 0
    
    
    _BricsCAD_Layer_Delete($oMyLayer)
    
    
    _BricsCAD_Quit($oBrics, True)
    Alles anzeigen
    AutoIt: Beispiel: Zeichnen
    #include<BricsCAD.au3>
    #include<Array.au3>
    
    
    $oBrics = _BricsCAD_Create( True )
    $oDoc = _BricsCAD_GetActiveDocument( $oBrics )
    $oMSpace = _BricsCAD_Document_GetMSpace( $oDoc )
    
    
    _BricsCAD_Ent_CreateLine( $oMSpace,    0,    0,    0,  100,    0,    0)
    MsgBox(0,"","Das...")
    _BricsCAD_Ent_CreateLine( $oMSpace,  100,    0,    0,    0,  100,    0)
    MsgBox(0,"","...ist...")
    _BricsCAD_Ent_CreateLine( $oMSpace,    0,  100,    0,  100,  100,    0)
    MsgBox(0,"","...das...")
    _BricsCAD_Ent_CreateLine( $oMSpace,  100,  100,    0,    0,    0,    0)
    MsgBox(0,"","...Haus...")
    _BricsCAD_Ent_CreateLine( $oMSpace,    0,    0,    0,    0,  100,    0)
    MsgBox(0,"","...vom...")
    _BricsCAD_Ent_CreateLine( $oMSpace,    0,  100,    0,   50,  150,    0)
    MsgBox(0,"","...Ni-...")
    _BricsCAD_Ent_CreateLine( $oMSpace,   50,  150,    0,  100,  100,    0)
    MsgBox(0,"","...-ko-...")
    _BricsCAD_Ent_CreateLine( $oMSpace,  100,  100,    0,  100,    0,    0)
    MsgBox(0,"","...-laus...")
    
    
    _BricsCAD_Ent_CreateCircle( $oMSpace,  50,  66.7,    0,  83.3)
    $oMText = _BricsCAD_Ent_CreateMText( $oMSpace, 0, -50, 0, 200, "Haus vom Nikolaus")
    _BricsCAD_Ent_SetHeight( $oMText, 20)
    $oMText = 0
    $aEnts = _BricsCAD_Ent_List( $oMSpace )
    Global $aShow[ @extended ][7]
    For $i = 0 to @extended -1
       $aShow[$i][0] = _BricsCAD_Ent_GetClassName( $aEnts[$i] )
       $aStartPoint = _BricsCAD_Ent_GetStartPoint( $aEnts[$i] )
       $aEndPoint = _BricsCAD_Ent_GetEndPoint( $aEnts[$i] )
       If IsArray($aStartPoint) and IsArray($aEndPoint) Then
    	  $aShow[$i][1] = $aStartPoint[0]
    	  $aShow[$i][2] = $aStartPoint[1]
    	  $aShow[$i][3] = $aStartPoint[2]
    	  $aShow[$i][4] = $aEndPoint[0]
    	  $aShow[$i][5] = $aEndPoint[1]
    	  $aShow[$i][6] = $aEndPoint[2]
       EndIf
    Next
    
    
    _ArrayDisplay($aShow)
    
    
    _BricsCAD_Quit( $oBrics, True )
    Alles anzeigen

    mfg


    Zeitriss

  • GDI+ Element klonen

    • Zeitriss
    • 30. Juni 2016 um 01:16

    Hi,

    _GDIPlus_BitmapCloneArea() erstellt neue Bitmaps, das ist nicht das was du suchst und du solltest auf gar keinen Fall neue Bitmaps in einer Schleife erstellen ohne sie wieder freizugeben.

    Benütze stattdessen _GDIPlus_GraphicsFillRect in der Schleife.

    mfg

    Zeitriss

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™