array(s) nach daten durchsuchen und zuordnen und damit dann ein neues array anlegen

bankesbusters

hallo zusammen,

ich nerve ein letztes mal glaube ich, zumindest ist das mein derzeitger plan, denn das meiste was ich fuer mein geplantes vorhaben/projekt brauche habe ich jetzt 'zusammengehamstert'. es geht abseits dieses problems nur noch um den zusammenbau und damit bin ich dann einige wochen/monate beschaeftigt.

ich habe nun eine simulation angefertigt und jene so gut es ging mit comments versehen

aber zum verständnis vorab: später werden die user eine eingabemaske mit 3 feldern sehen. in feld 1 gibt er seinen namen ein. in feld 2 gibt er den monat ein und aus dieser kombination wird dann feld 3 'errechnet' und ausgegeben.

damit keiner mit unnoetigen daten arbeiten muss, habe ich die eingabe von 12 namen und 12 monaten bereits angelegt. damit dann jedes mal eine andere _richtige_ loesung herauskommt, sind die 12 namen und die 12 monate jeweils durch einen shuffle durcheinandergemischt worden.

ich poste jetzt den gesamten code inklusive der kompletten loesungs-ini-datei. ich habe lediglich fehlerhafte (und inzwischen auskommentierte stellen aka fehlversuche) aus dem code entfernt.

alles klappt bis auf die eigentliche sache, die das script machen soll und es liegt wie immer an einer For-To-Next-Schleife ... bzw. 2x 1D-Array und 1x 2D-Array die miteinander verglichen bzw. abgelichen werden um dann das richtige ergebnis in ein neues 1x 1D-Array in der selben Reihenfolge wie die 12 eingaben sind abzuspeichern.

sprich: ein name und ein monat sind zusammen unzertrennlich und mit einem raum verbunden den es zu ermitteln gilt.

lange rede kurzer sinn, seht mal selbst:

komplette ini-datei (als text datei hochgeladen und begefuegt):

Der Inhalt kann nicht angezeigt werden, da du keine Berechtigung hast, diesen Inhalt zu sehen.

nun zum AutoIT-Code:

AutoIt

#include <MsgBoxConstants.au3>
#include <Array.au3>
#comments-start
als erstes holen wir uns die einzig _richtige_ loesung aus einer ini datei zum spaeteren vergleich:
ich habe mich fuer die varinate von schnuffel aus dem forum entschieden, weil es fuer meine zwecke
glaube ich genau das ist was ich benoetige und nach ein wenig anpassung es toll geklappt hat. danke.
#comments-end
Global $ini = @ScriptDir & "\loesung.ini"
Global $iniOutput[1][1]
Global $sections = IniReadSectionNames($ini)
For $a = 1 To UBound($sections) - 1
   $keys = IniReadSection($ini, $sections[$a])
    Redim $iniOutput[UBound($keys)][3]
   For $b = 1 To UBound($keys) - 1
       $data = StringSplit($keys[$b][1], '|')
        $iniOutput[$b][0] = $data[1]
        $iniOutput[$b][1] = $data[2]
        $iniOutput[$b][2] = $data[3]
   Next
