Beiträge von BinDannMalWeg

  • Frage zum Script :

    Zitat von baerchen

    Niemand eine Idee?

    Ich weis es kann frustrierend sein wenn man programmieren möchte, aber ein Problem nicht gelöst bekommt. Allerdings musst du dir überlegen, dass die Menschen die dir hier helfen auch noch eigene Probleme zu lösen haben. :D Wenn man hier schnell Hilfe bekommt wie es oft der Fall ist, dann ist das eine tolle Sache, aber eben keine Selbstverständlichkeit! Geduld... :)

    Zitat von baerchen

    Oder kann man das mit ewas anderes Definieren (Denn rand ?) via Label od rand angabe?

    Ums kurz zu machen: Ja, das kann man definieren. Und das ist eben die Aufgabe der wir Programmierer uns stellen müssen. :D Du musst dir überlegen was du erreichen möchtest: "Das innere Ding darf nicht aus dem äußeren Ding". Im nächsten Schritt gilt es festzustellen wie der Zustand den wir vermeiden möchten denn überhaupt zustande komm und man könnte feststellen: "Nur wenn sich das innere Ding bewegt kann es 'über den Rand gehen' . Ein logischer Schluss den wir nun daraus ziehen können ist, dass wir an der Stelle im Quellcode an der wir die Position verändern - also möglicher Weise über den Rand treten - eine Abfrage benötigen, die prüft ob wir denn aus dem GUI gelaufen sind.

    [autoit]

    Func bewegDasDing()
    If (Wat kommt denn hier hin? :o) Then
    bewegen() ; wir bewegen uns nur sofern wir nicht den Rand übertreten
    EndIf
    EndFunc

    [/autoit]

    Was nun noch fehlt ist ein Stückchen Software das feststellt ob wir denn über denn Rand laufen wenn wir uns jetzt wie gewünscht bewegen. In deinem Beispiel soll grob gesagt ein Rechteck (Bild) in einem anderen Rechteck (GUI) bleiben. Von beiden Rechtecken haben wir Position und Größe. Läuft das innere Rechteck zum Beispiel links aus dem Größeren, sinkt die X-Komponente der Position des Inneren unter den Wert der X-Komponente des Größeren. In einer Abfrage ausgedrückt könnte man das wie folgt schreiben: "Wenn (PositionInneres_X > PositionÄußeres_X) Dann dürfen wir uns Bewegen." Natürlch müsste man diese Abfrage noch um die anderen "Ränder" die überschritten werden könnten erweitern, damit das Ziel das wir oben definiert haben ("Das innere Ding darf nicht aus dem äußeren Ding") auch erreicht wird. Aber das schaffst du nun denke ich selbst. :)
    Ich hoffe ich konnte dir erklären wie du dein Problem selbst lösen kannst. :saint:
    Edit: Da will man einmal nicht mit fertigem Code um sich werfen :D

  • Frage zum Script :

    Hier mal ein kleines Beispiel wie das funktionieren könnte... ;)

    Spoiler anzeigen
    [autoit]

    #include <GUIConstantsEx.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $iSpeed = 10

    [/autoit] [autoit][/autoit] [autoit]

    $hGui = GUICreate("bsp", 500, 500, -1, -1)
    $hDummy = GUICtrlCreateLabel("", 100, 100, 50, 50)
    GUICtrlSetBkColor($hDummy, 16711680)
    GUISetState(@SW_SHOW)

    [/autoit] [autoit][/autoit] [autoit]

    HotKeySet("{ESC}", "keyPressed")
    HotKeySet("{Left}", "keyPressed")
    HotKeySet("{Right}", "keyPressed")
    HotKeySet("{Down}", "keyPressed")
    HotKeySet("{Up}", "keyPressed")

    [/autoit] [autoit][/autoit] [autoit]

    While True
    Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
    ExitLoop

    [/autoit] [autoit][/autoit] [autoit]

    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func keyPressed()
    ConsoleWrite(@HotKeyPressed & @LF)
    Switch @HotKeyPressed
    Case "{ESC}"
    GUICtrlSetPos($hDummy, 0, 0)
    Case "{UP}"
    setPosRelative($hDummy, 0, -$iSpeed)
    Case "{RIGHT}"
    setPosRelative($hDummy, $iSpeed, 0)
    Case "{DOWN}"
    setPosRelative($hDummy, 0, $iSpeed)
    Case "{LEFT}"
    setPosRelative($hDummy, -$iSpeed, 0)
    EndSwitch
    EndFunc ;==>keyPressed

    [/autoit] [autoit][/autoit] [autoit]

    Func setPosRelative($hCtrl, $iLeft, $iTop)
    Local $aPos = ControlGetPos("", "", $hCtrl)
    If @error Then Return SetError(1)
    GUICtrlSetPos($hCtrl, $aPos[0] + $iLeft, $aPos[1] + $iTop)
    EndFunc ;==>setPosRelative

    [/autoit]

  • DNS Cache auslesen

    Mit diesen beiden Funktionen lässt sich der lokale DNS Cache auslesen und leeren. Wie im Beispielscript gezeigt lässt sich mit ihnen zum Beispiel nachvollziehen welche Webseiten am Computer aufgerufen wurden.

    Spoiler anzeigen
    [autoit]

    Local $sHistory = ";"

    [/autoit] [autoit][/autoit] [autoit]

    While True
    $aCache = _ReadDNSCache()
    If Not @error Then
    For $url In $aCache
    If Not StringInStr($sHistory, ";" & $url & ";") Then
    $sHistory &= $url & ";"
    ConsoleWrite($url & @LF)
    EndIf
    Next
    _ClearDNSCache()
    EndIf
    Sleep(2048)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func _ReadDNSCache()
    Local $sOutput = "", $aResults
    $iPID = Run("cmd.exe /c ipconfig /displaydns", "", @SW_HIDE, 4 + 2)
    Do
    Sleep(10)
    $sOutput &= StdoutRead($iPID, False, False)
    Until @error
    $aResults = StringRegExp($sOutput, "\r\n (.+?)\r\n -{40}\r\n", 3)
    If IsArray($aResults) Then Return $aResults
    SetError(1)
    EndFunc ;==>_ReadDNSCache

    [/autoit] [autoit][/autoit] [autoit]

    Func _ClearDNSCache()
    RunWait('cmd.exe /c ipconfig /flushdns >nul', @TempDir, @SW_HIDE)
    EndFunc ;==>_ClearDNSCache

    [/autoit]

    Um dieses Beispiel zu testen: Script starten und in einem Webbrowser eine beliebige URL aufrufen. Ist die URL noch nicht in der Liste wird sie in der Konsole ausgegeben.

  • Uhr

    Hey gem,

    schöne Idee mit dem Youtube Tutorial. Beim schnellen drüber schauen sind mir ein/zwei Dinge aufgefallen die man in Autoit meiner Meinung nach etwas eleganter schreiben kann. Aber sieh selbst... :)
    Durch Menschen wie dich, die sich hinsetzen und Tutorials erarbeiten wird die Zahl der Programmierbegeisterten immer größer. Weiter so! :)

    Spoiler anzeigen
    [autoit]

    #include <GUIConstantsEx.au3>
    #include <GDIPlus.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $iWindowSize = 500
    Global $sWindowTitle = "Uhr"
    Global $iFrameRate = 30

    [/autoit] [autoit][/autoit] [autoit]

    Global $hGraphics
    Global $hBitmap
    Global $hBuffer
    Global $hPen, $hPen_hour, $hPen_minute, $hPen_second

    [/autoit] [autoit][/autoit] [autoit]

    Global $PI = 3.14159265359

    [/autoit] [autoit][/autoit] [autoit]

    init()

    [/autoit] [autoit][/autoit] [autoit]

    func init()
    Local $hWindow

    [/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_Startup()
    $hWindow = GUICreate($sWindowTitle, $iWindowSize, $iWindowSize)
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hWindow)
    $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iWindowSize, $iWindowSize, $hGraphics)
    $hBuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetSmoothingMode($hBuffer,2)
    GUISetState(@SW_SHOW)

    [/autoit] [autoit][/autoit] [autoit]

    $hPen = _GDIPlus_PenCreate(0xFF333333,10)
    $hPen_minute = _GDIPlus_PenCreate(0xFFDDDDDD,3)
    $hPen_hour = _GDIPlus_PenCreate(0xFF666666,3)
    $hPen_second = _GDIPlus_PenCreate(0xFFFF0000,2)

    [/autoit] [autoit][/autoit] [autoit]

    AdlibRegister("update",1000/$iFrameRate) ; $iFrameRate mal pro Sekunde die Funktion "update()" aufrufen

    [/autoit] [autoit][/autoit] [autoit]

    main()
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func main()
    While (GUIGetMsg() <> $GUI_EVENT_CLOSE)
    Sleep(50)
    WEnd
    close()
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func close()
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_PenDispose($hPen_minute)
    _GDIPlus_PenDispose($hPen_hour)
    _GDIPlus_PenDispose($hPen_second)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hBuffer)
    _GDIPlus_Shutdown()
    Exit
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func update()
    Local $dRad

    [/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_GraphicsClear($hBuffer,0xFFFFFFFF)
    _GDIPlus_GraphicsDrawEllipse($hBuffer,50,50,$iWindowSize-100,$iWindowSize-100,$hPen)

    [/autoit] [autoit][/autoit] [autoit]

    $dRad = 0
    $diff = ($PI*2) / 12
    Do
    _GDIPlus_GraphicsDrawLine($hBuffer,$iWindowSize/2+sin($dRad)*180,$iWindowSize/2+cos($dRad)*180,$iWindowSize/2+sin($dRad)*200,$iWindowSize/2+cos($dRad)*200,$hPen)
    $dRad += $diff
    Until $dRad >= $PI*2

    [/autoit] [autoit][/autoit] [autoit]

    ; minute
    $dRad = -(($PI*2) / 60) *@MIN-$PI
    drawPointer($dRad, 150, $hPen_minute)

    [/autoit] [autoit][/autoit] [autoit]

    ; hour
    $dRad = -(($PI*2) / 12) *@HOUR-$PI
    drawPointer($dRad, 80, $hPen_hour)

    [/autoit] [autoit][/autoit] [autoit]

    ; second
    $dRad = -(($PI*2) / 60) *@SEC-$PI
    drawPointer($dRad, 170, $hPen_second)

    [/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_GraphicsDrawImage($hGraphics,$hBitmap,0,0)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func drawPointer($dRad, $iLength, $hPen)
    _GDIPlus_GraphicsDrawLine($hBuffer, $iWindowSize/2, $iWindowSize/2, ($iWindowSize/2+sin($dRad)*$iLength), ($iWindowSize/2+cos($dRad)*$iLength), $hPen)
    EndFunc

    [/autoit]

  • Funktion aus Dictionary aufrufen

    Zitat von VinceA

    Schau dir dieses Thema genauer an:
    Alternativen zum Array

    Das kenne ich nur all zu gut - trotzdem danke. ;)

    Zitat von BugFix

    Dies ist eine unzulässige Syntax, Dictionary(Key) muss erst ausgewertet werden, bevor der Parameter übergeben werden kann.

    Und genau das hätte ich eigentlich vom Interpreter erwartet. Das zuerst der entsprechende Wert aus dem Dictionary geladen wird und dann im nächsten Schritt die enthaltene Funktion aufgerufen wird. Beispielsweise bei einem Array funktioniert das nämlich - auch ohne Klammern.
    Aber nun genug der Syntax-Vergewaltigung, ich setze an dieser Stelle mal auf gelöst.

  • Funktion aus Dictionary aufrufen

    Hallo Allerseits,
    ich versuche Funktionen direkt aus einem Dictionary heraus aufzurufen. Zur Demonstration habe ich folgendes kleines Beispielscript geschrieben:

    [autoit]

    $obj = ObjCreate("Scripting.Dictionary")
    $obj("func") = hello

    [/autoit][autoit][/autoit][autoit]

    $obj("func")("world 1")

    [/autoit][autoit][/autoit][autoit]

    ($obj("func"))("world 2")

    [/autoit][autoit][/autoit][autoit]

    $abc = $obj("func")
    $abc("world 3")

    [/autoit][autoit][/autoit][autoit]

    local $array = [hello]
    $array[0]("world 4")

    [/autoit][autoit][/autoit][autoit]

    Func hello($s)
    ConsoleWrite("hello " & $s & @LF)
    EndFunc

    [/autoit]

    Meine simple Frage dazu lautet: Warum scheitert der Interpreter, am ersten der vier Test-Funktionsaufrufe? ^^

  • Array und StringRegExp Problem

    :P

    [autoit]

    Local $sData, $aResult

    [/autoit][autoit][/autoit][autoit]

    $sData = FileRead("sid.txt")
    $aResult = StringRegExp($sData, "(\S.*\S)\h\h+(S-[\d\-]+)", 3)
    If @error Or Not IsArray($aResult) Or Mod(UBound($aResult), 2) <> 0 Then Exit

    [/autoit][autoit][/autoit][autoit]

    For $i = 0 To UBound($aResult) - 2 Step +2
    MsgBox(0, "", "samid: '" & $aResult[$i] & "'" & @LF & "sid: '" & $aResult[$i + 1] & "'")
    Next

    [/autoit]

  • Hilfe bei GUI Funktion aufrufen bzw Tastendruck senden

    Im Normalfall würde ich Anfängern erst später dazu raten sich den sogenannten "OnEventMode" für GUIs anzusehen, allerdings ist er für exakt den in deinem Script gezeigten Anwendungsfall konzipiert, weshalb ich ihn an dieser Stelle nur mal erwähnt haben möchte. Der OnEventMode ist wie der Name schon vermuten lässt ein Modus, in den du dein GUI versetzen kannst. Hast du dies getan brauchst du dich nicht mehr mit GUIGetMsg() und Co. herumzuschlagen. Stattdessen kannst du einfach festlegen "WENN zu irgend einem Zeitpunkt dieser Button gedrückt wird, DANN ruf doch bitte mal diese Funktion X hier auf" und alles andere erledigt Autoit für dich. Aber genug geredet mein kleiner Beispielcode sollte selbsterklärend sein... :)

    Spoiler anzeigen
    [autoit]

    #include <GUIConstantsEx.au3> ; Durch dieses Include können wir weiter unten die Variable $GUI_EVENT_CLOSE verwenden. Dies ist zwar nicht zwingend notwendig (du könntest auch einfach -3 schreiben, was dem Wert der Variable entspricht) allerdings ist es doch viel schöner und leserlicher wenn sofort klar ist um Welches Event es an einer bestimmten Stelle geht. Oder? :P

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIOnEventMode",1) ; GUIOnEventMode einschalten (1) da er standardmäßig deaktiviert ist

    [/autoit] [autoit][/autoit] [autoit]

    $hGUI = GUICreate("Meine GUI", 400, 300, 1000,350) ; GUI erstellen
    $hButtonExit = GUICtrlCreateButton("Close", 250, 250, 60,20) ; Button erstellen

    [/autoit] [autoit][/autoit] [autoit]

    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit") ; Wir legen fest was passieren soll, wenn in unserem GUI das Event $GUI_EVENT_CLOSED auftritt. Im zweiten Parameter geben wir den Namen einer Funktion an die im Falle eines Events - hier ein Klick auf das rote X des GUI - automatisch aufgerufen wird.
    GUICtrlSetOnEvent($hButtonExit,"_Exit") ; Mit dem Button verfahren wir genau gleich. "WENN Button gedrückt DANN '_Exit' aufrufen"

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState(@SW_SHOW) ; GUI sichtbar machen

    [/autoit] [autoit][/autoit] [autoit]

    while True ; Endlosschleife
    Sleep(250) ; Da wir den OnEventMode benutzen müssen wir uns hier in der Hauptschleife nicht mehr um das Aufrufen der Funktionen kümmern. :) Das Sleep ist nur zur Entlastung des Prozessors da. (Ohne dieses Sleep würde die Schleife tausende male in der Sekunde durchlaufen)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    FileDelete (@TempDir & "\bing.wav")
    MsgBox("","Info", "Programm beendet und geschlossen!")
    Exit
    EndFunc

    [/autoit]

  • Aktualisierung der Exe

    Du benötigst die neuste Autoit Version... ;)
    Wobei ich diese Lösung fast noch schöner finde:

    Spoiler anzeigen
    [autoit]

    #include <File.au3>
    Local $aFiles = _FileListToArray(@ScriptDir, "Backup*.exe", 1), $LatestFile

    [/autoit] [autoit][/autoit] [autoit]

    For $f In $aFiles ; Wir suchen die neuste Version der Exe-Datei
    If FileGetTime($f, 1, 1) > FileGetTime($LatestFile, 1, 1) Then $LatestFile = $f
    Next

    [/autoit] [autoit][/autoit] [autoit]

    If StringLen($LatestFile) = 0 Then Exit ConsoleWrite("no executables found" & @LF)
    ShellExecute($LatestFile) ; Wir starten die nesute Exe-Datei

    [/autoit] [autoit][/autoit] [autoit]

    For $f In $aFiles ; Wir versuchen die alten Exe-Dateien zu löschen
    If $f <> $LatestFile Then FileDelete($f)
    Next

    [/autoit]

    Hier werden alte Versionen mit der Zeit gelöscht. (In dem Moment in dem ein User sich anmeldet und kein anderer die alte Version gestartet hat)

  • Aktualisierung der Exe

    Lass die Verknüpfungen im Autostart auf dieses kompilierte Skript verweisen. Es startet immer die neuste Exe deren Namen mit der Zeichenfolge "Backup" beginnt...

    Spoiler anzeigen
    [autoit]

    Local $LatestFile[2] = [-1, ""]
    processFiles("Backup*.exe", findLatest)
    If $LatestFile[0] = -1 Then Exit ConsoleWrite("no executables found!" & @LF)
    ShellExecute($LatestFile[1])

    [/autoit] [autoit][/autoit] [autoit]

    Func findLatest($file)
    Local $age = FileGetTime($file, 1, 1)
    If $age > $LatestFile[0] Then
    $LatestFile[0] = $age
    $LatestFile[1] = $file
    EndIf
    EndFunc ;==>findLatest

    [/autoit] [autoit][/autoit] [autoit]

    Func processFiles($pattern, $callback)
    Local $search = FileFindFirstFile($pattern), $result
    While True
    $file = FileFindNextFile($search)
    If @error Then ExitLoop
    $callback($file)
    WEnd
    EndFunc ;==>processFiles

    [/autoit]

  • TCP-Verbindung (Dauer)

    Zitat von Racer

    Leider geht das nicht so ganz aus der deutschen Doku hervor, denn man kann das leicht (so wie ich) so interpredieren, das damit der Socket (der lauscht) wieder geschlossen wird!!!!


    Das hat nichts mit einem Fehler in der Hilfe zu tun. Dein Fehler ist lediglich ein Resultat aus der Tatsache, dass du TCP noch nicht verstanden hast bzw. hattest.
    Nebenbei bemerkt: Sendet der aktuelle Client nicht in ein paar Sekunden bzw Millisekunden seine Daten wird die Verbindung vom Server her abgebrochen ob wohl der Client noch nicht senden konnte. Außerdem wird alles größer 4096 einfach abgeschnitten...

  • RouteDesigner

    Du weist das es sehr große Firmen gibt, die in sehr großen Büros, mit sehr großen Programmierer-Schaaren an derartiger Software arbeiten, um dann sehr große Mengen Geld dafür zu kassieren? :whistling:^^
    Aber nun gut, ich denke dein Problem lässt sich lösen wenn genau geklärt ist was denn nun getan werden muss. Ich kann mir gut vorstellen, dass deine Problembeschreibung für dich - der du in der Sache 'drin steckst' - logisch klingen mag, aber zumindest ich habe da ein paar Fragen...

    Zitat von mreith

    Wir möchten unseren Kreisen
    eine neue Option bieten,

    Bedeutet das, dass das Programm in eine bestehende Software integriert werden soll?

    Zitat von mreith

    entsprechend "logisch" verteilt werden.

    Du solltest schon definieren was denn "logisch" sein soll. ;) Da ich schon vermute in welche Richtung das geht, merke ich an dieser Stelle gleich mal an, dass der hier benötigte Algorithmus wohl das Kern-Problem darstellen wird.
    Außerdem benötigen "wir" - die wir dir helfen könnten - natürlich Testdaten. (am besten natürlich in der Originalform in der sie später auch vorliegen...)
    So das war es erstmal von meiner Seite... :whistling: