1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Maus kreisen lassen

    • AspirinJunkie
    • 30. Dezember 2010 um 14:56

    Hatten wir hier schonmal und da wollte ich meine Lösung von damals auch nochmal anbringen (prinzipiell nicht groß anders als bei UEZ):

    Spoiler anzeigen
    [autoit]

    _MouseCircle(200, 1)

    [/autoit] [autoit][/autoit] [autoit]

    Func _MouseCircle($Radius, $Speed = 10)
    Local Const $M = MouseGetPos(), $Pi = ACos(-1)
    Local $Phi, $X, $Y

    [/autoit] [autoit][/autoit] [autoit]

    MouseMove($M[0] + $Radius, $M[1], 0)

    [/autoit] [autoit][/autoit] [autoit]

    For $Phi = 0 To 2 * $Pi Step 0.04
    $X = $M[0] + $Radius * Cos($Phi)
    $Y = $M[1] + $Radius * Sin($Phi)
    MouseMove($X, $Y, $Speed)
    Next
    EndFunc

    [/autoit]

    @Redclaw
    Mach mal bitte.
    Das hast du schon gerade in dem anderen Thread angebracht.
    Würde mich interessieren wie das dann am Ende aussieht.

  • Schittpunkt von Kreis und Grade

    • AspirinJunkie
    • 30. Dezember 2010 um 13:59

    Wenn also Kreismittelpunkt = Geradenpunkt = (0;600) und $EndPunkt = 2. Geradenpunkt dann sind die Schnittpunkte aus einer Verhältnisgleichung zu berechnnen:

    Verhältnisrechnung
    [autoit]

    ;Geradenpunkt
    $EndX = 300
    $EndY = 300

    [/autoit] [autoit][/autoit] [autoit]

    ;Kreis
    $Radius = 200
    $Mx = 0
    $My = 600

    [/autoit] [autoit][/autoit] [autoit]

    ; Distanz zwischen Mitelpunkt und Endpunkt berechnen
    $sDist = Sqrt(($Mx - $EndX) ^ 2 + ($My - $EndY) ^ 2)

    [/autoit] [autoit][/autoit] [autoit]

    ; Koordinatendifferenz zum Mittelpunkt berechnen durch Verhältnis zwischen Distanz und Radius
    $dX = $Radius * (($EndX - $Mx) / $sDist)
    $dY = $Radius * (($EndY - $My) / $sDist)

    [/autoit] [autoit][/autoit] [autoit]

    ; Neue Koordinaten durch hinzuaddieren der Mittelpunktskoordinaten berechnen
    $SX1 = $Mx + $dX
    $SY1 = $My + $dY
    $SX2 = $Mx - $dX
    $SY2 = $My - $dY

    [/autoit] [autoit][/autoit] [autoit]

    ConsoleWrite("X1: " & $SX1 & @TAB & "Y1: " & $SY1 & @CRLF & "X2: " & $SX2 & @TAB & "Y2: " & $SY2 & @CRLF)

    [/autoit]

    Andy
    Nun können wir doch sicher auch unsere allgemeinen Lösungen posten - oder? ;) :

    Meine allgemeine Berechnung der Schnittpunkte
    [autoit]

    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    #region Sekantenfall
    ; Kreisparameter:
    Const $XM = 5
    Const $YM = 1
    Const $R = 3

    [/autoit] [autoit][/autoit] [autoit]

    ; Geradenparameter:
    Const $m = 0.75
    Const $n = 1
    #endregion Sekantenfall

    [/autoit] [autoit][/autoit] [autoit]

    $aT = Schnitt_Kreis_Gerade($XM, $YM, $R, $m, $n)
    MsgBox(0, "", "Es existiert " & $aT[0] & " Schnittpunkt[e].")
    _ArrayDisplay($aT)

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ======================================================================================
    ; Name ..........: Schnitt_Kreis_Gerade()
    ; Description ...: Gibt ein Array mit der Anzahl und den Koordinaten der Schnittpunkte zwischen Kreis und Gerade zurück
    ; Syntax ........: Schnitt_Kreis_Gerade(Const $XM, Const $YM, Const $R, Const $m, Const $n [, Const $FLT_EPSILON])
    ; Parameters ....: $XM - X-Koordinate Kreismittelpunkt
    ; $YM - Y-Koordinate Kreismittelpunkt
    ; $R - Radius Kreis
    ; $m - Anstieg der Gerade
    ; $n - Schnittpunkt der Y-Achse mit der Geraden
    ; $FLT_EPSILON - optionale Toleranz um eventuelle binäre Rundungsfehler auszugleichen damit Sekantenfall erreicht werden kann
    ; Return values .: Success: Array[0]=Anzahl Schnittpunkte, dann [Xs1,Ys1 [,Xs2,Ys2]]
    ; Failure: Ich mache keine Fehler
    ; Author ........: AspirinJunkie
    ; Related .......: Distance_Point_Line
    ; Example .......: Yes
    ; #include <Array.au3>
    ; ; Kreisparameter:
    ; Const $XM = 4
    ; Const $YM = 3
    ; Const $R = 5
    ; ; Geradenparameter:
    ; Const $m = -1.3
    ; Const $n = 10
    ; $aT = Schnitt_Kreis_Gerade($XM, $YM, $R, $m, $n)
    ; _ArrayDisplay($aT)
    ; =================================================================================================
    Func Schnitt_Kreis_Gerade(Const $XM, Const $YM, Const $R, Const $m, Const $n, Const $FLT_EPSILON = 1e-16)
    Local Const $iD = Distance_Point_Line($XM, $YM, $m, $n) ; Abstand Mittelpunkt-Gerade

    [/autoit] [autoit][/autoit] [autoit]

    If Abs($iD - $R) <= $FLT_EPSILON Then ; Tangente: 1 Schnittpunkt da Gerade Kreis nur berührt
    Local Const $x = (Sqrt(($R ^ 2 - $XM ^ 2) * $m ^ 2 - 2 * $XM * (-$YM + $n) * $m + ($n - $YM + $R) * (-$n + $YM + $R)) + ($YM - $n) * $m + $XM) / (1 + $m ^ 2)

    [/autoit] [autoit][/autoit] [autoit]

    Local $aRet[3] = [1, _
    $x, $m * $x + $n]

    [/autoit] [autoit][/autoit] [autoit]

    Return $aRet

    [/autoit] [autoit][/autoit] [autoit]

    ElseIf $iD < $R Then ; Sekante: 2 Schnittpunkte da Gerade durch Kreis
    Local Const $fTemp1 = Sqrt(($R ^ 2 - $XM ^ 2) * $m ^ 2 - 2 * $XM * (-$YM + $n) * $m + ($n - $YM + $R) * (-$n + $YM + $R))
    Local Const $fTemp2 = ($YM - $n) * $m + $XM

    [/autoit] [autoit][/autoit] [autoit]

    Local Const $x1 = ($fTemp1 + $fTemp2) / (1 + $m ^ 2)
    Local Const $x2 = (-$fTemp1 + $fTemp2) / (1 + $m ^ 2)

    [/autoit] [autoit][/autoit] [autoit]

    Local $aRet[5] = [2, _
    $x1, $m * $x1 + $n, _
    $x2, $m * $x2 + $n]

    [/autoit] [autoit][/autoit] [autoit]

    Return $aRet

    [/autoit] [autoit][/autoit] [autoit]

    Else ; Passante: Kein Schnittpunkt da Gerade an Kreis vorbei geht
    Local $aRet[1] = [0]
    Return $aRet
    EndIf
    EndFunc ;==>Schnitt_Kreis_Gerade

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ======================================================================================
    ; Name ..........: Distance_Point_Line()
    ; Description ...: Gibt den Abstand zwischen einem Punkt und einer Geraden an
    ; Syntax ........: Distance_Point_Line(Const $Xp, Const $Yp, Const $m, Const $n)
    ; Parameters ....: $Xp - X-Koordinate Punkt
    ; $Yp - Y-Koordinate Punkt
    ; $m - Anstieg der Gerade
    ; $n - Schnittpunkt der Y-Achse mit der Geraden
    ; Return values .: Success: Gibt Abstand zurück
    ; Failure: ?
    ; Author ........: AspirinJunkie
    ; =================================================================================================
    Func Distance_Point_Line(Const $Xp, Const $Yp, Const $m, Const $n)
    Return Abs(($Yp - $m * $Xp - $n) / Sqrt(1 + $m ^ 2))
    EndFunc ;==>Distance_Point_Line

    [/autoit]
  • Schittpunkt von Kreis und Grade

    • AspirinJunkie
    • 30. Dezember 2010 um 12:24
    • Was ist $EndPunkt? - der Mittelpunkt des Kreises?
    • Falls nicht - wo ist der Mittelpunkt?
    • Wo sind die Parameter für die Gerade? (Anstieg/Schnittpunkt mit Y-Achse etc.)


    Es sind defnitiv zu wenig Parameter um einen Kreis UND eine Gerade zu beschreiben.

  • Komplexeres? schnelles durchsuchen größerer Arrays

    • AspirinJunkie
    • 30. Dezember 2010 um 09:34
    Zitat von Großvater

    Anmerkung 1: Die Funktion StringInStr() scheint nicht optimal umgesetzt zu sein.

    Warum?
    Hast du auch mal beim CaseSense-Parameter eine 2 eingetragen?
    Ansonsten sagen Einzelzeitmessungen nicht so viel aus da sie noch stark streuen.
    Besser wäre es mehrere Durchgänge zu machen - dann sind die Ergebnisse auch aufschlussreicher:

    Spoiler anzeigen
    [autoit]

    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $N = 100

    [/autoit] [autoit][/autoit] [autoit]

    $String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
    $aString = StringSplit($String, "", 2)
    $Len = StringLen($String)
    $sString = ""

    [/autoit] [autoit][/autoit] [autoit]

    Dim $aArray[$Len * $Len * $Len]
    $Index = 0
    For $I = 0 To $Len - 1
    For $J = 0 To $Len - 1
    For $K = 0 To $Len - 1
    $aArray[$Index] = $aString[$I] & $aString[$J] & $aString[$K]
    $Index += 1
    $sString &= $aString[$I] & $aString[$J] & $aString[$K] & @CRLF
    Next
    Next
    Next

    [/autoit] [autoit][/autoit] [autoit]

    Dim $aFind[3] = ["ABC", "MMM", "ZAB"]

    [/autoit] [autoit][/autoit] [autoit]

    For $A = 0 To 2
    ConsoleWrite(" >>>>>>>>>> Lauf " & ($A + 1) & " - gesucht wird " & $aFind[$A] & @CRLF)
    $Start = TimerInit()
    For $I = 1 To $N
    $Index = _ArraySearch($aArray, $aFind[$A])
    Next
    $Dauer = TimerDiff($Start) / $N
    ConsoleWrite(" _ArraySearch: " & $Dauer & ' ' & $aArray[$Index] & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    $Start = TimerInit()
    For $I = 1 To $N
    $Index = _ArrayBinarySearch($aArray, $aFind[$A])
    Next
    $Dauer = TimerDiff($Start) / $N
    ConsoleWrite(" _ArrayBinarySearch: " & $Dauer & ' ' & $aArray[$Index] & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    $Start = TimerInit()
    For $I = 1 To $N
    $Index = StringInStr(@CRLF & $sString, @CRLF & $aFind[$A] & @CRLF, 2)
    Next
    $Dauer = TimerDiff($Start) / $N
    ConsoleWrite(" StringInStr: " & $Dauer & ' ' & StringMid($sString, $Index, StringLen($aFind[$A])) & @CRLF)
    Next

    [/autoit]
  • zahl 08 darf nicht als 8 ausgegeben werden.... wie geht das?

    • AspirinJunkie
    • 29. Dezember 2010 um 12:14

    Ach na klar - nicht bloß die Formatierung war falsch sondern auch die Parameter... :whistling:

  • zahl 08 darf nicht als 8 ausgegeben werden.... wie geht das?

    • AspirinJunkie
    • 29. Dezember 2010 um 11:57

    Vollkommen richtig - ist natürlich falsch so wie es bei mir steht (war noch von vorhin wo nur der Nachkommateil dastand)
    Umso mehr macht es mir Gedanken warum damit dennoch die richtige Ausgabe erscheint... :huh:

  • zahl 08 darf nicht als 8 ausgegeben werden.... wie geht das?

    • AspirinJunkie
    • 29. Dezember 2010 um 11:19

    Klar ist da was mit raten - starten kann ich dein Skript nicht - es kommt ne Fehlermeldung.
    Jetzt wird es aber endlich mal bisschen konkreter.
    Willst du 1 Cent abziehen dann mal als Minimalbeispiel dein Minimalbeispiel angepasst:

    1 Cent abziehen - kommentiertes Minimalbeispiel
    [autoit]

    $pleft2= "EUR "
    $pright2="</strong>"

    [/autoit] [autoit][/autoit] [autoit]

    ; Zahl auslesen
    $source2 = _StringBetween($sText, $pleft2,$pright2)

    [/autoit] [autoit][/autoit] [autoit]

    ; Komma durch Punkt ersetzen
    $source2[0] = StringReplace($source2[0], ",", ".")

    [/autoit] [autoit][/autoit] [autoit]

    ; String in Zahl umwandeln
    $source2[0] = Number($source2[0])

    [/autoit] [autoit][/autoit] [autoit]

    ; 1 cent abziehen:
    $source2[0] -= 0.01

    [/autoit] [autoit][/autoit] [autoit]

    ; Zahl mit 2 Nachkommastellen ausgeben
    MsgBox(0,"", StringFormat($source2[0], "%02d", $source2[0]))

    [/autoit]


    Wie du nun die 2 Preise vergleichst überlasse ich erstmal dir.

  • zahl 08 darf nicht als 8 ausgegeben werden.... wie geht das?

    • AspirinJunkie
    • 29. Dezember 2010 um 10:41

    Sorry aber das ist kein funktionierendes Beispiel.
    Und was du machen willst ist mir auch dadurch nicht klar.
    Füll einfach die $sText mit einem passenden Beispielstring und sage was du bezwecken willst aber lass uns bitte nicht durch dieses Projekt durchraten.

  • zahl 08 darf nicht als 8 ausgegeben werden.... wie geht das?

    • AspirinJunkie
    • 29. Dezember 2010 um 10:21

    Kannst du noch bitte mal ein Minimalbeispiel mit einer entsprechend gefüllten $sText-Variablen mit eintragen?
    Und dann sagen was gemacht werden soll und was am Ende raus kommen soll?
    Bevor wir uns daran machen hier dieses Skript anzupassen könnte ich mir vorstellen das wir direkt mit den ganzen Zahlen rechnen können.
    Spontan hätte ich gesagt das du Probleme hast weil Number mit "," getrennten Werten nur die Vorkomma-Werte übernimmt.
    Das hängt einfach damit zusammen das im Englischen der Punkt als Trenner genommen wird und man da einfach nur mit einem StringReplace das Komma austauschen muss.
    Vielleicht denk ich da aber falsch - in jedem Fall wäre es schön wenn du ein funktionierendes Minimalbeispiel postest damit wir wissen wozu (wichtig!).

    Edit: Na da hat Bernd dir ja dafür schon ein Beispiel gemacht :)
    Bernd
    kürzer :P :

    [autoit]

    $fNK = Round(Mod($szFloat,1), 2)

    [/autoit]
  • Schittpunkt von Kreis und Grade

    • AspirinJunkie
    • 29. Dezember 2010 um 10:03

    Hilfe zur Selbsthilfe ;)
    Nach Bernds berechtigter Anfrage kam bisher nix und solange will ich da nun auch noch warten da ich sonst halt immer zu schnell Code raushaue statt dem User wirklich zu helfen in dem er es nachher selbst erstellen kann anstatt fertige Kost zu kauen.

  • zahl 08 darf nicht als 8 ausgegeben werden.... wie geht das?

    • AspirinJunkie
    • 29. Dezember 2010 um 09:59

    Wenn die Zahlen immer 2-stellig sind dann so:

    Spoiler anzeigen
    [autoit]

    MsgBox(0,"",StringFormat("%02d", 8))

    [/autoit]


    Ansonsten darfst du die ausgelesenen Zahlen welche als String vorliegen nicht in Zahlen umwandeln da Zahlenformate eben keine führende Null zulassen.
    Oder du musst dir halt per StringLen() irgendwo mitspeichern wieviel Stellen die Zahl hatte.

  • Schittpunkt von Kreis und Grade

    • AspirinJunkie
    • 28. Dezember 2010 um 22:44

    Oh danke - hab ich überlesen dann ist richtig so - mein Fehler.
    Wenn es aber tatsächlich durch den Mittelpunkt des Kreises geht braucht man aber nicht so umständlich gleichsetzen sondern hat dort einen Spezialfall den man mit dem Satz des Pythagoras lösen kann (Hypothenuse = Radius in diesem Fall).
    Einfach mal aufzeichnen und 2 Dreieck reinmalen dann sieht man wie man es einfacher lösen kann.

  • Schittpunkt von Kreis und Grade

    • AspirinJunkie
    • 28. Dezember 2010 um 21:43
    Zitat von Andy

    ergo 2 Ergebnisse. Eigentlich logisch, die Gerade schneidet den Kreis in 2 Punkten


    Gerade tangiert den Kreis - 1 Schnittpunkt.
    Gerade trifft den Kreis gar nicht - 0 Schnittpunkte.
    Die Fälle müssen halt mit beachtet werden.

  • Text aus Homepage extrahieren

    • AspirinJunkie
    • 28. Dezember 2010 um 14:45

    Das ist kein Fehler sondern sagt lediglich mit welchen Parametern AutoIt aufgerufen wurde.
    In dem Fall wo der ErrorLog gespeichert werden soll.
    Sieht so aus als ob er Probleme beim Auslesen des Quelltextes hat.
    Probier mal nochmal das:

    Spoiler anzeigen
    [autoit]

    #include <INet.au3>
    #include <Array.au3>
    #RequireAdmin

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $s_URL = "http://www.oddsoddsodds.com/goto/odds/s1/g965326/m1/d0/"
    Global $s_Source, $a_RegExp

    [/autoit] [autoit][/autoit] [autoit]

    HttpSetUserAgent("WasAnderes")

    [/autoit] [autoit][/autoit] [autoit]

    ; Quelltext auslesen:
    $s_Source = _INetGetSource($s_URL)
    If @error Then
    MsgBox(0,"Fehler", "Konnte Quelltext nicht lesen!")
    Exit
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ; Nur den Inhalt der gelben Spalte komplett auslesen:
    $a_RegExp = StringRegExp($s_Source, '<tr.+?style="background-color: #FFF700;"(.+?)</tr>', 3)

    [/autoit] [autoit][/autoit] [autoit]

    ; Die Gleitkommazahlen aus diesem Teil extrahieren (!: es kommen Punkt und Komma als Trenner vor):
    If Not @error Then $a_RegExp = StringRegExp($a_RegExp[0], "(\d+[\.,]\d+)", 3)

    [/autoit] [autoit][/autoit] [autoit]

    ; Ergebnis anzeigen:
    _ArrayDisplay($a_RegExp)

    [/autoit]


    Das @RequireAdmin ist dazugekommen und der HTTP UserAgent wurde geändert da manche Webseiten AutoIt blocken (was aber hier nicht wahrscheinlich ist da es bei uns ja auch so klappt).

  • Text aus Homepage extrahieren

    • AspirinJunkie
    • 28. Dezember 2010 um 14:35

    Nein.
    Ich lasse es selbst auf Win 7 laufen.
    Poste mal die gesamte Fehlermeldung.
    So sagt einem das gar nix.

  • Text aus Homepage extrahieren

    • AspirinJunkie
    • 28. Dezember 2010 um 14:12

    Anders rangegangen aber vielleicht etwas verständlicher:

    Zahlen rausfiltern
    [autoit]

    #include <INet.au3>
    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $s_URL = "http://www.oddsoddsodds.com/goto/odds/s1/g965326/m1/d0/"
    Global $s_Source, $a_RegExp

    [/autoit] [autoit][/autoit] [autoit]

    ; Quelltext auslesen:
    $s_Source = _INetGetSource($s_URL)
    If @error Then Exit

    [/autoit] [autoit][/autoit] [autoit]

    ; Nur den Inhalt der gelben Spalte komplett auslesen:
    $a_RegExp = StringRegExp($s_Source, '<tr.+?style="background-color: #FFF700;"(.+?)</tr>', 3)

    [/autoit] [autoit][/autoit] [autoit]

    ; Die Gleitkommazahlen aus diesem Teil extrahieren (!: es kommen Punkt und Komma als Trenner vor):
    If Not @error Then $a_RegExp = StringRegExp($a_RegExp[0], "(\d+[\.,]\d+)", 3)

    [/autoit] [autoit][/autoit] [autoit]

    ; Ergebnis anzeigen:
    _ArrayDisplay($a_RegExp)

    [/autoit]
  • _FTP_FileListRekursiv()

    • AspirinJunkie
    • 28. Dezember 2010 um 12:17

    Hab das mit der Dateigröße überlesen - daher das ganze nochmal angepasst und übersichtlicher in der Ausgabe gemacht:

    Spoiler anzeigen
    [autoit]

    #include <ftpEx.au3>
    #include <array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $server = 'ftp.csx.cam.ac.uk'
    $username = ''
    $pass = ''

    [/autoit] [autoit][/autoit] [autoit]

    $hFTP = _FTP_Open('FTP_open')
    $hFTPCon = _FTP_Connect($hFTP, $server, $username, $pass)

    [/autoit] [autoit][/autoit] [autoit]

    $aFileList = _FTP_FileList($hFTPCon, "pub/software/antivirus/datfiles_old")
    _ArrayDisplay($aFileList)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ======================================================================================
    ; Name ..........: _FTP_FileList()
    ; Description ...: Returns a List of all Files include SubDirs of a FTP-Path with Size
    ; Syntax ........: _FTP_FileList(ByRef $hConn[, $sPath = ""])
    ; Parameters ....: ByRef $hConn - as returned by _FTP_Connect().
    ; $sPath - [optional] path to be used when searching the files (default:"")
    ; Return values .: Success: A 2D Array with [Path, FileName,FileSize], $Array[0,0] = Number of Elements
    ; Failure: Sets @error and $Array[0,0] = -1
    ; Author ........: AspirinJunkie
    ; Modified ......: 28.12.2010
    ; Remarks .......: Needs .Net for System.Collections.Queue
    ; Example .......: Yes
    ; #include <ftpEx.au3>
    ; #include <array.au3>
    ; $server = 'ftp.csx.cam.ac.uk'
    ; $username = ''
    ; $pass = ''
    ; $hFTP = _FTP_Open('FTP_open')
    ; $hFTPCon = _FTP_Connect($hFTP, $server, $username, $pass)
    ; $aFileList = _FTP_FileList($hFTPCon, "pub/software/antivirus/datfiles_old")
    ; _ArrayDisplay($aFileList)
    ; =================================================================================================
    Func _FTP_FileList(ByRef $hConn, $sPath = "")
    Local $cSQueue = ObjCreate("System.Collections.Queue")
    Local $oRetDict = ObjCreate("Scripting.Dictionary")
    Local $hFFFF, $aNext, $sCurrentPath
    If StringRight($sPath, 1) = "/" Then $sPath = StringTrimRight($sPath, 1)
    $cSQueue.Enqueue($sPath)

    [/autoit] [autoit][/autoit] [autoit]

    While $cSQueue.Count > 0
    $sCurrentPath = $cSQueue.Dequeue

    [/autoit] [autoit][/autoit] [autoit]

    $aNext = _FTP_FindFileFirst($hConn, $sCurrentPath, $hFFFF)
    If @error Then
    If $oRetDict.Count > 0 Then ContinueLoop
    Local $Ret[1][3] = [[-1]]
    Return SetError(1, 0, $Ret)
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    If BitAND($aNext[1], 16) Then
    $cSQueue.Enqueue($sCurrentPath & '/' & $aNext[10])
    $oRetDict.Add($sCurrentPath & '\\' & $aNext[10] & '/' & "\\0", 0)
    Else
    $oRetDict.Add($sCurrentPath & '\\' & $aNext[10] & "\\" & BitOR(BitShift($aNext[8], -8), $aNext[9]), 0)
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Do
    $aNext = _FTP_FindFileNext($hFFFF)
    If @error Then ExitLoop
    If BitAND($aNext[1], 16) Then
    $cSQueue.Enqueue($sCurrentPath & '/' & $aNext[10])
    $oRetDict.Add($sCurrentPath & '\\' & $aNext[10] & '/' & "\\0", 0)
    Else
    $oRetDict.Add($sCurrentPath & '\\' & $aNext[10] & "\\" & BitOR(BitShift($aNext[8], -8), $aNext[9]), 0)
    EndIf
    Until 0
    _FTP_FindFileClose($hFFFF)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    If $oRetDict.Count > 0 Then
    Local $aRet[$oRetDict.Count + 1][3] = [[$oRetDict.Count, "Dateiname", "Dateigröße [Bytes]"]]
    Local $iC = 1, $aT
    For $i In $oRetDict.Keys
    $aT = StringSplit($i, "\\", 3)
    $aRet[$iC][0] = $aT[0]
    $aRet[$iC][1] = $aT[1]
    $aRet[$iC][2] = Number($aT[2])
    $iC += 1
    Next
    Return $aRet
    Else
    Local $Ret[1][3] = [[-1]]
    Return SetError(2, 0, $Ret)
    EndIf
    EndFunc ;==>_FTP_FileList

    [/autoit]

    @ChrisAttack
    So wie du es jetzt mit dem globalen Array machst kann man die Funktion nur 1x in einem Skript aufrufen da sonst die Daten einfach immer wieder nur an das globale Array angehängt werden.

  • _FTP_FileListRekursiv()

    • AspirinJunkie
    • 28. Dezember 2010 um 00:11

    auch wenn alles schon vorbei und geklärt ist - der vollständigkeit halber meine Lösung an der ich gerade gesessen habe:

    Spoiler anzeigen
    [autoit]

    #include <ftpEx.au3>
    #include <array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $server = 'ftp.csx.cam.ac.uk'
    $username = ''
    $pass = ''

    [/autoit] [autoit][/autoit] [autoit]

    $hFTP = _FTP_Open('FTP_open')
    $hFTPCon = _FTP_Connect($hFTP, $server, $username, $pass)

    [/autoit] [autoit][/autoit] [autoit]

    $aFileList = _FTP_FileList($hFTPCon, "pub/software/antivirus/")
    _ArrayDisplay($aFileList)

    [/autoit] [autoit][/autoit] [autoit]

    Func _FTP_FileList(Const $hConn, $sPath = "")
    ;by AspirinJunkie
    Local $cSQueue = ObjCreate("System.Collections.Queue")
    Local $oRetDict = ObjCreate("Scripting.Dictionary")
    Local $hFFFF, $aNext, $sCurrentPath

    [/autoit] [autoit][/autoit] [autoit]

    If StringRight($sPath, 1) = "/" Then $sPath = StringTrimRight($sPath, 1)
    $cSQueue.Enqueue($sPath)

    [/autoit] [autoit][/autoit] [autoit]

    While $cSQueue.Count > 0
    $sCurrentPath = $cSQueue.Dequeue

    [/autoit] [autoit][/autoit] [autoit]

    $aNext = _FTP_FindFileFirst($hConn, $sCurrentPath, $hFFFF)
    If @error Then
    If $oRetDict.Count > 0 Then ContinueLoop
    Local $Ret[1] = [-1]
    Return SetError(1, 0, $Ret)
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    If BitAND($aNext[1], 16) Then $cSQueue.Enqueue($sCurrentPath & '/' & $aNext[10])
    $oRetDict.Add($sCurrentPath & '/' & $aNext[10], 0)

    [/autoit] [autoit][/autoit] [autoit]

    Do
    $aNext = _FTP_FindFileNext($hFFFF)
    If @error Then ExitLoop
    If BitAND($aNext[1], 16) Then $cSQueue.Enqueue($sCurrentPath & '/' & $aNext[10])
    $oRetDict.Add($sCurrentPath & '/' & $aNext[10], 0)
    Until 0
    _FTP_FindFileClose($hFFFF)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    If $oRetDict.Count > 0 Then
    Return $oRetDict.Keys
    Else
    Local $Ret[1] = [0]
    Return SetError(2, 0, $Ret)
    EndIf
    EndFunc ;==>_FTP_FileListRekursiv

    [/autoit]
  • Problem nur bei kompiliertem Skript - Fehler in den Includes?

    • AspirinJunkie
    • 27. Dezember 2010 um 15:11

    Bis auf einen Syntax-Fehler in Zeile 46 (was auch logisch ist - es fehlt die 4) läuft es bei mir auch.
    Mir ist zwar nicht klar was das Skript macht (beim groben überfliegen sah ich nur das an der Prozesspriorität aufgrund der RAM-Auslastung rumgespielt wird (?!?).
    Ansonsten sind mir ein paar Sachen aufgefallen:

    • Includes welche gar nicht benötigt werden
    • Permanent wird vom AutoItSkript selber der Name mit ProcessgetName() (statt @AutoItExe?) ausgelesen und dann mit ProcessSetPriority() die Priorität gesetzt. Warum nicht nur einmal am Anfang?
    • Die _GetRam-Funktion ist vollkommen ineffektiv wenn sie wirklich permanent aufgerufen werden soll. WMI ist sowieso nicht sehr performant aber bei jedem Aufruf das WMI-Objekt neu zu erstellen ist nicht sehr effektiv. Lieber das Objekt per Static definieren. Ansonsten lieber gleich die komplette Funktion durch folgende ersetzen:
    Spoiler anzeigen
    [autoit]

    Func _GetRam($iPID)
    $iPID = ProcessExists($iPID)
    If $iPID = 0 Then Return SetError(1,0,-1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $aStats = ProcessGetStats($iPID)
    Return $aStats[0] / 1024
    EndFunc

    [/autoit]
  • Array anstatt Zahl mit Wort ($array[Wort] = "Test")

    • AspirinJunkie
    • 27. Dezember 2010 um 12:46

    Komfortabler wäre sicher das Dictionary-Objekt zu verwenden.
    Hier mal ein kleines Beispiel zur Verwendung:

    Spoiler anzeigen
    [autoit]

    ;//// Dictionary Erstellen ///////////
    $oDict = ObjCreate("Scripting.Dictionary")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;//// Einträge hinzufügen ///////////
    $oDict.add ("Berlin", 3395189)
    $oDict.add ("Hamburg", 1743627)
    $oDict.add ("München", 1259677)
    $oDict.add ("Köln", 983347)
    $oDict.add ("Dresden", 517052)
    ;Beispiel hier: Einwohnerzahl wird der jeweiligen Stadt zugeordnet.

    [/autoit] [autoit][/autoit] [autoit]

    ;//// Anzahl der Elemente bestimmen ///////////
    MsgBox(0,"Anzahl Elemente in Dictionary", $oDict.Count)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;//// Überprüft ob ein Element vorhanden ist ///////////
    If $oDict.Exists ("Bonn") Then MsgBox(0, "", "Bonn ist eingetragen") ;Bonn ist im Bsp. nicht enthalten

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;//// Löscht ein Element aus dem Dictionary ///////////
    $oDict.remove ("München")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;//// Elemente aufrufen ///////////
    ConsoleWrite("Einwohner(Berlin): " & $oDict("Berlin") & @CRLF)
    ConsoleWrite("Einwohner(Dresden): " & $oDict("Dresden") & @CRLF & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    ;//// alle Schlüssel durchgehen ///////////
    For $sKey in $oDict.Keys
    ConsoleWrite("Einwohner(" & $sKey & "): " & $oDict($sKey) & @CRLF)
    Next
    ;/// Alle Werte statt Schlüssel erreicht man mit $oDict.Items ////

    [/autoit] [autoit][/autoit] [autoit]

    ;//// Leert das Dictionary ///////////
    $oDict.RemoveAll

    [/autoit]

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™