Beiträge von Kanashius

#include <ScreenCapture.au3>
Global $Left=113,$Top=178,$Width=3,$Height=2


Local $arPixels = _screenGetPixel(113, 178, 3, 2)
For $i=0 To UBound($arPixels)-1
	For $j=0 To UBound($arPixels, 2)-1
		If $j<>0 Then ConsoleWrite(" : ")
		ConsoleWrite(StringFormat("%03d %03d %03d %03d", $arPixels[$i][$j][0], $arPixels[$i][$j][1], $arPixels[$i][$j][2], $arPixels[$i][$j][3]))
	Next
	ConsoleWrite(@crlf)
Next


Func _screenGetPixel($iLeft, $iTop, $iWidth, $iHeight)
	_GDIPlus_Startup()
	Local $hBitmapScreenCapture = _ScreenCapture_Capture("", $iLeft, $iTop, $iLeft + $iWidth, $iTop + $iHeight)
	Local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBitmapScreenCapture)
	If @error Then Return -1
	Local $iBitmapWidth = _GDIPlus_ImageGetWidth($hBitmap)
	Local $iBitmapHeight = _GDIPlus_ImageGetHeight($hBitmap)
	Local $arPixels[$iBitmapWidth][$iBitmapHeight][4]
	For $i=0 To $iBitmapWidth-1
		For $j=0 To $iBitmapHeight-1
			Local $iColor = _GDIPlus_BitmapGetPixel($hBitmap, $i, $j)
			$arPixels[$i][$j][0] = BitAND(BitShift($iColor, 24), 0xFF)
			$arPixels[$i][$j][1] = BitAND(BitShift($iColor, 16), 0xFF)
			$arPixels[$i][$j][2] = BitAND(BitShift($iColor, 8), 0xFF)
			$arPixels[$i][$j][3] = BitAND($iColor, 0xFF)
		Next
	Next
	_GDIPlus_BitmapDispose($hBitmap)
	_WinAPI_DeleteObject($hBitmapScreenCapture)
	_GDIPlus_Shutdown()
	Return $arPixels
EndFunc

; ================================= entferne alle Leer- und Kommentarzeilen und poste diesen Code-Block im Thread ==================================
Func _IntegerToRoman($sInteger)
	Local Static $arPattern=["", "I", "II", "III", "IV", "V", "VI", "VII", "VIII", "IX"]
	Local Static $arNumbers=[["I", "V"], ["X", "L"], ["C", "D"], ["M", ""], ["", ""]]
	Local $arData = StringSplit($sInteger, "", 3)
	Local $sResult = ""
	For $i=0 To UBound($arData)-1 Step 1
		Local $sSym1 = $arNumbers[UBound($arData)-$i-1][0]
		Local $sSym2 = $arNumbers[UBound($arData)-$i-1][1]
		Local $sSym3 = $arNumbers[UBound($arData)-$i][0]
		$sResult &= StringReplace(StringReplace(StringReplace($arPattern[$arData[$i]], "X", $sSym3), "V", $sSym2), "I", $sSym1)
	Next
	Return $sResult
EndFunc   ;==>_IntegerToRoman
Func _RomanToInteger($sRoman)
	Local $arData = StringSplit($sRoman, "", 3), $iResult = 0, $iBefore = 0
	For $i=0 To UBound($arData)-1 Step 1
		Local $iAdd = 0
		Switch $arData[$i]
			Case "M"
				$iAdd+=1000
			Case "D"
				$iAdd+=500
			Case "C"
				$iAdd+=100
			Case "L"
				$iAdd+=50
			Case "X"
				$iAdd+=10
			Case "V"
				$iAdd+=5
			Case "I"
				$iAdd+=1
		EndSwitch
		If $iBefore<$iAdd Then
			$iResult-=$iBefore*2
		EndIf
		$iResult+=$iAdd
		$iBefore = $iAdd
	Next
	Return $iResult
EndFunc   ;==>_RomanToInteger
Func _DateToRoman($sDate) ;Input date in the format "YYYY/MM/DD[ HH:MM:SS]", Output in same date-format with roman sign
	Local $arDate = StringRegExp($sDate, "\d+", 3)
	$sDate = StringRegExpReplace($sDate, "\d+", "$")
	For $i=0 To UBound($arDate)-1
		$sDate = StringReplace($sDate, "$", _IntegerToRoman($arDate[$i]), 1)
	Next
	Return $sDate
EndFunc   ;==>_DateToRoman
; ================================= entferne alle Leer- und Kommentarzeilen und poste diesen Code-Block im Thread ==================================

{
 "Strecken": {
   "1": {
     "name": "A",
     "path": [
       [0, 0],
       [15, 0]
     ]
   },
   "2": {
     "name": "B",
     "path": [
       [5, 5],
       [10, 0]
     ]
   },
   "3": {
     "name": "C",
     "path": [
       [5, 5],
       [5, 10]
     ]
   }
 },
 "Weichen":{
   "1": {
     "in": [1],
     "out": [2,3]
   }
 }
}

CREATE TABLE IF NOT EXISTS Bookings(
	id INTEGER PRIMARY KEY,
	account INTEGER NOT NULL,
	time INTEGER DEFAULT (unixepoch()),
	change INTEGER NOT NULL,
	short_desc TEXT DEFAULT NULL,
	purpose TEXT DEFAULT NULL,
	FOREIGN KEY (account) REFERENCES Accounts (id) ON DELETE CASCADE ON UPDATE NO ACTION
);

CREATE TABLE IF NOT EXISTS Accounts(
	id INTEGER PRIMARY KEY,
	name TEXT NOT NULL
);

BEGIN TRANSACTION;
INSERT INTO Bookings (account, time, change, short_desc) VALUES (1, unixepoch("2025-04-25 12:34:56"), 120000, "Einnahmen Lohn1");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, 25000, "Einnahmen Lohn2");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, 15000, "Einnahmen WGP");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, 6000, "Einnahmen LMP VM");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, 4000, "Einnahmen Extra");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, -50000, "Ausgaben Miete");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, -10000, "Ausgaben Strom");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, -1005, "Ausgaben Bank");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, -2000, "Ausgaben RuBe");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, -30000, "Ausgaben LMP");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, -10000, "Ausgaben DuS");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, -15000, "Ausgaben frei1");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, 0, "Ausgaben frei2");
INSERT INTO Bookings (account, change, short_desc) VALUES (1, 0, "Ausgaben Extra");
COMMIT;

