1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. autoiter

Beiträge von autoiter

  • Ecxel + Array

    • autoiter
    • 19. März 2017 um 10:23

    Hallo @Snow12,

    Ich denke, entweder füllst du die Einträge, die du in die Exceldatei schreiben möchtest in ein neues Array und setzt das dann anstelle von $aRecords in den _Excel_RangeWrite-Aufruf (dafür war dein Local $aArray[4] gesacht, oder?), oder du schreibst in Schleife die einzelnen Strings aus $aRecords in die Liste.

    So habe ich das mal gemacht.

    AutoIt
    Local $iRow = 1 ; Deine Startzeile
    
    
    For $i = $aRecords[0] - 4 To $aRecords[0] ; vom viertletzten bis zum letzten Eintrag.
    _Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $aRecords[$i], "A" & $iRow) ; Im ersten Durchlauf wird $aRecords[viertletzter Wert] in Spalte A Zeile 1 geschrieben.
    $iRow += 1 ; Für den nächsten Durchlauf, wird die Variable $iRow um 1 erhöht, damit immer in die nächste Spalte geschrieben wird.
    Next
  • Funktionen zur Anzeige von Markierungen

    • autoiter
    • 19. März 2017 um 09:57

    Hallo @Friesel,
    Das ist nochmal ein anderer Ansatz, aber auf den ersten Blick sieht das nachvollziehbar für mich aus.
    Vielen Dank dafür! :)

  • Funktionen zur Anzeige von Markierungen

    • autoiter
    • 18. März 2017 um 18:05

    Hey danke dir @alpines,
    genau das rausfaden meinte ich.

    Zitat von alpines

    Wenn du deine Fenster verschiebst werden die Boxen übrigens nicht aktualisiert, du musst also noch die WM_MOVE hooken mit GUIRegisterMsg.

    Ja, das fehlt definitiv noch. Bisher habe ich mir aber noch mit dem Erstellen der einfachen Boxen einen abgekrampft - da stand der Rest noch hinten an. Ich habe da noch viel Arbeit vor mir.

  • Funktionen zur Anzeige von Markierungen

    • autoiter
    • 18. März 2017 um 17:27

    Hallo Leute,

    ich wollte mir einige Funktionen zusammenbasteln, um Markierungen auf allen möglichen Fenstern anzuzeigen. Als Alternative zu Videotutorials, soll das Anlernen neuer Arbeitsvorgänge an einem konkret vorliegendem Fall möglich sein. Markierungen und Text-/Audioanleitungen sollen dabei unterstützen.

    Erst wollte ich es ganz ohne GDI+ machen, weil ich davon keine Ahnung habe. Mit GDI+ könnte ich aber auch Pfeile nutzen oder die Boxen variieren. Allerdings krampfe mir da einen ab. Kennt jemand hier vielleicht ein schon bestehendes Projekt, das ich nutzen kann?

    Bei meinem ersten Versuch blenden die Boxen schön aus (_WinAPI_AnimateWindow($aDeleteHandles[$i], BitOR($AW_BLEND, $AW_HIDE), 500) Zeile 221).

    Wie kann man das mit GDI+ machen?

    Zur Veranschaulichung mal meine beiden Versuche. Es gibt mehrere Beispiele (auskommentiert).
    Ohne GDI+

    Spoiler anzeigen
    AutoIt
    ; Zu den Funktionen __HintBoxes_GuiHole und __HintBoxes_AddCtrlRegion siehe Hilfe etwa zu _WinAPI_CreateRoundRectRgn
    
    
    #include-once
    #include <GUIConstantsEx.au3>
    #include <WinAPI.au3>
    #include <WindowsConstants.au3>
    #include <WinAPISys.au3>
    #include <Array.au3>
    
    
    ;~ Example1()
    ;~ Example2()
    ;~ Example3()
    Example4()
    
    
    Func Example1()
    	MsgBox(0, "Beispiel 1", "Zwei Markierungen werden um angegebene Positionen mit einem Timeout von 2 Sekunden angezeigt.")
    
    
    	Local $aCoords[2][5] = [[50, 50, 100, 200, 0xFFE9A2], [500, 500, 300, 500, 0x616161]]
    	Local $hBox = _HintBoxes_By_Pos($aCoords, 15, 1000)
    
    
    EndFunc   ;==>Example1
    
    
    Func Example2()
    	MsgBox(0, "Beispiel 2", "Der Editor wird geöffnet und ein Markierung darum mit einem Timeout von 1 Sekunde angezeigt.")
    
    
    	Run("notepad.exe")
    	WinWait("[CLASS:Notepad]", "", 10)
    	Local $hWnd = WinGetHandle("[CLASS:Notepad]")
    
    
    	_HintBoxes_By_Handle($hWnd, "", 10, 1000)
    
    
    	WinClose("[CLASS:Notepad]")
    EndFunc   ;==>Example2
    
    
    Func Example3()
    	MsgBox(0, "Beispiel 3", "Eine GUI wird eingeblendet und zwei Markierungen in unterschiedlichen Farben mit einem Timeout von 2 Sekunden angezeigt.")
    	Local $hGui = GUICreate("Test", 350, 210)
    	Local $id_Input = GUICtrlCreateInput("", 20, 30, 200, 25)
    	Local $id_Input2 = GUICtrlCreateInput("", 20, 60, 200, 25)
    	GUISetState(@SW_SHOW)
    
    
    	Local $aControlIDs[2] = [$id_Input, $id_Input2]
    	Local $aColors[2] = [0xFFE9A2, 0x616161]
    
    
    	_HintBoxes_By_Handle($hGui, $aControlIDs, 5, 2000, $aColors)
    
    
    	GUIDelete($hGui)
    EndFunc   ;==>Example3
    
    
    Func Example4()
    	Local $hGui = GUICreate("Test", 350, 210)
    	Local $id_Input = GUICtrlCreateInput("", 20, 30, 200, 25)
    	Local $id_Button_Show = GUICtrlCreateButton("1. Marker einblenden", 25, 170, 120, 25)
    	Local $id_Button_Hide = GUICtrlCreateButton("Alle Marker ausblenden", 180, 170, 140, 25)
    
    
    	GUISetState(@SW_SHOW)
    	Local $hBox1, $hBox2, $iCounter = 1
    	While 1
    		Switch GUIGetMsg()
    			Case $GUI_EVENT_CLOSE
    				ExitLoop
    			Case $id_Button_Show
    
    
    				If $iCounter = 1 Then
    					$hBox1 = _HintBoxes_By_Handle($hGui, $id_Input, 5, 0, 0xFFE9A2)
    					GUICtrlSetData($id_Button_Show, "2. Marker einblenden")
    					$iCounter += 1
    				ElseIf $iCounter = 2 Then
    					$hBox2 = _HintBoxes_By_Handle($hGui, "", 5, 0, 0x616161)
    					GUICtrlSetData($id_Button_Show, "2. Marker löschen")
    					$iCounter += 1
    				Else
    					_Delete_HintBoxes($hBox2)
    					GUICtrlSetData($id_Button_Show, "2. Marker einblenden")
    					$iCounter -= 1
    				EndIf
    			Case $id_Button_Hide
    				_Delete_HintBoxes()
    				GUICtrlSetData($id_Button_Show, "1. Marker einblenden")
    				$iCounter = 1
    		EndSwitch
    	WEnd
    
    
    	GUIDelete($hGui)
    EndFunc   ;==>Example4
    
    
    
    
    
    
    
    
    
    
    
    
    
    
    
    
    
    
    Func _HintBoxes_By_Handle($hWnd, $vControls = "", $iStrength = 5, $iDuration = 2000, $vColor = 0xB10000)
    
    
    	Local $aPos = WinGetPos($hWnd)
    
    
    	; get height of window title and width of window frame - may be different when XP theme is ON/OFF
    	Local $g_iHtit = _WinAPI_GetSystemMetrics($SM_CYCAPTION)
    	Local $g_iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)
    
    
    	Local $hGui = GUICreate("", $aPos[2] + $iStrength * 4, $aPos[3] + $iStrength * 4, $aPos[0] - $iStrength * 2, $aPos[1] - $iStrength * 2, -1, $WS_EX_TOPMOST + $WS_EX_TOOLWINDOW)
    
    
    	__HintBoxes_HandlesArray($hGui)
    
    
    	If IsArray($vControls) Then
    		If Not IsArray($vColor) Then Return 0
    		If UBound($vControls) <> UBound($vColor) Then Return 0
    		Local $aControls[UBound($vControls)], $aColor[UBound($vColor)]
    		For $i = 0 To UBound($vControls) - 1
    			$aControls[$i] = $vControls[$i]
    			$aColor[$i] = $vColor[$i]
    		Next
    		Local $ah_LabelIDs[UBound($vControls) * 4]
    	Else
    		Local $ah_LabelIDs[4]
    		Local $aControls[1], $aColor[1]
    		$aControls[0] = $vControls
    		$aColor[0] = $vColor
    		If $vControls = "" Then
    			WinMove($hGui, "", $aPos[0] - $iStrength * 2, $aPos[1] - $iStrength * 2 - $g_iHtit - $g_iFrame)
    			$aPos[0] = 0
    			$aPos[1] = 0
    			$aPos[3] = $aPos[3]
    		EndIf
    	EndIf
    
    
    	For $i = 0 To UBound($aControls) - 1
    		If $vControls <> "" Then
    			$aPos = ControlGetPos($hWnd, "", $aControls[$i])
    		EndIf
    		$ah_LabelIDs[$i * 4] = GUICtrlCreateLabel("", $aPos[0] + $iStrength, $aPos[1] + $iStrength, $iStrength, $aPos[3] + $iStrength) ; Left
    		GUICtrlSetBkColor(-1, $aColor[$i])
    		$ah_LabelIDs[$i * 4 + 1] = GUICtrlCreateLabel("", $aPos[0] + $iStrength, $aPos[1] + $iStrength, $aPos[2] + $iStrength, $iStrength) ; Top
    		GUICtrlSetBkColor(-1, $aColor[$i])
    		$ah_LabelIDs[$i * 4 + 2] = GUICtrlCreateLabel("", $aPos[0] + $aPos[2] + $iStrength, $aPos[1] + $iStrength, $iStrength, $aPos[3] + $iStrength) ; Right
    		GUICtrlSetBkColor(-1, $aColor[$i])
    		$ah_LabelIDs[$i * 4 + 3] = GUICtrlCreateLabel("", $aPos[0] + $iStrength, $aPos[1] + $aPos[3] + $iStrength, $aPos[2] + $iStrength, $iStrength) ; Bottom
    		GUICtrlSetBkColor(-1, $aColor[$i])
    	Next
    	__HintBoxes_GuiHole($hGui, 0, 0, $aPos[2], $aPos[3], $ah_LabelIDs, $g_iHtit, $g_iFrame)
    	WinActivate($hWnd)
    	GUISetState(@SW_SHOWNA)
    
    
    	If $iDuration = 0 Then Return $hGui
    
    
    	Sleep($iDuration)
    	_Delete_HintBoxes($hGui)
    EndFunc   ;==>_HintBoxes_By_Handle
    
    
    Func _HintBoxes_By_Pos($aAreas, $iStrength = 5, $iDuration = 2000)
    	If Not IsArray($aAreas) Then Return 0
    
    
    	Local $iCols = UBound($aAreas, $UBOUND_COLUMNS)
    	If $iCols < 4 Then Return 0
    	Local $hexColorDefault = 0xB10000, $hexColor, $bColors = False
    	If $iCols = 5 Then $bColors = True
    
    
    	Local $iWidth = @DesktopWidth
    	Local $iHeight = @DesktopHeight
    
    
    	Local $hGui = GUICreate("", $iWidth, $iHeight, 0, 0, -1, $WS_EX_TOPMOST + $WS_EX_TOOLWINDOW)
    
    
    	__HintBoxes_HandlesArray($hGui)
    
    
    	Local $g_iHtit = _WinAPI_GetSystemMetrics($SM_CYCAPTION)
    	Local $g_iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)
    
    
    	Local $ah_LabelIDs[UBound($aAreas) * 4]
    
    
    	For $i = 0 To UBound($aAreas) - 1
    
    
    		If $bColors Then
    			If $aAreas[$i][4] <> "" Then
    				$hexColor = $aAreas[$i][4]
    			Else
    				$hexColor = $hexColorDefault
    			EndIf
    		Else
    			$hexColor = $hexColorDefault
    		EndIf
    		$ah_LabelIDs[$i * 4] = GUICtrlCreateLabel("", $aAreas[$i][0] - $iStrength * 2 + $iStrength * 2, $aAreas[$i][1] - $iStrength * 2 + $iStrength * 2, $iStrength, $aAreas[$i][3] + $iStrength * 4) ; Left
    		GUICtrlSetBkColor(-1, $hexColor)
    		$ah_LabelIDs[$i * 4 + 1] = GUICtrlCreateLabel("", $aAreas[$i][0] - $iStrength + $iStrength * 2, $aAreas[$i][1] - $iStrength * 2 + $iStrength * 2, $aAreas[$i][2] + $iStrength * 2, $iStrength) ; Top
    		GUICtrlSetBkColor(-1, $hexColor)
    		$ah_LabelIDs[$i * 4 + 2] = GUICtrlCreateLabel("", $aAreas[$i][0] + $aAreas[$i][2] + $iStrength + $iStrength * 2, $aAreas[$i][1] - $iStrength * 2 + $iStrength * 2, $iStrength, $aAreas[$i][3] + $iStrength * 4) ; Right
    		GUICtrlSetBkColor(-1, $hexColor)
    		$ah_LabelIDs[$i * 4 + 3] = GUICtrlCreateLabel("", $aAreas[$i][0] - $iStrength + $iStrength * 2, $aAreas[$i][1] + $aAreas[$i][3] + $iStrength + $iStrength * 2, $aAreas[$i][2] + $iStrength * 2, $iStrength) ; Bottom
    		GUICtrlSetBkColor(-1, $hexColor)
    	Next
    
    
    	__HintBoxes_GuiHole($hGui, 0, 0, $iWidth, $iHeight, $ah_LabelIDs, $g_iHtit, $g_iFrame)
    	GUISetState(@SW_SHOWNA)
    
    
    	If $iDuration = 0 Then Return $hGui
    
    
    	Sleep($iDuration)
    	_Delete_HintBoxes($hGui)
    
    
    EndFunc   ;==>_HintBoxes_By_Pos
    
    
    Func _Delete_HintBoxes($hGui = "")
    	If $hGui = "" Then
    		Local $aDeleteHandles = __HintBoxes_HandlesArray("", False)
    	Else
    		Local $aDeleteHandles = __HintBoxes_HandlesArray($hGui, False)
    	EndIf
    	If Not @error Then
    		For $i = 0 To UBound($aDeleteHandles) - 1
    			_WinAPI_AnimateWindow($aDeleteHandles[$i], BitOR($AW_BLEND, $AW_HIDE), 500)
    		Next
    	EndIf
    EndFunc   ;==>_Delete_HintBoxes
    
    
    
    
    
    
    
    
    
    
    Func __HintBoxes_GuiHole($hWin, $iX, $iY, $iSizeW, $iSizeH, $ah_LabelIDs, $g_iHtit = 0, $g_iFrame = 0)
    	Local $hOuter_rgn, $hInner_rgn, $hCombined_rgn
    
    
    	$hOuter_rgn = _WinAPI_CreateRectRgn(0, 0, $iSizeW, $iSizeH)
    	$hInner_rgn = _WinAPI_CreateRectRgn($iX, $iY, $iX + $iSizeW, $iY + $iSizeH)
    	$hCombined_rgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    	_WinAPI_CombineRgn($hCombined_rgn, $hOuter_rgn, $hInner_rgn, $RGN_DIFF)
    	_WinAPI_DeleteObject($hOuter_rgn)
    	_WinAPI_DeleteObject($hInner_rgn)
    	For $i = 0 To UBound($ah_LabelIDs) - 1
    		__HintBoxes_AddCtrlRegion($hCombined_rgn, $ah_LabelIDs[$i], $hWin, $g_iHtit, $g_iFrame)
    	Next
    	_WinAPI_SetWindowRgn($hWin, $hCombined_rgn)
    EndFunc   ;==>__HintBoxes_GuiHole
    
    
    Func __HintBoxes_AddCtrlRegion($hFull_rgn, $idCtrl, $hWin, $g_iHtit, $g_iFrame)
    	Local $aCtrl_pos, $hCtrl_rgn
    
    
    	$aCtrl_pos = ControlGetPos($hWin, "", $idCtrl)
    	$hCtrl_rgn = _WinAPI_CreateRectRgn($aCtrl_pos[0] + $g_iFrame, $aCtrl_pos[1] + $g_iHtit + $g_iFrame, _
    			$aCtrl_pos[0] + $aCtrl_pos[2] + $g_iFrame, $aCtrl_pos[1] + $aCtrl_pos[3] + $g_iHtit + $g_iFrame)
    	_WinAPI_CombineRgn($hFull_rgn, $hFull_rgn, $hCtrl_rgn, $RGN_OR)
    	_WinAPI_DeleteObject($hCtrl_rgn)
    EndFunc   ;==>__HintBoxes_AddCtrlRegion
    
    
    Func __HintBoxes_HandlesArray($hGui = "", $bAdd = True)
    	Local Static $aHandles[0]
    	If $bAdd Then
    		_ArrayAdd($aHandles, $hGui)
    	Else
    		If $hGui = "" Then
    			Local $aDeleteHandles = $aHandles
    			ReDim $aHandles[0]
    			Return $aDeleteHandles
    		Else
    			$iIndex = _ArraySearch($aHandles, $hGui)
    			If Not @error Then
    				Local $aDeleteHandles[1] = [$aHandles[$iIndex]]
    				_ArrayDelete($aHandles, $iIndex)
    				Return $aDeleteHandles
    			Else
    				Return SetError(1)
    			EndIf
    		EndIf
    	EndIf
    EndFunc   ;==>__HintBoxes_HandlesArray
    Alles anzeigen

    Mit GDI+

    Spoiler anzeigen
    AutoIt
    _GDIPlus_Startup()
    
    
    
    
    ;~ Example1()
    ;~ Example2()
    ;~ Example3()
    Example4()
    
    
    
    
    
    
    
    
    Func Example1()
    	MsgBox(0, "Beispiel 1", "Zwei Markierungen werden um angegebene Positionen mit einem Timeout von 2 Sekunden angezeigt.")
    
    
    	Local $aCoords[2][5] = [[50, 50, 100, 200, 0xFFFF0000], [500, 500, 300, 500, 0xFF000000]]
    	Local $hBox = _HintBoxes_By_Pos($aCoords, 15, 1000)
    
    
    EndFunc   ;==>Example1
    
    
    Func Example2()
    	MsgBox(0, "Beispiel 2", "Der Editor wird geöffnet und ein Markierung darum mit einem Timeout von 1 Sekunde angezeigt.")
    
    
    	Run("notepad.exe")
    	WinWait("[CLASS:Notepad]", "", 10)
    	Local $hWnd = WinGetHandle("[CLASS:Notepad]")
    
    
    	_HintBoxes_By_Handle($hWnd, "", 10, 1000)
    
    
    	WinClose("[CLASS:Notepad]")
    EndFunc   ;==>Example2
    
    
    Func Example3()
    	MsgBox(0, "Beispiel 3", "Eine GUI wird eingeblendet und zwei Markierungen in unterschiedlichen Farben mit einem Timeout von 2 Sekunden angezeigt.")
    	Local $hGui = GUICreate("Test", 350, 210)
    	Local $id_Input = GUICtrlCreateInput("", 20, 30, 200, 25)
    	Local $id_Input2 = GUICtrlCreateInput("", 20, 60, 200, 25)
    	GUISetState(@SW_SHOW)
    
    
    	Local $aControlIDs[2] = [$id_Input, $id_Input2]
    	Local $aColors[2] = [0xFF8080FF, 0xFFFF0000]
    
    
    	_HintBoxes_By_Handle($hGui, $aControlIDs, 5, 2000, $aColors)
    
    
    	GUIDelete($hGui)
    EndFunc   ;==>Example3
    
    
    Func Example4()
    	Local $hGui = GUICreate("Test", 350, 210)
    	Local $id_Input = GUICtrlCreateInput("", 20, 30, 200, 25)
    	Local $id_Button_Show = GUICtrlCreateButton("1. Marker einblenden", 25, 170, 120, 25)
    	Local $id_Button_Hide = GUICtrlCreateButton("Alle Marker ausblenden", 180, 170, 140, 25)
    
    
    	GUISetState(@SW_SHOW)
    	Local $hBox1, $hBox2, $iCounter = 1
    	While 1
    		Switch GUIGetMsg()
    			Case $GUI_EVENT_CLOSE
    				ExitLoop
    			Case $id_Button_Show
    
    
    				If $iCounter = 1 Then
    					$hBox1 = _HintBoxes_By_Handle($hGui, $id_Input, 5, 0, 0xFF8080FF)
    					GUICtrlSetData($id_Button_Show, "2. Marker einblenden")
    					$iCounter += 1
    				ElseIf $iCounter = 2 Then
    					$hBox2 = _HintBoxes_By_Handle($hGui, "", 5, 0, 0xFF000000)
    					GUICtrlSetData($id_Button_Show, "2. Marker löschen")
    					$iCounter += 1
    				Else
    					_Delete_HintBoxes($hBox2)
    					GUICtrlSetData($id_Button_Show, "2. Marker einblenden")
    					$iCounter -= 1
    				EndIf
    			Case $id_Button_Hide
    				_Delete_HintBoxes()
    				GUICtrlSetData($id_Button_Show, "1. Marker einblenden")
    				$iCounter = 1
    		EndSwitch
    	WEnd
    
    
    	GUIDelete($hGui)
    EndFunc   ;==>Example4
    
    
    
    
    
    
    
    
    
    
    
    
    
    
    
    
    Func _HintBoxes_By_Handle($hWnd, $vControls = "", $iStrength = 5, $iDuration = 2000, $vColor = 0xFFFF0000)
    
    
    	Local $aPos = WinGetPos($hWnd)
    
    
    	; get height of window title and width of window frame - may be different when XP theme is ON/OFF -- siehe Hilfe etwa zu _WinAPI_CreateRoundRectRgn
    	Local $g_iHtit = _WinAPI_GetSystemMetrics($SM_CYCAPTION)
    	Local $g_iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)
    	Local $hGui = GUICreate("", $aPos[2] + $iStrength * 4, $aPos[3] + $iStrength * 4, $aPos[0] - $iStrength * 2, $aPos[1] - $iStrength * 2, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TRANSPARENT), $hWnd)
    
    
    	GUISetBkColor(0xABCDEF, $hGui)
    	_WinAPI_SetLayeredWindowAttributes($hGui, 0xABCDEF, 255)
    	GUISetState(@SW_SHOWNA)
    
    
    	__HintBoxes_HandlesArray($hGui)
    
    
    	If IsArray($vControls) Then
    		If Not IsArray($vColor) Then Return 0
    		If UBound($vControls) <> UBound($vColor) Then Return 0
    		Local $aControls[UBound($vControls)], $aColor[UBound($vColor)]
    		For $i = 0 To UBound($vControls) - 1
    			$aControls[$i] = $vControls[$i]
    			$aColor[$i] = $vColor[$i]
    		Next
    		Local $ah_LabelIDs[UBound($vControls) * 4]
    	Else
    		Local $ah_LabelIDs[4]
    		Local $aControls[1], $aColor[1]
    		$aControls[0] = $vControls
    		$aColor[0] = $vColor
    		If $vControls = "" Then
    			WinMove($hGui, "", $aPos[0] - $iStrength, $aPos[1] - $iStrength - $g_iHtit - $g_iFrame, $aPos[2] + $iStrength * 4, $aPos[3] + $iStrength * 4 + $g_iHtit + $g_iFrame)
    			$aPos[0] = 0
    			$aPos[1] = 0
    			$aPos[2] = $aPos[2] - $iStrength
    			$aPos[3] = $aPos[3] - $iStrength
    		EndIf
    	EndIf
    
    
    	Local $hPen, $hGraphics, $nX, $nY, $nWidth, $nHeight
    
    
    	For $i = 0 To UBound($aControls) - 1
    		If $vControls <> "" Then
    			$aPos = ControlGetPos($hWnd, "", $aControls[$i])
    		EndIf
    		$hPen = _GDIPlus_PenCreate($aColor[$i], $iStrength)
    		$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    		$nX = $aPos[0] + $iStrength + $g_iFrame
    		$nY = $aPos[1] + $iStrength + $g_iHtit + $g_iFrame
    		$nWidth = $aPos[2] + $iStrength - $g_iFrame
    		$nHeight = $aPos[3] + $iStrength - $g_iFrame
    		_GDIPlus_GraphicsDrawRect($hGraphics, $nX, $nY, $nWidth, $nHeight, $hPen)
    		_GDIPlus_GraphicsDispose($hGraphics)
    		_GDIPlus_PenDispose($hPen)
    	Next
    
    
    	WinActivate($hWnd)
    
    
    	If $iDuration = 0 Then Return $hGui
    
    
    	Sleep($iDuration)
    	_GDIPlus_GraphicsDispose($hGraphics)
    	_GDIPlus_PenDispose($hPen)
    	_Delete_HintBoxes($hGui)
    EndFunc   ;==>_HintBoxes_By_Handle
    
    
    
    
    Func _HintBoxes_By_Pos($aAreas, $iStrength = 5, $iDuration = 2000)
    	If Not IsArray($aAreas) Then Return 0
    
    
    	Local $iCols = UBound($aAreas, $UBOUND_COLUMNS)
    	If $iCols < 4 Then Return 0
    	Local $hexColorDefault = 0xB10000, $hexColor, $bColors = False
    	If $iCols = 5 Then $bColors = True
    
    
    	Local $iWidth = @DesktopWidth
    	Local $iHeight = @DesktopHeight
    
    
    	; get height of window title and width of window frame - may be different when XP theme is ON/OFF -- siehe Hilfe etwa zu _WinAPI_CreateRoundRectRgn
    	Local $g_iHtit = _WinAPI_GetSystemMetrics($SM_CYCAPTION)
    	Local $g_iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)
    	Local $hGui = GUICreate("", $iWidth, $iHeight, 0, 0, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TRANSPARENT, $WS_EX_TOOLWINDOW))
    
    
    	GUISetBkColor(0xABCDEF, $hGui)
    	_WinAPI_SetLayeredWindowAttributes($hGui, 0xABCDEF, 255)
    	GUISetState(@SW_SHOWNA)
    
    
    	__HintBoxes_HandlesArray($hGui)
    
    
    	Local $ah_LabelIDs[UBound($aAreas) * 4]
    
    
    	For $i = 0 To UBound($aAreas) - 1
    
    
    		If $bColors Then
    			If $aAreas[$i][4] <> "" Then
    				$hexColor = $aAreas[$i][4]
    			Else
    				$hexColor = $hexColorDefault
    			EndIf
    		Else
    			$hexColor = $hexColorDefault
    		EndIf
    		Local $hPen = _GDIPlus_PenCreate($hexColor, $iStrength)
    		Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    		Local $nX = $aAreas[$i][0] + $iStrength + $g_iFrame
    		Local $nY = $aAreas[$i][1] + $iStrength + $g_iHtit + $g_iFrame
    		Local $nWidth = $aAreas[$i][2] + $iStrength + $g_iFrame
    		Local $nHeight = $aAreas[$i][3] + $iStrength + $g_iFrame
    		_GDIPlus_GraphicsDrawRect($hGraphics, $nX, $nY, $nWidth, $nHeight, $hPen)
    		_GDIPlus_GraphicsDispose($hGraphics)
    		_GDIPlus_PenDispose($hPen)
    	Next
    
    
    
    
    	GUISetState(@SW_SHOWNA)
    
    
    	If $iDuration = 0 Then Return $hGui
    
    
    	Sleep($iDuration)
    	_Delete_HintBoxes($hGui)
    
    
    EndFunc   ;==>_HintBoxes_By_Pos
    
    
    Func _Delete_HintBoxes($hGui = "")
    	If $hGui = "" Then
    		Local $aDeleteHandles = __HintBoxes_HandlesArray("", False)
    	Else
    		Local $aDeleteHandles = __HintBoxes_HandlesArray($hGui, False)
    	EndIf
    	If Not @error Then
    		For $i = 0 To UBound($aDeleteHandles) - 1
    ;~ 			_WinAPI_AnimateWindow($aDeleteHandles[$i], BitOR($AW_BLEND, $AW_HIDE), 500) ; funktioniert nicht.
    			GUIDelete($aDeleteHandles[$i])
    		Next
    	EndIf
    EndFunc   ;==>_Delete_HintBoxes
    
    
    
    
    
    
    
    
    
    
    Func __HintBoxes_GuiHole($hWin, $iX, $iY, $iSizeW, $iSizeH, $ah_LabelIDs, $g_iHtit = 0, $g_iFrame = 0)
    	Local $hOuter_rgn, $hInner_rgn, $hCombined_rgn
    
    
    	$hOuter_rgn = _WinAPI_CreateRectRgn(0, 0, $iSizeW, $iSizeH)
    	$hInner_rgn = _WinAPI_CreateRectRgn($iX, $iY, $iX + $iSizeW, $iY + $iSizeH)
    	$hCombined_rgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    	_WinAPI_CombineRgn($hCombined_rgn, $hOuter_rgn, $hInner_rgn, $RGN_DIFF)
    	_WinAPI_DeleteObject($hOuter_rgn)
    	_WinAPI_DeleteObject($hInner_rgn)
    	For $i = 0 To UBound($ah_LabelIDs) - 1
    		__HintBoxes_AddCtrlRegion($hCombined_rgn, $ah_LabelIDs[$i], $hWin, $g_iHtit, $g_iFrame)
    	Next
    	_WinAPI_SetWindowRgn($hWin, $hCombined_rgn)
    EndFunc   ;==>__HintBoxes_GuiHole
    
    
    Func __HintBoxes_AddCtrlRegion($hFull_rgn, $idCtrl, $hWin, $g_iHtit, $g_iFrame)
    	Local $aCtrl_pos, $hCtrl_rgn
    
    
    	$aCtrl_pos = ControlGetPos($hWin, "", $idCtrl)
    	$hCtrl_rgn = _WinAPI_CreateRectRgn($aCtrl_pos[0] + $g_iFrame, $aCtrl_pos[1] + $g_iHtit + $g_iFrame, _
    			$aCtrl_pos[0] + $aCtrl_pos[2] + $g_iFrame, $aCtrl_pos[1] + $aCtrl_pos[3] + $g_iHtit + $g_iFrame)
    	_WinAPI_CombineRgn($hFull_rgn, $hFull_rgn, $hCtrl_rgn, $RGN_OR)
    	_WinAPI_DeleteObject($hCtrl_rgn)
    EndFunc   ;==>__HintBoxes_AddCtrlRegion
    
    
    Func __HintBoxes_HandlesArray($hGui = "", $bAdd = True)
    	Local Static $aHandles[0]
    	If $bAdd Then
    		_ArrayAdd($aHandles, $hGui)
    	Else
    		If $hGui = "" Then
    			Local $aDeleteHandles = $aHandles
    			ReDim $aHandles[0]
    			Return $aDeleteHandles
    		Else
    			$iIndex = _ArraySearch($aHandles, $hGui)
    			If Not @error Then
    				Local $aDeleteHandles[1] = [$aHandles[$iIndex]]
    				_ArrayDelete($aHandles, $iIndex)
    				Return $aDeleteHandles
    			Else
    				Return SetError(1)
    			EndIf
    		EndIf
    	EndIf
    EndFunc   ;==>__HintBoxes_HandlesArray
    Alles anzeigen
  • Tool: Datei(en) - Setzen von Datum Create/Modified

    • autoiter
    • 17. März 2017 um 16:10

    Toll! Ab und an stehe ich vor dem gleichen Szenario. Das Tool funktioniert, wie von dir natürlich zu erwarten, super. Ich werde es produktiv nutzen. Danke dafür @BugFix :)

  • In EXCEL Link folgen

    • autoiter
    • 17. März 2017 um 05:42

    Ach ja. Beim erneuten Lesen, scheint mir das auch klar.
    (Was war eben los mit mir?.. :D )

  • In EXCEL Link folgen

    • autoiter
    • 17. März 2017 um 05:27

    Hallo @tubsids

    Zitat von tubsids

    Wie kann ich den Link in Script folgen?

    Ich verstehe nicht, was geschehen soll. Browser mit dem Link öffnen (etwa ShellExecute) oder Quelltext laden (etwa _InetGetSource)?

  • WinAPIGdi: Seltsames Verhalten bei Skalierung eines Bildes mit _WinAPI_AdjustBitmap

    • autoiter
    • 17. März 2017 um 00:16

    Hallo @Friesel,
    ich meine @Oscar hat dein Problem antizipiert. Als Alternative kannst du dir ja mal seine UDF ansehen.
    _GuiCtrlSetImageEx

  • In Textdatei suchen

    • autoiter
    • 15. März 2017 um 13:00

    Hallo @DerSchatten,

    Du kannst ein Array anlegen.

    $Array[x][2] = ["11", "Samsung"]["12", "Dell"]...
    Dann etwa einfach in For Schleife ein StringReplace oder mit _ArraySearch den Treffer-Index ermitteln und dann die entsprechende Änderung vornehmen.

    alpines hat es bereits geschrieben.

  • GDI+ Rotating Earth build 2017-03-17

    • autoiter
    • 13. März 2017 um 22:08

    Der neue Effekt sieht ganz fabelhaft aus! :thumbup:
    PS: $iStep 4 ist mein Favorit.

  • AutoIt Gartenplanungs-Projekt

    • autoiter
    • 13. März 2017 um 20:44

    Hallo @olfibits,
    Entschuldige bitte meinen OT Beitrag. Könntest du aber deine Signatur etwas kürzen oder (teilweise) in einen Spoiler packen? Das wäre meiner Ansicht nach der Lesbarkeit von Threads, mit mehreren Beiträgen von dir, zuträglich sein.

  • AutoIt - Das Multitalent

    • autoiter
    • 12. März 2017 um 21:31

    Hm leider nicht. Ich bin dort nicht angemeldet. Ich werde es dafür im Umfeld weiter empfehlen. :)

  • _DynArray-UDF - halbdynamische Arrays mit AutoIt

    • autoiter
    • 12. März 2017 um 21:25

    Hey @AspirinJunkie,
    in der aktuellen UDF-Version kann ich das Problem auch nicht nachvollziehen. Alles gut. Ich habe das "2D-Array mit komplexer Sortiervorschrift" Beispiel mit der Version getestet, die ich Juni 2015 geladen habe. Damit bricht das Beispiel mit Fehler ab (da ist es auch in Zeile 596).

  • Schlagwortsuche in Textdateien

    • autoiter
    • 12. März 2017 um 19:24

    Danke dir, @bazii :)

  • Schlagwortsuche in Textdateien

    • autoiter
    • 11. März 2017 um 19:18

    Hey Leute,

    ich habe das Skript in der Zwischenzeit erweitert und es so viel besser geworden, dass ich es nochmal teilen wollte (eher an weniger erfahrene Nutzer gerichtet) .

    1. habe ich ein TextSuche-Programm von @wakillon entdeckt, dass ich wirklich ganz toll fand. Davon habe ich mir die Treffer-Vorschau bei der Auswahl abgeschaut. Er hat zwar hier ein Nutzerkonto, aber seine Programme hat er im englischen Forum gepostet. Der Link führt zu seiner Programmübersicht (weil das alles toll ist). Im Speziellen geht es aber um StringFinder. https://www.autoitscript.com/forum/profile/28198-wakillon/content/?type=downloads_file&sortby=file_views&sortdirection=desc&page=1

    2. Habe ich gelernt, dass es einen deutlichen Unterschied machen kann, ob man mit erst mit _FileListToArray(Rec) alle Dateien einsammelt und danach prüft, welche relevant sind oder eine eigene Funktion schreibt, die das bereits beim Einsammeln macht. Da habe ich mir eine Funktion von @Zeitriss angepasst.

    3. Hatte ich tatsächlich in der Schleife in der Suche (_SearchAndProgress) _ArrayAdd verwendet. Das habe ich durch ein übergroßes temporäres Array und eine Zählervariable ersetzt. Jedes neue Element wird einfach zugeordnet und am Ende gibt es ein ReDim auf die wirklich benötigte Größe. Anschließend wird das noch dem "Haupt"-Array ($aSQLFiles) angehängt. Das beschleunigt das Einlesen des AutoIt-Installationsverzeichnisses enorm (bei mir 5829 relevante Dateien. Einlesedauer alt: ~138 sek. Einlesedauer neu: ~50 sek! - habe SSD).


    Das Skript eignet sich weiterhin vor allem für wiederholte Suchen. Nach der ersten Suche kann man auch nur die Datenbank durchsuchen. Dann dauert das Durchsuchen der 5829 Dateien bei mir nur noch 1,6 Sekunden.

    Falls Dateien im Suchbereich gelöscht oder verändert werden, kann man Datenbankbereinigung aktivieren damit die Daten aus der DB entfernt werden. Es wird auch ein vacuum durchgeführt. Je nach Dateimenge, kann das aber etwas dauern.


    Das alte und das neue Skript sind dem ersten Beitrag angehängt, damit sich Interessierte auch die Änderungen anschauen können.

  • Frage zur Gui bzw GUICtrlSetState

    • autoiter
    • 11. März 2017 um 14:50

    Du, ich kann das nicht lesen.

    In der Funktion fuellungenarray füllst du eine Stringvariable, die $fuellungenArray heißt? Das verstehst du in zwei Wochen doch selbst nicht mehr! ^^

    Für den Befehl GUICtrlSetData brauchst du die controlID.

    AutoIt
    GUICtrlSetData ( controlID, data [, default] )

    Die controlID ist hier nach deinem Code folgende:

    AutoIt
    $arFuellung[$i] = GUICtrlCreateCombo($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1]) ; aus der Schleife, wo du die Controls erstellst. Ich habe nur Radio gegen Combo getauscht.

    $arFuellung[Das Element, wo das Control gespeichert wurde, in das du Fuellungen haben möchtest]


    Dein Vorhaben wird dich noch ziemlich beschäftigen. Du solltest dir momentan an jedem Punkt deiner Arbeit die Hilfe zu den Befehlen und die Beispiele genau anschauen (wirst dennoch ein paar graue Haare bekommen. ;) ).

  • Frage zur Gui bzw GUICtrlSetState

    • autoiter
    • 11. März 2017 um 14:10

    Ich weiß ja nicht wo $setcontrol her kommt und was es für einen Wert hat ^^

    Hier noch mal anhand deines Codes aus Beitrag 16.

    AutoIt
    Local $arFuellung[$Anzahl]
    For $i = 0 To UBound($arFuellung) -1
    	If $i = 0 Then
    		$wahl[0][1] = 'Nichts gewählt'
    	EndIf
    	$arFuellung[$i] = GUICtrlCreateRadio($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1])
    		GUICtrlSetState($arFuellung[$i], 160)
     Next
    For $i = 0 To UBound($arFuellung) -2 Step 2
        GUICtrlSetState($arFuellung[0], $GUI_CHECKED)
    Next
    Alles anzeigen


    Hier erstellst du ja in Schleife deine Controls. Jedes Control wird gespeichert in $arFuellung. Das heißt, wenn etwas in Control 3 ($arFuellung[2]) ausgewählt wurde und du nun Control 4 füllen möchtest, dann gibst du $arFuellung[3] an. (Immer eines weniger, weil du ja in der Schleife bei 0 angefangen hast und das erste Control ja das Element Null im Array $arFuellung ist). Also:

    AutoIt
    GUICtrlSetData($arFuellung[3], $fuellungenArray)
  • Frage zur Gui bzw GUICtrlSetState

    • autoiter
    • 11. März 2017 um 12:37

    War nicht böse gemeint @Rigobert. Ich bin auch kein Programmierer und kann das total nachvollziehen. :)

    Es ist einfach leichter für jemanden, der nur einen Teilausschnitt des Skripts sieht, wenn er weiß, dass du an der Stelle mit einem Array, da mit einem Integer arbeitest (arbeiten willst) usw. . Das kann dir auch selbst helfen, wenn du dir deine Skripte nach einigen Wochen noch einmal anschaust.
    Genauso ist es sehr sinnvoll, wenn du dir kurze Kommentare in deinen Quelltext schreibst (Was will ich mit dieser Funktion, Variable, Zeile). Das muss man natürlich nicht konsequent machen. Wenn du aber später mal etwas anpassen musst, wirst du bei größeren Skripten froh sein, schnell zu sehen, was du dir damals gedacht hast. (Beim Kommentieren wird man auch mal auf eigene Denkfehler aufmerksam).

  • Frage zur Gui bzw GUICtrlSetState

    • autoiter
    • 11. März 2017 um 11:42

    Ich finde deine paar Zeilen Code schon schwer zu lesen ^^

    Die For Schleife sollte da also gar nicht hin? Dann bezieht sich

    Zitat von Rigobert

    Ok, ich denke statt $arFuellung, kann ich da ja $Anzahl einsetzen.

    nur auf die erste Schleife?

    Im ersten Code (Beitrag 16) schreibst du

    AutoIt
    Local $arFuellung[$Anzahl]

    dann meinst du, "$arFuellung, kann ich da ja (durch) $Anzahlkönnte" ersetzen und machst im zweiten Code:

    AutoIt
    For $i = 0 To UBound($Anzahl) -1

    Ist Anzahl hier die selbe Variable wie oben? (Hier hast du die Deklaration nicht mit im Code, daher kann ich nicht sicher sein).
    Wenn ja, dann ist das ein Fehler. Wenn $Anzahl nur eine Variable mit der Anzahl der Elemente eines Arrays ist, brauchst du kein/kannst du kein Ubound verwenden, womit du die Anzahl der Elemente eines Array ermittelst. Auf eine Variable angewendet führt das zu einem Fehler.
    Du könntest das durch

    AutoIt
    For $i = 0 To $Anzahl ; oder $Anzahl -1, wenn notwendig.

    ersetzen. Dann passiert hier auch etwas in der Schleife.


    Hierzu frage ich mich,

    Zitat von Rigobert

    Also das aus $auswahl[$i] gleich sowas wird wie $auswahl[$setini][$i]

    was ist denn $setini? Wenn du $setini einen Zahlenwert wie 0, 1, 2 usw. gibst, kann das doch als Indexwert von $auswahl dienen. $auswahl[1] ist dann gleich $auswahl[$setini], wenn $setini den Wert 1 hat. Das wäre eindeutig.


    Prinzipiell schau dir mal das hier an: https://www.autoitscript.com/wiki/Best_coding_practices

    Der Code wäre viel leichter nachvollziehbarer, wenn du dich an Regeln für die Benennung deiner Variablen halten würdest. (Ausführbare Beispiele sind auch nie schlecht ;) ).

  • Frage zur Gui bzw GUICtrlSetState

    • autoiter
    • 11. März 2017 um 11:04

    Hey @Rigobert,
    ich verstehe den Code nicht komplett. Aber ändere doch mal bei deinem ersten Code..

    AutoIt
    Local $arFuellung[$Anzahl]
    For $i = 0 To UBound($arFuellung) -1
    	If $i = 0 Then
    		$wahl[0][1] = 'Nichts gewählt' ; Was soll das?
    	EndIf
    	$arFuellung[$i] = GUICtrlCreateRadio($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1])
    		GUICtrlSetState($arFuellung[$i], 160)
     Next
    For $i = 0 To UBound($arFuellung) -2 Step 2
        GUICtrlSetState($arFuellung[0], $GUI_CHECKED) ; Hier Setzt du immer den Wert vom Control $arFuellung[0]. Deshalb wird es überschrieben, statt dass das nächste den Wert bekommt. Also $arFuellung[$i]
    Next
    Alles anzeigen

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™