Next
_ArrayDisplay($iniOutput) ;  dies ist nur ein test zur kontrolle der daten!
_ArrayDelete($iniOutput, 0) ; wir loeschen die leere zeile am anfang des arrays
_ArrayDisplay($iniOutput) ; dies ist nur ein test zur kontrolle der daten!
Global $monate, $namen
#comments-start
die folgenden daten waeren daten die von Usern eingegeben werden muessen: Monat und Name!
Die Monate Januar bis Dezember in Verbindung mit 12 unterschiedlichen Namen von Usern.
hier folgt nun eine komplette liste der monate und namen als liste als anschauliches beispiel:
#comments-end
$monate = 'Januar Februar Maerz April Mai Juni Juli August September Oktober November Dezember'
MsgBox(0, "MONATE", $monate) ; dies ist nur ein test zur kontrolle der daten!
$namen = 'Paul Ursula Robert Marion Peter Nadine Stefan Esther Oliver Evelyn Michael Doris'
MsgBox(0, "NAMEN", $namen) ; dies ist nur ein test zur kontrolle der daten!
#comments-start
jetzt wandeln wir die auflistung der Monate und die auflistung der Namen jeweils in ein array um
und nutzen hierzu die stringsplit moeglichkeit wobei die leerschritte als 'delimiter' genutzt werden:
ich weiss, ich haette einfach direkt ein array darus machen koennen, aber ich moechte ja die eingabe
vom user 'simulieren'. die user geben einen string ein und das wird dann vom script als array 
gespeichert bzw. weiter verarbeitet. 
#comments-end
$arr_monate = StringSplit($monate," ",$STR_NOCOUNT) ; no-count damit array sofort mit daten beginnt
_ArrayDisplay($arr_monate, "MONATE") ; dies ist nur ein test zur kontrolle der daten!
$arr_namen = StringSplit($namen," ",$STR_NOCOUNT) ; no-count damit array sofort mit daten beginnt
_ArrayDisplay($arr_namen, "NAMEN") ; dies ist nur ein test zur kontrolle der daten!
#comments-start
an dieser stelle sollen eingaben in einer eingabemaske 'simuliert' werden. spaeter in der GUI
gibt es zwei eingabefelder in der die entsprechenden daten eingegeben werden muessen um dann
das ergebnis zu bekommen ... zum thema ermittlung vom ergebnis: spaeter (weiter unten) mehr!
[ ... ]
zur eingabesimulation nutzen wir jetzt einen _ArrayShuffle() damit bei jedem neuen versuch
ein anderes ergebnis zu ermitteln ist. es gibt 144*144 = 20736 moeglichkeiten (glaube ich
zumindest, aber es koennte auch 144*144*144 sein) also sollte so die funktion vom script 
eigentlich gut zu testen sein auf ihr koennen:
#comments-end
_ArrayShuffle($arr_monate, 0,11) ; daten durch die waschmaschiene jagen.
_ArrayDisplay($arr_monate, "M-SHUFF.") ; dies ist nur ein test zur kontrolle der daten!
_ArrayShuffle($arr_namen, 0,11) ; daten durch die waschmaschiene jagen.
_ArrayDisplay($arr_namen, "N-SHUFF.") ; dies ist nur ein test zur kontrolle der daten!
#comments-start
so nun kommen wir zu der magie ... ab hier beginnt die arbeit, die das script erledigen soll:
der plan sieht so aus: das script hat also jetzt 12 monatseingaben und 12 namenseingaben erhalten
und nun soll der dazugehörige Raum ermittelt werden. hierzu muessen die arrays verglichen werden
also wenn der name aus der eingegebenen namensliste ($arr_namen) und der monat aus der eingegebenen
monatsliste ($arr_monate) mit name und monat der ini-loesungs-datei-array ($iniOutput) uebereinstimmen,
so soll in einem neuen array ($result) die entsprechende raumnummer in der _richtigen_ reihenfolge
(sprich genau die gleiche reihenfolge der eingegebenen daten) wieder ausgegeben werden.
zunächst (zu testzwecken) fuer alle 12 eingaben direkt und spaeter (im eigentlichen geplanten script)
nur bei einer einzelnen eingabe von name und monat. sprich: wenn ein monat und ein namen eingegeben
wird, so wird zu diesem namen und zu diesem monat die entsprechende Raumnummer ausgegeben.
also versuchen wir mal unser glueck:
#comments-end
Global $result[1] ; wir stellen ein neues array her um dort die loesung zu speichern, die wir suchen  ... 1D-Array
_ArrayDisplay($result)  ; dies ist nur ein test zur kontrolle der daten!
Global $arows = UBound($iniOutput, $UBOUND_ROWS) ; erstellte daten für die For-To-Next-Schleife für $iniOutput (loesungsdaten) ... 2D-Array
Global $acols = UBound($iniOutput, $UBOUND_COlUMNS) ; erstellte daten für die For-To-Next-Schleife für $iniOutput (loesungsdaten) ... 2D-Array
Global $adims = UBound($iniOutput, $UBOUND_DIMENSIONS) ; erstellte daten für die For-To-Next-Schleife für $iniOutput (loesungsdaten) ... 2D-Array
Global $brows = UBound($arr_monate, $UBOUND_ROWS) ; erstellte daten für die For-To-Next-Schleife für $arr_monate (die eingegebenen monate) ... 1D-Array
Global $bcols = UBound($arr_monate, $UBOUND_COlUMNS) ; erstellte daten für die For-To-Next-Schleife für $arr_monate (die eingegebenen monate) ... 1D-Array
Global $bdims = UBound($arr_monate, $UBOUND_DIMENSIONS) ; erstellte daten für die For-To-Next-Schleife für $arr_monate (die eingegebenen monate) ... 1D-Array
Global $crows = UBound($arr_namen, $UBOUND_ROWS) ; erstellte daten für die For-To-Next-Schleife für $arr_namen (die eingegebenen namen) ... 1D-Array
Global $ccols = UBound($arr_namen, $UBOUND_COlUMNS) ; erstellte daten für die For-To-Next-Schleife für $arr_namen (die eingegebenen namen) ... 1D-Array
Global $cdims = UBound($arr_namen, $UBOUND_DIMENSIONS) ; erstellte daten für die For-To-Next-Schleife für $arr_namen (die eingegebenen namen) ... 1D-Array
Global $drows = UBound($result, $UBOUND_ROWS) ; erstellte daten für die For-To-Next-Schleife für $result (die auszugebene loesung) ... 1D-Array
Global $dcols = UBound($result, $UBOUND_COlUMNS) ; erstellte daten für die For-To-Next-Schleife für $result (die auszugebene loesung) ... 1D-Array
Global $ddims = UBound($result, $UBOUND_DIMENSIONS) ; erstellte daten für die For-To-Next-Schleife für $result (die auszugebene loesung) ... 1D-Array
#cs
;jetzt pruefen wir ob die daten der eingegebenen namen auch ausgegeben werden
ConsoleWrite("-----------"&"Array: $arr_namen"&"-----------"&@crlf)
For $1 = 0 To $crows -1
    ;ConsoleWrite($arr_namen[$1] & " _ ") ;funktioniert: ausgabe der namen _nach_ dem shuffle
    ConsoleWrite("Access $arr_namen["&$1&"]: "&$arr_namen[$1]&@crlf)
Next
;pruefung (mit erfolg) beendet: die liste der namen wird korrekt ausgegeben
;ConsoleWrite(@CRLF & @CRLF) ; einfach nur wegen der uebersichtlichkeit
;jetzt pruefen wir ob die daten der eingegebenen monate auch ausgegeben werden
ConsoleWrite("-----------"&"Array: $arr_monate"&"-----------"&@crlf)
For $2 = 0 To $brows - 1
    ;ConsoleWrite($arr_monate[$2] & " _ ") ;funktioniert: ausgabe der monate _nach_ dem shuffle
    ConsoleWrite("Access $arr_monate["&$2&"]: "&$arr_monate[$2]&@crlf)
Next
;pruefung (mit erfolg) beendet: die liste der monate wird korrekt ausgegeben
;ConsoleWrite(@CRLF & @CRLF) ; einfach nur wegen der uebersichtlichkeit
;jetzt pruefen wir ob die daten der loesung (ini datei array) auch ausgegeben werden
ConsoleWrite("-----------"&"Array: $iniOutput"&"-----------"&@crlf)
For $3a = 0 To $arows - 1
    For $3b = 0 To $acols - 1
        ;ConsoleWrite($iniOutput[$3a][$3b] & " _ ") ; funktioniert: ausgabe der gesamten loesungsliste
        ConsoleWrite("Access $iniOutput["&$3a&"]["&$3b&"]: "&$iniOutput[$3a][$3b]&@crlf)
    Next