BEGIN TRANSACTION;
INSERT INTO Bookings (account, change, short_desc) VALUES (2, 10000, "Eingang Sparbuch");
INSERT INTO Bookings (account, change, short_desc, purpose) VALUES (2, -7500, "Ausgang Sparbuch", "X, Y, Z");
COMMIT;

BEGIN TRANSACTION;
INSERT INTO Accounts (name) VALUES ("Haushaltsbuch"), ("Sparbuch");
COMMIT;

#include <SQLite.au3>

Global $sDataFolder = "Data\", $sSQLiteDLL = $sDataFolder&"sqlite3_"&(@AutoItX64?"64":"86")&".dll", $sDatabase = $sDataFolder&"database.sqlite"
Global $sSQLCreateTableBooking = "" & _
	"CREATE TABLE IF NOT EXISTS Bookings(" & _
	  "id INTEGER PRIMARY KEY," & _
	  "account INTEGER NOT NULL," & _
	  "time INTEGER DEFAULT (unixepoch())," & _
	  "change INTEGER NOT NULL," & _
	  "short_desc TEXT DEFAULT NULL," & _
	  "purpose TEXT DEFAULT NULL," & _
	  "FOREIGN KEY (account) REFERENCES Accounts (id) ON DELETE CASCADE ON UPDATE NO ACTION" & _
	");"
Global $sSQLCreateTableAccounts = "" & _
	"CREATE TABLE IF NOT EXISTS Accounts(" & _
	  "id INTEGER PRIMARY KEY," & _
	  "name TEXT NOT NULL" & _
	");"
Global $sSQLReset = "DROP TABLE IF EXISTS Bookings; DROP TABLE IF EXISTS Accounts;"
Global $sSQLAllData = "SELECT " & _
							"b.account, " & _
							"a.name, " & _
							"b.time, " & _
							"datetime(b.time, 'unixepoch') as stime, " & _
							"strftime('%Y', datetime(b.time, 'unixepoch')) as year, " & _
							"strftime('%m', datetime(b.time, 'unixepoch')) as month, " & _
							"strftime('%d', datetime(b.time, 'unixepoch')) as day, " & _
							"strftime('%w', datetime(b.time, 'unixepoch')) as weekday, " & _
							"b.change, " & _
							"b.short_desc, " & _
							"b.purpose " & _
						"FROM Bookings b JOIN Accounts a ON b.account=a.id"

_SQLite_Startup($sSQLiteDLL)
If @error Then MsgBox(16, "Error", 'SQLite could not be loaded. Check, if the file "'&$sSQLiteDLL&'" exists.')

Global $hDB = _SQLite_Open($sDatabase)

; For Debugging to remove old data
_SQLite_ExecCatchErr($hDB, $sSQLReset, False, True)

_SQLite_ExecCatchErr($hDB, $sSQLCreateTableBooking, False, True)
_SQLite_ExecCatchErr($hDB, $sSQLCreateTableAccounts, False, True)

_fillWithExampleData($hDB)

Local $arColumns, $arData

; Output Table Accounts
$arData = _SQLite_GetAllCatchErr($hDB, "SELECT * From Accounts", $arColumns)
_printData($arData, $arColumns, "Table Accounts")

; Output Table Bookings
$arData = _SQLite_GetAllCatchErr($hDB, "SELECT * From Bookings", $arColumns)
_printData($arData, $arColumns, "Table Bookings")

; Output everything with extra data
; $arData = _SQLite_GetAllCatchErr($hDB, $sSQLAllData, $arColumns)
; _printData($arData, $arColumns, "All data with extra infos for further processing")


; output change by month
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, month, cast(SUM(change) as float)/100 as change FROM ("&$sSQLAllData&") GROUP BY name, month, year ORDER BY name, year, month", $arColumns)
; _printData($arData, $arColumns, "Change by Month-Year")

; output change by year
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, cast(SUM(change) as float)/100 as change FROM ("&$sSQLAllData&") GROUP BY name, year ORDER BY name, year", $arColumns)
; _printData($arData, $arColumns, "Change by Year")

; output change by half year
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, month/6+1 as halfyear, cast(SUM(change) as float)/100 as change FROM ("&$sSQLAllData&") GROUP BY name, year, (month-1)/6 ORDER BY name, year, halfyear", $arColumns)
; _printData($arData, $arColumns, "Change by Half Year")

; output change by quarter
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, month/3+1 as quarter, cast(SUM(change) as float)/100 as change FROM ("&$sSQLAllData&") GROUP BY name, year, (month-1)/3 ORDER BY name, year, quarter", $arColumns)
; _printData($arData, $arColumns, "Change by Quarter")

; output change by third
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, month/4+1 as third, cast(SUM(change) as float)/100 as change FROM ("&$sSQLAllData&") GROUP BY name, year, (month-1)/4 ORDER BY name, year, third", $arColumns)
; _printData($arData, $arColumns, "Change by Year/3")

; output change by day
Global $sSQLChangeByDay = "SELECT name, year, month, day, cast(SUM(change) as float)/100 as change FROM ("&$sSQLAllData&") GROUP BY name, year, month, day ORDER BY name, year, month, day"
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, month, day, cast(SUM(change) as float)/100 as change FROM ("&$sSQLAllData&") GROUP BY name, year, month, day ORDER BY name, year, month, day", $arColumns)
; _printData($arData, $arColumns, "Change by Day")

; output spending avarage by day
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, AVG(change) as average FROM ("&$sSQLChangeByDay&") GROUP BY name, year ORDER BY name, year", $arColumns)
; _printData($arData, $arColumns, "Average change by day")

