1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Array kopieren/umbenennen

    • AspirinJunkie
    • 17. Februar 2011 um 20:48

    Wie schon gesagt wurde meinst du kein normales Array sondern ein assoziatives.
    Die effektivste und nutzerfreundlichste Möglichkeit dessen Funktionalität in AutoIt abzubilden ist das Dictionary-Objekt.
    Mal ein kleines Beispiel zur Verwendung:

    Spoiler anzeigen
    [autoit]

    ;//// Dictionary Erstellen ///////////
    $oDict = ObjCreate("Scripting.Dictionary")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;//// Einträge hinzufügen ///////////
    $oDict.add ("Berlin", 3395189)
    $oDict.add ("Hamburg", 1743627)
    $oDict.add ("München", 1259677)
    $oDict.add ("Köln", 983347)
    $oDict.add ("Dresden", 517052)
    ;Beispiel hier: Einwohnerzahl wird der jeweiligen Stadt zugeordnet.

    [/autoit] [autoit][/autoit] [autoit]

    ;//// Anzahl der Elemente bestimmen ///////////
    MsgBox(0,"Anzahl Elemente in Dictionary", $oDict.Count)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;//// Überprüft ob ein Element vorhanden ist ///////////
    If $oDict.Exists ("Bonn") Then MsgBox(0, "", "Bonn ist eingetragen") ;Bonn ist im Bsp. nicht enthalten

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;//// Löscht ein Element aus dem Dictionary ///////////
    $oDict.remove ("München")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;//// Elemente aufrufen ///////////
    ConsoleWrite("Einwohner(Berlin): " & $oDict("Berlin") & @CRLF)
    ConsoleWrite("Einwohner(Dresden): " & $oDict("Dresden") & @CRLF & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    ;//// alle Schlüssel durchgehen ///////////
    For $sKey in $oDict.Keys
    ConsoleWrite("Einwohner(" & $sKey & "): " & $oDict($sKey) & @CRLF)
    Next
    ;/// Alle Werte statt Schlüssel erreicht man mit $oDict.Items ////

    [/autoit] [autoit][/autoit] [autoit]

    ;//// Leert das Dictionary ///////////
    $oDict.RemoveAll

    [/autoit]
  • Array kopieren/umbenennen

    • AspirinJunkie
    • 17. Februar 2011 um 19:21

    Ich denke du hast Arrays noch nicht ganz verstanden.
    Anders kann ich mir deine Indizierung wo du Strings anstatt Integer(Ganzzahlen) als Index nimmst nicht erklären.

    Um deine Ausgangsfrage zu klären:

    Spoiler anzeigen
    [autoit]

    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    ; Array Definieren:
    Global $ArrayAlt[4]

    [/autoit] [autoit][/autoit] [autoit]

    ; Array initialisieren:
    $ArrayAlt[0] = "Wert1"
    $ArrayAlt[1] = "Wert2"
    $ArrayAlt[2] = "Wert3"
    $ArrayAlt[3] = "Wert4"

    [/autoit] [autoit][/autoit] [autoit]

    ; Neue Variable für Array erstellen:
    Global $ArrayNeu

    [/autoit] [autoit][/autoit] [autoit]

    ; $ArrayAlt in $ArrayNeu umkopieren
    $ArrayNeu = $ArrayAlt

    [/autoit] [autoit][/autoit] [autoit]

    ; Inhalt des neuen Array ausgeben:
    _ArrayDisplay($ArrayNeu, "Inhalt von $ArrayNeu")

    [/autoit]
  • Schnellste Skript zur Rätsellösung

    • AspirinJunkie
    • 17. Februar 2011 um 19:16

    Super Lösung - runden wir es uns schön... 8|
    War jetzt hoffentlich nicht dein Ernst dass du das wirklich jemanden als eine Lösung anbieten willst?
    Wie Raupi schon sagte: Dein Ergebnis hat mit der Aufgabenstellung rein gar nix zu tun.

    Wenn man wirklich schnell sein will sollte man hier eher mathematisch überlegen welche Zahlen überhaupt in Frage kommen und so die abzufragende Zahlenmenge zu verkleinern.
    Z.B. ist die größte mögliche Zahl 111111 weil darüber nur noch 7-stellige Zahlen herauskommen würden.
    Da die Zahl also zwischen 100000 (muss ja eine 6-stellige Zahl sein) und 111111 liegen kann kommen nur 2 Zahlen für die ersten beiden Stellen in Frage: 10 und 11.
    Ergo kommen als letzte Ziffern für die Zahl nur 90 und 99 in Frage.
    Daher kann man die überhaupt möglichen Zahlen welche man testen muss schon mal mindestens auf nur noch 22 eindämmen.
    Dann ist so eine Rechnung auch deutlich schneller machbar (und man wird feststellen das es keine Lösung gibt):

    Spoiler anzeigen
    [autoit]

    Global $i = 100090, $n = 0
    ConsoleWrite(" i 9*i <i_neu> " & @CRLF & "------------------------" & @CRLF)
    Do
    If Mod($i, 100) = Int(StringLeft(9*$i,2)) Then
    ConsoleWrite($i & @TAB & $i * 9 & @TAB & Int((Mod($i, 100) * 1e4) + $i/100) & @CRLF)
    $n += 1
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    If Mod($i, 100) = 90 Then
    $i += 9
    Else
    $i += 91
    EndIf
    Until $i > 111111
    ConsoleWrite ("Gesamtanzahl möglicher Zahlen: " & $n & @CRLF)

    [/autoit]
  • Frage zu StringRegExp

    • AspirinJunkie
    • 17. Februar 2011 um 00:06

    Ganz am Anfang meiner AutoIt-Zeit hab ich genau diesen Anwendungsfall gehabt.
    PE-Signaturen mit Signaturmustern vergleichen.
    Daher hab ich vermutet das es sich darum handelt.

    Ist das Problem erstmal gelöst für dich oder hast du noch ne Frage?

  • 3/4 acht

    • AspirinJunkie
    • 16. Februar 2011 um 13:47

    Mit dem Staat der DDR wird es eher weniger zu tun haben da es unter anderem auch in Österreich verbreitet ist.

    Alina
    >>Norddeutsche lernen die Uhr zu lesen<< ;)

  • Frage zu StringRegExp

    • AspirinJunkie
    • 15. Februar 2011 um 22:41
    Spoiler anzeigen
    [autoit]

    Global $Hex1 = "AA BB CC DD EE FF"
    Global $Hex2 = "AA ?? ?C DD"

    [/autoit] [autoit][/autoit] [autoit]

    If StringRegExp($Hex1, "^" & StringReplace($Hex2, "?", "[[:xdigit:]]") & "(?:\s[[:xdigit:]]{2})*$") Then
    MsgBox(0, "", "$Hex1 == $Hex2")
    Else
    MsgBox(0, "", "$Hex1 != $Hex2")
    EndIf

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; alternative Möglichkeit um den String $Hex2 auf die Länge von $Hex1 zu verlängern:
    ;#include <String.au3>
    ;$Hex2 &= _StringRepeat(" ??", (StringLen($Hex1) - StringLen($Hex2))/3)

    [/autoit]


    Mal ins Blaue geraten: Geht es zufällig um PE-Signaturen?

  • Problem mit InetGet()

    • AspirinJunkie
    • 15. Februar 2011 um 19:59

    Der Server hat was gegen AutoIt und sperrt HTTP UserAgents mit dem Namen AutoIt3 (oder ähnlich).
    Daher einfach vorher noch den UserAgent ändern:

    [autoit]

    HttpSetUserAgent("irgendwasanderes")

    [/autoit]
  • Geschwindigkeits Bug ?

    • AspirinJunkie
    • 15. Februar 2011 um 19:46

    Wie weist du das nach?
    Mir ist dieses Verhalten noch nie aufgefallen.
    Daher wäre ein Beispielcode zum nachvollziehen wichtig.

  • Das letzte CRFL in einer Textdatei löschen.

    • AspirinJunkie
    • 15. Februar 2011 um 19:09

    Die Lösungen sind, vor allem bei großen Dateien, aber unnötig langsam da in allen Fällen in jedem Fall erst die komplette Datei eingelesen wird und dann die komplette Datei nur ohne abschließendes @CRLF neu geschrieben wird.
    Effektiver wäre es da z.B. zu checken ob überhaupt ein abschließendes @CRLF existiert und in dem Fall die Dateigröße nur um 2 Byte zu verringern und somit das @CRLF abzuschneiden.
    Der Rest der Datei bleibt dann völlig unangetastet.

    Beispiel:

    Spoiler anzeigen
    [autoit]

    #include <WinAPI.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $sDatei = "Test.csv"

    [/autoit] [autoit][/autoit] [autoit]

    $iReturn = _FileDeleteLastCRLF($sDatei)
    Switch $iReturn
    Case -1
    MsgBox(0, "Fehler", "Fehler aufgetreten")
    Case 0
    MsgBox(0, "", "Kein abschließendes @CRLF gefunden")
    Case 1
    MsgBox(0, "", "Abschließendes @CRLF gelöscht")
    EndSwitch

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ======================================================================================
    ; Name ..........: _FileDeleteLastCRLF()
    ; Description ...: Delete ending @CRLF in a File if exists
    ; Syntax ........: _FileDeleteLastCRLF($sDateiname)
    ; Parameters ....: $sDateiname - Filepath as a string
    ; Return values .: Success: returns 1 if @CRLF deleted or 0 if no @CRLF exists
    ; Failure: returns -1 and set @error
    ; Author ........: AspirinJunkie
    ; Related .......: WinAPI.au3
    ; =================================================================================================
    Func _FileDeleteLastCRLF($sDateiname)
    Local $hFile = _WinAPI_CreateFile($sDateiname, 2, 6)
    Local $iRet = 0
    If $hFile = 0 Then Return SetError(1, @error, -1)
    Local $tBuffer = DllStructCreate("byte[2]"), $nbytes

    [/autoit] [autoit][/autoit] [autoit]

    _WinAPI_SetFilePointer($hFile, -2, $FILE_END)
    _WinAPI_ReadFile($hFile, DllStructGetPtr($tBuffer), 2, $nbytes)
    If BinaryToString(DllStructGetData($tBuffer, 1)) == @CRLF Then
    _WinAPI_SetFilePointer($hFile, -2, $FILE_END)
    _WinAPI_SetEndOfFile($hFile)
    $iRet = 1
    EndIf
    _WinAPI_CloseHandle($hFile)
    Return $iRet
    EndFunc ;==>_FileDeleteLastCRLF

    [/autoit]
  • Programmablauf beschleunigen, Datei Extraction

    • AspirinJunkie
    • 15. Februar 2011 um 08:01
    Zitat von JaneDoe
    [autoit]

    $bData = FileRead($hFile)

    [/autoit]

    Du liest die ganze Datei direkt in den Speicher obwohl du nur einen kleinen Teil der Datei brauchst?
    Sieh dir FileSetPos an und geh in kleineren Blöcken mit FileRead über deinen Bereich und schreib das ganze blockweise in deine neue Datei.
    So hast du nie mehr als die Blockgröße in deinem Speicher.

    Zitat von JaneDoe
    [autoit]

    For $r = 0 to UBound($split,1) - 1

    [/autoit]

    Wo kommt das her - was ist das?

  • Befehlsuche für Gesamt-Linien Anzahl

    • AspirinJunkie
    • 13. Februar 2011 um 21:59
    Zitat von autoBert

    Kannst du (vielleicht mit Bildern) erklären welche Schalter für diese Art der Suche gesetzt sein müssen?

    _IsDefault.au3 Der Inhalt kann nicht angezeigt werden, da er nicht mehr verfügbar ist.

    @CodaXYZ
    Das hat hier auch nichts mit Arroganz oder ähnlichem zu tun dass ich dich belehren will oder sowas.
    Die Hilfe-Datei ist das A und O bei der AutoIt-Programmierung und ohne sie wird man mit AutoIt nicht sehr weit kommen.
    Ich persönlich benötige sie immer - selbst wenn es nur ein 3-Zeilenskript ist.
    Man kann sich einfach nicht alle Befehle merken.

    Dateien

    Suche 1.png 172,68 kB – 0 Downloads Suche 2.png 33,82 kB – 0 Downloads
  • Befehlsuche für Gesamt-Linien Anzahl

    • AspirinJunkie
    • 13. Februar 2011 um 21:03

    In der deutschen Hilfedatei wird man mit englischen Begriffen sicher nicht sehr weit kommen.
    Eine Suche in der deutschen Hilfedatei (nicht in der Online-Hilfe) nach "Datei Zeilen" brachte mir direkt das Ergebnis.

  • Befehlsuche für Gesamt-Linien Anzahl

    • AspirinJunkie
    • 13. Februar 2011 um 20:43

    Tut mir leid aber wenn du diese simple Frage nicht mit einem Blick in die AutoIt-Hilfe selbst beantworten kannst brauchst du mit AutoIt nicht weiter zu machen.

  • [UDF] Virtual PC erkennung (Vmware, VirtualBox, VirtualPc und Qemu )

    • AspirinJunkie
    • 13. Februar 2011 um 13:31
    Zitat von Blume

    Man kann es sogar noch kürzen

    Das nennst du kürzen? ;) :

    Spoiler anzeigen
    [autoit]

    If _IsInVBox() Then
    MsgBox(64,"","Ich bin in einem Virtuellen Computer")
    Else
    MsgBox(64,"","Ich bin NICHT in einem Virtuellen Computer")
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Func _IsInVBox($strComputer = '.')
    Local $oWMI = ObjGet('winmgmts:\\' & $strComputer & '\root\cimv2')
    For $i In $oWMI.ExecQuery('SELECT Model FROM Win32_DiskDrive', 'WQL', 48)
    If StringRegExp($i.Model, "(VBOX|QEMU|VMWARE VIRTUAL|VIRTUAL HD)") Then Return True
    Next
    Return False
    EndFunc

    [/autoit]
  • Überprüfen von Werten eines Objekts

    • AspirinJunkie
    • 13. Februar 2011 um 13:08

    Würde dir lieber eine Alternative vorschlagen.
    Damit kannst du die existieren Property-Namen einer WMI-Klasse bekommen:

    Spoiler anzeigen
    [autoit]

    #include <Array.au3>
    Global $oWMI = ObjGet("winmgmts:\\localhost\")

    [/autoit] [autoit][/autoit] [autoit]

    $aProperties = WMIClassGetProperties($oWMI, "Win32_BIOS")
    If Not @error Then _ArrayDisplay($aProperties, "Eigenschaften von Win32_BIOS")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func WMIClassGetProperties(ByRef $oWMI, Const $sClassName)
    ; By AspirinJunkie
    Local $sRet = ""
    Local $oClass = $oWMI.Get($sClassName)
    If @error Then Return SetError(1, @error, "")

    [/autoit] [autoit][/autoit] [autoit]

    For $i In $oClass.Properties_()
    $sRet &= $i.Name & "|"
    Next

    [/autoit] [autoit][/autoit] [autoit]

    Return StringSplit(StringTrimRight($sRet, 1), "|", 2)
    EndFunc ;==>WMIClassGetProperties

    [/autoit]
  • Script schließen -> batch datei ausführen

    • AspirinJunkie
    • 12. Februar 2011 um 19:23
    Zitat von Raupi

    Sobald Test.exe auf deinem Desktop gefunden wird, wird sie gelöscht und kann somit nicht durch Test.exe ersetzt werden.


    Wird durch folgendes Codestück verhindert:

    Code
    IF /I %1 NEQ %QUELLDATEI% ( ... )
  • Gleichungen lösen

    • AspirinJunkie
    • 12. Februar 2011 um 14:18

    Numerisch lässt es sich ziemlich einfach in AutoIt lösen:

    Spoiler anzeigen
    [autoit]

    Global Const $FLT_EPSILON = _GET_FLT_EPSILON()

    [/autoit] [autoit][/autoit] [autoit]

    ; Definition der Funktionen
    Global $sF1 = "-4*x*(5+2*x)*(3*x-9)"
    Global $sF2 = "0"

    [/autoit] [autoit][/autoit] [autoit]

    ; Definition des Suchbereiches
    Global $iStart = -1000
    Global $iEnd = 1000
    Global $iStep = 1.1

    [/autoit] [autoit][/autoit] [autoit]

    ; Größer/Kleiner Vergleichskriterium
    Global $bSw = _Fx($sF1, $iStart) > _Fx($sF2, $iStart)

    [/autoit] [autoit][/autoit] [autoit]

    For $x = $iStart To $iEnd Step $iStep ; Gehe den Bereich grob ab
    If $bSw <> (_Fx($sF1, $x) > _Fx($sF2, $x)) Then ; Wenn Wechsel der Größer/Kleiner Beziehung dann muss Schnittpunkt dazwischen liegen
    $bSw = Not $bSw
    $dX_Schnitt = Schnittsuche($sF1, $sF2, $x - $iStep, $x) ; Starte die feine Schnittpunktsuche im Intervall
    $dY_Schnitt = (_Fx($sF1, $dX_Schnitt) + _Fx($sF2, $dX_Schnitt)) / 2 ;Y-Wert als Mittelwert beider Funktionswerte bestimmen
    MsgBox(0, "Schnittpunkt gefunden", "x = " & Round($dX_Schnitt,15) & @CRLF & "y = " & Round($dY_Schnitt,14))
    EndIf
    Next

    [/autoit] [autoit][/autoit] [autoit]

    Func _Fx(Const $sF, Const $dW)
    Return Number(Execute(StringReplace($sF, "x", "(" & $dW & ")")))
    EndFunc ;==>_Fx

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Bestimmt die Schnittpunkte 2er Funktionen in einem Intervall iterativ mit dem Regula Falsi Algorithmus
    ; Hinweis: Sollte noch ungültige Ergebnisse liefern wenn einer der Grenzen = dem Schnittpunkt
    Func Schnittsuche(Const $sF1, Const $sF2, $dA, $dB, $iMaxIt = 100)
    ;by AspirinJunkie
    Local $xA = $dA, $xB = $dB
    Local $Ya, $Yb, $x, $Yx
    Local $xOld = $dB

    [/autoit] [autoit][/autoit] [autoit]

    For $n = 1 To $iMaxIt
    $Ya = _Fx($sF1, $xA) - _Fx($sF2, $xA) ;Differenz der Funktionen da Regula Falsi nach Nullstellen sucht
    $Yb = _Fx($sF1, $xB) - _Fx($sF2, $xB)
    $x = $xA - ($Ya * ($xB - $xA)) / ($Yb - $Ya)
    $Yx = _Fx($sF1, $x) - _Fx($sF2, $x)

    [/autoit] [autoit][/autoit] [autoit]

    If Abs($x - $xOld) < (4 * $FLT_EPSILON) Or Abs($Yx) < (5 * $FLT_EPSILON) Then ; Wenn Differenz der Durchgänge unter einer gewissen Genauigkeit liegt abbrechen
    Return $x
    Else ;Festlegung der neuen grenzen für den neuen Durchlauf
    $xOld = $x
    If $Ya > $Yx Then
    $xA = $x
    Else
    $xB = $x
    EndIf
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Next
    Return SetError(1, $iMaxIt, $x)
    EndFunc ;==>Schnittsuche

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION#=================================================================================
    ; Name...........: _GET_FLT_EPSILON
    ; Description ...: Berechnet den binären Rundungsfehler und damit die Rechengenauigkeit
    ; Syntax.........: _GET_FLT_EPSILON
    ; Return values .: Epsilon
    ; Author ........: AspirinJunkie
    ;============================================================================================
    Func _GET_FLT_EPSILON()
    Local $x = 1
    Do
    $x /= 2
    Until 1 + $x <= 1
    Return $x
    EndFunc ;==>_GET_FLT_EPSILON

    [/autoit]
  • FileCopy mit Progressbar

    • AspirinJunkie
    • 12. Februar 2011 um 11:27
    Zitat von igillan

    Die Funktionen die ich bis jetzt gefunden habe nutzen "copy" bzw. "xcopy" im Hintergrund oder es lassen sich nur Verzeichnisse als Quelle angeben.


    Diese hier nicht: >>Klickmich<<

    Hinweis: Das Sleep auskommentieren um volle Geschwindigkeit zu bekommen und unter Umständen ein #RequireAdmin hinzu wenn entsprechende Verzeichnisse genommen werden.

  • Hilfe bei FAT32 in NTFS Umwandlungstool

    • AspirinJunkie
    • 11. Februar 2011 um 11:59

    Lass dir doch mal den Aufrufstring ausgeben dann solltest du schnell sehen wo das Problem liegt:

    [autoit]

    msgbox(0,"",@ComSpec & "/c convert " & $Laufwerk & " /FS:NTFS")

    [/autoit]
  • Verbesserungsvorschläge? zu oft StringRegExpReplace

    • AspirinJunkie
    • 11. Februar 2011 um 11:54

    Sowas?:

    Spoiler anzeigen
    [autoit]

    Global $aRepl[6][2] = [["u00253A",":"], ["u00252F","/"], ["u00253F","?"], ["u00253D","="], ["u002526","&"], ["\\",""]]

    [/autoit] [autoit][/autoit] [autoit]

    $String = "http\u00253A\u00252F\u00252Fvideo.ak.fbcdn.net\u00252Fcfs-ak-ash1\u00252F12345\u00252F123\u00252F12345678901234567_12345.mp4\u00253Foh\u00253D123456789012345678901234567890123\u002526oe\u00253D12345678\u002526__gda__\u00253D1234567890_12345678901234567890123456789012"

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 0 To UBound($aRepl) - 1
    $String = StringReplace($String, $aRepl[$i][0], $aRepl[$i][1])
    Next

    [/autoit] [autoit][/autoit] [autoit]

    ConsoleWrite($String & @CRLF)

    [/autoit]

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™