Next
;pruefung (mit erfolg) beendet: die liste der loesung wird korrekt ausgegeben
#ce
#comments-start
jetzt versuchen wir mal das ganze aufzuloesen in einer For-To-Next-Schleife:
#comments-end
For $4a = 0 To $arows - 1 ;$arows: loesungsarray (2D-Array)
    For $4b = 0 To $acols - 1 ;$acols: loesungsarry (2D-Array)
        ConsoleWrite("Access $iniOutput["&$4a&"]["&$4b&"]: "&$iniOutput[$4a][$4b]&@crlf)
        For $5 = 0 To $crows - 1 ;$crows: namensarray (1D-Array)
            ConsoleWrite("Access $arr_namen["&$5&"]: "&$arr_namen[$5]&@crlf)
            For $6 = 0 To $brows - 1 ;$brows: monatsarray (1D-Array)
                ConsoleWrite("Access $arr_monate["&$6&"]: "&$arr_monate[$6]&@crlf)
                    For $7 = 0 To $drows - 1 ;$drows: ausgabearray (1D-Array)
                    ConsoleWrite("Access $result["&$7&"]: "&$result[$7]&@crlf)
                    If $arr_namen[$5] = $iniOutput[$4a][$4b] And $arr_monate[$6] = $iniOutput[$4a][$4b] Then
                   $iniOutput[$4a][2] = _ArrayAdd($result, $result[$7])
               EndIf
                Next
            Next
        Next
    Next
Next
_ArrayDisplay($result, "loesung") ; normalerweise haben wir jetzt die loesungsdaten, aber heute noch nicht ... denkfehler?
#comments-start
im prinzip soll das in etwa diese funktion haben (vereinfachtes beispiel ... aber snytax inkorrekt)!
If $arr_namen[0 - 11] = $iniOutput[gleich wie $arr_namen[0 - 11]][0] And $arr_monate[0 - 11] = $iniOutput[gleich wie $arr_monate[0 - 11]][1] Then
_ArrayAdd($result, $iniOutput[an korrter stelle die Raumnummer][2])
#comments-end

Alles anzeigen

ich weiss nicht ob das alles so nachvollziehbar ist? das ganze scheitert nur an der letzten Schleife, weil die wahrscheinlich total falsch ist.

in manuellen versuchen habe ich zumindest ansatzweise erfolg gehabt mit vielen vielen vielen solchen zeilen. bei 144 zeilen hatte ich manchmal zwischen 0 und 2 treffern, als weiss ich zumindest, das es so halbwegs funktioniert:

AutoIt

If $arr_namen[0] = $iniOutput[0][0] And $arr_monate[0] = $iniOutput[0][1] Then _ArrayAdd($result, $iniOutput[0][2])
If $arr_namen[1] = $iniOutput[1][0] And $arr_monate[1] = $iniOutput[1][1] Then _ArrayAdd($result, $iniOutput[1][2])
If $arr_namen[2] = $iniOutput[2][0] And $arr_monate[2] = $iniOutput[2][1] Then _ArrayAdd($result, $iniOutput[2][2])
If $arr_namen[3] = $iniOutput[3][0] And $arr_monate[3] = $iniOutput[3][1] Then _ArrayAdd($result, $iniOutput[3][2])
If $arr_namen[4] = $iniOutput[4][0] And $arr_monate[4] = $iniOutput[4][1] Then _ArrayAdd($result, $iniOutput[4][2])
If $arr_namen[5] = $iniOutput[5][0] And $arr_monate[5] = $iniOutput[5][1] Then _ArrayAdd($result, $iniOutput[5][2])
If $arr_namen[6] = $iniOutput[6][0] And $arr_monate[6] = $iniOutput[6][1] Then _ArrayAdd($result, $iniOutput[6][2])
If $arr_namen[7] = $iniOutput[7][0] And $arr_monate[7] = $iniOutput[7][1] Then _ArrayAdd($result, $iniOutput[7][2])
If $arr_namen[8] = $iniOutput[8][0] And $arr_monate[8] = $iniOutput[8][1] Then _ArrayAdd($result, $iniOutput[8][2])
If $arr_namen[9] = $iniOutput[9][0] And $arr_monate[9] = $iniOutput[9][1] Then _ArrayAdd($result, $iniOutput[9][2])
If $arr_namen[10] = $iniOutput[10][0] And $arr_monate[10] = $iniOutput[10][1] Then _ArrayAdd($result, $iniOutput[10][2])
If $arr_namen[11] = $iniOutput[11][0] And $arr_monate[11] = $iniOutput[11][1] Then _ArrayAdd($result, $iniOutput[11][2])

Alles anzeigen

wo sind die denkfehler? ich bin in der For-To-Next-Schleife jede instanz durchgegangen und normalerweise muesste das doch so funktionieren. meine ausgabe array ($result) bleibt aber leer und ein fehler bekomme ich nicht angezeigt, also weiss ich nicht genau wo der fehler liegt.

ich danke für jegliche hilfe.

gruss

**Kanashius**

Wenn ich deine Beschreibung richtig verstanden habe, ist das Ziel ein Programm, in dem du den Namen und Monat auswählst und dann den zugehörigen Raum angezeigt bekommst.
Ich würde in dem Fall nicht mit Arrays, sondern mit Maps arbeiten. Die sind extra dafür da, Daten so abzulegen, dass man mit Schlüsselwörtern (Name/Monat) schnell darauf zugreifen kann:

AutoIt

_example()

_startGui()