; output spending avarage by week
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, AVG(change)*7 as average FROM ("&$sSQLChangeByDay&") GROUP BY name, year ORDER BY name, year", $arColumns)
; _printData($arData, $arColumns, "Average change by week")

; output spending avarage by weekday
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, weekday, cast(AVG(change) as float)/100 as average FROM ("&$sSQLAllData&") GROUP BY name, year, weekday ORDER BY name, year, weekday", $arColumns)
; _printData($arData, $arColumns, "Average change by day")

; output saldo
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT a.name, cast(SUM(b.change) as float)/100 as saldo FROM Bookings b JOIN Accounts a ON b.account=a.id GROUP BY a.name", $arColumns)
; _printData($arData, $arColumns, "Saldo")

; output saldo until specific datetime
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT a.name, cast(SUM(b.change) as float)/100 as saldo FROM Bookings b JOIN Accounts a ON b.account=a.id WHERE b.time<unixepoch('2025-01-01 00:00:00') GROUP BY a.name", $arColumns)
; _printData($arData, $arColumns, "Saldo at 2025-01-01 00-00-00")

; output change by quarter for year 2025
; $arData = _SQLite_GetAllCatchErr($hDB, "SELECT name, year, month/3+1 as quarter, cast(SUM(change) as float)/100 as change FROM ("&$sSQLAllData&") WHERE year='2025' GROUP BY name, year, (month-1)/3 ORDER BY name, year, quarter", $arColumns)
; _printData($arData, $arColumns, "Change by Quarter (2025)")

Func _exit()
	_SQLite_Close($hDB)
	_SQLite_Shutdown()
	Exit
EndFunc

