1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. water

Beiträge von water

  • Anomalie _IECreate MSIE9 AtMail (Webmail)

    • water
    • 7. April 2012 um 12:21
    Zitat von wirr4all

    ... und nicht über sinnlosen texten brüten muss ...

    Wieso sinnlos? Hier versuchen alle dem OP zu helfen und ihn an den bereits gemachten Erfahrungen teilhaben zu lassen. Die Hinweise der Forumuser bringen ihn mit der Zeit auch dahin, dass er verlässliche Skripte schreiben kann. Damit es dann nicht mehr heissen muss: "Mein Skript funktioniert nur 9 von 10 mal ..."

  • Anomalie _IECreate MSIE9 AtMail (Webmail)

    • water
    • 7. April 2012 um 12:03

    Wo es auch immer wieder Probleme gibt:
    Wenn Windows 64 bit ist und die Applikation die über COM angesprochen wird ist 32 bit, dann muss das AutoIt Skript für 32 bit übersetzt/ausgeführt werden.

  • Anomalie _IECreate MSIE9 AtMail (Webmail)

    • water
    • 7. April 2012 um 11:45
    Zitat

    Mit meinem Script will ich mich automatisch (mittels AutoIt) im Webmail einloggen.

    Ich interpretiere das als: IE starten, WebSite aufrufen, Name und Passwort eingeben und einen Button drücken.
    Das Füllen der Formularfelder etc. passiert derzeit mit Send und Sleep. Jetztr braucht nur der IE etwas länger zu brauchen, eine andere Anwendung den Focus wegzunehmen und schon funktioniert das Spiel nicht mehr ... Daher: Formularfelder füllen und Buttonklicks auch mit dem IE UDF.

  • Anomalie _IECreate MSIE9 AtMail (Webmail)

    • water
    • 7. April 2012 um 10:53

    Der "Send" und "Sleep" Teil in Deinem Skript ist doch ziemlich trial-and-error. Mach doch auch diese Funktionen mit dem IE UDF. Das funktioniert dann verlässlicher.

  • LDAP Abfrage in Word schreiben DC Windows 2008 in AD

    • water
    • 6. April 2012 um 16:18

    Hier nun die aktuellste Version. Ausdruck nach Name oder Abteilung (darum 2 Druck Buttons).
    Die ListView kann durch klicken auf die Spaltenüberschriften sortiert werden.

    Spoiler anzeigen
    [autoit]

    #region ;**** Directives created by AutoIt3Wrapper_GUI ****
    #AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
    #AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
    #endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
    #AutoIt3Wrapper_Run_Debug_Mode=N
    #include-once
    #include <AD.au3>
    #include <ButtonConstants.au3>
    #include <Excel.au3>
    #include <GuiConstantsEx.au3>
    #include <GuiListView.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $sName = "", $sTitle = "Telefonnummernabfrage BST"
    Global $sVersion = "0.7 beta", $sAutor = "water", $sVDatum = "2012/04/06"
    Global $sLDAPName, $sLDAPAbteilung, $asResult, $nMsg, $sAbteilung, $sSelected
    Global $oExcel, $iMaxRow, $iFirstRow, $sFirstLetter
    Global Const $xlDown = -4121
    Global $sLogoFile = "", $sSaveFile = "C:\temp\Telefonbuch"

    [/autoit] [autoit][/autoit] [autoit]

    #region ### START Koda GUI section ### Form=
    Global $hForm = GUICreate($sTitle, 615, 440, 192, 124)
    GUICtrlCreateLabel("Name:", 10, 24, 35, 17)
    Global $hInputName = GUICtrlCreateInput("", 64, 22, 225, 21)
    GUICtrlCreateLabel("Abteilung:", 10, 59, 51, 17)
    Global $hInputAbteilung = GUICtrlCreateInput("", 64, 57, 225, 21)
    Global $hBtn_OK = GUICtrlCreateButton("OK", 304, 22, 41, 21)
    GUICtrlSetTip(-1, "Abfrage starten")
    Global $hBtn_Help = GUICtrlCreateButton("?", 358, 22, 41, 21)
    GUICtrlSetTip(-1, "Hilfe")
    Global $hBtn_info = GUICtrlCreateButton("Info", 412, 22, 41, 21)
    GUICtrlSetTip(-1, "Programminfo")
    Global $hBtn_TF = GUICtrlCreateButton("TF", 466, 22, 41, 21)
    GUICtrlSetTip(-1, "??")
    Global $hBtn_Exit = GUICtrlCreateButton("Exit", 536, 22, 65, 21)
    GUICtrlSetTip(-1, "Programm beenden")
    Global $hBtn_Copy = GUICtrlCreateButton("Copy", 358, 57, 41, 21)
    GUICtrlSetTip(-1, "Datensatz in Zwischenablage")
    Global $hBtn_DruckN = GUICtrlCreateButton("Druck", 412, 57, 41, 21)
    GUICtrlSetTip(-1, "Ergebnis drucken - Nach Name sortiert")
    Global $hBtn_DruckA = GUICtrlCreateButton("Druck", 466, 57, 41, 21)
    GUICtrlSetTip(-1, "Ergebnis drucken - Nach Abteilung sortiert")
    Global $hList = GUICtrlCreateListView("Name|Abteilung|Telefon Büro|Handy", 8, 96, 601, 336)
    ; Set accelerators for Enter
    Global $AccelKeys[2][2] = [["{ENTER}", $hBtn_OK],["^c", $hBtn_Copy]]
    GUISetAccelerators($AccelKeys)
    GUISetState(@SW_SHOW)
    #endregion ### END Koda GUI section ###

    [/autoit] [autoit][/autoit] [autoit]

    _GUICtrlListView_RegisterSortCallBack($hList)

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE, $hBtn_Exit
    ExitLoop
    Case $hBtn_OK, 3
    $sName = StringStripWS(GUICtrlRead($hInputName), 3)
    $sAbteilung = StringStripWS(GUICtrlRead($hInputAbteilung), 3)
    If $sName <> "" Or $sAbteilung <> "" Then _Process()
    Case $hBtn_Help
    MsgBox(64, "About", $sTitle & @CRLF & @CRLF & "Programm written by ... " & _
    @CRLF & @CRLF & "Version: " & $sVersion & @CRLF & "Autor: " & $sAutor & @CRLF & "Date: " & $sVDatum)
    Case $hBtn_TF
    ShellExecute("tf.pdf")
    Case $hBtn_info
    ShellExecute("info.pdf")
    Case $hBtn_Copy
    _Copy()
    Case $hBtn_DruckN
    _Druck($asResult, "N")
    Case $hBtn_DruckA
    _Druck($asResult, "A")
    Case $hList
    _GUICtrlListView_SortItems($hList, GUICtrlGetState($hList))
    EndSwitch
    WEnd
    _GUICtrlListView_UnRegisterSortCallBack($hList)

    [/autoit] [autoit][/autoit] [autoit]

    Func _Process()

    [/autoit] [autoit][/autoit] [autoit]

    _GUICtrlListView_BeginUpdate($hList)
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($hList)) ; Clear the ListView
    _AD_Open()
    If @error Then Exit MsgBox(16, $sTitle, "Error: " & @error & " bei Erstellung der Verbindung zum Active Directory!")
    $sLDAPName = ""
    $sLDAPAbteilung = ""
    If $sName <> "" Then
    $sLDAPName = "(name=" & $sName
    If $sName <> "*" Then $sLDAPName &= "*"
    $sLDAPName &= ")"
    EndIf
    If $sAbteilung <> "" Then $sLDAPAbteilung = "(department=" & $sAbteilung & "*)"
    $asResult = _AD_GetobjectsInOU("", "(&(objectcategory=person)(objectclass=user)" & $sLDAPName & $sLDAPAbteilung & "(telephoneNumber=*)(!userAccountControl:1.2.840.113556.1.4.803:=" & $ADS_UF_ACCOUNTDISABLE & "))", 2, "name,department,telephoneNumber,mobile", "name")
    Select
    Case @error = 0
    For $i = 1 To $asResult[0][0]
    GUICtrlCreateListViewItem($asResult[$i][0] & "|" & $asResult[$i][1] & "|" & $asResult[$i][2] & "|" & $asResult[$i][3], $hList)
    Next
    Case @error = 3
    MsgBox(16, $sTitle, "Name '" & $sName & "' wurde nicht gefunden!")
    Case Else
    MsgBox(16, $sTitle, "Error: " & @error & " bei Abfrage nach Name '" & $sName & "'!")
    EndSelect
    _GUICtrlListView_SetColumnWidth($hList, 0, $LVSCW_AUTOSIZE)
    _GUICtrlListView_SetColumnWidth($hList, 1, $LVSCW_AUTOSIZE)
    _GUICtrlListView_SetColumnWidth($hList, 2, $LVSCW_AUTOSIZE)
    _GUICtrlListView_SetColumnWidth($hList, 3, $LVSCW_AUTOSIZE)
    _GUICtrlListView_EndUpdate($hList)
    _AD_Close()

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>_Process

    [/autoit] [autoit][/autoit] [autoit]

    Func _Copy()

    [/autoit] [autoit][/autoit] [autoit]

    Local $IDItem = GUICtrlRead($hList)
    If $IDItem = 0 Then Return
    $sSelected = GUICtrlRead($IDItem)
    $sSelected = StringLeft($sSelected, StringLen($sSelected) - 1) ; letztes | entfernen
    $sSelected = StringReplace($sSelected, "|", @TAB) ; | in @Tab umwandeln
    ClipPut($sSelected) ; In Zwischenablage schreiben

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>_Copy

    [/autoit] [autoit][/autoit] [autoit]

    Func _Druck($avArray, $sType)

    [/autoit] [autoit][/autoit] [autoit]

    ProgressOn($sTitle, "Telefonbuch drucken", "", -1, -1, 16)
    ProgressSet(10, "", "Excel Arbeitsblatt verarbeiten")
    ; Open Excel Worksheet
    $oExcel = _ExcelBookNew(0)
    $oExcel.ScreenUpdating = False
    ; Ziffern als Text formatieren
    $oExcel.Activesheet.Columns("C:D").NumberFormat = "@"
    ; Daten nach Excel kopieren
    ProgressSet(25, "", "Excel Arbeitsblatt Daten importieren")
    ; _ExcelWriteSheetFromArray($oExcel, $avArray, 2, 1, 1, 0)
    Local $avArrayTransposed = $oExcel.transpose($avArray)
    ; Copy data to Excel. Taken from http://www.avdf.com/apr98/art_ot003.html
    $oExcel.Range("A1:A1").Resize(UBound($avArray, 1), UBound($avArray, 2)) = $avArrayTransposed
    _ExcelWriteCell($oExcel, "Name", "A1")
    _ExcelWriteCell($oExcel, "Abteilung", "B1")
    _ExcelWriteCell($oExcel, "Telefon Büro", "C1")
    _ExcelWriteCell($oExcel, "Handy", "D1")
    ProgressSet(50, "", "Excel Arbeitsblatt Daten gruppieren")
    ; Jeweils Anfangsbuchstaben oder Abteilung markieren
    $iMaxRow = $oExcel.ActiveSheet.UsedRange.Rows.Count
    $iFirstRow = 2
    If $sType = "N" Then ; Nach Name gruppieren
    _ExcelSortExtended($oExcel, "A1", 1, 1, $iMaxRow, 4, 1, 1, False, 1) ; Nach Name sortieren
    For $i = $iMaxRow To $iFirstRow Step -1
    $sFirstLetter = StringLeft($oExcel.ActiveSheet.Range("A" & $i).Value, 1)
    If $i = $iFirstRow Or $sFirstLetter <> StringLeft($oExcel.ActiveSheet.Range("A" & $i - 1).Value, 1) Then
    $oExcel.ActiveSheet.Range("A" & $i).EntireRow.Insert($xlDown)
    $oExcel.ActiveSheet.Range("A" & $i).Value = $sFirstLetter
    $oExcel.Activesheet.Range("A" & $i).Interior.ColorIndex = 15 ; Grau hinterlegen
    $oExcel.Activesheet.Range("A" & $i).Font.Bold = True
    EndIf
    Next
    Else
    _ExcelSortExtended($oExcel, "B1", 1, 1, $iMaxRow, 4, 1, 1, False, 1) ; Nach Abteilung sortieren
    For $i = $iMaxRow To $iFirstRow Step -1
    $sFirstLetter = $oExcel.ActiveSheet.Range("B" & $i).Value
    If $i = $iFirstRow Or $sFirstLetter <> $oExcel.ActiveSheet.Range("B" & $i - 1).Value Then
    $oExcel.ActiveSheet.Range("B" & $i).EntireRow.Insert($xlDown)
    $oExcel.ActiveSheet.Range("B" & $i).Value = $sFirstLetter
    $oExcel.Activesheet.Range("B" & $i).Interior.ColorIndex = 15 ; Grau hinterlegen
    $oExcel.Activesheet.Range("B" & $i).Font.Bold = True
    EndIf
    Next
    EndIf
    ProgressSet(75, "", "Excel Arbeitsblatt Daten formatieren")
    ; Erste Zeile fett drucken
    _ExcelFontSetProperties($oExcel, "A1:D1", 1, 1, 1, True)
    ; Erste Zeile grau hinterlegen
    $oExcel.Activesheet.Range("A1:D1").Interior.ColorIndex = 15
    ; Schriftgröße auf 10 setzen
    $oExcel.Range("A:Z").Font.Size = 10
    ; Erste Spalte fett drucken
    _ExcelFontSetProperties($oExcel, "A:A", 1, 1, 1, True)
    ; Spaltenbreite festlegen
    $oExcel.Activesheet.Columns("A:D").AutoFit
    ; Alle Spalten links ausrichten
    $oExcel.Activesheet.Columns("A:D").HorizontalAlignment = 2
    $oExcel.ActiveSheet.Range("A1").Select
    With $oExcel.Activesheet.PageSetup
    ; Ränder setzen. Angabe in Punkt (1pt=0.035cm). http://msdn.microsoft.com/en-us/library/…gin(VS.80).aspx
    .TopMargin = 40
    .BottomMargin = 40
    .HeaderMargin = 18
    .FooterMargin = 18
    .LeftMargin = 45
    .RightMargin = 22
    ; Breite reduzieren so dass alle auf 1 Seite passt
    .FitToPagesWide = 1
    .FitToPagesTall = False
    .Zoom = False
    ; Gitternetzlinien
    .PrintGridlines = True
    ; Set the rows to print on every page
    .PrintTitleRows = "1:1"
    ; Seitentitel setzen
    .LeftHeader = "&"",Fett""&12Telefonbuch BST"
    .RightHeader = "Stand: " & @MDAY & "." & @MON & "." & @YEAR
    .RightFooter = "Seite &S von &A"
    .LeftFooter = "Gedruckt: &D &U"
    EndWith
    ; Titelblatt einfügen
    _ExcelSheetAddNew($oExcel, "Titelseite")
    $oExcel.Activesheet.Columns("A").ColumnWidth = 77.25
    With $oExcel.Activesheet.PageSetup
    ; Ränder setzen. Angabe in Punkt (1pt=0.035cm). http://msdn.microsoft.com/en-us/library/…gin(VS.80).aspx
    .TopMargin = 72
    .BottomMargin = 72
    .HeaderMargin = 38
    .FooterMargin = 38
    .LeftMargin = 58
    .RightMargin = 58
    ; Breite reduzieren so dass alle auf 1 Seite passt
    .FitToPagesWide = 1
    .FitToPagesTall = False
    .Zoom = False
    EndWith
    ; Alle Spalten zentrieren
    $oExcel.Activesheet.Columns("A:A").HorizontalAlignment = 3
    ; Höhe der Zeilen festlegen
    $oExcel.Activesheet.Rows("1:1").RowHeight = 182
    $oExcel.Activesheet.Rows("2:2").RowHeight = 27
    $oExcel.Activesheet.Rows("3:3").RowHeight = 45
    $oExcel.Activesheet.Rows("4:4").RowHeight = 58
    $oExcel.Activesheet.Rows("5:5").RowHeight = 84
    #cs
    ; Bild einfügen
    $oExcel.Range("A1").Select
    $oExcel.ActiveSheet.Pictures.Insert($sLogoFile).Select
    $oExcel.Selection.ShapeRange.Height = 44.57
    $oExcel.Selection.ShapeRange.Width = 391.71
    $oExcel.Selection.ShapeRange.Left = 40
    $oExcel.Selection.ShapeRange.Top = 25
    #ce
    ; Texte eingeben
    $oExcel.ActiveSheet.Range("A2").Font.Size = 20
    _ExcelWriteCell($oExcel, "Telefonbuch", "A2")
    _ExcelFontSetProperties($oExcel, "A2", 1, 1, 1, True)
    _ExcelWriteCell($oExcel, "von", "A3")
    _ExcelWriteCell($oExcel, "BST", "A4")
    _ExcelWriteCell($oExcel, "Stand: " & @MDAY & "." & @MON & "." & @YEAR, "A6")
    ; Arbeitsblatt speichern
    ; _ExcelBookSaveAs($oExcel, "C:\temp\telefonbuch", "xls", 0, 1)
    ; Datei als PDF speichern
    $oExcel.ActiveWorkbook.ExportAsFixedFormat(0, $sSaveFile & ".pdf")
    _ExcelBookClose($oExcel, 0, 0)
    ProgressSet(100, "", "FERTIG")
    ProgressOff()
    MsgBox(64, $sTitle, "Gesichert als " & @CRLF & $sSaveFile & ".pdf", 3)
    ShellExecute($sSaveFile & ".pdf")

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>_Druck

    [/autoit] [autoit][/autoit] [autoit]

    ;===============================================================================
    ; Description: Performs an advanced sort on a range.
    ; Syntax: _ExcelSortExtended($oExcel, $sKey, $sRangeOrRowStart, $iColStart = 1, $iRowEnd = 1, $iColEnd = 1, _
    ; $iDirection = 2, $iHeader = 0, $fMatchCase = False, $iOrientation = 2, $iDataOption = 0)
    ; Parameter(s): $oExcel - An Excel object opened by a preceding call to _ExcelBookOpen() or _ExcelBookNew()
    ; $sKey - The key column or row to sort by (in A1 format)
    ; $sRangeOrRowStart - Either an A1 range, or an integer row number to start from if using R1C1
    ; $iColStart - The starting column for the number format(left) (default=1)
    ; $iRowEnd - The ending row for the number format (bottom) (default=1)
    ; $iColEnd - The ending column for the number format (right) (default=1)
    ; $iDirection - Sort direction (1=Ascending, 2=Descending) (default=descending)
    ; $iHeader - Assume sort data has a header? (1=yes, 2=No, 0=guess) (default=guess)
    ; $fMatchCase - Match case when performing sort (True|False)
    ; $iOrientation - Specify how sort data is arranged (1=sort columns, 2=sort rows) (default=sort rows)
    ; $iDataOption - Specify how sort will treat data (0=sort normal, 1=sort text as numbers) (default = sort normal)
    ; Requirement(s): None
    ; Return Value(s): On Success - Returns 1
    ; On Failure - Returns 0 and sets @error on errors:
    ; @error=1 - Specified object does not exist
    ; @error=2 - Starting row or column invalid
    ; @extended=0 - Starting row invalid
    ; @extended=1 - Starting column invalid
    ; @error=3 - Ending row or column invalid
    ; @extended=0 - Ending row invalid
    ; @extended=1 - Ending column invalid
    ; Author(s): SEO <locodarwin at yahoo dot com>, many thanks to DaLiMan
    ; Note(s): This sort routine will not function properly with pivot tables. Please
    ; use the pivot table sorting functions instead.
    ; Link: http://www.autoitscript.com/forum/topic/96…elsortextended/
    ;===============================================================================
    Func _ExcelSortExtended($oExcel, $sKey, $sRangeOrRowStart, $iColStart = 1, $iRowEnd = 1, $iColEnd = 1, $iDirection = 2, $iHeader = 0, $fMatchCase = False, $iOrientation = 2, $iDataOption = 0)
    If Not IsObj($oExcel) Then Return SetError(1, 0, 0)
    If Not StringRegExp($sRangeOrRowStart, "[A-Z,a-z]", 0) Then
    If $sRangeOrRowStart < 1 Then Return SetError(2, 0, 0)
    If $iColStart < 1 Then Return SetError(2, 1, 0)
    If $iRowEnd < $sRangeOrRowStart Then Return SetError(3, 0, 0)
    If $iColEnd < $iColStart Then Return SetError(3, 1, 0)
    $oExcel.Range($oExcel.Cells($sRangeOrRowStart, $iColStart), $oExcel.Cells($iRowEnd, $iColEnd)).Sort _
    ($oExcel.Range($sKey), $iDirection, $oExcel.Range($sKey), Default, $iDirection, $oExcel.Range($sKey), _
    $iDirection, $iHeader, True, $fMatchCase, $iOrientation, Default, $iDataOption)
    Else
    $oExcel.Range($sRangeOrRowStart).Sort($oExcel.Range($sKey), $iDirection, $oExcel.Range($sKey), Default, _
    $iDirection, $oExcel.Range($sKey), $iDirection, $iHeader, True, $fMatchCase, $iOrientation, Default, $iDataOption)
    EndIf
    Return 1
    EndFunc ;==>_ExcelSortExtended

    [/autoit]
  • AutoIt und TAPI

    • water
    • 3. April 2012 um 18:03

    Ich habe mal ein bestehendes VB Skript auf AutoIt umgebaut mit dem denn eine Nummer gewählt werden konnte.
    Kommt also drauf an, was Du machen möchtest.

  • Connect auf Oracle 11r2 Database

    • water
    • 3. April 2012 um 12:26

    Richtig: Muss auch "Func MyErrFunc(($oError)" statt "Func _ErrFunc($oError)" heissen.

  • Connect auf Oracle 11r2 Database

    • water
    • 3. April 2012 um 12:08

    Ersetz die Funktion _MyErrFunc mal mit dieser:

    [autoit]

    Func _ErrFunc($oError)
    MsgBox(16, "COM Error handler", "err.number is: " & @TAB & $oError.number & @CRLF & _
    "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
    "err.description is: " & @TAB & $oError.description & @CRLF & _
    "err.source is: " & @TAB & $oError.source & @CRLF & _
    "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
    "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
    "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
    "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
    "err.retcode is: " & @TAB & $oError.retcode & @CRLF & @CRLF)
    EndFunc ;==>_ErrFunc

    [/autoit]
  • Connect auf Oracle 11r2 Database

    • water
    • 3. April 2012 um 11:33

    Was Du auf jeden Fall brauchst ist: Mehr Fehlerprüfungen!
    Was zusätzlich hilft ist ein COM error handler!

    Details folgen später.

  • Connect auf Oracle 11r2 Database

    • water
    • 3. April 2012 um 11:10

    Dann poste doch mal Deinen Code.

  • Connect auf Oracle 11r2 Database

    • water
    • 3. April 2012 um 11:03
    Zitat von CrazyER

    Als Benutzer- oder System DSN ?? ;o))

    Egal.

  • Connect auf Oracle 11r2 Database

    • water
    • 3. April 2012 um 10:56

    So wie ich das verstehe muss die angegebene "Data Source" mit "odbcad32" definiert werden.

  • Connect auf Oracle 11r2 Database

    • water
    • 3. April 2012 um 10:36

    Durchsuch das Forum mal nach "Oracle". Da kriegst Du eine ganze Liste an Ergebnissen z.B. das hier .

  • Outlook-Regel als Parameter übergeben?

    • water
    • 31. März 2012 um 12:14

    Hallo Dino,

    hier ein erster Versuch. Doku etc. noch unvollständig aber die Beispiele funktionieren.
    Die Beispiele durchsuchen die Inbox nach den in den Variablen $sStringx angegebenen Inhalten. Bitte einfach diese Variablen für Deine Umgebung anpassen.

    Spoiler anzeigen
    [autoit]

    #AutoIt3Wrapper_AU3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
    #AutoIt3Wrapper_AU3Check_Stop_OnWarning=Y
    #include <OutlookEX.au3>
    $iOL_Debug = 2

    [/autoit] [autoit][/autoit] [autoit]

    ; *****************************************************************************
    ; Create test environment
    ; *****************************************************************************
    Global $oOutlook = _OL_Open()
    If @error Then Exit MsgBox(16, "OutlookEX UDF - _OL_ItemSearch Example Script", "Error running _OL_Open. @error = " & @error & ", @extended = " & @extended)
    ;Global $iResult = _OL_TestEnvironmentCreate($oOutlook)
    ;If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF - Manage Test Environment", "Error creating the test environment. @error = " & @error)
    Global $aFolder = _OL_FolderAccess($oOutlook, "", $olFolderInbox)
    If @error Then Exit MsgBox(16, "OutlookEX UDF - _OL_ItemSearch Example Script", "Error running _OL_Open. @error = " & @error & ", @extended = " & @extended)

    [/autoit] [autoit][/autoit] [autoit]

    ; *****************************************************************************
    ; Example 1
    ; Search the subject of mail items containing $sString1 or
    ; starting with $sString2
    ; Returns: Subject, CreationTime, Sendername
    ; *****************************************************************************
    Global $sString1 = "nicht", $sString2 = "DEMI"
    Global $aSearchArray[3][4] = [[2, 4],[0x0037001E, 3, $sString1, "or"],["subject", 2, $sString2, ""]]
    Global $aResult = _OL_ItemSearch($oOutlook, $aFolder[1], $olMail, $aSearchArray, "subject,CreationTime,Sendername")
    If @error Then
    MsgBox(16, "OutlookEX UDF - _OL_ItemSearch Example Script", "Error running _OL_ItemSearch. @error = " & @error & ", @extended = " & @extended)
    Else
    _Arraydisplay($aResult, "Example 1")
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ; *****************************************************************************
    ; Example 2
    ; Same as example 1 but filter specified in DASL format
    ; Returns: EntryID, Subject, CreationTime, Sendername
    ; *****************************************************************************
    Global $sFilter = "@SQL=""http://schemas.microsoft.com/mapi/proptag/0x0037001E"" ci_phrasematch '" & $sString1 & "' or ""http://schemas.microsoft.com/mapi/proptag/0x0037001E"" ci_startswith '" & $sString2 & "'"
    $aResult = _OL_ItemSearch($oOutlook, $aFolder[1], $olMail, $sFilter, "EntryID,Subject,CreationTime,Sendername")
    If @error Then
    MsgBox(16, "OutlookEX UDF - _OL_ItemSearch Example Script", "Error running _OL_ItemSearch. @error = " & @error & ", @extended = " & @extended)
    Else
    _Arraydisplay($aresult, "Example 2")
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ; *****************************************************************************
    ; Example 3
    ; Search the subject of mail items with exact matching $sString3
    ; Returns: EntryID, Subject
    ; *****************************************************************************
    Global $sString3 = "cert"
    Global $aSearchArray[2][4] = [[1, 4],[0x0037001E, 1, $sString3]]
    $aResult = _OL_ItemSearch($oOutlook, $aFolder[1], $olMail, $aSearchArray, "EntryID,Subject")
    If @error Then
    MsgBox(16, "OutlookEX UDF - _OL_ItemSearch Example Script", "Error running _OL_ItemSearch. @error = " & @error & ", @extended = " & @extended)
    Else
    _Arraydisplay($aresult, "Example 3")
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ; *****************************************************************************
    ; Example 4
    ; Search the body of mail items for phrase $sString4
    ; Returns: EntryID, Subject, max 255 characters of the body
    ; *****************************************************************************
    Global $sString4 = "Kamera"
    $sFilter = "@SQL=""urn:schemas:httpmail:textdescription"" ci_phrasematch '" & $sString4 & "'"
    $aResult = _OL_ItemSearch($oOutlook, $aFolder[1], $olMail, $sFilter, "EntryID,Subject,urn:schemas:httpmail:textdescription")
    If @error Then
    MsgBox(16, "OutlookEX UDF - _OL_ItemSearch Example Script", "Error running _OL_ItemSearch. @error = " & @error & ", @extended = " & @extended)
    Else
    _Arraydisplay($aresult, "Example 4")
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    _OL_Close($oOutlook)
    Exit

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ====================================================================================================================
    ; Name ..........: _OL_ItemSearch
    ; Description ...: Find items (extended search) using a DASL query returning an array of all specified properties.
    ; Syntax.........: _OL_ItemSearch($oOL, $vOL_Folder, $iOL_ObjectClass, $avOL_Search, $sOL_ReturnProperties[, $sOL_Sort = ""[, $iOL_Flags = 0]])
    ; Parameters ....: $oOL - Outlook object returned by a preceding call to _OL_Open()
    ; $vOL_Folder - Folder object as returned by _OL_FolderAccess or full name of folder where the search will be started.
    ; +If you want to search a default folder you have to specify the folder object.
    ; $iOL_ObjectClass - Class of items to search for. Defined by the Outlook OlObjectClass enumeration (default = Default = $olContact)
    ; $avOL_Search - Can bei either a string containing the full DASL query or a one based two-dimensional array with unlimited number of rows containing the elements to build the DASL query:
    ; |0: Property to query. This can be either the hex value or the name of the property. The function transaltes the name to the hex value. Unknown names set @error
    ; |1: Type of comparison operator: 1 = "=", 2 = "ci_startswith", 3 = "ci_phrasematch", 3 = "like"
    ; |2: Value to search for
    ; |3: Operator to concatenate the next comparison. Has to be "and", "or", "or not" or "and not"
    ; For details please see Remarks
    ; $sOL_ReturnProperties - Comma separated list of properties to return. Can be the property name (e.g. "subject") or the MAPI proptag (e.g. "http://schemas.microsoft.com/mapi/proptag/0x10F4000B")
    ; $sOL_Sort - Optional: Property to sort the result on plus optional flag to sort descending (default = None). E.g. "[Subject], True" sorts the result descending on the subject
    ; $iOL_Flags - Optional: Flags to set different processing options. Can be a combination of the following:
    ; |1: Subfolders will be included
    ; |2: Row 1 contains column headings. Therefore the number of rows/columns in the table has to be calculated using UBound
    ; |4: Just return the number of records. You don't get an array, just a single integer denoting the total number of records found
    ; Return values .: Success - One based two-dimensional array with the properties specified by $sOL_ReturnProperties
    ; Failure - Returns "" and sets @error:
    ; |1 - $oOL is not an object
    ; |2 - Error accessing the specified folder. See @extended for errorcode returned by _OL_FolderAccess
    ; |3 - $iOL_ObjectClass is not an integer
    ; |4 - $avOL_Search is an array but not a two dimensional array or the first row doesn't contain the numbers of rows and columns
    ; |5 - $sOL_ReturnProperties is empty
    ; |6 - Specified search property could not be translated to a hex code. @extended is set to the row in $avOL_Search
    ; |7 - Specified search operator is not an integer or < 1 or > 3. @extended is set to the row in $avOL_Search
    ; |8 - Specified search value is empty. @extended is set to the row in $avOL_Search
    ; |9 - Error splitting $sOL_ReturnProperties
    ; |10 - Error adding $sOL_ReturnProperties to the result set. @extended is the number of the property in error
    ; |11 - Invalid search operator. Must be "and" or "or". @extended is set to the row in $avOL_Search
    ; |12 - The last entry in the search array has a search operator
    ; |13 - The entry in the search array has no operator but more search arguments follow
    ; |14 - Error executing the search operation. @extended is set to the error returned by method GetTable
    ; |15 - No records returned by the search operation
    ; Author ........: water
    ; Modified ......:
    ; Remarks .......: DASL syntax: "Searching Outlook Data" - http://msdn.microsoft.com/en-us/library/cc513841.aspx"
    ; List of MAPI proptags: - http://www.dimastr.com/redemption/enum_MAPITags.htm
    ; Related .......:
    ; Link ..........:
    ; Example .......: Yes
    ; ===============================================================================================================================
    Func _OL_ItemSearch($oOL, $vOL_Folder, $iOL_ObjectClass, $avOL_Search, $sOL_ReturnProperties);, $sOL_Sort = "", $iOL_Flags = 0)

    [/autoit] [autoit][/autoit] [autoit]

    Local $asOL_Operator[5] = [4, "=", "ci_startswith", "ci_phrasematch", "like"]
    Local $sOL_Filter = '@SQL=', $aOL_Temp, $sOL_Property, $iOL_Rows, $iOL_Cols, $oOL_Row
    If Not IsObj($oOL) Then Return SetError(1, 0, "")
    If Not IsObj($vOL_Folder) Then
    $aOL_Temp = _OL_FolderAccess($oOL, $vOL_Folder)
    If @error Then Return SetError(2, @error, "")
    $vOL_Folder = $aOL_Temp[1]
    EndIf
    If Not IsInt($iOL_ObjectClass) Then Return SetError(3, 0, "")
    If StringStripWs($sOL_ReturnProperties, 7) = "" Then Return SetError(5, 0, "")
    Local $aOL_ReturnProperties = StringSplit(StringStripWS($sOL_ReturnProperties, 8), ",")
    If @error Then Return SetError(9, 0, "")
    ; Build search string
    If IsArray($avOL_Search) Then
    If UBound($avOL_Search, 0) <> 2 Or Not IsInt($avOL_Search[0][0]) Or Not IsInt($avOL_Search[0][1]) Then Return SetError(4, 0, "")
    Local Const $sPropTag = "http://schemas.microsoft.com/mapi/proptag/"
    For $iOL_Index = 1 To $avOL_Search[0][0]
    If IsInt($avOL_Search[$iOL_Index][0]) Then
    $sOL_Property = "0x" & Hex(Int($avOL_Search[$iOL_Index][0]))
    Else
    $sOL_Property = __OL_Property2Hex($avOL_Search[$iOL_Index][0])
    If @error Then Return SetError(6, $iOL_Index, "")
    Endif
    If Not IsInt($avOL_Search[$iOL_Index][1]) Or $avOL_Search[$iOL_Index][1] < 1 Or $avOL_Search[$iOL_Index][1] > 3 Then Return SetError(7, $iOL_Index, "")
    $avOL_Search[$iOL_Index][2] = StringStripWS($avOL_Search[$iOL_Index][2], 7)
    If $avOL_Search[$iOL_Index][2] = "" Then Return SetError(8, $iOL_Index, "")
    $avOL_Search[$iOL_Index][3] = StringStripWS($avOL_Search[$iOL_Index][3], 7)
    If $avOL_Search[$iOL_Index][3] <> "" Then
    If $avOL_Search[$iOL_Index][3] <> "and" And $avOL_Search[$iOL_Index][3] <> "or" And _
    $avOL_Search[$iOL_Index][3] <> "and not" And $avOL_Search[$iOL_Index][3] <> "or not" _
    Then Return SetError(11, $iOL_Index, "")
    If $iOL_Index = $avOL_Search[0][0] Then Return SetError(12, $iOL_Index, "")
    Else
    If $iOL_Index < $avOL_Search[0][0] Then Return SetError(13, $iOL_Index, "")
    EndIf
    $sOL_Filter = $sOL_Filter & '"' & $sPropTag & $sOL_Property & '" ' & $asOL_Operator[$avOL_Search[$iOL_Index][1]] & " '" & $avOL_Search[$iOL_Index][2] & "'"
    If $avOL_Search[$iOL_Index][3] <> "" Then $sOL_Filter = $sOL_Filter & " " & $avOL_Search[$iOL_Index][3] & " "
    Next
    Else
    $sOL_Filter = $avOL_Search
    EndIf
    ; execute the search
    Local $oOL_Table = $vOL_Folder.GetTable($sOL_Filter)
    If @error Or Not IsObj($oOL_Table) Then Return SetError(14, @error, "")
    If $oOL_Table.GetRowCount = 0 Then Return SetError(15, 0, "")
    ; http://msdn.microsoft.com/en-us/library/…fice.12%29.aspx
    ; Remove all columns in the default column set
    $oOL_Table.Columns.RemoveAll
    ; Specify desired properties
    For $iOL_Index = 1 To $aOL_ReturnProperties[0]
    $oOL_Table.Columns.Add($aOL_ReturnProperties[$iOL_Index])
    If @error Then Return SetError(10, $iOL_Index, "")
    Next
    ; Create and fill the result table
    $iOL_Rows = $oOL_Table.GetRowCount + 1
    If @error Then Return SetError(14, @error, "")
    $iOL_Cols = $aOL_ReturnProperties[0]
    Local $avOL_Result[$iOL_Rows][$iOL_Cols] = [[$iOL_Rows - 1, $iOL_Cols]]
    Local $iOL_Index2 = 1
    While Not $oOL_Table.EndOfTable
    $oOL_Row = $oOL_Table.GetNextRow
    For $iOL_Index = 1 To $aOL_ReturnProperties[0]
    $avOL_Result[$iOL_Index2][$iOL_Index-1] = $oOL_Row($aOL_ReturnProperties[$iOL_Index])
    Next
    $iOL_Index2 = $iOL_Index2 + 1
    WEnd
    Return $avOL_Result

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>_OL_ItemSearch

    [/autoit] [autoit][/autoit] [autoit]

    Func __OL_Property2Hex($sOL_Property)

    [/autoit] [autoit][/autoit] [autoit]

    Local $aProperties[100][2] = [[2, 2],["subject", "0x0037001E"],["SenderName","0x0C1A001F"]]
    For $i = 1 To $aProperties[0][0]
    If $aProperties[$i][0] = $sOL_Property Then Return $aProperties[$i][1]
    Next
    Return SetError(1, 0, "")

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>__OL_Property2Hex

    [/autoit]
  • _ExcelBookOpen (Return Values, falls das Passwort nicht stimmt)

    • water
    • 28. März 2012 um 00:55

    Für Skripte die ich in Produktion verwende - oder wie ein anderer User meinte: für "ernsthafte Skripte" - verwende ich auch nur die aktuelle stabile Version.
    Aber es ist immer gut zu wissen, wo die Reise hingeht und dann spiele ich nicht ungern auch schon mal mit 'ner Beta rum um zu sehen, ob das dann auch funktioniert :rolleyes:
    Grüße vom Bodensee

  • _ExcelBookOpen (Return Values, falls das Passwort nicht stimmt)

    • water
    • 27. März 2012 um 18:18
    Zitat von BugFix

    Und du kannst Objekt-Fehler nicht mit "If @error..." abfangen. Diese Aufgabe übernimmt ja der Error-Handler.

    Ab 3.3.9.2 schon. Sagt zumindest trancexx. Und die muss es wissen, pinselt sie ja an dieser Stelle im Source Code rum ;)

  • AutoIT Software

    • water
    • 26. März 2012 um 18:13

    peethebee hat ein schönes Buch zu AutoIt (fast fertig) geschrieben.
    Auf english gibt es tutorials ohne Ende - wie es mit deutschen Unterlagen aussieht, kann ich nicht genau sagen.

  • _ExcelBookOpen (Return Values, falls das Passwort nicht stimmt)

    • water
    • 25. März 2012 um 23:27

    Lass Dein Script mal mit der aktuellen beta Version 3.3.9.2 laufen. Da gibt es kein crashen mehr mit der Meldung "The requested action with this object has failed".
    Das Skript soll dann immer korrekt weiterlaufen und nur das Makro @error setzen. Ein COM error handler ist damit nicht mehr notwendig und erleichtert die ganze Geschichte.

  • Win7 64bit Office 2010 64bit IE 64bit und FF 64bit

    • water
    • 22. März 2012 um 18:58

    Wenn Du Office in der 32-bit Version installiert hast, dann musst Du Deine AutoIt Skripte auch für 32-bit kompilieren, unabhängig ob das OS 64- oder 32-bit läuft.
    Sonst gibt's Probleme bezüglich COM.

  • LDAP Abfrage in Word schreiben DC Windows 2008 in AD

    • water
    • 22. März 2012 um 12:53

    Ich hätte noch ein paar andere Verbesserungen. Wenn ich das in Deinen Code einbaue, dann brauche ich meine Änderungen nicht zu markieren bzw. Du sie nicht wieder mühsam in Deinen Code einbauen.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™