Func _example()
	Local $mData = _readIniToMap("loesung.ini", "Data")
	Local $arNames = ["Paul", "Ursula", "Robert", "Marion", "Peter", "Nadine", "Stefan", "Esther", "Oliver", "Evelyn" ,"Michael", "Doris"]
	Local $arMonth = ["Januar", "Februar", "Maerz", "April", "Mai", "Juni", "Juli", "August", "September", "Oktober", "November", "Dezember"]
	For $i=0 To UBound($arNames)-1 Step 1
		For $j=0 To UBound($arMonth)-1 Step 1
			ConsoleWrite(StringFormat("%-10s is in %-10s in Room: %s", $arNames[$i], $arMonth[$j], _getRoom($mData, $arNames[$i], $arMonth[$j]))&@crlf)
		Next
	Next
EndFunc

Func _getRoom(ByRef $mData, $sName, $sMonth)
	If MapExists($mData, $sName) Then
		If MapExists($mData[$sName], $sMonth) Then Return $mData[$sName][$sMonth]
	EndIf
	Return -1
EndFunc

Func _readIniToMap($sFile, $sSection)
	Local $arSec = IniReadSection($sFile, $sSection)
	Local $mData[]
	For $i=1 To UBound($arSec)-1 Step 1
		;Local $arValue = StringSplit($arSec[$i][1], "|", BitOR(1, 2))
		;If UBound($arValue)<3 Then ContinueLoop
		Local $arValue = StringRegExp($arSec[$i][1], "([^|]*)\|(Januar|Februar|Maerz|April|Mai|Juni|Juli|August|September|Oktober|November|Dezember){1}\|Raum(\d+)", 1)
		If @error Then
			ConsoleWrite(StringFormat('Error reading IniKey "%s" with Value "%s"', $arSec[$i][0], $arSec[$i][1])&@crlf)
			ContinueLoop
		EndIf

		If MapExists($mData, $arValue[0]) Then
			$mData[$arValue[0]][$arValue[1]] = $arValue[2]
		Else
			Local $mEntry[]
			$mEntry[$arValue[1]] = $arValue[2]
			$mData[$arValue[0]] = $mEntry
		EndIf
	Next
	Return $mData
EndFunc

Func _startGui()
	Local $mData = _readIniToMap("loesung.ini", "Data")
	Local $arNames = MapKeys($mData)
	Local $sNames = ""
	For $i=0 To UBound($arNames)-1 Step 1
		$sNames&=$arNames[$i]
		If $i<>UBound($arNames)-1 Then $sNames&="|"
	Next
	Local $sMonth = "Januar|Februar|Maerz|April|Mai|Juni|Juli|August|September|Oktober|November|Dezember"
	Local $iWidth = 300, $iHeight = 100, $iSpace = 10, $iCtrlHeight = 20
	Local $hGui = GUICreate("Room searcher", $iWidth, $iHeight)
	Local $idComboNames = GUICtrlCreateCombo("", $iSpace, $iSpace, $iWidth-$iSpace*2, $iCtrlHeight)
	GUICtrlSetData($idComboNames, $sNames)
	Local $idComboMonth = GUICtrlCreateCombo("", $iSpace, $iSpace*2+$iCtrlHeight, $iWidth-$iSpace*2, $iCtrlHeight)
	GUICtrlSetData($idComboMonth, $sMonth)
	Local $idLabelRoom = GUICtrlCreateLabel("Raum: ", $iSpace, $iSpace*3+$iCtrlHeight*2, $iWidth-$iSpace*2, $iCtrlHeight)
	GUISetState(@SW_SHOW, $hGui)
	While True
		Local $iMsg = GUIGetMsg()
		Switch $iMsg
			Case -3
				Exit
			Case $idComboNames, $idComboMonth
				Local $sRoom = _getRoom($mData, GUICtrlRead($idComboNames), GUICtrlRead($idComboMonth))
				If $sRoom<>-1 Then
					GUICtrlSetData($idLabelRoom, "Raum: "&$sRoom)
				Else
					GUICtrlSetData($idLabelRoom, "Raum: ?")
				EndIf
		EndSwitch
	WEnd
EndFunc

Alles anzeigen

Ich habe hier eine Funktion erstellt, welche die Ini in eine Map einliest. Bei einer Map wird anders als bei einem Array, nicht mit einer Zahl als Index auf einen Wert zugegriffen, sondern stattdessen mit beliebigen Daten. Hier mit dem Namen oder dem Monat.
Dabei ist das ganze hier in zwei Maps verschachtelt (wie ein 2D-Array).
Eine Map, bei der man mit dem Namen eine weitere Map bekommt, in der für jeden Monat der Raum steht.

Code

Local $mData[]
$mData["Paul"] = "Something"
$mData["Mustermann"] = "Something else"
; dann kann man mit
ConsoleWrite("Paul: "&$mData["Paul"]&@crlf)
; auf die Daten zugreifen.
; in dem Code oben habe ich das ganze beim einlesen der Ini gemacht (_readIniToMap):
Local $mPersonData[]
$mPersonData["Januar"] = "Raum 103"
$mPersonData["Februar"] = "Raum 104"
$mData["Mustermann"] = $mPersonData
; Dann kann so auf die Infos zugegriffen werden:
ConsoleWrite("Mustermann im Januar: "&$mData["Mustermann"]["Januar"]&@crlf)

Alles anzeigen

Das ganze hat auch den Vorteil, dass ich alle Namen aus der $mData Map mit MapKeys($mData) auslesen kann und dann ein Array mit allen Namen aus der Ini-Datei habe, was ich in dem Code nutze um die ComboBox mit Namen zu befüllen.
Da sich die Monate nicht ändern, musst du das Script also nie anpassen, wenn du eine weitere Person hinzufügst. Es reicht die Datei in der Ini hinzuzufügen.

