1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. autoiter

Beiträge von autoiter

  • ListView und ContextMenu Problem

    • autoiter
    • 9. April 2017 um 17:00
    Zitat von alpines

    Du solltest die Antworten nicht überfliegen. Er sprach nicht davon warum man StringInStr benutzt wird, sondern warum du die Abfrage = True dahinter noch hast.

    Das stimmt zu meiner Schande nicht ganz @alpines.
    Ich hatte StringInStr und das "= True" in Zweifel gezogen. StringInStr scheint schon richtig zu sein. Der "= True"-Vergleich ist aber wie du schreibst nicht falsch aber unnötig.

  • ListView und ContextMenu Problem

    • autoiter
    • 9. April 2017 um 16:53
    Zitat von NO1 :-)

    Zu deiner Aussage "Warum StringInStr benutzen": Es kann ja sein, dass durch FileGetAttrib mehrere Attribute zurückgegeben werden in einem String und dann muss man ja überprüfen, ob das Attribut "D" in dem String vorhanden ist...

    Ah ja, ein Blick in die Hilfe hilft immer! :D

    Bei meinen Versuchen, kam immer nur ein Buchstabe und ich habe das nicht weiter hinterfragt. Ich hoffe meine anderen Anmerkungen bringen dir wirklich etwas. ;)

  • ListView und ContextMenu Problem

    • autoiter
    • 9. April 2017 um 14:20

    Hallo @NO1 :-),

    Das Skript hat doch noch einige Schwächen. Ein paar Dinge haben mir gar nicht gefallen (Schreib z.B. mal ConsoleWrite(0) in die erste Zeile deiner _IsDir- Funktion und klicke ein Item an...). Ganz schlimm finde ich:

    AutoIt
    AdlibRegister("_ListviewDoubleclick", 100)

    Schmeiß das unbedingt raus! Das kann dir ständig in alles hineinhacken. Du wertest mit WM_NOTIFY doch schon Klicks aus. Mach das auch für Doppelklicks. Schau dir am Besten mal die Hilfe etwa zu "_GUICtrlListView_HitTest" an. Da findest du im Grunde eine fertige Lösung für dieses und andere Szenarien.

    So hab ich die WM_NOTIFY-Funktion für dein Skript genutzt. ($ListviewDoubleclicked ist dann überflüssig):

    AutoIt
    Func WM_NOTIFY($hWnd, $MsgID, $wParam, $lParam)
    	Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView
    	$hWndListView = $Listview
    	If Not IsHWnd($Listview) Then $hWndListView = GUICtrlGetHandle($Listview)
    
    
    	$tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    	$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    	$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    	$iCode = DllStructGetData($tNMHDR, "Code")
    
    
    	Switch $hWndFrom
    		Case $hWndListView
    			Switch $iCode
    				Case $NM_DBLCLK
    					_ListviewDoubleclick()
    				Case $NM_RCLICK
    					GUICtrlDelete($ContextMenu)
    					_SetContextMenu()
    			EndSwitch
    	EndSwitch
    
    
    	Return $GUI_RUNDEFMSG
    EndFunc
    Alles anzeigen

    (Hier lösche ich explizit das Control (GUICtrlDelete($ContextMenu)))!
    Darüber hinaus habe ich $ContextMenu zu einer globalen Variable gemacht.


    Einige Hinweise:
    - Statt: If StringInStr(FileGetAttrib($Path), "D") = True Then genügt If StringInStr(FileGetAttrib($Path), "D") Then

    (Das Auswerten ("= True") ist unnötig, wenn du schon die Lösung zurückgibst (True/False)).
    - Warum überhaupt eine StringInStr-Prüfung hier?

    - Alle Variablen, die du außerhalb von Funktionen deklarierst sind Global - auch wenn du sie Local deklarierst (Dim würde ich ganz weglassen).

    (Es wäre besser, das auch richtig zu benennen. Das diszipliniert mich wenigstens zu überlegen, ob ich das für die betreffende Variable wirklich brauche. Je größer ein Projekt, desto wahrscheinlicher wird es, dass du mal versehentlich in einer Funktion mit einer globalen Variable arbeitest..).

    - Darüber hinaus möchte ich dir raten Namenskonventionen einzuhalten, die klar machen, um welchen Datentyp es sich bei der Variable handelt. Das erleichtert dir im Nachhinein (und Fremden, die sich deinen Code ansehen sollen) das Zurechtfinden ungemein. Schau dir bei Interesse folgende Seite an: https://www.autoitscript.com/wiki/Best_coding_practices


    PS: Klingt jetzt alles sehr kritisch. Aber es ist nicht so böse gemeint und soll nicht heißen, dass das alles Mist wäre. :)

  • Kleine Übungen mit Spoilern als html-Datei erstellen

    • autoiter
    • 6. April 2017 um 18:39

    Hey Leute,
    Ich schicke mir gerade mit einem Bekannten Übungsaufgaben hin und her. Da wollte ich gerne die Ergebnisse in der gleichen Datei, jedoch nicht sofort sichtbar, haben. HTML-Dateien mit Spoilern bieten sich da an. Dann habe ich ein kleines Tool gebastelt, dass mir etwas Schreibarbeit sparen sollte und diese Dateien erstellt. Es funktioniert so wie html. Man kapselt einfach seinen sichtbaren Text und seinen versteckten Text mit den entsprechenden Schlagworten und das Skript erstellt im Textdatei-Verzeichnis eine html-Datei, die direkt ausgeführt wird.
    Das ist total plump und war für mich nun leider doch nicht das Richtige. Vielleicht kann das hier aber mal jemand nutzen. Im Anhang findet sich das Skript mit einer Beispieldatei. (Skript ausführen, Beispieldatei auswählen, fertig.).
    Das Skript erstellt eine Config-Datei, in der man seine eigenen Schlagworte und Farben einstellen kann.

    Spoiler anzeigen
    AutoIt
    #cs ----------------------------------------------------------------------------
    
    
    	AutoIt Version: 3.3.15.0 (Beta)
    
    
    
    
    	Script Function:
    	Erstellt einfache html-Dateien aus mit Containern zum Verstecken con Code (Soll für Übungen dienen).
    	Elemente müssen in eine Textdatei geschrieben und gekapselt werden.
    																			(Standardschlagworte: )
    	1-mal Titel																(0TitelStart ... 0TitelEnde)
    	x-mal Textfelder mit einer Beschreibung und/oder Aufgabe.				(0TextStart ... 0TextEnde)
    	x-mal Codefelder mit zu versteckendem Text oder Code.					(0CodeStart ... 0CodeEnde)
    	x-mal Markierungen im Code.												(0MarkierungStart ...0MarkierungEnde
    
    
    #ce ----------------------------------------------------------------------------
    
    
    #include <Array.au3>
    
    
    $hIniFile = @ScriptDir & "\Übungen-Einstellungen.txt"
    
    
    If Not FileExists($hIniFile) Then _IniWrite()
    
    
    #Region Deklarationen
    Global $sStartTitle = IniRead($hIniFile, "Einstellungen", "Startmarkierung für Titel", "0TitelStart")
    Global $sEndTitle = IniRead($hIniFile, "Einstellungen", "Endmarkierung für Titel", "0TitelEnde")
    Global $sStartText = IniRead($hIniFile, "Einstellungen", "Startmarkierung für Text", "0TextStart")
    Global $sEndText = IniRead($hIniFile, "Einstellungen", "Endmarkierung für Text", "0TextEnde")
    Global $sStartCode = IniRead($hIniFile, "Einstellungen", "Startmarkierung für Code", "0CodeStart")
    Global $sEndCode = IniRead($hIniFile, "Einstellungen", "Endmarkierung für Code", "0CodeEnde")
    Global $sStartMark = IniRead($hIniFile, "Einstellungen", "Startmarkierung für Markierungen", "0MarkierungStart")
    Global $sEndMark = IniRead($hIniFile, "Einstellungen", "Endmarkierung für Markierungen", "0MarkierungEnde")
    Global $WindowBKColor = IniRead($hIniFile, "Einstellungen", "Hintergrund-Farbe Fenster", "#E6E6E6")
    Global $CodeBKColor = IniRead($hIniFile, "Einstellungen", "Hintergrund-Farbe Codefeld", "#FE9A2E")
    Global $MarkBKColor = IniRead($hIniFile, "Einstellungen", "Hintergrund-Farbe Markierungen", "#FFFF00")
    #EndRegion Deklarationen
    
    
    Global $sFileOpenDialog = FileOpenDialog("Wähle die Übungsdatei aus", @ScriptDir & "\", "Textdatei (*.txt)", 1)
    If @error Then Exit
    
    
    Global $s_htmlFile = StringTrimRight($sFileOpenDialog, 3) & "html"
    
    
    Global $aOrder = _ParseTestFile()
    
    
    _Write_HTML()
    ShellExecute($s_htmlFile)
    
    
    
    
    Func _ParseTestFile()
    
    
    	Local $sString = FileRead($sFileOpenDialog)
    
    
    	Local $aTitle = StringRegExp($sString, '(?s)' & $sStartTitle & '(.*?)' & $sEndTitle, 1)
    	If @error Then
    		Exit MsgBox(0, 'Fehler-Abbruch', 'Titel konnte nicht gefunden werden.')
    	EndIf
    	StringReplace($aTitle[0], @LF, '')
    	If @extended > 3 Then Exit MsgBox(0, 'Fehler-Abbruch', 'Maximal dreizeiliger Titel erlaubt.')
    	Local $sTitle = StringReplace($aTitle[0], @CRLF, @LF)
    	StringReplace(StringLeft($sTitle, 2), @LF, '')
    	If @extended > 0 Then $sTitle = StringTrimLeft($sTitle, @extended)
    	StringReplace(StringRight($sTitle, 2), @LF, '')
    	If @extended > 0 Then $sTitle = StringTrimRight($sTitle, @extended)
    	$sTitle = StringReplace($sTitle, @LF, '<br>')
    
    
    
    
    	StringReplace($sString, $sStartCode, "")
    	$iCodeStart = @extended
    	StringReplace($sString, $sEndCode, "")
    	$iCodeEnd = @extended
    	If $iCodeStart <> $iCodeEnd Then Exit MsgBox(0, 'Fehler-Abbruch', 'Codefelder nicht ausbalanciert. (Immer Starten und Beenden.)')
    
    
    
    
    	StringReplace($sString, $sStartText, "")
    	$iTextStart = @extended
    	StringReplace($sString, $sEndText, "")
    	$iTextEnd = @extended
    	If $iTextStart <> $iTextEnd Then Exit MsgBox(0, 'Fehler-Abbruch', 'Textfelder nicht ausbalanciert.. (Immer Starten und Beenden.)')
    
    
    	Local $aText = StringRegExp($sString, '(?s)' & $sStartText & '(.*?)' & $sEndText, 3)
    	If Not @error Then
    		If UBound($aText) <> $iTextStart Then Exit MsgBox(0, 'Fehler-Abbruch', 'Textfelder nicht ausbalanciert. (Reihenfolge von Starten und Beenden stimmt nicht immer.)')
    	Else
    		MsgBox(0, 'Hinweis', 'Keine Textfelder gefunden.', 5)
    	EndIf
    
    
    
    
    	Local $aCode = StringRegExp($sString, '(?s)' & $sStartCode & '(.*?)' & $sEndCode, 3)
    	If Not @error Then
    		If UBound($aCode) <> $iCodeStart Then Exit MsgBox(0, 'Fehler-Abbruch', 'Codefelder nicht ausbalanciert. (Reihenfolge von Starten und Beenden stimmt nicht immer.)')
    	Else
    		MsgBox(0, 'Hinweis', 'Keine Codefelder gefunden.', 5)
    	EndIf
    
    
    
    
    	Local $iOldCodeStartPos = 1, $iOldTextStartPos = 1
    	Local $aTextTemp[$iTextStart + 1][3], $aCodeTemp[$iCodeStart][3]
    	$aTextTemp[0][0] = "Titel"
    	$aTextTemp[0][1] = 0
    	$aTextTemp[0][2] = $sTitle
    
    
    
    
    	For $i = 1 To $iTextEnd
    		$iTextStartPos = StringInStr($sString, $sStartText, 1, 1, $iOldTextStartPos)
    		If $iTextStartPos <> 0 Then
    			$aTextTemp[$i][0] = "Text"
    			$aTextTemp[$i][1] = $iTextStartPos
    			$aTextTemp[$i][2] = $aText[$i - 1]
    		EndIf
    		$iTextEndPos = StringInStr($sString, $sEndText, 1, 1, $iTextStartPos)
    		Local $sSub = StringTrimLeft(StringLeft($sString, $iTextEndPos), $iTextStartPos)
    		If StringInStr($sSub, $sStartCode) Or StringInStr($sSub, $sEndCode, 1) Then
    			Exit MsgBox(0, 'Fehler-Abbruch', 'Codefeld-Marker innerhalb eines Textfeldes gefunden!')
    		EndIf
    		$iOldTextStartPos = $iTextEndPos
    	Next
    
    
    	For $i = 1 To $iCodeEnd
    		$iCodeStartPos = StringInStr($sString, $sStartCode, 1, 1, $iOldCodeStartPos)
    		If $iCodeStartPos <> 0 Then
    			$aCodeTemp[$i - 1][0] = "Code"
    			$aCodeTemp[$i - 1][1] = $iCodeStartPos
    			$aCodeTemp[$i - 1][2] = $aCode[$i - 1]
    		EndIf
    		$iCodeEndPos = StringInStr($sString, $sEndCode, 1, 1, $iCodeStartPos)
    		Local $sSub = StringTrimLeft(StringLeft($sString, $iCodeEndPos), $iCodeStartPos)
    		If StringInStr($sSub, $sStartText) Or StringInStr($sSub, $sEndText, 1) Then
    			Exit MsgBox(0, 'Fehler-Abbruch', 'Textfeld-Marker innerhalb eines Codefeldes gefunden!')
    		EndIf
    		$iOldCodeStartPos = $iCodeEndPos
    	Next
    	_ArrayConcatenate($aTextTemp, $aCodeTemp)
    	_ArraySort($aTextTemp, 0, 1, 0, 1)
    ;~ 	_ArrayDisplay($aTextTemp)
    	Return $aTextTemp
    EndFunc   ;==>_ParseTestFile
    
    
    Func _Write_HTML()
    	Local $sString = _HTML_head()
    	$sString &= _HTML_title()
    	For $i = 1 To UBound($aOrder) - 1
    		If $aOrder[$i][0] = "Text" Then
    			$sString &= _HTML_text($i)
    		Else
    			$sString &= _HTML_code($i)
    		EndIf
    	Next
    	$sString &= _HTML_footer()
    
    
    	Local $hFileOpen = FileOpen($s_htmlFile, 2)
    	If @error Then Exit MsgBox(0, 'Fehler-Abbruch', 'Beim Erstellen der Datei ist ein Fehler aufgetreten. Keine Schreibrechte?')
    	FileWrite($hFileOpen, $sString)
    	FileClose($hFileOpen)
    EndFunc   ;==>_Write_HTML
    
    
    Func _HTML_head()
    	Local $sString = '<html>' & @LF
    	$sString &= '	<head>' & @LF
    	$sString &= '		<meta http-equiv="Content-Type" content="text/html; charset=UTF-8">' & @LF
    	$sString &= '		<style type="text/css">' & @LF
    	$sString &= '			body	{background-color: ' & $WindowBKColor & ';}' & @LF
    	$sString &= '			h1	{text-align: center;}' & @LF
    	$sString &= '			div	{text-align: center;}' & @LF
    	$sString &= '		</style>' & @LF
    	$sString &= '	</head>' & @LF
    	$sString &= '	<body>' & @LF
    	Return $sString
    EndFunc   ;==>_HTML_head
    
    
    Func _HTML_title()
    	Local $sString = '		<h1>' & $aOrder[0][2] & '</h1>' & @LF
    	$sString &= '		<br>' & @LF
    	Return $sString
    EndFunc   ;==>_HTML_title
    
    
    Func _HTML_footer()
    	Local $sString = '	</body>' & @LF
    	$sString &= '</html>' & @LF
    	Return $sString
    EndFunc   ;==>_HTML_footer
    
    
    Func _HTML_code($iIndex)
    	Local $sString = '		<div>' & @LF
    	$sString &= '			<button title="" type="button"' & @LF
    	$sString &= '			onclick="' & @LF
    	$sString &= "			if(document.getElementById('spoiler" & $iIndex & "') .style.display=='none')" & @LF
    	$sString &= "			{document.getElementById('spoiler" & $iIndex & "') .style.display=''}" & @LF
    	$sString &= "			else{document.getElementById('spoiler" & $iIndex & "') .style.display='none'" & @LF
    	$sString &= '			}">Einblenden / Ausblenden</button>' & @LF
    	$sString &= '		</div>' & @LF
    	$sString &= '		<div id="spoiler' & $iIndex & '" style="display:none;' & @LF
    	$sString &= '						border: 2px black dashed;' & @LF
    	$sString &= '						margin: 20px;' & @LF
    	$sString &= '						padding: 5px;' & @LF
    	$sString &= '						text-align: left;' & @LF
    	$sString &= '						background-color: ' & $CodeBKColor & '">' & @LF
    
    
    	$sCodeString = StringReplace($aOrder[$iIndex][2], @CRLF, @LF)
    	$sCodeString = StringReplace($sCodeString, @TAB, "&nbsp;&nbsp;&nbsp;&nbsp;")
    	Local $sMarkStyle = '<div style="background-color: ' & $MarkBKColor & '; margin: 0px; padding: 0px; text-align: left;">'
    	$sCodeString = StringReplace($sCodeString, @LF & $sStartMark & @LF, $sMarkStyle, 0, 1)
    	$sCodeString = StringReplace($sCodeString, @LF & $sStartMark, $sMarkStyle, 0, 1)
    	$sCodeString = StringReplace($sCodeString, $sStartMark & @LF, $sMarkStyle, 0, 1)
    	$sCodeString = StringReplace($sCodeString, $sStartMark, $sMarkStyle, 0, 1)
    	If StringInStr($sCodeString, $sMarkStyle) Then
    		$sCodeString = StringReplace($sCodeString, @LF & $sEndMark & @LF, '</div>', 0, 1)
    		$sCodeString = StringReplace($sCodeString, @LF & $sEndMark, '</div>', 0, 1)
    		$sCodeString = StringReplace($sCodeString, $sEndMark & @LF, '</div>', 0, 1)
    		$sCodeString = StringReplace($sCodeString, $sEndMark, '</div>', 0, 1)
    	EndIf
    	If StringLeft($sCodeString, 1) == @LF Then $sCodeString = StringTrimLeft($sCodeString, 1)
    	If StringRight($sCodeString, 1) == @LF Then $sCodeString = StringTrimRight($sCodeString, 1)
    	Local $aCodeSplit = StringSplit($sCodeString, @LF)
    ;~ 	_ArrayDisplay($aCodeSplit)
    
    
    	For $i = 1 To $aCodeSplit[0]
    		$sString &= '			' & $aCodeSplit[$i] & '<br>' & @LF
    	Next
    	$sString = StringTrimRight($sString, 5) & @LF
    
    
    	$sString &= '			<center><button title="" type="button"' & @LF
    	$sString &= '			onclick="' & @LF
    	$sString &= "			document.getElementById('spoiler" & $iIndex & "') .style.display='none'" & @LF
    	$sString &= '			">Ausblenden</button></center>' & @LF
    	$sString &= '		</div>' & @LF
    	$sString &= '		<br><br>' & @LF
    	Return $sString
    EndFunc   ;==>_HTML_code
    
    
    Func _HTML_text($iIndex)
    	Local $sString = '		<div>' & @LF
    	$sTextString = StringReplace($aOrder[$iIndex][2], @CRLF, @LF)
    	If StringInStr(StringLeft($sTextString, 1), @LF) Then $sTextString = StringTrimLeft($sTextString, 1)
    	If StringInStr(StringRight($sTextString, 1), @LF) Then $sTextString = StringTrimRight($sTextString, 1)
    	$sTextString = StringReplace($sTextString, @TAB, "&nbsp;&nbsp;&nbsp;&nbsp;")
    	Local $aTextSplit = StringSplit($sTextString, @LF)
    	For $i = 1 To $aTextSplit[0]
    		$sString &= '			<FONT SIZE="4">' & $aTextSplit[$i] & '</FONT><br>' & @LF
    	Next
    	$sString &= '			<br>' & @LF
    	$sString &= '		</div>' & @LF
    	Return $sString
    EndFunc   ;==>_HTML_text
    
    
    
    
    Func _IniWrite()
    	Local $sString = "[Einstellungen]" & @CRLF & @CRLF & "----------------------------------------" & @CRLF & @CRLF
    	$sString &= "// Schlagworte für die Container. Groß und Kleinschreibung müssen beachtet werden." & @CRLF
    	$sString &= "// Habe hier mit Zahlen begonnen, damit nicht mal versehentlich Variablen die gleichen Namen bekommen." & @CRLF & @CRLF
    	$sString &= "// Ein Titel muss angegeben werden (darf maximal vierzeilig sein)." & @CRLF & @CRLF & @CRLF
    	$sString &= "Startmarkierung für Titel=0TitelStart" & @CRLF & "Endmarkierung für Titel=0TitelEnde" & @CRLF & @CRLF & @CRLF
    	$sString &= "Startmarkierung für Text=0TextStart" & @CRLF & "Endmarkierung für Text=0TextEnde" & @CRLF & @CRLF & @CRLF
    	$sString &= "Startmarkierung für Code=0CodeStart" & @CRLF & "Endmarkierung für Code=0CodeEnde" & @CRLF & @CRLF & @CRLF
    	$sString &= "Startmarkierung für Markierungen=0MarkierungStart" & @CRLF & "Endmarkierung für Markierungen=0MarkierungEnde" & @CRLF
    	$sString &= @CRLF & @CRLF & "----------------------------------------" & @CRLF & @CRLF
    	$sString &= "// Farben im HTML-Farbcodes. Bspw. hier zu finden: http://html-color-codes.info/webfarben_hexcodes/" & @CRLF & @CRLF & @CRLF
    	$sString &= "Hintergrund-Farbe Fenster=#E6E6E6" & @CRLF & "Hintergrund-Farbe Codefeld=#FE9A2E" & @CRLF & "Hintergrund-Farbe Markierungen=#FFFF00"
    	FileWrite($hIniFile, $sString)
    EndFunc   ;==>_IniWrite
    Alles anzeigen

    Dateien

    Quelltext.zip 3,72 kB – 327 Downloads
  • Den im Input eingegebenen Text als Hotkey verwenden

    • autoiter
    • 5. April 2017 um 18:50
    Zitat von alpines

    Der Fehler lag nicht in dem Bereich den er uns gepostet hat. Sowas passiert hier leider öfters als man es sich wünscht.

    Sehe ich ja genauso. Eigentlich hätte ich den gesamten Beitrag an @pltnpcs adressieren sollen. Ich wollte nur darauf hinaus, dass es nicht notwendig ist, den betreffenden Code zu posten. Es genügt statt dessen ja auch, einen beschreibenden Fall zu erstellen. (Ich denke da vllt. zu sehr aus meiner Perspektive. Aber mein Hauptproblem waren weniger einzelne sensible Bereiche, sondern die Scham davor, euch meinen Dreckscode zu zeigen ;) ).

    Du hast auf jeden Fall recht, dass es viel zu oft passiert, dass die falschen Stellen/nicht genug Code gezeigt wird. Schlimmer sind aber noch die Leute, die gar nichts zeigen, sondern nur schreiben, es gibt ein Problem xy. Wie geht das?

  • Den im Input eingegebenen Text als Hotkey verwenden

    • autoiter
    • 5. April 2017 um 18:41

    Kleine Korrektur @alpines: Wenn er wenigstens ein ausführbares Skript postet, dass sein Problem aufzeigt.

    @pltnpcs Ich verstehe ja, dass viele Anfänger lieber nicht ihr Skript posten (habe mich auch schon oft geschämt ;) ). Aber ein Beispiel zu erstellen, sollte meist möglich sein. Manchmal löst sich das Problem auch bereits in Luft aus, wenn man einen Beispielcode schreibt, weil einem selbst das Problem bewusst wird.

  • Den im Input eingegebenen Text als Hotkey verwenden

    • autoiter
    • 5. April 2017 um 07:44

    Hallo @pltnpcs,
    Das war doch nicht böse gemeint. Aber an meinem Beitrag musst du doch auch merken, dass es bei Mutmaßungen bleibt, wenn man nicht den vielleicht relevanten Code sieht. Wahrscheinlich gibt es einfach ein Missverständnis.

    Wo liegt denn eigentlich genau dein Problem?
    Du fragtest ja nach Befehlen. Was fehlt dir denn?

  • Den im Input eingegebenen Text als Hotkey verwenden

    • autoiter
    • 4. April 2017 um 17:59

    Hallo @pltnpcs,

    Ich halte ein Input nicht für die beste Variante. Besser wäre wohl eine Combobox mit von dir festgelegten Möglichkeiten. Denn nicht jede Kombination ist möglich..


    Zitat von pltnpcs

    Kann mir jemand helfen die richtigen Befehle dafür zu finden?

    Du hast nur den Anfang gepostet.. Daher ist dein Problem schwer zu ermitteln.. Die Befehle stimmen jedenfalls.

    Nehmen wir an, in Wirklichkeit hast du eine Schleife und der Benutzer kann wirklich einen Hotkey eintragen. Dann hast du aber nach dem oberen Code das Problem, dass du die Inputbox nicht in der Schleife ausliest, sondern direkt nach der Erstellung.. Der Hotkey lautet "Input1".


    EDIT: Gerade ausprobiert. Umschalt+i führt bereits den Hotkey aus. (Also wird hier nur der erste Buchstabe ausgewertet. War das dein Problem?)

  • Probleme mit _Excel_RangeRead --> unterschiedliche Inhalte erfassen

    • autoiter
    • 31. März 2017 um 19:35

    Ähm, mal Columns durch Rows ersetzt? ;)

    AutoIt
    Local $aResult = _Excel_RangeRead($oWorkbook, Default, $oWorkbook.ActiveSheet.Usedrange.Rows(1), 2)
  • PDF ´s automatisch umbennen

    • autoiter
    • 29. März 2017 um 13:35

    @chesstiger hat es ja beantwortet. Da war ich gerade am Schreiben :D

  • PDF ´s automatisch umbennen

    • autoiter
    • 29. März 2017 um 13:34

    Hey @Sascha123456

    Der Absturz ist auch passiert, weil du das Script nicht angepasst hast. Das Skript sollte besser nicht weiterlaufen, wenn ein Schritt nicht klappt. Das führt zu Folgefehlern ;)

    Spoiler anzeigen
    AutoIt
    #include <File.au3>
    
    
    
    
    
    
    Global $sSourcePath = @ScriptDir & "\pdfcreatorDir\PDFCreator.pdf" ; Datei die PDFCreator die Dateien erstellt.
    
    
    Global $sResultFolder = @ScriptDir & "\ArtikelnummerDir\" ; Ordner, in den deine Ergebnisse abgelegt werden.
    
    
    Global $sXPDF = @ScriptDir & "\pdftotext\pdftotext.exe" ; Pfad der pdftotext.exe
    
    
    
    
    
    
    $sContent = _GetContent_PDF($sSourcePath) ; Funktion gibt den Text als String zurück.
    $aMatches = StringRegExp($sContent, "(?i)ARTIKEL\h+:\h+([0-9.]+)_", 3) ; Das Pattern von chesstiger, um die Artikelnummer auszulesen.
    If @error Then Exit MsgBox(0, "", "Fehler beim Auslesen der Artikelnummer!" &  @CRLF & "Skript wird abgebrochen.")
    
    
    
    
    Local $sNewFullPath = $sResultFolder & $aMatches[0] & ".pdf" ; Zielpfad der neuen Datei.
    
    
    If FileExists($sNewFullPath) Then ; Wenn die Datei bereits existiert.
    	Local $i = 1
    	Do
    		$sNewFullPath = $sResultFolder & $aMatches[0] & "_" & StringFormat("%03d", $i) & ".pdf" ; In Schleife wird hochgezählt.
    		$i += 1
    	Until Not FileExists($sNewFullPath) ; Bis neu konstruierter Dateiname nicht existiert.
    EndIf
    
    
    FileMove($sSourcePath, $sNewFullPath, 8) ; Datei wird verschoben/umbenannt.
    
    
    
    
    
    
    
    
    
    
    
    
    Func _GetContent_PDF($sFullPath)
    	Local $sTempFile = _TempFile()
    
    
    	Local $sFile = StringReplace($sTempFile, @TempDir & "\", "")
    
    
    	Local $sTestread = _XPDF_ToText($sFullPath, $sFile, @TempDir)
    	If @error Then Exit MsgBox(0, "", "Fehler beim Lesen der PDF-Datei! (" & @error & ")" & @CRLF & "Skript wird abgebrochen.")
    	Local $sString = FileRead($sTempFile)
    	FileDelete($sTempFile)
    
    
    	Return $sString
    
    
    EndFunc   ;==>_GetContent_PDF
    
    
    
    
    Func _XPDF_ToText($sPDFFile, $sTXTFile, $sTXTPath = @ScriptDir, $iFirstPage = 1, $iLastPage = 0, $bLayout = True) ; https://www.autoitscript.com/forum/topic/160718-code-to-extract-plain-text-from-a-pdf-file/?do=findComment&comment=1166469
    	; #FUNCTION# ====================================================================================================================
    	; Name...........: _XPDF_ToText
    	; Description....: Converts a PDF file to plain  text.
    	; Syntax.........: _XPDF_ToText ( "PDFFile" , "TxtFile" [ TxtPath[, FirstPage [, LastPage [, Layout ]]]] )
    	; Parameters.....: PDFFile    - PDF Input File.
    	;                  TxtFile    - Plain text fileneme to convert to
    	;                  TxtPath    - Path to the txt file (default is @ScriptDir)
    	;                  FirstPage  - First page to convert (default is 1)
    	;                  LastPage   - Last page to convert (default is last page of the document)
    	;                  Layout     - If true, maintains (as  best as possible) the original physical layout of the text
    	;                               If false, the behavior is to 'undo'  physical  layout  (columns, hyphenation, etc.)
    	;                                 and output the text in reading order.
    	;                               Default is True
    	; Return values..: Success - 1
    	;                  Failure - 0, and sets @error to :
    	;                   1 - PDF File not found
    	;                   2 - Unable to find the external program
    	; ===============================================================================================================================
    	Local $sOptions
    
    
    	If Not FileExists($sPDFFile) Then Return SetError(1, 0, 0)
    	If Not FileExists($sXPDF) Then Return SetError(2, 0, 0)
    
    
    	If $iFirstPage <> 1 Then $sOptions &= " -f " & $iFirstPage
    	If $iLastPage <> 0 Then $sOptions &= " -l " & $iLastPage
    	If $bLayout = True Then $sOptions &= " -layout"
    
    
    	Local $iReturn = ShellExecuteWait($sXPDF, $sOptions & ' "' & $sPDFFile & '" "' & $sTXTFile & '"', $sTXTPath, "", @SW_HIDE)
    	If $iReturn = 0 Then Return 1
    
    
    	Return 0
    
    
    EndFunc   ;==>_XPDF_ToText
    Alles anzeigen

    Jetzt sollte das Skript sich bei einem Problem melden und Beenden.
    Hier hatte sich eigentlich nur die Schreibweise von ARTIKEL geändert. Mit einer case insensitive Suche ist dieses Problem behoben. Falls es aber noch andere Unterschiede bei weiteren Maschinen gibt, muss man die Fälle im Skript abprüfen. Du solltest es mal an allen Maschinen testen.

  • PDF ´s automatisch umbennen

    • autoiter
    • 29. März 2017 um 10:06

    Muss es wirklich ein Skript sein, dass du mit PDFCreator startest? Sonst kannst du die chsstigers oder mein Skript doch einfach zu einer exe kompilieren und starten.

  • PDF ´s automatisch umbennen

    • autoiter
    • 29. März 2017 um 09:53

    Hey @Sascha123456,
    ich habe dir mal die Variante mit pdftotext erstellt.

    Spoiler anzeigen
    AutoIt
    #include <File.au3>
    
    
    
    
    
    
    Global $sSourcePath = @ScriptDir & "\pdfcreatorDir\PDFCreator.pdf" ; Datei die PDFCreator die Dateien erstellt.
    
    
    Global $sResultFolder = @ScriptDir & "\ArtikelnummerDir\" ; Ordner, in den deine Ergebnisse abgelegt werden.
    
    
    Global $sXPDF = @ScriptDir & "\pdftotext\pdftotext.exe" ; Pfad der pdftotext.exe
    
    
    
    
    
    
    $sContent = _GetContent_PDF($sSourcePath) ; Funktion gibt den Text als String zurück.
    $aMatches = StringRegExp($sContent, "ARTIKEL\h+:\h+([0-9.]+)_", 3) ; Das Pattern von chesstiger, um die Artikelnummer auszulesen.
    If @error Then MsgBox(0, "", "Fehler beim Auslesen der Artikelnummer!")
    
    
    
    
    Global $sNewFullPath = $sResultFolder & $aMatches[0] & ".pdf" ; Zielpfad der neuen Datei.
    
    
    If FileExists($sNewFullPath) Then ; Wenn die Datei bereits existiert.
    	Local $i = 1
    	Do
    		$sNewFullPath = $sResultFolder & $aMatches[0] & "_" & $i & ".pdf" ; In Schleife wird hochgezählt.
    		$i += 1
    	Until Not FileExists($sNewFullPath) ; Bis neu konstruierter Dateiname nicht existiert.
    EndIf
    
    
    FileMove($sSourcePath, $sNewFullPath, 8) ; Datei wird verschoben/umbenannt.
    
    
    
    
    
    
    
    
    
    
    
    
    Func _GetContent_PDF($sFullPath)
    	Local $sTempFile = _TempFile()
    
    
    	Local $sFile = StringReplace($sTempFile, @TempDir & "\", "")
    
    
    	Local $sTestread = _XPDF_ToText($sFullPath, $sFile, @TempDir)
    	If @error Then Return MsgBox(0, "", "Fehler beim Lesen der PDF-Datei! (" & @error & ")", 4)
    	Local $sString = FileRead($sTempFile)
    	FileDelete($sTempFile)
    
    
    	Return $sString
    
    
    EndFunc   ;==>_GetContent_PDF
    
    
    
    
    Func _XPDF_ToText($sPDFFile, $sTXTFile, $sTXTPath = @ScriptDir, $iFirstPage = 1, $iLastPage = 0, $bLayout = True) ; https://www.autoitscript.com/forum/topic/160718-code-to-extract-plain-text-from-a-pdf-file/?do=findComment&comment=1166469
    	; #FUNCTION# ====================================================================================================================
    	; Name...........: _XPDF_ToText
    	; Description....: Converts a PDF file to plain  text.
    	; Syntax.........: _XPDF_ToText ( "PDFFile" , "TxtFile" [ TxtPath[, FirstPage [, LastPage [, Layout ]]]] )
    	; Parameters.....: PDFFile    - PDF Input File.
    	;                  TxtFile    - Plain text fileneme to convert to
    	;                  TxtPath    - Path to the txt file (default is @ScriptDir)
    	;                  FirstPage  - First page to convert (default is 1)
    	;                  LastPage   - Last page to convert (default is last page of the document)
    	;                  Layout     - If true, maintains (as  best as possible) the original physical layout of the text
    	;                               If false, the behavior is to 'undo'  physical  layout  (columns, hyphenation, etc.)
    	;                                 and output the text in reading order.
    	;                               Default is True
    	; Return values..: Success - 1
    	;                  Failure - 0, and sets @error to :
    	;                   1 - PDF File not found
    	;                   2 - Unable to find the external program
    	; ===============================================================================================================================
    	Local $sOptions
    
    
    	If Not FileExists($sPDFFile) Then Return SetError(1, 0, 0)
    	If Not FileExists($sXPDF) Then Return SetError(2, 0, 0)
    
    
    	If $iFirstPage <> 1 Then $sOptions &= " -f " & $iFirstPage
    	If $iLastPage <> 0 Then $sOptions &= " -l " & $iLastPage
    	If $bLayout = True Then $sOptions &= " -layout"
    
    
    	Local $iReturn = ShellExecuteWait($sXPDF, $sOptions & ' "' & $sPDFFile & '" "' & $sTXTFile & '"', $sTXTPath, "", @SW_HIDE)
    	If $iReturn = 0 Then Return 1
    
    
    	Return 0
    
    
    EndFunc   ;==>_XPDF_ToText
    Alles anzeigen

    Im Anhang noch das Verzeichnis mit der exe, wie ich es getestet habe.
    Wenn du es mehrfach ausprobieren möchtest, ersetze einfach FileMove durch FileCopy.

    EDIT: Mir ist gerade aufgefallen, dass man bei den Fehlermeldungen eigentlich auch das Programm verlassen sollte ;)

    Dateien

    Neuer Ordner.zip 440,64 kB – 546 Downloads
  • PDF ´s automatisch umbennen

    • autoiter
    • 29. März 2017 um 08:51

    Hallo @Sascha123456

    Zitat von Sascha123456

    Bei Programmende gebe ich ein Signal an den PDFCreator
    Dieser erstellt mir nun automatisch das Messprotokoll als PDF (was auch PDF sein muss wegen Schreibschutz etc)

    Aus was erstellt der PDFCreator denn die Messergebnisse PDF? Erstellt deine Messmaschine eine Textdatei?
    Kann man denn da nicht einfach vor der Erstellung des PDF die Artikelnummer auslesen?
    Du kannst dann auch einfach warten bis PDFCreator fertig ist und dann die PDF-Datei umbenennen..

  • PDF ´s automatisch umbennen

    • autoiter
    • 28. März 2017 um 22:27

    Meine Frage nach dem Ablauf, ging in eine ähnliche Richtung. Ich wollte eben wissen, ob man wirklich mit der erstellten PDF-Datei arbeiten muss.
    Wenn es tatsächlich so ist, finde ich pdftotext total super. Ich habe hier eine Textsuche gepostet, indem ich xpdf benutze. Damit geht es genauso einfach, wie mit der Ghostscript-Variante von @chesstiger.
    Die Infos findest du hier: https://www.autoitscript.com/forum/topic/160718-code-to-extract-plain-text-from-a-pdf-file/?do=findComment&comment=1166469

  • PDF ´s automatisch umbennen

    • autoiter
    • 28. März 2017 um 19:03

    Hallo @Sascha123456,
    Kannst du die entsprechenden Informationen "Artikel: 106546blabla" nicht vor der PDF-Erstellung ermitteln und dann PDFCreator einfach die Datei mit richtigem Namen erstellen lassen? Schreib doch mal genau, was aktuell in welcher Reihenfolge passiert - mir ist das noch nicht ganz klar.

  • Das Ende der InputBox

    • autoiter
    • 21. März 2017 um 17:03

    OT:
    Glückwunsch @bam176 zu dem genialen Threadtitel!
    Ich war sofort extrem neugierig und habe den Thread direkt angeklickt. So muss man das machen. :D

  • GUISetonEvent, Close clicked bei GUI

    • autoiter
    • 19. März 2017 um 20:26

    Hallo @Mikki,

    Schau dir mal das Tutorial von BugFix an. http://www.bug-fix.info/array_tut.htm

    Stichwort: Vergleichscode ohne/mit Array ;)

  • Ecxel + Array

    • autoiter
    • 19. März 2017 um 19:41

    Hallo @Snow12,

    versuch mal deinen Code in ein Codefeld zu packen. Das sieht besser aus und andere erkennen besser den Code, da es eine AutoIt Code-Hervorhebung gibt.
    Das ist bei einem neuen Beitrag oder dem Bearbeiten eines Beitrags in der Toolbar über dem Beitrag zu finden. (sieht so aus </> anklicken, den Code hinein kopieren und AutoIt als Hervorhebung wählen).

    Das Problem ist, dass du die zweite Schleife in der ersten hast. Das heißt für jeden Durchlauf von Schleife 1 führst du auch die zweite aus. Dabei wird $iRow hochgezählt und du hast in B dann natürlich den einfach gewünschten Eintrag in jeder Zeile, deren Wert $iRow angenommen hat.

    AutoIt
    Local $iRow = 1 ; Deine Startzeile
    For $i = $aRecords[0] To $aRecords[0] - 3 Step -1 ; vom letzten bis zum viertletzten Eintrag rückwärts gehen.
    	_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $aRecords[$i], "A" & $iRow) ; Im ersten Durchlauf wird $aRecords[viertletzter Wert] in Spalte A Zeile 1 geschrieben.
    	$iRow += 1 ; Für den nächsten Durchlauf, wird die Variable $iRow um 1 erhöht, damit immer in die nächste Spalte geschrieben wird.
    Next
    
    
    ; Da es sich hier nur um einen Eintrag handelt, ist eine Schleife ja eigentlich nicht notwendig, ich habe es aber so belassen.
    
    
    $iRow = 1 ; wieder 1
    
    
    For $i = $aRecords[0] - 4 To $aRecords[0] - 4 Step -1 ; vom fünftletzten bis zum fünftletzten Eintrag rückwärts gehen. ;)
    	_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $aRecords[$i], "B" & $iRow)
    	$iRow += 1
    Next
    Alles anzeigen
  • Ecxel + Array

    • autoiter
    • 19. März 2017 um 17:31
    Zitat von Snow12

    Hallo Herr autoiter

    Sie haben mir sehr weitergeholfen,

    Hallo @Snow12
    Das ist wirklich witzig! :D

    Ja, wir kennen uns nicht. Dennoch pflegt man in Foren gemeinhin die persönlichere Anrede du. (Und dann auch noch Herr autoiter :D ). In diesem Umfeld, solltest du das nicht als Unhöflichkeit empfinden.

    Zitat von Snow12

    If Not _FileReadToArray("C:\Users\dd\Desktop\Array\1.txt",$aRecords) Then

    Hier gibt es sicher viele Wege, wie du an die aktuellen Dateinamen kommst. Sind es viele Dateien, die auf einmal verarbeitet werden sollen, böte sich _FileListToArray oder _FileListToArrayRec an. Wenn du immer eine Datei auswählen möchtest, ist FileOpenDialog die Wahl. Im Zweifel musst du konkreter werden.
    Schau dir das Beispiel in der Hilfe dazu an. Benutzt du eine IDE wie SciTE? Weißt du wie man dort die Hilfe aufruft und die Beispiele direkt ausführt?

    Zitat von Snow12

    und die 2 Sache ist es möglich die letzten 4 Werte zu "Spiegeln" d.h also der letzte Wert in A1, vorletzter A2, usw....

    Das ist kein Problem. Du kannst in der For.. To-Schleife auch rückwerts zählen. Bei dem aktuellen Beispiel wäre das einfach so:

    AutoIt
    Local $iRow = 1 ; Deine Startzeile
    For $i = $aRecords[0] To $aRecords[0] - 4 Step -1; vom letzten bis zum viertletzten Eintrag rückwärts gehen.
    _Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $aRecords[$i], "A" & $iRow) ; Im ersten Durchlauf wird $aRecords[viertletzter Wert] in Spalte A Zeile 1 geschrieben.
    $iRow += 1 ; Für den nächsten Durchlauf, wird die Variable $iRow um 1 erhöht, damit immer in die nächste Spalte geschrieben wird.
    Next

    Die Änderung ist in Zeile 2. Du gibst ja immer an, von welchem Wert bis welchen Wert $i Schleifendurchläufe stattfinden sollen. Beim Rückwerts-Zählen musst du nur Step zwingend angeben. Schau dir dazu auch die Hilfe an.


    Zitat von Snow12

    und wenn ich den 5 Wert in die Spalte B bringen möchte muss ich diese Zeile
    _Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $aRecords[$i], "B" & $iRow)
    so nochmal eingeben?
    Oder einfacher gesagt kann man jeden Wert speziell zuweisen.

    Du siehst ja in meinem Beispiel, dass ich "A1" durch "A" & $iRow ersetzt habe. Das gleiche kannst du auch mit dem Buchstaben machen. Du kannst also vor dem Einfügen jedem Array-Eintrag eine Position zuweisen und die als Variable bei _Excel_RangeWrite mitgeben.

    Am einfachsten wäre es wahrscheinlich, wenn du ein Array so aufbaust, wie es in die Exceldatei soll. Dann wählst du nur deinen Startpunkt etwa A1 und fügst ganz ohne Schleife das ganze Array ein, wie in deinem Code auch (nur eben mit einem Array das genau die Inhalte hat, die du willst).

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™