Func _SQLite_ExecCatchErr($hDB, $sSql, $bTransaction = True, $bFatal = False)
	_SQLite_Exec($hDB, 'BEGIN TRANSACTION;'&$sSql&'COMMIT;')
	If @error Then
		_SQLite_Exec($hDB, "ROLLBACK;")
		MsgBox(16, "SQLite Error", "Error Code: " & _SQLite_ErrCode() & @CRLF & "Error Message: " & _SQLite_ErrMsg() & "Executing """&$sSql&"""")
		If $bFatal Then _exit()
	EndIf
EndFunc

Func _SQLite_GetDataCatchErr($hDB, $sSql)
	Local $arColumns
	Return _SQLite_GetAllCatchErr($hDB, $sSql, $arColumns)
EndFunc

Func _SQLite_GetAllCatchErr($hDB, $sSql, ByRef $arColumns)
	Local $arResult, $iRows
	_SQLite_GetTableData2D($hDB, $sSql, $arResult, $iRows, $arColumns)
	If @error Then
		MsgBox(16, "SQLite Error", "Error Code: " & _SQLite_ErrCode() & @CRLF & "Error Message: " & _SQLite_ErrMsg() & "Executing """&$sSql&"""")
		Local $arResult[0][0]
		Return SetError(1, 0, $arResult)
	EndIf
	Return $arResult
EndFunc

Func _printData(ByRef $arData, ByRef $arColumns, $sTitle = Default)
	If Not IsArray($arData) Or Not IsArray($arColumns) Then Return -1
	If UBound($arData,0)<>2 Then Return -1
	Local $arColWidth[UBound($arData, 2)]
	For $i=0 To UBound($arColumns)-1 Step 1
		If StringLen($arColumns[$i])>$arColWidth[$i] Then $arColWidth[$i] = StringLen($arColumns[$i])
	Next
	For $j=0 To UBound($arData, 2)-1 Step 1
		For $i=0 To UBound($arData, 1)-1 Step 1
			Local $arMatch = StringRegExp($arData[$i][$j], "(\d{4})-(\d{2})-(\d{2}) (\d{2}):(\d{2}):(\d{2})", 1)
			If Not @error Then
				$arData[$i][$j] = $arMatch[0]&"-"&$arMatch[1]&"-"&$arMatch[2]&" "&$arMatch[3]&"-"&$arMatch[4]&"-"&$arMatch[5]
			EndIf
			If StringLen($arData[$i][$j])>$arColWidth[$j] Then $arColWidth[$j] = StringLen($arData[$i][$j])
		Next
	Next
	Local $arSeps[UBound($arColWidth)], $iMaxLength = 0
	For $i=0 To UBound($arColWidth)-1 Step 1
		$iMaxLength+=$arColWidth[$i]+3
	Next
	Local $iAdd = 0
	If $iMaxLength<StringLen($sTitle) Then $iAdd = Int((StringLen($sTitle)-$iMaxLength+4)/UBound($arColWidth))+(Mod((StringLen($sTitle)-$iMaxLength)+4, UBound($arColWidth))>0?1:0)
	For $i=0 To UBound($arColWidth)-1 Step 1
		$arColWidth[$i] += $iAdd
	Next
	For $i=0 To UBound($arColWidth)-1 Step 1
		For $j=0 To $arColWidth[$i]+1 Step 1
			$arSeps[$i] &= "-"
		Next
	Next
	If $sTitle<>Default Then
		ConsoleWrite("+")
		For $i=0 To UBound($arSeps)-1 Step 1
			ConsoleWrite($arSeps[$i])
			If $i<UBound($arSeps)-1 Then ConsoleWrite("-")
		Next
		ConsoleWrite("+"&@crlf)
		Local $iTitleSpace = Int(($iMaxLength-3-StringLen($sTitle))/2)
		If $iTitleSpace<0 Then $iTitleSpace=0
		Local $iExtra = 0
		If Mod(($iMaxLength-3-StringLen($sTitle))/2, 2)<>0 Then $iExtra = 1
		ConsoleWrite(StringFormat("| %"&$iTitleSpace&"s%s%"&$iTitleSpace+$iExtra&"s |", "", $sTitle, "")&@crlf)
	EndIf
	For $i=0 To UBound($arSeps)-1 Step 1
		ConsoleWrite("+"&$arSeps[$i])
	Next
	ConsoleWrite("+"&@crlf)
	For $i=0 To UBound($arColumns)-1 Step 1
		ConsoleWrite(StringFormat("| %-"&$arColWidth[$i]&"s ", StringUpper($arColumns[$i])))
	Next
	ConsoleWrite("| "&@crlf)
	ConsoleWrite("+")
	For $i=0 To UBound($arSeps)-1 Step 1
		ConsoleWrite($arSeps[$i])
		If $i<UBound($arSeps)-1 Then ConsoleWrite("-")
	Next
	ConsoleWrite("+"&@crlf)
	For $i=0 To UBound($arData, 1)-1 Step 1
		For $j=0 To UBound($arData, 2)-1 Step 1
			ConsoleWrite(StringFormat("| %-"&$arColWidth[$j]&"s ", $arData[$i][$j]))
		Next
		ConsoleWrite("| "&@crlf)
	Next
	For $i=0 To UBound($arSeps)-1 Step 1
		ConsoleWrite("+"&$arSeps[$i])
	Next
	ConsoleWrite("+"&@crlf)
EndFunc

Func _fillWithExampleData($hDB)
	_SQLite_ExecCatchErr($hDB, 'INSERT INTO Accounts (name) VALUES ("Haushaltsbuch"), ("Sparbuch");')
	#cs
	_SQLite_ExecCatchErr($hDB, '' & _
			'INSERT INTO Bookings (account, time, change, short_desc) VALUES (1, unixepoch("2025-04-25 12:34:56"), 120000, "Einnahmen Lohn1");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, 25000, "Einnahmen Lohn2");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, 15000, "Einnahmen WGP");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, 6000, "Einnahmen LMP VM");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, 4000, "Einnahmen Extra");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, -50000, "Ausgaben Miete");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, -10000, "Ausgaben Strom");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, -1005, "Ausgaben Bank");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, -2000, "Ausgaben RuBe");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, -30000, "Ausgaben LMP");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, -10000, "Ausgaben DuS");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, -15000, "Ausgaben frei1");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, 0, "Ausgaben frei2");' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (1, 0, "Ausgaben Extra");' & _
		'')
	_SQLite_ExecCatchErr($hDB, '' & _
			'INSERT INTO Bookings (account, change, short_desc) VALUES (2, 10000, "Eingang Sparbuch");' & _
			'INSERT INTO Bookings (account, change, short_desc, purpose) VALUES (2, -7500, "Ausgang Sparbuch", "X, Y, Z");' & _
		'')
	#ce
	; generate some example data for 2024+2025 (complete years)
	Local $arData = [ _
		[1, 120000, "Einnahmn Lohn1", ""], _
		[1, 25000, "Einnahmen Lohn2", ""], _
		[1, 15000, "Einnahmen WGP", ""], _
		[1, 6000, "Einnahmen LMP VM", ""], _
		[1, 4000, "Einnahmen Extra", ""], _
		[1, -50000, "Ausgaben Miete", ""], _
		[1, -10000, "Ausgaben Strom", ""], _
		[1, -1005, "Ausgaben Bank", ""], _
		[1, -2000, "Ausgaben RuBe", ""], _
		[1, -30000, "Ausgaben LMP", ""], _
		[1, -10000, "Ausgaben DuS", ""], _
		[1, -15000, "Ausgaben frei1", ""], _
		[1, 0, "Ausgaben frei2", ""], _
		[1, 0, "Ausgaben Extra", ""], _
		[2, 10000, "Eingang Sparbuch", ""], _
		[2, -7500, "Ausgang Sparbuch", "X, Y, Z"] _
	]
	For $iYear=2024 To 2025 Step 1
		For $iMonth=1 To 12 Step 1
			Local $sSql = ""
			For $i=0 To UBound($arData)-1 Step 1
				Local $iDay = Random(1, 28, 1)
				Local $sDate = StringFormat("%04d-%02d-%02d %02d:%02d:%02d", $iYear, $iMonth, $iDay, 12, 30, 00)
				Local $iMultiplier = Random(0.6, 1)
				If $arData[$i][3]="" Then
					$sSql &= StringFormat('INSERT INTO Bookings (account, time, change, short_desc) VALUES (%d, unixepoch("%s"), %d, "%s");', $arData[$i][0], $sDate, $arData[$i][1]*$iMultiplier, $arData[$i][2])
				Else
					$sSql &= StringFormat('INSERT INTO Bookings (account, time, change, short_desc, purpose) VALUES (%d, unixepoch("%s"), %d, "%s", "%s");', $arData[$i][0], $sDate, $arData[$i][1]*$iMultiplier, $arData[$i][2], $arData[$i][3])
				EndIf
			Next
			_SQLite_ExecCatchErr($hDB, $sSql)
		Next
	Next
EndFunc

For $a = 0 To 144
    For $b = 0 To 144
        ConsoleWrite("Dice: " & $numbers2[$b] & " ----------> " & " Number: " & $numbers1[$b] &@CRLF)
    Next
Next
; 0-144 sind 145 Durchläufe, was ein Index zu groß ist, deshalb die Fehlermeldung "Array variable has incorrect number of subscripts"

For $a = 0 To $numbers2
    For $b = 0 To $numbers1
        ConsoleWrite("Dice: " & $numbers2[$b] & " ----------> " & " Number: " & $numbers1[$b] &@CRLF)
    Next
Next
; $numbers2 und $numbers1 sind Arrays. In den meisten Sprachen fliegt dir das um die Ohren, weil es keine Zahlen sind, in AutoIt passiert das nicht,
; stattdessen wird versucht, sie in eine Zahl umzuwandeln. Das geht bei Arrays nicht, also wird 0 zurückgegeben.
; For $a = 0 To $numbers2 ist das gleiche wie For $a=0 to 0 => Es läuft genau einmal mit $a=0

For $a = 0 To UBound($numbers2) - 1
    For $b = 0 To UBound($numbers1) - 1
        ConsoleWrite("Dice: " & $numbers2[$b] & " ----------> " & " Number: " & $numbers1[$b] &@CRLF)
    Next
Next
; Es ist alles richtig und es passiert genau das, was dort geschrieben steht, ohne seltsame nebeneffekte.
; Du läufts von 0 bis UBound($numbers2)-1 => 0 bis 143 und führst alles in der Schleife 144x aus.
; Da du in der Schleife eine weitere Schleife hast, die auch von 0 bis 143 geht und diese für jeden der 144x durchlaufe einmal durchlaufen wird
; kommst du auf 144x144 durchläufe der Zeile => ConsoleWrite("Dice: " & $numbers2[$b] & " ----------> " & " Number: " & $numbers1[$b] &@CRLF)
; Hier ist es kein Fehler in AutoIt oder beim Programmieren, sondern ein Logik-Fehler, was genau du umsetzen willst

For $a = 0 To 143
    For $b = 0 To 143
        ConsoleWrite("Dice: " & $numbers2[$b] & " ----------> " & " Number: " & $numbers1[$b] &@CRLF)
    Next
Next
; Selbe wie vorher, nur dass du die Größe der Arrays nicht verändern darfst

For $a = 0 To $numbers2[$a]
    For $b = 0 To $numbers1[$b]
        ConsoleWrite("Dice: " & $numbers2[$b] & " ----------> " & " Number: " & $numbers1[$b] &@CRLF)
    Next
Next
; Du gehst von $a=0 bis zu dem Wert, der in $numbers2[$a] steht, also in $numbers2[0] (Im ersten durchlauf)
; Da du die Arrays durchmischt, wird dort jedesmal eine andere Zahl stehen, welche auch immer dort hingemischt wurde...
; Wenn das zufällig 144 ist, wird das ganze mit ner Fehlermeldung abstürzen
; Das ganze ergibt also nicht mal Ansatzweise einen Sinn
; Selbes auch für das Beispiel, wo du nochmal 1 abziehst...



; Ich bin mir nicht sicher, was genau du machen willst, aber ich hab mal zwei sachen gebastelt, die vermutlich in die Richtung gehen...
Local $arData = [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]
Local $arData2 = [10, 9, 8, 7, 6, 5, 4, 3, 2, 1]

ConsoleWrite("--------------------------"&@crlf)
For $i=0 To UBound($arData)-1 Step 1
	ConsoleWrite($i&": "&$arData[$i]&" - "&$arData2[$i]&@crlf)
Next

ConsoleWrite("--------------------------"&@crlf)
For $i=0 To 100
	Local $iRandom = Random(0, UBound($arData)-1, 1)
	ConsoleWrite($iRandom&": "&$arData[$iRandom]&@crlf)
Next

Func _CypherEnigma($sString, $nKlein, $nGross, $nSonder, $nExtra)
	Local $arLetters = StringToASCIIArray($sString)
	Local $iExtra = $nExtra
	For $i=0 To UBound($arLetters)-1 Step 1
		Local $iCode = $arLetters[$i]
		If $iCode>64 And $iCode<91 Then
			$iCode = 65 + Mod($iCode + $nGross + $iExtra - 65, 26)
		ElseIf $iCode>96 And $iCode<123 Then
			$iCode = 97 + Mod($iCode + $nKlein + $iExtra - 97, 26)
		ElseIf $iCode>31 And $iCode<127 Then
			$iCode -= 32
			If $iCode>32 Then $iCode-=26
			If $iCode>38 Then $iCode-=26
			$iCode = Mod($iCode + $nSonder + $iExtra, 43) + 32
			If $iCode>64 Then $iCode+=26
			If $iCode>96 Then $iCode+=26
		EndIf
		$arLetters[$i] = $iCode
		$iExtra += $nExtra
	Next
	Return StringFromASCIIArray($arLetters)
EndFunc   ;==>_CypherEnigma

Global $sExampleText = "dieses kleine aber durchaus feine AutoIT test script soll einen total konfus"&@crlf& _
						"gewirbelten satz durch eine ini map wieder in einen lesbaren string bzw."&@crlf& _
						"array verwandeln. es basiert auf dem prinzip eines zwoelf mal zwoelf rasters"&@crlf& _
						"und stellt ein magisches quadrat dar. es ist das einfachste bzw. simpelste"&@crlf& _
						"magische quadrat was es im internet zu finden gibt. es besteht also"&@crlf& _
						"aus zwoelf worten in jeweils zwoelf reihen und zwoelf worten in jeweils"&@crlf& _
						"zwoelf spalten. somit sind es dann insgesamt 144 worte. ich habe das"&@crlf& _
						"ganze vorher in libre office calc ausrechen lassen wo welches wort stehen"&@crlf& _
						"muss um dann eine ini datei zu schreiben wo das richtige wort"&@crlf& _
						"aus dem text eigentlich stehen muss damit es auch einen sinn ergibt."&@crlf& _
						"AutoIT hilft dann dabei die ganzen woerter zu sortieren. ich finde das"&@crlf& _
						"immer so toll kleine scripte zu testen und ihr hoffentlich dann auch!"

; Print a square to console
; Local $arSquare = _calcMagicSquare(12)
; _printMagicSquare($arSquare)

; checking if the square generation works:
; For $i=0 To 100 Step 1
;	 Local $arSquare = _calcMagicSquare($i)
;	 If (Not _checkAllOneValue(_getArrayLineSums($arSquare))) Or (Not _checkAllOneValue(_getArrayLineSums($arSquare, True))) Then ConsoleWrite("Magic Square for "&$i&" was wrong."&@crlf)
; Next

; open encrypt/decrypt gui
_openGui()

Func _openGui()
	Local $iWidth = 1200, $iHeight=800, $iSpace = 10, $iCtrlHeight=25
	Local $hGui = GUICreate("Text scrambler", $iWidth, $iHeight)
	Local $iEditWidth = ($iWidth-($iSpace*3))/2, $iEditHeight = $iHeight-$iSpace*4-$iCtrlHeight*2
	Local $iWidth4th = ($iWidth-$iSpace*5)/4
	GUICtrlCreateLabel("Delimeter: ", $iSpace, $iSpace, $iWidth4th, $iCtrlHeight)
	Local $idInputDelimeter = GUICtrlCreateInput(" ", $iSpace*2+$iWidth4th, $iSpace, $iWidth4th, $iCtrlHeight)
	GUICtrlCreateLabel("Filler: ", $iSpace*3+$iWidth4th*2, $iSpace, $iWidth4th, $iCtrlHeight)
	Local $idInputFiller = GUICtrlCreateInput(".", $iSpace*4+$iWidth4th*3, $iSpace, $iWidth4th, $iCtrlHeight)
	Local $idEditClearText = GUICtrlCreateEdit($sExampleText, $iSpace, $iSpace*2+$iCtrlHeight, $iEditWidth, $iEditHeight)
	Local $idButtonEncrypt = GUICtrlCreateButton("Encrypt >>", $iSpace, $iHeight-$iSpace-$iCtrlHeight, $iEditWidth, $iCtrlHeight)
	Local $idEditEncrypted = GUICtrlCreateEdit("", $iSpace*2+$iEditWidth, $iSpace*2+$iCtrlHeight, $iEditWidth, $iEditHeight)
	Local $idButtonDecrypt = GUICtrlCreateButton("<< Decrypt", $iSpace*2+$iEditWidth, $iHeight-$iSpace-$iCtrlHeight, $iEditWidth, $iCtrlHeight)
	GUISetState(@SW_SHOW, $hGui)
	Local $iMsg
	While 1
		$iMsg = GUIGetMsg()
		Switch $iMsg
			Case -3
				Exit
			Case $idButtonEncrypt
				Local $sDelimeter = GUICtrlRead($idInputDelimeter)
				Local $sFiller = GUICtrlRead($idInputFiller)
				Local $sEncrypted = _cryptSquare(GUICtrlRead($idEditClearText), True, $sDelimeter, $sFiller)
				GUICtrlSetData($idEditEncrypted, $sEncrypted)
			Case $idButtonDecrypt
				Local $sDelimeter = GUICtrlRead($idInputDelimeter)
				Local $sFiller = GUICtrlRead($idInputFiller)
				Local $sEncrypted = _cryptSquare(GUICtrlRead($idEditEncrypted), False, $sDelimeter, $sFiller)
				If @error Then MsgBox(16, "Error", "Input length does not match any magic square size.")
				GUICtrlSetData($idEditClearText, $sEncrypted)
		EndSwitch
	WEnd
EndFunc

Func _cryptSquare($sText, $bEncrypt = True, $sDelimeter=" ", $sFiller = ".")
	Local $arParts = StringSplit($sText, $sDelimeter, BitOR(1,2))
	Local $iSize = Sqrt(UBound($arParts))
	If Mod($iSize, 1)<>0 Then $iSize = Int($iSize+1)
	If $iSize=2 Then $iSize+=1
	Local $arSquare = _calcMagicSquare($iSize)
	If $bEncrypt Then
		Local $sResult = ""
		For $i=0 To UBound($arSquare)-1 Step 1
			For $j=0 To UBound($arSquare)-1 Step 1
				Local $iVal = $arSquare[$i][$j]
				If $iVal>UBound($arParts) Then
					$sResult &= $sFiller
				Else
					$sResult &= $arParts[$arSquare[$i][$j]-1]
				EndIf
				If $i<UBound($arSquare)-1 Or $j<UBound($arSquare)-1 Then $sResult &= $sDelimeter
			Next
		Next
		Return $sResult
	Else
		Local $arResult[UBound($arParts)], $iCount = 0
		For $i=0 To UBound($arSquare)-1 Step 1
			For $j=0 To UBound($arSquare)-1 Step 1
				Local $iIndex = $arSquare[$i][$j]-1
				If $iCount>UBound($arParts)-1 Then Return SetError(1, 0, -1)
				If $iIndex<UBound($arResult) Then $arResult[$iIndex] = $arParts[$iCount]
				$iCount+=1
			Next
		Next
		Local $sResult = ""
		For $i=0 To UBound($arResult)-1 Step 1
			$sResult &= $arResult[$i]
			If $i<UBound($arResult)-1 Then $sResult&=$sDelimeter
		Next
		Return $sResult
	EndIf
EndFunc

Func _checkAllOneValue(ByRef $arArray)
	Local $iVal = $arArray[0]
	For $i=0 To UBound($arArray)-1 Step 1
		If $arArray[$i]<>$iVal Then Return False
	Next
	Return True
EndFunc

Func _printMagicSquare(ByRef $arSquare, $bShowInfo = True)
	Local $arSumRight, $arSumBottom
	If $bShowInfo Then
		$arSumRight = _getArrayLineSums($arSquare)
		$arSumBottom = _getArrayLineSums($arSquare, True)
	EndIf
	Local $iSize = UBound($arSquare)
	Local $iMaxLength = StringLen(String($iSize*$iSize))
	If $bShowInfo Then
		If StringLen($arSumBottom[UBound($arSumBottom)-1])+1>$iMaxLength Then $iMaxLength=StringLen($arSumBottom[UBound($arSumBottom)-1])+1
	EndIf
	Local $sNumberFormat = "%"&$iMaxLength&"d|"
	For $x=0 To $iSize-1 Step 1
		_printLine($iSize, $iMaxLength)
		ConsoleWrite("|")
		For $y=0 To $iSize-1 Step 1
			ConsoleWrite(StringFormat($sNumberFormat, $arSquare[$x][$y]))
		Next
		If $bShowInfo Then ConsoleWrite(" ="&$arSumRight[$x])
		ConsoleWrite(@crlf)
	Next
	If $bShowInfo Then
		_printLine($iSize, $iMaxLength)
		For $x=0 To $iSize-1 Step 1
			ConsoleWrite(StringFormat("%"&$iMaxLength+1&"s", "="&$arSumBottom[$x]))
		Next
		ConsoleWrite(@crlf)
	EndIf
EndFunc

; Last item contains the max sum
Func _getArrayLineSums(ByRef $arSquare, $bRow=False)
	Local $iSize = UBound($arSquare)
	Local $arSum[$iSize+1]
	For $i=0 To $iSize-1 Step 1
		Local $iSum = 0
		For $j=0 To $iSize-1 Step 1
			If $bRow Then
				$iSum += $arSquare[$j][$i]
			Else
				$iSum += $arSquare[$i][$j]
			EndIf
		Next
		$arSum[$i] = $iSum
		If $iSum>$arSum[$iSize] Then $arSum[$iSize] = $iSum
	Next
	Return $arSum
EndFunc

Func _printLine($iSegmentCount, $iSegmentLength)
	Local $sSep = ""
	For $x=0 To $iSegmentLength-1 Step 1
		$sSep&="-"
	Next
	ConsoleWrite("+")
	For $y=0 To $iSegmentCount-1 Step 1
		ConsoleWrite($sSep&"+")
	Next
	ConsoleWrite(@crlf)
EndFunc

; https://www.iupindia.in/910/IJCM_Magic_Square_Construction_Algorithms34.pdf
Func _calcMagicSquare($iSize)
	If $iSize=2 Then Return SetError(1, -1, -1) ; not possible for $iSize=2
	Local $arSquare[$iSize][$iSize]
	If $iSize=4 Then
		Local $arTmp = [[1, 15, 14, 4], [12, 6, 7, 9], [8, 10, 11, 5], [13, 3, 2, 16]] ; algorithm used only once, so why implement it
		Return $arTmp
	ElseIf Mod($iSize, 2)=0 Then ; size is even
		If Mod($iSize, 4)=2 Then
			Local $iMatMax = ($iSize*$iSize)/4, $iMatSize = $iSize/2
			Local $arM1 = _calcMagicSquare($iSize/2)
			; initial square
			For $i=0 To 1 Step 1
				For $j=0 To 1 Step 1
					Local $iAdd = 0
					If $i=1 And $j=0 Then $iAdd = $iMatMax*3
					If $i=0 And $j=1 Then $iAdd = $iMatMax*2
					If $i=1 And $j=1 Then $iAdd = $iMatMax
					For $x=0 To $iMatSize-1 Step 1
						For $y=0 To $iMatSize-1 Step 1
							$arSquare[$x+($i*$iMatSize)][$y+($j*$iMatSize)] = $arM1[$x][$y] + $iAdd
						Next
					Next
				Next
			Next
			; swapping around
			Local $iMatSizeHalf = Int($iMatSize/2)
			For $x=0 To $iMatSizeHalf-1
				For $y=0 To $iMatSizeHalf-1
					_swap($arSquare, $x, $y, $x+$iMatSize, $y)
				Next
			Next
			For $x=$iMatSizeHalf+1 To $iMatSize-1 Step 1
				For $y=0 To $iMatSizeHalf-1 Step 1
					_swap($arSquare, $x, $y, $x+$iMatSize, $y)
				Next
			Next
			Local $x=$iMatSizeHalf
			For $y=1 To $iMatSizeHalf Step 1
				_swap($arSquare, $x, $y, $x+$iMatSize, $y)
			Next
			For $x=0 To $iMatSize-1 Step 1
				For $y=($iMatSize-$iMatSizeHalf)+1 To $iMatSize-1 Step 1
					_swap($arSquare, $x, $y+$iMatSize, $x+$iMatSize, $y+$iMatSize)
				Next
			Next
		Else
			Local $iMatMax = ($iSize*$iSize)/4, $iMatSize = $iSize/2
			Local $arM1 = _calcMagicSquare($iSize/2)
			; initial square
			For $i=0 To 1 Step 1
				For $j=0 To 1 Step 1
					Local $iAdd = 0
					If $i=1 And $j=0 Then $iAdd = $iMatMax*2
					If $i=0 And $j=1 Then $iAdd = $iMatMax*3
					If $i=1 And $j=1 Then $iAdd = $iMatMax
					For $x=0 To $iMatSize-1 Step 1
						For $y=0 To $iMatSize-1 Step 1
							$arSquare[$x+($i*$iMatSize)][$y+($j*$iMatSize)] = $arM1[$x][$y] + $iAdd
						Next
					Next
				Next
			Next
			If Mod($iMatSize, 4) = 2 Then
				Local $iMiddleRows = Int($iMatSize/2)+1
				For $x=$iMiddleRows/2 To $iMatSize-$iMiddleRows/2 Step 1
					For $y=0 To $iMatSize-1 Step 1
						_swap($arSquare, $x, $y, $x, $y+$iMatSize)
					Next
				Next
				For $x=$iMiddleRows/2 To $iMatSize-$iMiddleRows/2 Step 1
					For $y=0 To $iMatSize-1 Step 1
						_swap($arSquare, $x+$iMatSize, $y, $x+$iMatSize, $y+$iMatSize)
					Next
				Next
			Else
				Local $iMiddleRows = $iMatSize/2
				For $x=$iMiddleRows/2 To $iMatSize-$iMiddleRows/2-1 Step 1
					For $y=0 To $iMatSize-1 Step 1
						_swap($arSquare, $x, $y, $x, $y+$iMatSize)
					Next
				Next
				For $x=$iMiddleRows/2 To $iMatSize-$iMiddleRows/2-1 Step 1
					For $y=0 To $iMatSize-1 Step 1
						_swap($arSquare, $x+$iMatSize, $y, $x+$iMatSize, $y+$iMatSize)
					Next
				Next
			EndIf
		EndIf
	Else ; size is odd
		Local $iN = 1, $x=0, $y=Int($iSize/2), $iLimit = $iSize*$iSize
		While $iN<=$iLimit
			If $arSquare[$x][$y]=0 Then
				$arSquare[$x][$y] = $iN
				$iN+=1
				$x -= 1
				If $x<0 Then $x=$iSize-1
				$y -= 1
				If $y<0 Then $y=$iSize-1
			Else
				$x = Mod($x+2, $iSize)
				$y = Mod($y+1, $iSize)
			EndIf
		WEnd
	EndIf
	Return $arSquare
EndFunc

Func _swap(ByRef $arSquare, $x1, $y1, $x2, $y2)
	Local $iTmp = $arSquare[$x1][$y1]
	$arSquare[$x1][$y1] = $arSquare[$x2][$y2]
	$arSquare[$x2][$y2] = $iTmp
EndFunc

#include <Array.au3>
_example2()

Func _example2()
	Local $mData = _readIniToMap("loesung.ini", "Data")
	Local $sMonth = 'Januar Februar Maerz April Mai Juni Juli August September Oktober November Dezember'
	Local $sNames = 'Paul Ursula Robert Marion Peter Nadine Stefan Esther Oliver Evelyn Michael Doris'
	Local $arMonth = StringSplit($sMonth, " ", BitOR(1, 2))
	Local $arNames = StringSplit($sNames, " ", BitOR(1, 2))
	_ArrayShuffle($arMonth, 0,11)
	_ArrayShuffle($arNames, 0,11)
	Local $arResult[UBound($arMonth)][3]
	For $i=0 To UBound($arMonth)-1 Step 1
		$arResult[$i][0] = $arNames[$i]
		$arResult[$i][1] = $arMonth[$i]
		Local $sRoom = _getRoom($mData, $arNames[$i], $arMonth[$i])
		If $sRoom<>-1 Then $arResult[$i][2] = "Raum "&$sRoom
	Next
	_ArrayDisplay($arResult)
EndFunc

_example()

_startGui()

Func _example()
	Local $mData = _readIniToMap("loesung.ini", "Data")
	Local $arNames = ["Paul", "Ursula", "Robert", "Marion", "Peter", "Nadine", "Stefan", "Esther", "Oliver", "Evelyn" ,"Michael", "Doris"]
	Local $arMonth = ["Januar", "Februar", "Maerz", "April", "Mai", "Juni", "Juli", "August", "September", "Oktober", "November", "Dezember"]
	For $i=0 To UBound($arNames)-1 Step 1
		For $j=0 To UBound($arMonth)-1 Step 1
			ConsoleWrite(StringFormat("%-10s is in %-10s in Room: %s", $arNames[$i], $arMonth[$j], _getRoom($mData, $arNames[$i], $arMonth[$j]))&@crlf)
		Next
	Next
EndFunc

Func _getRoom(ByRef $mData, $sName, $sMonth)
	If MapExists($mData, $sName) Then
		If MapExists($mData[$sName], $sMonth) Then Return $mData[$sName][$sMonth]
	EndIf
	Return -1
EndFunc

Func _readIniToMap($sFile, $sSection)
	Local $arSec = IniReadSection($sFile, $sSection)
	Local $mData[]
	For $i=1 To UBound($arSec)-1 Step 1
		;Local $arValue = StringSplit($arSec[$i][1], "|", BitOR(1, 2))
		;If UBound($arValue)<3 Then ContinueLoop
		Local $arValue = StringRegExp($arSec[$i][1], "([^|]*)\|(Januar|Februar|Maerz|April|Mai|Juni|Juli|August|September|Oktober|November|Dezember){1}\|Raum(\d+)", 1)
		If @error Then
			ConsoleWrite(StringFormat('Error reading IniKey "%s" with Value "%s"', $arSec[$i][0], $arSec[$i][1])&@crlf)
			ContinueLoop
		EndIf

		If MapExists($mData, $arValue[0]) Then
			$mData[$arValue[0]][$arValue[1]] = $arValue[2]
		Else
			Local $mEntry[]
			$mEntry[$arValue[1]] = $arValue[2]
			$mData[$arValue[0]] = $mEntry
		EndIf
	Next
	Return $mData
EndFunc

Func _startGui()
	Local $mData = _readIniToMap("loesung.ini", "Data")
	Local $arNames = MapKeys($mData)
	Local $sNames = ""
	For $i=0 To UBound($arNames)-1 Step 1
		$sNames&=$arNames[$i]
		If $i<>UBound($arNames)-1 Then $sNames&="|"
	Next
	Local $sMonth = "Januar|Februar|Maerz|April|Mai|Juni|Juli|August|September|Oktober|November|Dezember"
	Local $iWidth = 300, $iHeight = 100, $iSpace = 10, $iCtrlHeight = 20
	Local $hGui = GUICreate("Room searcher", $iWidth, $iHeight)
	Local $idComboNames = GUICtrlCreateCombo("", $iSpace, $iSpace, $iWidth-$iSpace*2, $iCtrlHeight)
	GUICtrlSetData($idComboNames, $sNames)
	Local $idComboMonth = GUICtrlCreateCombo("", $iSpace, $iSpace*2+$iCtrlHeight, $iWidth-$iSpace*2, $iCtrlHeight)
	GUICtrlSetData($idComboMonth, $sMonth)
	Local $idLabelRoom = GUICtrlCreateLabel("Raum: ", $iSpace, $iSpace*3+$iCtrlHeight*2, $iWidth-$iSpace*2, $iCtrlHeight)
	GUISetState(@SW_SHOW, $hGui)
	While True
		Local $iMsg = GUIGetMsg()
		Switch $iMsg
			Case -3
				Exit
			Case $idComboNames, $idComboMonth
				Local $sRoom = _getRoom($mData, GUICtrlRead($idComboNames), GUICtrlRead($idComboMonth))
				If $sRoom<>-1 Then
					GUICtrlSetData($idLabelRoom, "Raum: "&$sRoom)
				Else
					GUICtrlSetData($idLabelRoom, "Raum: ?")
				EndIf
		EndSwitch
	WEnd
EndFunc

Local $mData[]
$mData["Paul"] = "Something"
$mData["Mustermann"] = "Something else"
; dann kann man mit
ConsoleWrite("Paul: "&$mData["Paul"]&@crlf)
; auf die Daten zugreifen.
; in dem Code oben habe ich das ganze beim einlesen der Ini gemacht (_readIniToMap):
Local $mPersonData[]
$mPersonData["Januar"] = "Raum 103"
$mPersonData["Februar"] = "Raum 104"
$mData["Mustermann"] = $mPersonData
; Dann kann so auf die Infos zugegriffen werden:
ConsoleWrite("Mustermann im Januar: "&$mData["Mustermann"]["Januar"]&@crlf)