Du hast übrigens in der Ini bei einigen Nutzern "Mai" und bei anderen "May" als Monat angegeben, deshalb wird der Raum für manche Nutzer im Mai nicht gefunden.
Deshalb hab ich mal beim einlesen der Ini das StringSplit mit einem RegExp ausgetauscht. Dadurch wird die Ini geprüft, ob die Eingabe richtig ist, oder ob irgendwo ein Fehler ist und der Fehler ggf. ausgegeben.

bankesbusters

hi,

so toll das auch ist (und es ist echt toll), glaube ich nicht das dies die loesung ist wonach ich suche, weil:

ich muss das tatsächlich in array form zum laufen bringen, denn es geht tatsaechlich um die extakte reihenfolge der namen, monate und raeume.

der shuffle ist nur dazu da um zu sehen ob das ergebnis immer unter allen bedingungen das gleiche richtige ergebnis ausgibt wie in der ini vorgegeben ist.

der name der in &arr_namen[0] steht UND der monat der in &arr_monat[0] steht muss immer als erstes in der loesungsarray $result[0] stehen. das verhältnis zueinander ist bei deiner loesung zwar gewaerhleistet, aber die reihenfolge ist ganz entscheidend wichtig bei dem projekt. also es geht wirklich um die beziehung zwischen der exakten position und den darin enthaltenen daten und der suche nach der einzig richtigen loesungsantwort in der ini datei und die einzige richtige loesung von dort dann an diese stelle auszugeben.

die zwoelf namen sind in einer bestimmten reihenfolge also zum beispiel:

Code

$position_01    ==============     $arr_namen[0] = "Paul"      ==============	 $arr_monate[0] = "Maerz" 		==============	$result[0] = "Raum_X"
$position_02    ==============     $arr_namen[1] = "Michael"   ==============    $arr_monate[1] = "August"		==============	$result[1] = "Raum_X"
$position_03    ==============     $arr_namen[2] = "Stefan"    ==============    $arr_monate[2] = "September"	==============	$result[2] = "Raum_X"
$position_04    ==============     $arr_namen[3] = "Nadine"    ==============    $arr_monate[3] = "Januar"		==============	$result[3] = "Raum_X"
$position_05    ==============     $arr_namen[4] = "Robert"    ==============    $arr_monate[4] = "Juni"		==============	$result[4] = "Raum_X"
$position_06    ==============     $arr_namen[5] = "Esther"    ==============    $arr_monate[5] = "Juli"		==============	$result[5] = "Raum_X"
$position_07    ==============     $arr_namen[6] = "Evelyn"    ==============    $arr_monate[6] = "Dezember"	==============	$result[6] = "Raum_X"
$position_08    ==============     $arr_namen[7] = "Oliver"    ==============    $arr_monate[7] = "April"		==============	$result[7] = "Raum_X"
$position_09    ==============     $arr_namen[8] = "Ursula"    ==============    $arr_monate[8] = "November"	==============	$result[8] = "Raum_X"
$position_10    ==============     $arr_namen[9] = "Marion"    ==============    $arr_monate[9] = "Februar"		==============	$result[9] = "Raum_X"
$position_11    ==============     $arr_namen[10] = "Doris"    ==============    $arr_monate[10] = "Dezember"	==============	$result[10] = "Raum_X"
$position_12    ==============     $arr_namen[11] = "Peter"    ==============    $arr_monate[11] = "Mai"		==============	$result[11] = "Raum_X"

Raum_X = "X" stehend für die nummer aus der ini-datei bzw. des ini-arrays

Alles anzeigen

deswegen auch die suche nach einem genauen durchsuchen der 3 arrays und dann aus dem ini-array die einzige richtige loesung zu erfassen und exakt an der stelle wieder auszugeben wo sie urspruenglich abgefragt wurde. also position 1 muss unbedingt auf position 1 bleiben und nicht etwa auf position 5.

das mit der falschen positon hatte ich bei meiner manuellen versuchen naemlich auch gehabt, aber ich wollte erst einmal das ich ueberhaupt daten habe um dann solange daran rumzuschrauben bis die daten auch wirklich an der stelle stehen von wo sie abgefragt worden. die beziehungen der daten und postionen sind also das aller wichtigste fuer mich.

---

wie gesagt, es heisst nicht, dass die map loesung 'schlecht' ist, aber fuer _dieses_ projekt glaube ich nicht die richtige moeglichkeit?

ich brauche als loesung quasi ein array welches in den in einen string umwandeln und ausgeben kann und der muss zu den eingegebenen positionen stimmen.

bei der map loesung kann zwar die genaue beziehung abgefragt werden aber (glaube ich) ggf. nicht an exakt der gleichen stelle wieder ausgegeben werden. ich kann bei der map loesung wirklich einzelne daten gezielt abfragen und immer die richtige loesung erhalten, welches sogar total nuetzlich ist um das script auf die richtigkeit zu ueberpruefen, aber eine verbindung zu der genauen position sehe ich damit nicht wirklich umsetzbar. (ich mag mich irren, weil anfaenger, aber ich denke hier geht es 'nur' um die richtige loesung in bezug auf raum und nicht in bezug auf position und raum.

etwas verstaendlicher?

gruss

PS: trotz allem bin ich auch dankbar fuer diesen loesungsansatz, da er mir wieder ganz neue moeglichkeiten offenbart, die ich an anderer stelle prima nutzen kann. deswegen trotzdem vielen dank. ich hatte vorher noch keinerlei tutorial zu maps gesehen oder gesucht, also ist das ein thema was mir jetzt nicht wirklich bekannt war. danke dafuer.

**Kanashius**

Doch, die Map ist immernoch die beste Möglichkeit, um den Raum von einer Namen/Monats kombination zu ermitteln.
Wie du die Namen/Monate speicherst und in welcher Reihenfolge kannst du dir frei aussuchen.

Wenn du diese Funktion in mein Script von vorher einfügst sollte es das sein, was du willst (wenn ich es jetzt richtig verstanden hab)

AutoIt

#include <Array.au3>
_example2()

Func _example2()
	Local $mData = _readIniToMap("loesung.ini", "Data")
	Local $sMonth = 'Januar Februar Maerz April Mai Juni Juli August September Oktober November Dezember'
	Local $sNames = 'Paul Ursula Robert Marion Peter Nadine Stefan Esther Oliver Evelyn Michael Doris'
	Local $arMonth = StringSplit($sMonth, " ", BitOR(1, 2))
	Local $arNames = StringSplit($sNames, " ", BitOR(1, 2))
	_ArrayShuffle($arMonth, 0,11)
	_ArrayShuffle($arNames, 0,11)
	Local $arResult[UBound($arMonth)][3]
	For $i=0 To UBound($arMonth)-1 Step 1
		$arResult[$i][0] = $arNames[$i]
		$arResult[$i][1] = $arMonth[$i]
		Local $sRoom = _getRoom($mData, $arNames[$i], $arMonth[$i])
		If $sRoom<>-1 Then $arResult[$i][2] = "Raum "&$sRoom
	Next
	_ArrayDisplay($arResult)
EndFunc

Alles anzeigen

bankesbusters

hi Kanashius

sorry wegen der spaeten antwort, ich musste erst testen, testen, testen und noch mehr testen ob es auch wirklich geht: ja, es klappt und es ist absolut genial! (millionen fachen dank.)

also ich habe das jetzt mal etwas 'modifiziert' um es so auszugeben wie ich es brauche, aber habe noch kleine fragen.

ergebnis nach mehreren manuellen versuchen der kontrolle (hier nur ein einziges beispiel ... mindestens 20 mal durchgetestet):

Code

                          ini       script    script2
oktober     michael       135       135       135
november    nadine        131       131       131
juni        oliver        121       121       121
september   robert        123       123       123
februar     evelyn        111       111       111
dezember    ursula        115       115       115
mai         paul          139       139       139
maerz       doris         137       137       137
april       marion        134       134       134
august      stefan        136       136       136
januar      esther        126       126       126
juli        peter         124       124       124

ini = ini datei (manuell alles nachgeschlagen)
script = das (leicht) modifizierte script von kanahius
script2 = das script von kanahius mit den dropdownlisten

alles perfekt

Alles anzeigen

die (leichten) modifizierungen die ich gemacht habe. in erster linie habe ich nur zwei zeilen 'geloescht' (auskommentiert) und vom ergebnis 2 spalten geloescht:

Code

#include <Array.au3>
_example2()
Func _example2()
    Local $mData = _readIniToMap("loesung.ini", "Data")
    Local $sMonth = 'Januar Februar Maerz April Mai Juni Juli August September Oktober November Dezember'
    Local $sNames = 'Paul Ursula Robert Marion Peter Nadine Stefan Esther Oliver Evelyn Michael Doris'
    Local $arMonth = StringSplit($sMonth, " ", BitOR(1, 2))
    Local $arNames = StringSplit($sNames, " ", BitOR(1, 2))
    _ArrayDisplay($arMonth) ; anzeigen nur zu test zwecken vorab bei monaten
    _ArrayShuffle($arMonth, 0,11)
    _ArrayDisplay($arMonth) ; anzeigen nur zu test zwecken zur ueberpruefung des shuffle bei monaten
    _ArrayDisplay($arNames) ; anzeigen nur zu test zwecken vorab bei namen
    _ArrayShuffle($arNames, 0,11)
    _ArrayDisplay($arNames) ; anzeigen nur zu test zwecken zur ueberpruefung des shuffle bei namen
    Local $arResult[UBound($arMonth)][3]
    For $i=0 To UBound($arMonth)-1 Step 1
        ;$arResult[$i][0] = $arNames[$i] <<<<<<<<<<<<< ========== wird nicht benoetigt fuer die ausgabe
        ;$arResult[$i][1] = $arMonth[$i] <<<<<<<<<<<<< ========== wird nicht benoetigt fuer die ausgabe
        Local $sRoom = _getRoom($mData, $arNames[$i], $arMonth[$i])
        If $sRoom<>-1 Then $arResult[$i][2] = "Raum "&$sRoom
    Next
    _ArrayDisplay($arResult) ; anzeige um zu sehen ob das ergebnis auch so klappt.
    _ArrayColDelete($arResult, 0) ; weg mit der ersten spalte. brauche ich nicht, weil hat user ja eingegeben
    _ArrayDisplay($arResult) ; anzeige zu testzwecken wegen geloeschter spalte!
    _ArrayColDelete($arResult, 0) ; weg mit der naechsten spalte. brauche ich nicht, weil hat der user eingegeben.
    _ArrayDisplay($arResult) ; mein gewunschtes ergebnis ... 'ja', 'ja' und nochmals 'ja' ... 'perfekt!'
EndFunc

Alles anzeigen

wahrscheinlich geht es noch ein wenig vereinfachter durch eine loeschung von den spalten in einem rutsch, aber das ergebnis stimmt und ist PERFEKT. ich werde jetzt daran noch testen, denn es gibt einige dinge die ich da noch ueberpruefen moechte um es auf herz und nieren zu testen, aber ich bin so unglaublich zufrieden, dass du dir das nicht vorstellen kannst, was das fuer mich bedeutet, danke danke danke!

dinge die auf meiner AutoIT-Liste sind, die noch zu erledigen sind:

Spoiler anzeigen

1) ini mit bedingungen einlesen. bsp: in ini steht eine zahl z.b. "327" und wenn diese eingelesen wird, dann soll zu jeder zahl in einer reihe die zahl "17" hinzugefuegt oder abgezogen werden und eventuelle weitere moeglichkeiten hierzu (jede reihe unterschiedliche werte hinzufuegen oder abziehen) ... ich glaube das kriege ich aber selber hin. zumindest werde ich es erstmal versuchen.

2) ein ini in eine map einlesen (gerade dabei das zu lernen bedingt durch das script von kanahius) und dann ein array in die selbe map einzulesen und dann das besagte array an vorgegebene stellen neu zusammensetzen (bsp. position[0][0] ist spaeter position [12][2] und position [1][0] ist spaeter position[3][5], etc.) und das ganze wieder rueckgaenig machen. das wird mit dieser map geschichte bestimmt gehen. mal sehen ich glaube ich muss mich wohl mehr mit map(s) beschaeftigen.

ich habe allerdings noch einige fragen:

du (und auch viele andere), ja teilweise sogar in den AutoIT hilfe-seiten und den darin enthaltenen beispielen arbeiten unglaublich oft und viel mit 'Func'. ich sehe den vorteil nicht wirklich davon, weil es macht alles nur (meiner meinung nach) unuebersichtlicher. ... du hast dann irgendwo im script "Func _example()" und musst dann erst suchen im script wo die func abgelegt ist (meist ganz unten) und wenn man auf func verzichtet, sieht man den kompletten notwendigen code an der stelle wo er abgearbeitet wird bzw. werden soll. ich sehe den vorteil nicht in der nutzung von funktionen. also wo ist der vorteil?

jetzt schreibe bitte nicht so etwas wie: "du kannst funktionen mehrmals nutzen an verschiedenen stellen" ... jetzt mal ehrlich, wie oft brauchst du ein und die selbe funktion in einem einzigen script? ich habe eine funktion noch nie ein zweites mal verwendet, oder wenn ich sie ein zweites mal verwendet werden musste, dann musste in der funktion irgend eine kleinigkeit geaendert werden, welches die nutzung der selben funktion ebenfalls unmoeglich machte. gebe mir doch mal bitte ein beispiel wo exakt die gleiche funktion sinnvoll mehrmals genutzt wird in einem script unabhaengig vom user oder usereingaben. geht doch gar nicht, oder doch?

jedenfalls meine (test)scripte arbeiten alle nach einem schema: wenn dies, dann das und dann jenes und danach etwas anderes. sprich nur wenn prozess 'a' ausgefuehrt wird kann prozess 'b' beginnen usw.

aber zu diesem topic meiner frage nach dem vergleich von 2D-array und 1D-array(s) und der ausgabe eines 1D-array als loesung ist jedenfalls 'erledigt'

wie gesagt, vielen dank an Kanashius

---

abseits dessen wuensche ich allen lesern ein frohes osterfest. heute ist kar-freitag ... meine bessere haelfte und dutzende von anderen bekannten sagen immer: 'heute (kar-freitag) ist fisch-tag' na dann guten appetit.

gruss

bankesbusters

**Kanashius**

Zitat von bankesbusters

ich habe allerdings noch einige fragen:
du (und auch viele andere), ja teilweise sogar in den AutoIT hilfe-seiten und den darin enthaltenen beispielen arbeiten unglaublich oft und viel mit 'Func'. ich sehe den vorteil nicht wirklich davon, weil es macht alles nur (meiner meinung nach) unuebersichtlicher. ... du hast dann irgendwo im script "Func _example()" und musst dann erst suchen im script wo die func abgelegt ist (meist ganz unten) und wenn man auf func verzichtet, sieht man den kompletten notwendigen code an der stelle wo er abgearbeitet wird bzw. werden soll. ich sehe den vorteil nicht in der nutzung von funktionen. also wo ist der vorteil?
jetzt schreibe bitte nicht so etwas wie: "du kannst funktionen mehrmals nutzen an verschiedenen stellen" ... jetzt mal ehrlich, wie oft brauchst du ein und die selbe funktion in einem einzigen script? ich habe eine funktion noch nie ein zweites mal verwendet, oder wenn ich sie ein zweites mal verwendet werden musste, dann musste in der funktion irgend eine kleinigkeit geaendert werden, welches die nutzung der selben funktion ebenfalls unmoeglich machte. gebe mir doch mal bitte ein beispiel wo exakt die gleiche funktion sinnvoll mehrmals genutzt wird in einem script unabhaengig vom user oder usereingaben. geht doch gar nicht, oder doch?
jedenfalls meine (test)scripte arbeiten alle nach einem schema: wenn dies, dann das und dann jenes und danach etwas anderes. sprich nur wenn prozess 'a' ausgefuehrt wird kann prozess 'b' beginnen usw.

Naja... es reicht ein Blick in dein Script, warum Funktionen Sinn machen:
Was ist denn _ArrayDisplay, _ArrayShuffle, ... Genau: Funktionen, die du mehrfach nutzt... wär jetzt doof, wenn du jedesmal den Code von _ArrayShuffle stattdessen dort hinschreiben würdest, oder?

Spoiler anzeigen

Der sieht nämlich so aus:

AutoIt

Func _ArrayShuffle(ByRef $aArray, $iStart_Row = 0, $iEnd_Row = 0, $iCol = -1)

	; Fisher-Yates algorithm

	If $iStart_Row = Default Then $iStart_Row = 0
	If $iEnd_Row = Default Then $iEnd_Row = 0
	If $iCol = Default Then $iCol = -1

	If Not IsArray($aArray) Then Return SetError(1, 0, -1)
	Local $iDim_1 = UBound($aArray, $UBOUND_ROWS)
	If $iEnd_Row = 0 Then $iEnd_Row = $iDim_1 - 1
	If $iStart_Row < 0 Or $iStart_Row > $iDim_1 - 1 Then Return SetError(3, 0, -1)
	If $iEnd_Row < 1 Or $iEnd_Row > $iDim_1 - 1 Then Return SetError(3, 0, -1)
	If $iStart_Row > $iEnd_Row Then Return SetError(4, 0, -1)

	Local $vTmp, $iRand
	Switch UBound($aArray, $UBOUND_DIMENSIONS)
		Case 1
			For $i = $iEnd_Row To $iStart_Row + 1 Step -1
				$iRand = Random($iStart_Row, $i, 1)
				$vTmp = $aArray[$i]
				$aArray[$i] = $aArray[$iRand]
				$aArray[$iRand] = $vTmp
			Next
			Return 1
		Case 2
			Local $iDim_2 = UBound($aArray, $UBOUND_COLUMNS)
			If $iCol < -1 Or $iCol > $iDim_2 - 1 Then Return SetError(5, 0, -1)
			Local $iCol_Start, $iCol_End
			If $iCol = -1 Then
				$iCol_Start = 0
				$iCol_End = $iDim_2 - 1
			Else
				$iCol_Start = $iCol
				$iCol_End = $iCol
			EndIf
			For $i = $iEnd_Row To $iStart_Row + 1 Step -1
				$iRand = Random($iStart_Row, $i, 1)
				For $j = $iCol_Start To $iCol_End
					$vTmp = $aArray[$i][$j]
					$aArray[$i][$j] = $aArray[$iRand][$j]
					$aArray[$iRand][$j] = $vTmp
				Next
			Next
			Return 1
		Case Else
			Return SetError(2, 0, -1)
	EndSwitch

EndFunc   ;==>_ArrayShuffle

Alles anzeigen

Ein weiterer wichtiger Punkt ist nicht nur die Wiederverwendbarkeit (was in meinem Script auch schon mehrfach auftaucht: _readIniToMap wird 2x genutzt, _getRoom 3x,... ) sondern auch die Struktur.
Je größer ein Programm wird, desto unübersichtlicher wird es. Deshalb gibt es auch so als Richtwert: Wenn ein Codeabschnitt (auch in einer Funktion) mehr als so ca. 30 Zeilen hat sollte er in eine eigene Funktion (gibt natürlich ausnahmen, aber in die Richtung geht es).
Die Aufgabe wird dadurch in mehrere Abschnitte unterteilt, was das ganze übersichtlicher macht.
Wenn jemand sich neuen Code von jemand anders anschaut um den zu Verstehen ist es halt übersichtlicher zu sehen:

Code

Func _processData()
	Local $arData = _readData()
	$arData = _removeDuplicates($arData)
	$arData = _multiplyDataValues($arData)
	_saveData($arData)
EndFunc

Wo ich abstrahiert erfahre, was gemacht wird. Einlesen->Duplikate entfernen->Daten multiplizieren (als Beispiel für z.B. Zahlen)->Ergebnis speichern.
Insbesondere, wenn ich später mal was verändern will, weiß ich direkt, in welchen Abschnitt ich gehen muss um ihn mir anzuschauen.
Ich habe nicht direkt 200 Zeilen Code und muss rausfinden, wo jetzt was passiert, sondern kann direkt zu dem Abschnitt/der Funktion gehen, die ich verändern muss.

Dazu kommt, dass Funktionen normalerweise auch genutzt werden um bestimmte Aufgaben zu erledigen.
Am besten ist es dabei, wenn die Funktion alles, was sie braucht als Parameter bekommt und auf keine Globalen Variablen oder ähnliches zugreifen muss.
Ich kann dann eine Funktion schreiben, die z.B. zwei Matritzen multipliziert und übergebe dort die beiden Matrizen als Parameter.
Ich habe dann ein geschlossenes System, das genau eine Aufgabe hat: Die beiden Matritzen-Parameter zu multiplizieren und kann genau schauen, wie das passiert und ggf. Fehler korrigieren, ohne das ich das gesamte Script kennen muss, weil ich keine Ahnung hab, wo die Variable denn jetzt herkommt, die 100 Zeilen zuvor erstellt wurde, 10x zwischendurch verändert wird und dann am Ende bei meiner Multiplikation landet.

Und wenn man immer mit diesem Stil programmiert macht man das natürlich auch in kleinen 50 Zeilen programmen, auch wenn es da nicht unbedingt notwendig wäre.
Man weiß ja auch nie, ob das Script vielleicht wächst und immer größer erweitert wird und dann steht man am Ende mit 1000 Zeilen durcheinander da

Ein weiterer Punkt: Es trennt die verschiedenen Variablen voneinandern.
Variablen sind immer in einem Bereich gülitig. Schreibst du sie einfach in die Datei, gilt sie überall, du kannst also dort z.B. $arData definieren und überall darauf zugreifen.
Wenn man aber nicht aufpasst kann in größeren Scripten schnell vergessen, dass man den Variable Namen schonmal genutzt hat.
Dann überschreibt man ausversehen diese Variable und hat dort was komplett anderes drin stehen, als man denkt, was zu Fehlern führen kann, die versteckt sind und deshalb sehr lange brauchen, bis man das Problem findet.
Nutzt man Funktionen und Lokale Variablen, sind die nur in der Funktion gültig und die Wahrscheinlichkeit für irgendwelche Namens-Konflikte ist erheblich geringer.

**Schnuffel**

Zitat von bankesbusters

jetzt schreibe bitte nicht so etwas wie: "du kannst funktionen mehrmals nutzen an verschiedenen stellen"

aber genau das wird seine Antwort sein.

Wenn du dir Funktionen ansiehst und dass diese auch Parameter übergeben bekommen können, dann kann man damit schon ganz schön viel anstellen.

PS: fast alle komplexeren Befehle die User geschrieben haben, sind Funktionen
Wenn du mal bei 1000+ Zeilen Code angekommen bist, wirst du diese sehr zu schätzen lernen...

bankesbusters

ah, ok ... ergibt sinn. also muss ich mich auch damit wohl beschaeftigen. auf liste hinzugefuegt. danke fuer den tip.